Object  - AS3

Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto. Se un oggetto è un'istanza di una classe, la proprietà constructor contiene un riferimento all'oggetto classe. Se un oggetto viene creato con una funzione di costruzione, la proprietà constructor contiene un riferimento alla funzione di costruzione. Non confondere le funzioni di costruzione con i metodi di costruzione di una classe. Una funzione di costruzione è un oggetto Function utilizzato per creare oggetti ed è alternativo all'utilizzo della parola chiave class per la definizione delle classi.

Se utilizzate la parola chiave class per definire una classe, all'oggetto prototipo della classe viene assegnata una proprietà di nome constructor che contiene un riferimento all'oggetto classe. Un'istanza della classe eredita questa proprietà dall'oggetto prototipo. Ad esempio, il codice seguente crea una nuova classe, A, e un'istanza di classe di nome myA:

     dynamic class A {}
     trace(A.prototype.constructor);      // [class A]
     trace(A.prototype.constructor == A); // true
     var myA:A = new A();
     trace(myA.constructor == A);         // true

Gli utenti più esperti possono decidere di utilizzare la parola chiave function anziché la parola chiave class per definire un oggetto Function utilizzabile come modello per la creazione degli oggetti. Una funzione di questo tipo viene definita funzione di costruzione perché può essere utilizzata in combinazione con l'operatore new per creare gli oggetti. Se utilizzate la parola chiave function per creare una funzione di costruzione, all'oggetto prototipo della classe viene assegnata una proprietà di nome constructor che contiene un riferimento alla funzione di costruzione. Se quindi utilizzate la funzione di costruzione per creare un oggetto, l'oggetto eredita la proprietà constructor dall'oggetto prototipo della funzione di costruzione. Ad esempio, il codice seguente crea una nuova funzione di costruzione, f, e un oggetto di nome myF:

     function f() {}
     trace(f.prototype.constructor);      // function Function() {}
     trace(f.prototype.constructor == f); // true
     var myF = new f();
     trace(myF.constructor == f);         // true

Nota: la proprietà constructor è scrivibile, cioè il codice utente può modificare il valore con un'istruzione di assegnazione. Non è consigliabile modificare il valore della proprietà constructor, tuttavia se scrivete del codice che dipende dal valore della proprietà constructor, assicuratevi che il valore non venga reimpostato. Il valore può essere modificato solo quando si accede alla proprietà attraverso l'oggetto prototipo (ad esempio, className.prototype.constructor).

Se accedete alla proprietà constructor e compilate in modalità rigorosa, viene generato un errore in fase di compilazione perché la proprietà constructor dipende dall'oggetto protoype, che è un'entità della fase runtime. Se utilizzate la modalità standard oppure se la descrizione della classe specifica "dynamic", il codice viene eseguito senza errori.

Elementi API correlati

Un riferimento all'oggetto prototipo di un oggetto classe o funzione. La proprietà prototype viene creata automaticamente e associata a qualsiasi oggetto classe o funzione creato. Questa proprietà è di tipo statico ed è specifica della classe o della funzione creata. Se, ad esempio, create una classe, il valore della proprietà prototype viene condiviso da tutte le istanze della classe ed è accessibile solo come proprietà della classe. Le istanze della classe non possono accedere direttamente alla proprietà prototype.

L'oggetto prototipo di una classe è un'istanza speciale di tale classe che fornisce un meccanismo per condividere lo stato tra tutte le istanze di una classe. In fase di runtime, quando una proprietà non viene trovata in un'istanza di classe, la proprietà viene cercata nel delegato, cioè nell'oggetto prototipo della classe. Se l'oggetto prototipo non contiene la proprietà, il processo continua con la ricerca del delegato dell'oggetto prototipo in livelli sempre più elevati della gerarchia fino a quando il runtime Flash non trova la proprietà.

Nota: in ActionScript 3.0, l'ereditarietà di prototipo non è il meccanismo di ereditarietà principale. L'ereditarietà di classe, che comanda l'ereditarietà delle proprietà fisse nelle definizioni di classe, è il meccanismo di ereditarietà principale in ActionScript 3.0.

Crea un oggetto Object e memorizza un riferimento al metodo della funzione di costruzione dell'oggetto nella proprietà constructor dell'oggetto.

Indica se per un oggetto è definita una proprietà specifica. Questo metodo restituisce true se all'oggetto target è associata una proprietà che corrisponde alla stringa specificata dal parametro name; false in caso contrario. I seguenti tipi di proprietà fanno in modo che questo metodo restituisca true per gli oggetti che sono istanze di una classe (diversamente dagli oggetti classe):

• Proprietà di istanza fisse: variabili, costanti o metodi definiti dalla classe dell'oggetto e che non sono statici.
• Proprietà di istanza fisse non ereditate: variabili, costanti o metodi ereditati dalla classe dell'oggetto.
• Proprietà dinamiche: proprietà aggiunte a un oggetto dopo che per esso sono state create delle istanze (al di fuori della definizione di classe). Per aggiungere delle proprietà dinamiche, la classe di definizione dell'oggetto deve essere dichiarata con la parola chiave dynamic.

I seguenti tipi di proprietà fanno in modo che questo metodo restituisca false per gli oggetti che sono istanze di una classe:

• Proprietà statiche: variabili, costanti o metodi definiti con la parola chiave static in una classe di definizione di un oggetto o in una qualunque delle sue superclassi.
• Proprietà prototype: proprietà definite su un oggetto prototipo che fa parte della catena di prototipi dell'oggetto. In ActionScript 3.0, la catena di prototipi non viene utilizzata per l'ereditarietà di classe, ma è presente come ereditarietà alternativa. Ad esempio, un'istanza della classe Array può accedere al metodo valueOf() perché esiste su Object.prototype, che fa parte della catena di prototipi della classe Array. Anche se potete utilizzare valueOf() su un'istanza Array, il valore restituito da hasOwnProperty("valueOf") per tale istanza è false.

ActionScript 3.0 comprende anche degli oggetti classe che sono delle rappresentazioni dirette delle definizioni di classe. Quando viene chiamato sugli oggetti classe, il metodo hasOwnProperty() restituisce true solo se una proprietà è una proprietà statica definita in tale oggetto classe. Ad esempio, se create una sottoclasse di Array di nome CustomArray e definite una proprietà statica in CustomArray di nome foo, una chiamata a CustomArray.hasOwnProperty("foo") restituisce true. Tuttavia, per la proprietà statica DESCENDING definita nella classe Array, una chiamata a CustomArray.hasOwnProperty("DESCENDING") restituisce false.

Nota: i metodi della classe Object vengono creati dinamicamente sul prototipo di Object. Per ridefinire questo metodo in una sottoclasse di Object, non utilizzate la parola chiave override. Ad esempio, una sottoclasse di Object implementa function hasOwnProperty():Boolean anziché utilizzare un override della classe base.

Parametri

Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro. Il metodo restituisce true se l'oggetto si trova nella catena di prototipi dell'oggetto specificato dal parametro theClass. Il metodo restituisce false non solo se l'oggetto target è assente dalla catena di prototipi dell'oggetto theClass, ma anche se il parametro theClass non è un oggetto.

Nota: i metodi della classe Object vengono creati dinamicamente sul prototipo di Object. Per ridefinire questo metodo in una sottoclasse di Object, non utilizzate la parola chiave override. Ad esempio, una sottoclasse di Object implementa function isPrototypeOf():Boolean anziché utilizzare un override della classe base.

Parametri

Indica se la proprietà specificata esiste ed è enumerabile. Se true, la proprietà esiste e può essere enumerata in un ciclo for..in. La proprietà deve esistere nell'oggetto target, poiché questo metodo non controlla la catena di prototipi dell'oggetto target.

Le proprietà create dall'utente sono enumerabili, mentre le proprietà incorporate, in genere, non lo sono.

Nota: i metodi della classe Object vengono creati dinamicamente sul prototipo di Object. Per ridefinire questo metodo in una sottoclasse di Object, non utilizzate la parola chiave override. Ad esempio, una sottoclasse di Object implementa function propertyIsEnumerable():Boolean anziché utilizzare un override della classe base.

Parametri

Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche. La proprietà deve esistere nell'oggetto target, poiché questo metodo non controlla la catena di prototipi dell'oggetto target.

Parametri

Elementi API correlati

Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate.

L'implementazione predefinita di questo metodo non applica la formattazione in base alle convenzioni specifiche per le versioni localizzate e restituisce la stessa stringa come toString(). Quando appropriato, le sottoclassi dovrebbero fornire la propria implementazione in grado di riconoscere la versione localizzata.

Nota: i metodi della classe Object vengono creati dinamicamente sul prototipo di Object. Per ridefinire questo metodo in una sottoclasse di Object, non utilizzate la parola chiave override. Una sottoclasse di Object implementa, ad esempio, function toLocaleString():String anziché utilizzare un override della classe base.

Elementi API correlati

Restituisce la rappresentazione in formato stringa dell'oggetto specificato.

Nota: i metodi della classe Object vengono creati dinamicamente sul prototipo di Object. Per ridefinire questo metodo in una sottoclasse di Object, non utilizzate la parola chiave override. Ad esempio, una sottoclasse di Object implementa function toString():String anziché utilizzare un override della classe base.

Restituisce il valore di base dell'oggetto specificato. Se l'oggetto non ha un valore di base, viene restituito l'oggetto stesso.

Nota: i metodi della classe Object vengono creati dinamicamente sul prototipo di Object. Per ridefinire questo metodo in una sottoclasse di Object, non utilizzate la parola chiave override. Ad esempio, una sottoclasse di Object implementa function valueOf():Object anziché utilizzare un override della classe base.

Elementi API correlati

L'esempio crea gli oggetti valore firstInitObj e secondInitObj. La classe personalizzata Circle accetta l'oggetto valore, ne esegue elaborazioni cicliche e ne imposta le proprietà interne su quelle definite nell'oggetto valore.

package {
    import flash.display.Sprite;

    public class ObjectExample extends Sprite {
        public function ObjectExample() {
            var firstInitObj:Object = new Object();
            firstInitObj.bgColor = 0xFF0000;
            firstInitObj.radius = 25;
            firstInitObj.xCenter = 25;
            firstInitObj.yCenter = 25;
                        
            var firstCircle:Circle = new Circle(firstInitObj);
            addChild(firstCircle);
            firstCircle.x = 50;
            firstCircle.y = 50;

            var secondInitObj:Object = {bgColor:0xCCCCCC, radius:50, xCenter:50, yCenter:50};

            var secondCircle:Circle = new Circle(secondInitObj);            
            addChild(secondCircle);
            secondCircle.x = 100;
            secondCircle.y = 100;
        }
        
    }
}

import flash.display.Shape;
    
class Circle extends Shape {
    public var bgColor:Number = 0xFFFFFF;
    public var radius:Number = 0;
    public var xCenter:Number = 0;
    public var yCenter:Number = 0;
        
    public function Circle(initObj:Object) {
        for(var i:String in initObj) {
            this[i] = initObj[i];
        }
        draw();
    }
        
    public function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawCircle(xCenter, yCenter, radius);
        graphics.endFill();
    }
}