String

Pacchetto	Primo livello
Classe	public final class String
Ereditarietà	String Object

Versioni runtime:

Flash Player 9, AIR 1.0, Flash Lite 4

La classe String è un tipo di dati che rappresenta una stringa di caratteri. Fornisce i metodi e le proprietà che consentono di modificare i tipi di valore di stringa di base. Potete convertire in un oggetto di tipo di dati String il valore di qualunque oggetto utilizzando la funzione String().

Dal momento che tutti gli indici di stringa sono a base zero, l'indice dell'ultimo carattere di una qualunque stringa x è x.length -1.

È possibile chiamare qualunque metodo della classe String sia che si utilizzi il metodo di costruzione new String() per creare una nuova variabile di stringa sia che si assegni semplicemente un valore letterale di stringa. A differenza delle precedenti versioni di ActionScript, non fa alcuna differenza se si utilizza la funzione di costruzione, la funzione globale o se si assegna semplicemente un valore letterale di stringa. Le righe di codice seguenti sono equivalenti:

 var str:String = new String("foo");
 var str:String = "foo";
 var str:String = String("foo");

Quando si imposta una variabile di stringa su undefined, i runtime Flash imposta forzatamente undefined su null. Pertanto, l'istruzione seguente:

 var s:String = undefined;

imposta il valore su null anziché su undefined. Utilizzate la funzione String() se dovete utilizzare undefined.

Vedere gli esempi

Altri esempi

Creazione di stringhe
Operazioni con i caratteri nelle stringhe
Confronto tra stringhe
Concatenazione di stringhe
Ricerca di sottostringhe e modelli nelle stringhe
Conversione di stringhe da maiuscole a minuscole
Esempi di stringhe: ASCII art
Sintassi delle espressioni regolari

Altre informazioni

Operazioni con le stringhe
Elementi fondamentali delle stringhe

Elementi API correlati

Funzione globale String()

Proprietà pubbliche

Nascondi proprietà pubbliche ereditate

Mostra proprietà pubbliche ereditate

	Proprietà		Definito da
		constructor : Object Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto.	Object
		length : int [sola lettura] Un numero intero che specifica il numero di caratteri presenti nell'oggetto String specificato.	String

Metodi pubblici

Nascondi metodi pubblici ereditati

Mostra metodi pubblici ereditati

	Metodo		Definito da
		String(val:String) Crea un nuovo oggetto String inizialmente impostato sulla stringa specificata.	String
		charAt(index:Number = 0):String Restituisce il carattere nella posizione specificata dal parametro index.	String
		charCodeAt(index:Number = 0):Number Restituisce il codice del carattere Unicode numerico per il carattere che si trova nella posizione index specificata.	String
		concat(... args):String Aggiunge gli argomenti forniti alla fine dell'oggetto String, convertendoli in stringhe se necessario, e restituisce la stringa risultante.	String
		fromCharCode(... charCodes):String [statico] Restituisce una stringa che comprende i caratteri rappresentati dai codici dei caratteri Unicode presenti nei parametri.	String
		hasOwnProperty(name:String):Boolean Indica se per un oggetto è definita una proprietà specifica.	Object
		indexOf(val:String, startIndex:Number = 0):int Cerca la stringa e restituisce la posizione della prima occorrenza di val trovata in corrispondenza o dopo startIndex all'interno della stringa chiamante.	String
		isPrototypeOf(theClass:Object):Boolean Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro.	Object
		lastIndexOf(val:String, startIndex:Number = 0x7FFFFFFF):int Cerca la stringa da destra a sinistra e restituisce l'indice dell'ultima occorrenza di val trovata prima di startIndex.	String
		localeCompare(other:String, ... values):int Confronta il tipo di ordinamento di due o più stringhe e restituisce il risultato del confronto sotto forma di un numero intero.	String
		match(pattern:*):Array Cerca la corrispondenza del criterio specificato rispetto alla stringa.	String
		propertyIsEnumerable(name:String):Boolean Indica se la proprietà specificata esiste ed è enumerabile.	Object
		replace(pattern:*, repl:Object):String Cerca la corrispondenza del criterio specificato rispetto alla stringa e restituisce una nuova stringa in cui la prima corrispondenza del criterio viene sostituita con il contenuto specificato da repl.	String
		search(pattern:*):int Cerca il criterio specificato e restituisce l'indice della prima sottostringa corrispondente.	String
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche.	Object
		slice(startIndex:Number = 0, endIndex:Number = 0x7fffffff):String Restituisce una stringa che comprende il carattere startIndex e tutti i caratteri fino a endIndex escluso.	String
		split(delimiter:*, limit:Number = 0x7fffffff):Array Suddivide un oggetto String in un array di sottostringhe dividendolo in corrispondenza del parametro delimitatore specificato.	String
		substr(startIndex:Number = 0, len:Number = 0x7fffffff):String Restituisce una sottostringa costituita dai caratteri che iniziano in corrispondenza del parametro startIndex specificato e la cui lunghezza è specificata da len.	String
		substring(startIndex:Number = 0, endIndex:Number = 0x7fffffff):String Restituisce una stringa che comprende il carattere specificato da startIndex e tutti i caratteri fino a endIndex -1.	String
		toLocaleLowerCase():String Restituisce una copia di questa stringa, convertendo tutti i caratteri maiuscoli in minuscoli.	String
		toLocaleString():String Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate.	Object
		toLocaleUpperCase():String Restituisce una copia di questa stringa, convertendo tutti i caratteri minuscoli in maiuscoli.	String
		toLowerCase():String Restituisce una copia di questa stringa, convertendo tutti i caratteri maiuscoli in minuscoli.	String
		toString():String Restituisce la rappresentazione in formato stringa dell'oggetto specificato.	Object
		toUpperCase():String Restituisce una copia di questa stringa, convertendo tutti i caratteri minuscoli in maiuscoli.	String
		valueOf():String Restituisce il valore di base di un'istanza String.	String

Descrizione delle proprietà

length

proprietà

length:int [sola lettura]

Versioni runtime:

Flash Player 9, AIR 1.0, Flash Lite 4

Un numero intero che specifica il numero di caratteri presenti nell'oggetto String specificato.

Dal momento che tutti gli indici di stringa sono a base zero, l'indice dell'ultimo carattere di una qualunque stringa x è x.length -1.

Implementazione
public function get length():int

Altri esempi

Proprietà length

Descrizione della funzione di costruzione

()

Funzione di costruzione

public function String(val:String)

Versioni runtime:

Flash Player 9, AIR 1.0, Flash Lite 4

Crea un nuovo oggetto String inizialmente impostato sulla stringa specificata.

Nota: dal momento che i caratteri letterali di stringa utilizzano meno risorse rispetto agli oggetti String e generalmente sono più facili da utilizzare, è consigliabile utilizzarli al posto della classe String, se non è strettamente necessario utilizzare un oggetto String.

Parametri

val:String — Il valore iniziale del nuovo oggetto String.

Altri esempi

Sintassi delle espressioni regolari

Descrizione dei metodi

charAt

()

metodo

AS3 function charAt(index:Number = 0):String

Versioni runtime:

Flash Player 9, AIR 1.0, Flash Lite 4

Restituisce il carattere nella posizione specificata dal parametro index. Se index non è un numero compreso tra 0 e string.length -1, viene restituita una stringa vuota.

Questo metodo è simile a String.charCodeAt() a eccezione del fatto che il valore restituito è un carattere e non un codice di carattere intero a 16 bit.

Parametri

index:Number (default = 0) — Un numero intero che specifica la posizione di un carattere nella stringa. Il primo carattere è indicato con 0, mentre l'ultimo è indicato mediante my_str.length - 1.

Restituisce

String — Il carattere nella posizione di indice specificata oppure una stringa vuota se l'indice specificato è al di fuori dell'intervallo degli indici di questa stringa.

Altri esempi

Operazioni con i caratteri nelle stringhe

Elementi API correlati

charCodeAt()

charCodeAt

()

metodo

AS3 function charCodeAt(index:Number = 0):Number

Versioni runtime:

Flash Player 9, AIR 1.0, Flash Lite 4

Restituisce il codice del carattere Unicode numerico per il carattere che si trova nella posizione index specificata. Se index non è un numero compreso tra 0 e string.length - 1, viene restituito NaN.

Questo metodo è simile a String.charAt() a eccezione del fatto che il valore restituito è un codice di carattere intero a 16 bit e non il carattere vero e proprio.

Parametri

Restituisce

Number — Il codice del carattere Unicode numerico per il carattere che si trova in corrispondenza dell'indice specificato. Oppure NaN, se l'indice è al di fuori dell'intervallo degli indici di questa stringa.

I valori Unicode sono definiti nella specifica Unicode Character Database.

Altri esempi

Operazioni con i caratteri nelle stringhe

Elementi API correlati

charAt()

concat

()

metodo

AS3 function concat(... args):String

Versioni runtime:

Flash Player 9, AIR 1.0, Flash Lite 4

Aggiunge gli argomenti forniti alla fine dell'oggetto String, convertendoli in stringhe se necessario, e restituisce la stringa risultante. Il valore originale dell'oggetto String di origine rimane invariato.

Parametri

... args — Zero o più valori da concatenare.

Restituisce

String — Una nuova stringa costituita da questa stringa concatenata con i parametri specificati.

Altri esempi

Concatenazione di stringhe

fromCharCode

()

metodo

AS3 static function fromCharCode(... charCodes):String

Versioni runtime:

Flash Player 9, AIR 1.0, Flash Lite 4

Restituisce una stringa che comprende i caratteri rappresentati dai codici dei caratteri Unicode presenti nei parametri.

Parametri

... charCodes — Una serie di numeri interi decimali che rappresentano i valori Unicode.

I valori Unicode sono definiti nella specifica Unicode Character Database.

Restituisce

String — Il valore di stringa dei codici di caratteri Unicode specificati.

Altri esempi

Operazioni con i caratteri nelle stringhe

indexOf

()

metodo

AS3 function indexOf(val:String, startIndex:Number = 0):int

Versioni runtime:

Flash Player 9, AIR 1.0, Flash Lite 4

Cerca la stringa e restituisce la posizione della prima occorrenza di val trovata in corrispondenza o dopo startIndex all'interno della stringa chiamante. Questo indice è a base zero, pertanto l'indice 0 (e non l'indice 1) viene considerato come posizione del primo carattere di una stringa. Se val non viene trovato, il metodo restituisce -1.

Parametri

	`val:String` — La sottostringa da cercare.

	`startIndex:Number` (default = `0`) — Un numero intero opzionale che specifica l'indice del punto iniziale della porzione.

Restituisce

int — L'indice della prima occorrenza della sottostringa specificata oppure -1.

Altri esempi

Individuazione della posizione del carattere di una sottostringa corrispondente

Elementi API correlati

lastIndexOf()

lastIndexOf

()

metodo

AS3 function lastIndexOf(val:String, startIndex:Number = 0x7FFFFFFF):int

Versioni runtime:

Flash Player 9, AIR 1.0, Flash Lite 4

Cerca la stringa da destra a sinistra e restituisce l'indice dell'ultima occorrenza di val trovata prima di startIndex. Questo indice è a base zero, pertanto l'indice 0 viene considerato come posizione del primo carattere, mentre la posizione dell'ultimo carattere è string.length - 1. Se val non viene trovato, il metodo restituisce -1.

Parametri

	`val:String` — La stringa da cercare.

	`startIndex:Number` (default = `0x7FFFFFFF`) — Un numero intero opzionale che specifica l'indice del punto iniziale da cui cercare `val`. Il valore predefinito è rappresentato dal valore massimo consentito per un indice. Se `startIndex` non è specificato, la ricerca comincia dall'ultimo elemento della stringa.

Restituisce

int — La posizione dell'ultima occorrenza della sottostringa specificata, oppure -1 se non viene trovata.

Altri esempi

Individuazione della posizione del carattere di una sottostringa corrispondente

Elementi API correlati

indexOf()

localeCompare

()

metodo

AS3 function localeCompare(other:String, ... values):int

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Confronta il tipo di ordinamento di due o più stringhe e restituisce il risultato del confronto sotto forma di un numero intero. Mentre questo metodo è progettato per gestire il confronto in modo specifico per le singole versioni localizzate, l'implementazione ActionScript 3.0 non produce un risultato diverso rispetto ad altri confronti di stringa, quali gli operatori di uguaglianza (==) o di disuguaglianza (!=). Se le stringhe sono equivalenti, il valore restituito è 0. Se il valore di stringa originale precede il valore di stringa specificato da other, il valore restituito è un numero intero negativo, il valore assoluto del quale rappresenta il numero di caratteri che separano i due valori di stringa. Se il valore di stringa originale viene dopo il valore di stringa specificato da other, il valore restituito è un numero intero positivo, il valore assoluto del quale rappresenta il numero di caratteri che separano i due valori di stringa.

Parametri

	`other:String` — Un valore di stringa da confrontare.

	`... values` — Gruppo opzionale di altre stringhe da confrontare.

Restituisce

int — Il valore 0 se le stringhe sono uguali. In caso contrario, un numero intero negativo se la stringa originale precede l'argomento String e un numero intero positivo se l'argomento String precede la stringa originale. In entrambi i casi, il valore assoluto del numero rappresenta la differenza tra le due stringhe.

match

()

metodo

AS3 function match(pattern:*):Array

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Cerca la corrispondenza del parametro pattern specificato rispetto alla stringa.

Parametri

pattern:* — Il modello (pattern) di cui deve essere cercata la corrispondenza e che può essere un oggetto di qualsiasi tipo, ma che generalmente è una stringa o un’espressione regolare. Se pattern non è un'espressione regolare o una stringa, il metodo lo converte in una stringa prima dell'esecuzione.

Restituisce

Array — Un array di stringhe costituito da tutte le sottostringhe nella stringa che corrispondono al parametro pattern specificato.

Se pattern è un'espressione regolare, per restituire un array con più di una sottostringa corrispondente, il flag g (global) deve essere impostato nell'espressione regolare:

Se il flag g (global) non è impostato, l'array restituito non contiene più di una corrispondenza e la proprietà lastIndex dell'espressione regolare rimane invariata.
Se il flag g (global) è impostato, il metodo avvia la ricerca dall'inizio della stringa (posizione di indice 0). Se una sottostringa corrispondente è una stringa vuota (ad esempio, nel caso dell'espressione regolare /x*/), il metodo aggiunge tale stringa vuota all'array di corrispondenza, quindi continua a cercare a partire dalla posizione di indice successiva. La proprietà lastIndex dell'espressione regolare viene impostata su 0 dopo il completamento del metodo.

Quando il parametro pattern è un’espressione regolare con il flag g (global) impostato, se non viene trovata una corrispondenza, il metodo restituisce un array vuoto. Se il parametro pattern è una stringa oppure un’espressione regolare non globale e non viene trovata una corrispondenza, il metodo restituisce null. Se non passate alcun valore (o passate un valore undefined) come parametro pattern, il metodo restituisce null.

Altri esempi

Ricerca di modelli nelle stringhe e sostituzione di sottostringhe
Sintassi delle espressioni regolari

Elementi API correlati

RegExp

replace

()

metodo

AS3 function replace(pattern:*, repl:Object):String

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Cerca la corrispondenza del parametro pattern specificato rispetto alla stringa e restituisce una nuova stringa in cui la prima corrispondenza di pattern viene sostituita con il contenuto specificato da repl. Il parametro pattern può essere una stringa o un'espressione regolare. Il parametro repl può essere una stringa o una funzione; se è una funzione, la stringa restituita dalla funzione viene inserita al posto della corrispondenza. La stringa originale non viene modificata.

Nell'esempio seguente, viene sostituita solo la prima istanza di "sh" (sensibile alle maiuscole e minuscole):

    var myPattern:RegExp = /sh/;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // She sells seaschells by the seashore.

Nell'esempio seguente, vengono sostituite tutte le istanze di "sh" (sensibile alle maiuscole e minuscole) perché nell'espressione regolare è impostato il flag g (global):

    var myPattern:RegExp = /sh/g;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // She sells seaschells by the seaschore.

Nell'esempio seguente, vengono sostituite tutte le istanze di "sh" perché nell'espressione regolare è impostato il flag g (global), e le corrispondenze non sono sensibili alle maiuscole e minuscole perché è impostato il flag i (ignoreCase):

    var myPattern:RegExp = /sh/gi;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // sche sells seaschells by the seaschore.

Parametri

pattern:* — Il modello di cui deve essere cercata la corrispondenza, e che può essere un oggetto di qualsiasi tipo ma che generalmente è una stringa o un'espressione regolare. Se specificate un parametro pattern che è un oggetto diverso da una stringa o da un'espressione regolare, il metodo toString() viene applicato al parametro e il metodo replace() viene eseguito utilizzando la stringa risultante come parametro pattern.

repl:Object — Di solito, la stringa che viene inserita al posto del contenuto corrispondente. Tuttavia, potete anche specificare una funzione come parametro. Se specificate una funzione, la stringa restituita dalla funzione viene inserita al posto del contenuto corrispondente.

Quando specificate una stringa come parametro repl e un'espressione regolare come parametro pattern, potete utilizzare i seguenti codici di sostituzione $ speciali nella stringa repl:

Codice $	Testo sostitutivo
`$$`	`$`
`$&`	La sottostringa di cui si è trovata la corrispondenza.
$`	La porzione della stringa che precede la sottostringa di cui si è trovata la corrispondenza. Notate che questo codice utilizza il carattere di virgoletta dritta sinistra (`), non il carattere di virgoletta semplice dritta (') o il carattere di virgoletta semplice sinistra (‘).
`$'`	La porzione della stringa che segue la sottostringa di cui si è trovata la corrispondenza. Notate che questo codice utilizza il carattere di virgoletta semplice dritta (').
`$`n	La corrispondenza con l'nsimo gruppo parentetico catturato, dove n è un numero a cifra singola compreso tra 1 e 9 e `$`n non è seguito da una cifra decimale.
`$`nn	La corrispondenza con l'nnsimo gruppo parentetico catturato, dove nn è un numero decimale a due cifre (01-99). Se l'nnsimo elemento catturato è undefined, il testo sostitutivo è una stringa vuota.

Ad esempio, il codice seguente illustra l'utilizzo dei codici sostitutivi $2 e $1, che rappresentano il primo e il secondo gruppo di cattura di cui è stata trovata una corrispondenza:

var str:String = "flip-flop";
    var pattern:RegExp = /(\w+)-(\w+)/g;
    trace(str.replace(pattern, "$2-$1")); // flop-flip

Quando specificate una funzione come parametro repl, il metodo replace() passa i seguenti parametri alla funzione:

La porzione corrispondente della stringa.
Tutte le corrispondenze dei gruppi parentetici catturati vengono fornite come argomenti successivi. Il numero di argomenti passati in questo modo varia a seconda del numero di corrispondenze parentetiche. Potete determinare il numero di corrispondenze parentetiche verificando arguments.length - 3 all'interno del codice della funzione.
La posizione di indice nella stringa in cui inizia la corrispondenza.
La stringa completa.

Ad esempio, considerate il codice seguente:

    var str1:String = "abc12 def34";
    var pattern:RegExp = /([a-z]+)([0-9]+)/;
    var str2:String = str1.replace(pattern, replFN);
    trace (str2);   // 12abc 34def
    
    function replFN():String {
      return arguments[2] + arguments[1];
    }

La chiamata al metodo replace() utilizza una funzione come parametro repl. L'espressione regolare (/([a-z]([0-9]/g) ha due corrispondenze. Nella prima, il modello corrisponde alla sottostringa "abc12" e viene passato alla funzione il seguente elenco di argomenti:

    {"abc12", "abc", "12", 0, "abc12 def34"}

Nella seconda, il modello corrisponde alla sottostringa "def23" e viene passato alla funzione il seguente elenco di argomenti:

    {"def34", "def", "34", 6, "abc123 def34"}

Restituisce

String — La stringa risultante. La stringa di origine rimane invariata.

Altri esempi

Ricerca di modelli nelle stringhe e sostituzione di sottostringhe
Sintassi delle espressioni regolari

Elementi API correlati

RegExp

search

()

metodo

AS3 function search(pattern:*):int

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Cerca il parametro pattern specificato e restituisce l'indice della prima sottostringa corrispondente. Se non viene trovata alcuna sottostringa corrispondente, il metodo restituisce -1.

Parametri

pattern:* — Il modello di cui deve essere cercata la corrispondenza e che può essere un oggetto di qualsiasi tipo, ma che generalmente è una stringa o un'espressione regolare. Se pattern non è un'espressione regolare o una stringa, il metodo lo converte in una stringa prima dell'esecuzione. Se specificate un'espressione regolare, il metodo ignora il flag globale ("g") dell'espressione regolare e ignora la proprietà lastIndex dell'espressione regolare (che lascia invariata). Se non si passa alcun valore (o si passa un valore undefined), il metodo restituisce -1.

Restituisce

int — L'indice della prima sottostringa corrispondente, oppure -1 se non viene trovata alcuna corrispondenza. Notate che la stringa ha indice a base zero; il primo carattere della stringa si trova in corrispondenza dell'indice 0, mentre l'ultimo si trova in corrispondenza di string.length - 1.

Altri esempi

Ricerca di modelli nelle stringhe e sostituzione di sottostringhe
Sintassi delle espressioni regolari

Elementi API correlati

RegExp

slice

()

metodo

AS3 function slice(startIndex:Number = 0, endIndex:Number = 0x7fffffff):String

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Restituisce una stringa che comprende il carattere startIndex e tutti i caratteri fino a endIndex escluso. L'oggetto String originale non viene modificato. Se il parametro endIndex non viene specificato, la fine della sottostringa coincide con la fine della stringa. Se il carattere con indice startIndex è lo stesso o si trova a destra del carattere con indice endIndex, il metodo restituisce una stringa vuota.

Parametri

	`startIndex:Number` (default = `0`) — L'indice a base zero del punto iniziale della porzione. Se `startIndex` è un numero negativo, la porzione viene creata da destra a sinistra, dove -1 è l'ultimo carattere.

	`endIndex:Number` (default = `0x7fffffff`) — Un numero intero che corrisponde a 1+ l'indice del punto finale della porzione. Il carattere indicizzato dal parametro `endIndex` non è compreso nella stringa estratta. Se `endIndex` è un numero negativo, il punto finale è determinato dal conteggio a partire dalla fine della stringa, dove -1 corrisponde all'ultimo carattere. Il valore predefinito è rappresentato dal valore massimo consentito per un indice. Se omettete questo parametro, viene utilizzato `String.length`.

Restituisce

String — Una sottostringa in base agli indici specificati.

Altri esempi

Ricerca di una sottostringa in base alla posizione del carattere

Elementi API correlati

substr()
substring()

split

()

metodo

AS3 function split(delimiter:*, limit:Number = 0x7fffffff):Array

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Suddivide un oggetto String in un array di sottostringhe in corrispondenza di ogni parametro delimiter.

Se il parametro delimiter è un'espressione regolare, viene considerata solo la prima corrispondenza in una data posizione della stringa, anche se il backtracking fosse in grado di trovare una corrispondenza di sottostringa non vuota in quella posizione. Ad esempio:

     var str:String = "ab";
     var results:Array = str.split(/a*?/); // results == ["","b"]
     
     results = str.split(/a*/); // results == ["","b"].)

Se il parametro delimiter è un'espressione regolare che contiene delle parentesi di raggruppamento, ogni volta che viene trovata una corrispondenza di delimiter i risultati (compresi quelli eventualmente undefined) delle parentesi di raggruppamento vengono suddivisi nell'array di output. Ad esempio

     var str:String = "Thi5 is a tricky-66 example.";
     var re:RegExp = /(\d+)/;
     var results:Array = str.split(re);
         // results == ["Thi","5"," is a tricky-","66"," example."]

Se il parametro limit è specificato, l'array restituito ha al massimo il numero specificato di elementi.

Se delimiter è una stringa vuota, un'espressione regolare vuota o un'espressione regolare che può corrispondere a una stringa vuota, ogni singolo carattere nella stringa viene restituito come elemento dell'array.

Se il parametro delimiter non è definito, l'intera stringa viene collocata nel primo elemento dell'array restituito.

Parametri

	`delimiter:*` — Il modello che specifica dove suddividere questa stringa. Può essere un oggetto di qualsiasi tipo, ma generalmente è una stringa o un'espressione regolare. Se `delimiter` non è un'espressione regolare o una stringa, il metodo lo converte in una stringa prima dell'esecuzione.

	`limit:Number` (default = `0x7fffffff`) — Il numero massimo di voci da inserire nell'array. Il valore predefinito è il massimo valore consentito.

Restituisce

Array — Un array di sottostringhe.

Altri esempi

Creazione di un array di sottostringhe segmentate da un delimitatore
Sintassi delle espressioni regolari

Elementi API correlati

Array.join()
RegExp

substr

()

metodo

AS3 function substr(startIndex:Number = 0, len:Number = 0x7fffffff):String

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Restituisce una sottostringa costituita dai caratteri che iniziano in corrispondenza del parametro startIndex specificato e la cui lunghezza è specificata da len. La stringa originale è invariata.

Parametri

	`startIndex:Number` (default = `0`) — Un numero intero che specifica l'indice del primo carattere da utilizzare per creare la sottostringa. Se `startIndex` è un numero negativo, l'indice iniziale è determinato dalla fine della stringa, dove `-1` corrisponde all'ultimo carattere.

	`len:Number` (default = `0x7fffffff`) — Il numero di caratteri presenti nella sottostringa creata. Il valore predefinito è il massimo valore consentito. Se non specificate `len`, nella sottostringa vengono inclusi tutti i caratteri da `startIndex` alla fine della stringa.

Restituisce

String — Una sottostringa in base ai parametri specificati.

Altri esempi

Ricerca di una sottostringa in base alla posizione del carattere

substring

()

metodo

AS3 function substring(startIndex:Number = 0, endIndex:Number = 0x7fffffff):String

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Restituisce una stringa costituita dal carattere specificato da startIndex e tutti i caratteri fino a endIndex -1. Se endIndex non è specificato, viene utilizzato String.length. Se il valore di startIndex è uguale a quello di endIndex, il metodo restituisce una stringa vuota. Se il valore di startIndex è maggiore di quello di endIndex, i parametri vengono automaticamente scambiati prima che la funzione venga eseguita La stringa originale è invariata.

Parametri

	`startIndex:Number` (default = `0`) — Un numero intero che specifica l'indice del primo carattere utilizzato per creare la sottostringa. I valori validi per `startIndex` sono compresi nell'intervallo da `0` a `String.length`. Se `startIndex` è un valore negativo, viene utilizzato `0`.

	`endIndex:Number` (default = `0x7fffffff`) — Un numero intero che corrisponde a 1+ l'indice dell'ultimo carattere nella sottostringa estratta. I valori validi per `endIndex` sono compresi nell'intervallo da `0` a `String.length`. Il carattere che si trova in corrispondenza di `endIndex` non viene incluso nella sottostringa. Il valore predefinito è rappresentato dal valore massimo consentito per un indice. Se omettete questo parametro, viene utilizzato `String.length`. Se questo parametro è un valore negativo, viene utilizzato `0`.

Restituisce

String — Una sottostringa in base ai parametri specificati.

Altri esempi

Ricerca di una sottostringa in base alla posizione del carattere

toLocaleLowerCase

()

metodo

AS3 function toLocaleLowerCase():String

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Restituisce una copia di questa stringa, convertendo tutti i caratteri maiuscoli in minuscoli. La stringa originale è invariata. Mentre questo metodo è progettato per gestire la conversione in modo specifico per le singole versioni localizzate, l'implementazione ActionScript 3.0 non produce un risultato diverso rispetto al metodo toLowerCase().

Restituisce

String — Una copia di questa stringa, con tutti i caratteri maiuscoli convertiti in minuscoli.

Elementi API correlati

toLowerCase()

toLocaleUpperCase

()

metodo

AS3 function toLocaleUpperCase():String

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Restituisce una copia di questa stringa, convertendo tutti i caratteri minuscoli in maiuscoli. La stringa originale è invariata. Mentre questo metodo è progettato per gestire la conversione in modo specifico per le singole versioni localizzate, l'implementazione ActionScript 3.0 non produce un risultato diverso rispetto al metodo toUpperCase().

Restituisce

String — Una copia di questa stringa, con tutti i caratteri minuscoli convertiti in maiuscoli.

Elementi API correlati

toUpperCase()

toLowerCase

()

metodo

AS3 function toLowerCase():String

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Restituisce una copia di questa stringa, convertendo tutti i caratteri maiuscoli in minuscoli. La stringa originale è invariata.

Questo metodo converte tutti i caratteri (non solo da A a Z) per cui esistono degli equivalenti Unicode minuscoli:

     var str:String = " JOSÉ BARÇA";
     trace(str.toLowerCase()); // josé barça

Queste mappature tra maiuscole e minuscole sono definite nella specifica Unicode Character Database.

Restituisce

String — Una copia di questa stringa, con tutti i caratteri maiuscoli convertiti in minuscoli.

Altri esempi

Conversione di stringhe da maiuscole a minuscole

Elementi API correlati

toUpperCase()

toUpperCase

()

metodo

AS3 function toUpperCase():String

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Restituisce una copia di questa stringa, convertendo tutti i caratteri minuscoli in maiuscoli. La stringa originale è invariata.

Questo metodo converte tutti i caratteri (non solo a-z) per cui esistono degli equivalenti Unicode maiuscoli:

     var str:String = "José Barça";
     trace(str.toUpperCase()); // JOSÉ BARÇA

Queste mappature tra maiuscole e minuscole sono definite nella specifica Unicode Character Database.

Restituisce

String — Una copia di questa stringa, con tutti i caratteri minuscoli convertiti in maiuscoli.

Altri esempi

Conversione di stringhe da maiuscole a minuscole

Elementi API correlati

toLowerCase()

valueOf

()

metodo

AS3 function valueOf():String

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

Flash Lite 4, Flash Player 9, AIR 1.0

Restituisce il valore di base di un'istanza String. Questo metodo è progettato per convertire un oggetto String in un valore di stringa di base. Dal momento che i runtime Flash chiamano automaticamente valueOf() quando necessario, è raro che sia necessario chiamare esplicitamente questo metodo.

Restituisce

String — Il valore della stringa.

Esempi Come utilizzare questo esempio

StringExample.as

L'esempio seguente utilizza le classi StringExample e StringHelper per mostrare come vengono utilizzati i diversi metodi della classe String. Questa operazione viene eseguita mediante la procedura seguente:

La funzione di costruzione per la classe StringExample dichiara diverse istanze String locali che vengono inizializzate con diverse stringhe e un nuovo oggetto StringHelper.
La classe StringHelper utilizza i seguenti metodi:
- replace(): chiama i metodi split() e join() di String per rimuovere una sottostringa della stringa passata e sostituirla con una nuova.
- trim(): chiama trimBack() e trimFront() utilizzando le stringhe passate e restituisce la stringa aggiornata.
- trimFront():sostituisce in modo ricorsivo tutti i caratteri che corrispondono al parametro char, a partire dall'inizio della stringa verso la fine, fino a che l'ultimo carattere della stringa non corrisponde a char e restituisce la stringa aggiornata.
- trimBack(): sostituisce in modo ricorsivo tutti i caratteri che corrispondono al parametro char, a ritroso a partire dalla fine della stringa, fino a che l'ultimo carattere della stringa non corrisponde a char e restituisce la stringa aggiornata.
- stringToCharacter(): restituisce il primo carattere della stringa passata.
Vengono quindi prodotte tre stringhe utilizzando le variabili di stringa dichiarate con una chiamata al metodo replace() utilizzato per produrre la seconda stringa e trim() per produrre la terza stringa.

package {
    import flash.display.Sprite;

    public class StringExample extends Sprite {
        public function StringExample() {
            var companyStr:String = new String("     Company X");
            var productStr:String = "Product Z Basic     ";
            var emptyStr:String = " ";
            var strHelper:StringHelper = new StringHelper();

            var companyProductStr:String = companyStr + emptyStr + productStr;
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Basic     '

            companyProductStr = strHelper.replace(companyProductStr, "Basic", "Professional");
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Professional     '

            companyProductStr = strHelper.trim(companyProductStr, emptyStr);
            trace("'" + companyProductStr + "'");    // 'Company X Product Z Professional'
        }
    }
}

class StringHelper {
    public function StringHelper() {
    }

    public function replace(str:String, oldSubStr:String, newSubStr:String):String {
        return str.split(oldSubStr).join(newSubStr);
    }

    public function trim(str:String, char:String):String {
        return trimBack(trimFront(str, char), char);
    }

    public function trimFront(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(0) == char) {
            str = trimFront(str.substring(1), char);
        }
        return str;
    }

    public function trimBack(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(str.length - 1) == char) {
            str = trimBack(str.substring(0, str.length - 1), char);
        }
        return str;
    }

    public function stringToCharacter(str:String):String {
        if (str.length == 1) {
            return str;
        }
        return str.slice(0, 1);
    }
}

Note legali | Informativa sulla privacy online

String - AS3

Classi x

length

String

charAt

charCodeAt

concat

fromCharCode

indexOf

lastIndexOf

localeCompare

match

replace

search

slice

split

substr

substring

toLocaleLowerCase

toLocaleUpperCase

toLowerCase

toUpperCase

valueOf