| Pacchetto | fl.controls.dataGridClasses |
| Classe | public class DataGridColumn |
| Ereditarietà | DataGridColumn  Object |
| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Potete specificare il tipo di componente che visualizza i dati per DataGridColumn. Tra le varie caratteristiche, potete specificare il testo che viene visualizzato nell'intestazione di colonna e se la colonna può essere modificata, ordinata o ridimensionata.
Elementi API correlati
Nascondi proprietà pubbliche ereditate
Mostra proprietà pubbliche ereditate| Proprietà | Definito da | ||
|---|---|---|---|
| cellRenderer : Object
La classe utilizzata per il rendering delle voci di questa colonna. | DataGridColumn | ||
 | constructor : Object
Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto. | Object | |
| dataField : String
Identifica il nome del campo o della proprietà nella voce del fornitore di dati associata alla colonna. | DataGridColumn | ||
| editable : Boolean = true
Indica se le voci nella colonna sono modificabili (true) o meno (false). | DataGridColumn | ||
| editorDataField : String = "text"
Identifica il nome della proprietà dell'editor di voci che contiene i nuovi dati per la voce di elenco. | DataGridColumn | ||
| headerRenderer : Object
La classe utilizzata per il rendering dell'intestazione di questa colonna. | DataGridColumn | ||
| headerText : String
Il nome di colonna da visualizzare nell'intestazione della colonna. | DataGridColumn | ||
| imeMode : String
La modalità IME (Input Method Editor). | DataGridColumn | ||
| itemEditor : Object = fl.controls.dataGridClasses.DataGridCellEditor
Indica la classe delle istanze dell'editor di voci da utilizzare per la colonna, se quest'ultima è modificabile. | DataGridColumn | ||
| labelFunction : Function
Una funzione che determina il testo da visualizzare in questa colonna. | DataGridColumn | ||
| minWidth : Number
La larghezza minima della colonna, espressa in pixel. | DataGridColumn | ||
| resizable : Boolean = true
Indica se all'utente è consentito modificare la larghezza della colonna. | DataGridColumn | ||
| sortable : Boolean = true
Indica se l'utente può fare clic sull'intestazione della colonna corrente per ordinare il fornitore di dati. | DataGridColumn | ||
| sortCompareFunction : Function
Una funzione di callback che viene chiamata quando si ordinano i dati nella colonna. | DataGridColumn | ||
| sortDescending : Boolean = false
Indica se l'ordinamento di DataGridColumn deve essere ascendente o discendente. | DataGridColumn | ||
| sortOptions : uint = 0
Una o più costanti definite, identificate in base al nome o al numero e separate dall'operatore OR (|) bit a bit. | DataGridColumn | ||
| visible : Boolean
Indica se la colonna è visibile. | DataGridColumn | ||
| width : Number
La larghezza della colonna, espressa in pixel. | DataGridColumn | ||
| Metodo | Definito da | ||
|---|---|---|---|
DataGridColumn(columnName:String = null)
Crea una nuova istanza DataGridColumn. | DataGridColumn | ||
|
Indica se per un oggetto è definita una proprietà specifica. | Object | |
|
Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro. | Object | |
Restituisce la stringa visualizzata dal renderer di voci per l'oggetto di dati specificato. | DataGridColumn | ||
|
Indica se la proprietà specificata esiste ed è enumerabile. | Object | |
|
Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche. | Object | |
|
Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate. | Object | |
Restituisce la rappresentazione in formato stringa dell'oggetto DataGridColumn. | DataGridColumn | ||
|
Restituisce il valore di base dell'oggetto specificato. | Object | |
cellRenderer | proprietà |
cellRenderer:Object| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
La classe utilizzata per il rendering delle voci di questa colonna. Il tipo di questa proprietà può essere Class, Sprite o String. Se il tipo è String, il valore String deve essere un nome di classe completo.
Il valore predefinito è null.
Implementazione
public function get cellRenderer():Object public function set cellRenderer(value:Object):voidElementi API correlati
Esempio ( Come utilizzare questo esempio )
import fl.controls.dataGridClasses.DataGridColumn;
var dgc:DataGridColumn = new DataGridColumn("Field");
dgc.cellRenderer = "MyCustomCellRendererClass";
dg.addColumn(dgc);
dataField | proprietà |
public var dataField:String| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Identifica il nome del campo o della proprietà nella voce del fornitore di dati associata alla colonna.
editable | proprietà |
public var editable:Boolean = true| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Indica se le voci nella colonna sono modificabili (true) o meno (false). Il valore true indica che è possibile modificare le voci della colonna; il valore false indica che non è possibile.
Se questa proprietà è impostata su true e anche la proprietà editable di DataGrid è true, le voci di una colonna sono modificabili ed è possibile modificarle singolarmente facendo clic su una voce o selezionandola mediante il tasto Tab e i tasti freccia.
Il valore predefinito è true.
editorDataField | proprietà |
public var editorDataField:String = "text"| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Identifica il nome della proprietà dell'editor di voci che contiene i nuovi dati per la voce di elenco.
Ad esempio, il valore predefinito di itemEditor è TextInput, il valore predefinito della proprietà editorDataField è "text". Questo valore specifica la proprietà text del componente TextInput.
Il valore predefinito è "text".
headerRenderer | proprietà |
headerRenderer:Object| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
La classe utilizzata per il rendering dell'intestazione di questa colonna.
Il tipo di questa proprietà può essere Class, Sprite o String. Se il tipo è String, il valore String deve essere un nome di classe completo.
Il valore predefinito è null.
Implementazione
public function get headerRenderer():Object public function set headerRenderer(value:Object):voidElementi API correlati
headerText | proprietà |
headerText:String| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Il nome di colonna da visualizzare nell'intestazione della colonna. Per impostazione predefinita, il componente DataGrid utilizza il valore della proprietà dataField come nome della colonna.
Implementazione
public function get headerText():String public function set headerText(value:String):voidEsempio ( Come utilizzare questo esempio )
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
var dp:DataProvider = new DataProvider();
dp.addItem({name:"Person A", sales:13453});
dp.addItem({name:"Person B", sales:23432});
dp.addItem({name:"Person C", sales:9454});
var nameCol:DataGridColumn = new DataGridColumn("name");
nameCol.headerText = "Employee:";
var salesCol:DataGridColumn = new DataGridColumn("sales");
salesCol.headerText = "Sales:";
salesCol.labelFunction = currencyFormatter;
salesCol.sortOptions = Array.NUMERIC;
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(nameCol);
myDataGrid.addColumn(salesCol);
myDataGrid.dataProvider = dp;
myDataGrid.move(10, 10);
myDataGrid.setSize(320, 240);
addChild(myDataGrid);
function currencyFormatter(item:Object):String {
return "$" + item.sales.toFixed(0);
}
imeMode | proprietà |
imeMode:String| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
La modalità IME (Input Method Editor). La modalità IME consente agli utenti di immettere testo in cinese, giapponese e coreano. La classe flash.system.IMEConversionMode definisce le costanti da utilizzare come valori validi per questa proprietà.
Se questa proprietà è null, la modalità IME è impostata sul valore della proprietà imeMode del componente DataGrid.
Il valore predefinito è null.
Implementazione
public function get imeMode():String public function set imeMode(value:String):voidElementi API correlati
itemEditor | proprietà |
public var itemEditor:Object = fl.controls.dataGridClasses.DataGridCellEditor| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Indica la classe delle istanze dell'editor di voci da utilizzare per la colonna, se quest'ultima è modificabile. Il tipo di questa proprietà può essere Class, Sprite o String. Se il tipo è String, il valore String deve essere un nome di classe completo.
Il valore predefinito è "fl.controls.dataGridClasses.DataGridCellEditor".
Esempio ( Come utilizzare questo esempio )
import fl.controls.dataGridClasses.DataGridColumn;
var dgc:DataGridColumn = new DataGridColumn("Field");
dgc.itemEditor = "MyCustomItemEditorClass";
dg.addColumn(dgc);
labelFunction | proprietà |
labelFunction:Function| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Una funzione che determina il testo da visualizzare in questa colonna. Per impostazione predefinita, la colonna visualizza il testo per il campo di dati che corrisponde al nome della colonna. Tuttavia, è possibile utilizzare una colonna anche per visualizzare il testo di più campi di dati o per visualizzare del contenuto che non ha un formato appropriato. Questa operazione può essere eseguita utilizzando la proprietà labelFunction per specificare una funzione di callback.
Se sono definite sia la proprietà labelFunction che la proprietà labelField, labelFunction ha la precedenza.
Il valore predefinito è null.
Implementazione
public function get labelFunction():Function public function set labelFunction(value:Function):voidEsempio ( Come utilizzare questo esempio )
import fl.controls.DataGrid;
import fl.controls.ScrollPolicy;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
var i:uint;
var totalRows:uint = 16;
var dp:DataProvider = new DataProvider();
for (i = 0; i < totalRows; i++) {
dp.addItem({col1:getRandomNumber(), col2:getRandomNumber(), col3:getRandomNumber(), col4:getRandomNumber()});
}
var c1:DataGridColumn = new DataGridColumn("col1");
c1.sortOptions = Array.NUMERIC;
var c2:DataGridColumn = new DataGridColumn("col2");
c2.sortOptions = Array.NUMERIC;
var c3:DataGridColumn = new DataGridColumn("col3");
c3.sortOptions = Array.NUMERIC;
c3.labelFunction = currencyFormatter;
var dg:DataGrid = new DataGrid();
dg.setSize(200, 300);
dg.addColumn(c1);
dg.addColumn(c2);
dg.addColumn(c3);
dg.dataProvider = dp;
addChild(dg);
function getRandomNumber():Number {
return Math.random() * 100;
}
function currencyFormatter(data:Object):String {
var value:Number = Number(data.col3);
return "$" + value.toFixed(2);
}
labelFunction che sortCompareFunction:
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
var data:XML = <data>
<item name="Employee A" isManager="1" />
<item name="Employee B" isManager="0" />
<item name="Employee C" isManager="1" />
</data>;
var dp:DataProvider = new DataProvider(data);
var nameDGC:DataGridColumn = new DataGridColumn("name");
nameDGC.sortCompareFunction = isManager;
nameDGC.labelFunction = nameLabelFunction;
var myDataGrid:DataGrid = new DataGrid()
myDataGrid.addColumn(nameDGC);
myDataGrid.dataProvider = dp;
myDataGrid.width = 200;
myDataGrid.rowCount = myDataGrid.length;
myDataGrid.move(10, 10);
addChild(myDataGrid);
function nameLabelFunction(item:Object):String {
var managerString:String = "";
if (item.isManager == "1") {
managerString = " (Manager)";
}
return item.name + managerString;
}
function isManager(itemA:Object, itemB:Object):int {
if (itemA.isManager > itemB.isManager) {
return -1;
} else if (itemA.isManager < itemB.isManager) {
return 1;
} else {
return 0;
}
}
minWidth | proprietà |
minWidth:Number| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
La larghezza minima della colonna, espressa in pixel.
Il valore predefinito è 20.
Implementazione
public function get minWidth():Number public function set minWidth(value:Number):voidElementi API correlati
Esempio ( Come utilizzare questo esempio )
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;
var data:XML = <data>
<row col1="item 1.A" col2="item 1.B" col3="item 1.C" />
<row col1="item 2.A" col2="item 2.B" col3="item 2.C" />
<row col1="item 3.A" col2="item 3.B" col3="item 3.C" />
</data>;
var dp:DataProvider = new DataProvider(data);
var c1:DataGridColumn = new DataGridColumn("col1");
c1.minWidth = 100;
var c2:DataGridColumn = new DataGridColumn("col2");
var c3:DataGridColumn = new DataGridColumn("col3");
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(c1);
myDataGrid.addColumn(c2);
myDataGrid.addColumn(c3);
myDataGrid.dataProvider = dp;
myDataGrid.move(10, 10);
myDataGrid.setSize(300, 200);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);
function columnStretchHandler(event:DataGridEvent):void {
var column:DataGridColumn;
for each (column in myDataGrid.columns) {
trace(column.dataField, "width:" + column.width, "minWidth:" + column.minWidth);
}
trace("---");
}
resizable | proprietà |
public var resizable:Boolean = true| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Indica se all'utente è consentito modificare la larghezza della colonna. Il valore true indica che l'utente può modificare la larghezza della colonna; il valore false indica che non può.
Il valore predefinito è true.
sortable | proprietà |
public var sortable:Boolean = true| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Indica se l'utente può fare clic sull'intestazione della colonna corrente per ordinare il fornitore di dati. Il valore true indica che la colonna può essere ordinata facendo clic sulla sua intestazione; il valore false indica che non è possibile.
Il valore predefinito è true.
Esempio ( Come utilizzare questo esempio )
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;
var data:XML = <dataProvider>
<data col1="Person A" col2="11.383" />
<data col1="Person B" col2="3.399" />
<data col1="Person C" col2="25.624" />
</dataProvider>
var dp:DataProvider = new DataProvider(data);
var c1:DataGridColumn = new DataGridColumn("col1");
var c2:DataGridColumn = new DataGridColumn("col2");
c2.sortable = false;
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(c1);
myDataGrid.addColumn(c2);
myDataGrid.dataProvider = dp;
myDataGrid.move(10, 10);
myDataGrid.setSize(160, 120);
addChild(myDataGrid);
sortable della colonna su false:
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;
var xmlDP:XML = <items>
<item name="Person 1" bio="Person 1 bio" />
<item name="Person 2" bio="Person 2 bio" />
</items>;
var dp:DataProvider = new DataProvider(xmlDP);
var nameCol:DataGridColumn = new DataGridColumn("name");
nameCol.headerText = "Name:";
var bioCol:DataGridColumn = new DataGridColumn("bio");
bioCol.headerText = "Bio:";
bioCol.sortable = false;
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(nameCol);
myDataGrid.addColumn(bioCol);
myDataGrid.dataProvider = dp;
myDataGrid.rowCount = dp.length;
myDataGrid.width = 200;
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);
function headerReleaseHandler(event:DataGridEvent):void {
var myDG:DataGrid = event.currentTarget as DataGrid;
trace("dataField:" + event.dataField);
trace("columnIndex:" + event.columnIndex);
trace("{DataGrid}.sortDescending:" + myDG.sortDescending);
trace("{DataGridColumn}.sortDescending:" + myDG.getColumnAt(event.columnIndex).sortDescending);
trace("");
}
sortCompareFunction | proprietà |
sortCompareFunction:Function| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Una funzione di callback che viene chiamata quando si ordinano i dati nella colonna. Se questa proprietà non viene specificata, i dati vengono ordinati in base alle stringhe o ai numeri, a seconda della proprietà sortOptions. Se specificata, la proprietà sortCompareFunction consente di creare un metodo di ordinamento personalizzato per la colonna corrente della griglia di dati.
Il valore predefinito è null.
Implementazione
public function get sortCompareFunction():Function public function set sortCompareFunction(value:Function):voidElementi API correlati
Esempio ( Come utilizzare questo esempio )
labelFunction che sortCompareFunction:
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
var data:XML = <data>
<item name="Employee A" isManager="1" />
<item name="Employee B" isManager="0" />
<item name="Employee C" isManager="1" />
</data>;
var dp:DataProvider = new DataProvider(data);
var nameDGC:DataGridColumn = new DataGridColumn("name");
nameDGC.sortCompareFunction = isManager;
nameDGC.labelFunction = nameLabelFunction;
var myDataGrid:DataGrid = new DataGrid()
myDataGrid.addColumn(nameDGC);
myDataGrid.dataProvider = dp;
myDataGrid.width = 200;
myDataGrid.rowCount = myDataGrid.length;
myDataGrid.move(10, 10);
addChild(myDataGrid);
function nameLabelFunction(item:Object):String {
var managerString:String = "";
if (item.isManager == "1") {
managerString = " (Manager)";
}
return item.name + managerString;
}
function isManager(itemA:Object, itemB:Object):int {
if (itemA.isManager > itemB.isManager) {
return -1;
} else if (itemA.isManager < itemB.isManager) {
return 1;
} else {
return 0;
}
}
sortDescending | proprietà |
public var sortDescending:Boolean = false| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Indica se l'ordinamento di DataGridColumn deve essere ascendente o discendente. Il valore true indica che l'ordinamento di DataGridColumn deve essere discendente; il valore false indica che deve essere ascendente.
Il valore predefinito è false.
sortOptions | proprietà |
public var sortOptions:uint = 0| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Una o più costanti definite, identificate in base al nome o al numero e separate dall'operatore OR (|) bit a bit. Queste costanti vengono utilizzate per specificare l'operazione di ordinamento.
Il valore predefinito è 0.
Elementi API correlati
Esempio ( Come utilizzare questo esempio )
sortOptions per specificare che una colonna di una griglia di dati deve essere ordinata numericamente:
import fl.data.DataProvider;
import fl.controls.dataGridClasses.DataGridColumn;
var data:XML = <players>
<player name="Player 1" score="1234" />
<player name="Player 2" score="198" />
<player name="Player 3" score="987" />
</players>;
var dp:DataProvider = new DataProvider(data);
var nameDGC:DataGridColumn = new DataGridColumn("name");
var scoreDGC:DataGridColumn = new DataGridColumn("score");
scoreDGC.sortOptions = Array.NUMERIC;
dg.addColumn(nameDGC);
dg.addColumn(scoreDGC);
dg.dataProvider = dp;
visible | proprietà |
visible:Boolean| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Indica se la colonna è visibile. Il valore true indica che la colonna è visibile; il valore false indica che non lo è.
Il valore predefinito è true.
Implementazione
public function get visible():Boolean public function set visible(value:Boolean):voidEsempio ( Come utilizzare questo esempio )
visible di ciascuna colonna facendo clic sull'istanza Button corrispondente sullo stage.
import fl.controls.Button;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
var dp:DataProvider = new DataProvider();
dp.addItem({name:"Person A", average:0.297});
dp.addItem({name:"Person B", average:0.288});
dp.addItem({name:"Person C", average:0.310});
var nameCol:DataGridColumn = new DataGridColumn("name");
nameCol.headerText = "Name:";
var averageCol:DataGridColumn = new DataGridColumn("average");
averageCol.headerText = "Average:";
averageCol.labelFunction = numberFormatter;
averageCol.sortOptions = Array.NUMERIC;
averageCol.visible = false;
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(nameCol);
myDataGrid.addColumn(averageCol);
myDataGrid.dataProvider = dp;
myDataGrid.rowCount = dp.length;
myDataGrid.width = 320;
myDataGrid.move(10, 10);
addChild(myDataGrid);
var nameButton:Button = new Button();
nameButton.label = "Toggle name";
nameButton.toggle = true;
nameButton.selected = nameCol.visible;
nameButton.move(myDataGrid.x, myDataGrid.y + myDataGrid.height + 10);
nameButton.addEventListener(Event.CHANGE, changeHandler);
addChild(nameButton);
var averageButton:Button = new Button();
averageButton.label = "Toggle average";
averageButton.toggle = true;
averageButton.selected = averageCol.visible;
averageButton.move(nameButton.x + nameButton.width + 10, nameButton.y);
averageButton.addEventListener(Event.CHANGE, changeHandler);
addChild(averageButton);
function numberFormatter(item:Object):String {
return Number(item.average).toFixed(3);
}
function changeHandler(event:Event):void {
var colIndex:int = -2;
var col:DataGridColumn;
switch (event.currentTarget) {
case nameButton:
colIndex = myDataGrid.getColumnIndex("name");
break;
case averageButton:
colIndex = myDataGrid.getColumnIndex("average");
break;
default:
return;
}
if (colIndex > -1) {
col = myDataGrid.getColumnAt(colIndex);
col.visible = !col.visible;
myDataGrid.removeColumnAt(colIndex);
myDataGrid.addColumnAt(col, colIndex);
}
myDataGrid.spaceColumnsEqually();
}
width | proprietà |
width:Number| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
La larghezza della colonna, espressa in pixel.
Il valore predefinito è 100.
Implementazione
public function get width():Number public function set width(value:Number):voidElementi API correlati
DataGridColumn | () | Funzione di costruzione |
public function DataGridColumn(columnName:String = null)| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Crea una nuova istanza DataGridColumn.
ParametricolumnName:String (default = null)dataField.
|
Elementi API correlati
itemToLabel | () | metodo |
public function itemToLabel(data:Object):String| Versione linguaggio: | ActionScript 3.0 |
| Versione prodotto: | Flash CS3 |
| Versioni runtime: | Flash Player 9.0.28.0, AIR 1.0 |
Restituisce la stringa visualizzata dal renderer di voci per l'oggetto di dati specificato. Se DataGridColumn o il relativo componente DataGrid contiene una proprietà labelFunction diversa da null, applica la funzione all'oggetto di dati. Altrimenti, il metodo estrae il contenuto del campo specificato dalla proprietà dataField oppure ottiene il valore stringa dell'oggetto di dati. Se il metodo non è in grado di convertire il parametro in una stringa, restituisce uno spazio singolo.
Parametri
data:Object — L'oggetto di cui eseguire il rendering.
|
String — Stringa visualizzabile in base all'oggetto data specificato.
|
toString | () | metodo |
- Aggiungete i componenti DataGrid e Button alla libreria.
- Salvate questo codice come DataGridColumnExample.as nella stessa directory del FLA.
- Impostate DocumentClass nel FLA su DataGridColumnExample.
package
{
import flash.display.Sprite;
import flash.events.MouseEvent;
import fl.data.DataProvider;
import fl.events.DataChangeEvent;
import fl.controls.DataGrid;
import fl.controls.Button;
import fl.controls.dataGridClasses.DataGridColumn;
public class DataGridColumnExample extends Sprite
{
private var dg:DataGrid;
private var dp:DataProvider;
private var names:Array = [ "Mary", "Bob", "Sue", "Joe" ];
public function DataGridColumnExample() {
dp = new DataProvider();
dp.addEventListener(DataChangeEvent.DATA_CHANGE,dataChanged);
dg = new DataGrid();
addChild(dg);
dg.move(10,45);
dg.setSize(450,300);
dg.addColumn(new DataGridColumn("name"));
dg.addColumn(new DataGridColumn("phone"));
dg.addColumn(new DataGridColumn("email"));
var firstColumn = dg.columns[0];
firstColumn.resizable = false;
var secondColumn = dg.columns[1];
secondColumn.sortable = false;
var thirdColumn = dg.columns[2];
thirdColumn.sortable = false;
var addContactBtn:Button = new Button();
addContactBtn.label = "Add Contact";
addContactBtn.move(10,10);
addContactBtn.addEventListener(MouseEvent.CLICK, addContact);
addChild(addContactBtn);
}
private function getRandomPhone():String {
return randomDigit()+randomDigit()+randomDigit()+"-"+randomDigit()+randomDigit()+randomDigit()+"-"+randomDigit()+randomDigit()+randomDigit()+randomDigit();
}
private function randomDigit():String {
return String(Math.round(Math.random()*10)%10);
}
private function getRandomName():String {
return names[Math.round(Math.random()*names.length)%names.length];
}
private function addContact(e:MouseEvent):void {
var randomName:String = getRandomName()
dp.addItem( { name: randomName, phone: getRandomPhone(), email: randomName + "@fictitious.com" } );
}
private function dataChanged(e:DataChangeEvent):void {
var changedItems:Array = e.items;
dg.addItem(changedItems[0]);
}
}
}
Tue Jun 12 2018, 02:44 PM Z