Ricerca di sottostringhe e modelli nelle stringhe

Ricerca di sottostringhe corrispondenti

Il metodo search() restituisce la posizione di indice della prima sottostringa corrispondente a un dato modello, come nell'esempio seguente:

var str:String = "The more the merrier."; 
// (This search is case-sensitive.) 
trace(str.search("the")); // output: 9 

Potete utilizzare le espressioni regolari anche per definire il modello da utilizzare come corrispondenza, come illustrato nell'esempio seguente:

var pattern:RegExp = /the/i; 
var str:String = "The more the merrier."; 
trace(str.search(pattern)); // 0

Il risultato del metodo trace() è 0, in quanto il primo carattere della stringa si trova nella posizione di indice. L'indicatore i viene impostato nell'espressione regolare, in modo che nella ricerca non si faccia distinzione tra maiuscole e minuscole.

Il metodo search() consente di trovare solo una corrispondenza e restituisce la sua posizione di indice iniziale, anche se l'indicatore g (global) viene impostato nell'espressione regolare.

Nell'esempio seguente è illustrata un'espressione regolare più complessa, che deve corrispondere a una stringa racchiusa tra virgolette doppie:

var pattern:RegExp = /"[^"]*"/; 
var str:String = "The \"more\" the merrier."; 
trace(str.search(pattern)); // output: 4 
 
str = "The \"more the merrier."; 
trace(str.search(pattern)); // output: -1  
// (Indicates no match, since there is no closing double quotation mark.)

Il metodo match() funziona in modo simile. Esso consente di cercare una sottostringa corrispondente. Tuttavia, se usate l'indicatore global in un modello di espressione regolare, come nell'esempio seguente, il metodo match() restituisce un array di sottostringhe corrispondenti:

var str:String = "bob@example.com, omar@example.org"; 
var pattern:RegExp = /\w*@\w*\.[org|com]+/g; 
var results:Array = str.match(pattern);

L'array results è impostato come segue:

["bob@example.com","omar@example.org"]

Per ulteriori informazioni sulle espressioni regolari, vedete Uso delle espressioni regolari .

Sostituzione di sottostringhe corrispondenti

Utilizzate il metodo replace() per cercare un modello specifico all'interno di una stringa e sostituire le corrispondenze trovate con la stringa specificata, come illustrato nell'esempio seguente:

var str:String = "She sells seashells by the seashore."; 
var pattern:RegExp = /sh/gi; 
trace(str.replace(pattern, "sch")); //sche sells seaschells by the seaschore. 

Notate come, nell'esempio, nelle stringe corrispondenti non si fa distinzione tra lettere maiuscole e minuscole, in quanto è stato impostato l'indicatore i ( ignoreCase ) nell'espressione regolare e le corrispondenze multiple vengono sostituite in quanto è stato specificato l'indicatore g ( global ). Per ulteriori informazioni, vedete Uso delle espressioni regolari .

Nella stringa di sostituzione è possibile includere i seguenti codici di sostituzione $ . Il testo di sostituzione visualizzato nella tabella seguente viene inserito al posto del codice di sostituzione $ :

Ad esempio, il codice seguente illustra l'utilizzo dei codici sostitutivi $2 e $1 , che rappresentano il primo e il secondo gruppo di cattura di cui è stata trovata una corrispondenza:

var str:String = "flip-flop"; 
var pattern:RegExp = /(\w+)-(\w+)/g; 
trace(str.replace(pattern, "$2-$1")); // flop-flip

È possibile usare una funzione come secondo parametro del metodo replace() . Il testo corrispondente viene sostituito dal valore restituito dalla funzione.

var str:String = "Now only $9.95!"; 
var price:RegExp = /\$([\d,]+.\d+)+/i; 
trace(str.replace(price, usdToEuro)); 
 
function usdToEuro(matchedSubstring:String,                                  capturedMatch1:String,                                  index:int,                                  str:String):String 
{ 
    var usd:String = capturedMatch1; 
    usd = usd.replace(",", ""); 
    var exchangeRate:Number = 0.853690; 
    var euro:Number = parseFloat(usd) * exchangeRate; 
    const euroSymbol:String = String.fromCharCode(8364); 
    return euro.toFixed(2) + " " + euroSymbol; 
}

Se usate una funzione come secondo parametro del metodo replace() , alla funzione vengono inviati i seguenti argomenti:

• La porzione corrispondente della stringa.

• Tutte le corrispondenze dei gruppi parentetici catturati. Il numero di argomenti passati in questo modo varia a seconda del numero di corrispondenze parentetiche. Potete determinare il numero di corrispondenze parentetiche verificando il valore arguments.length - 3 all'interno del codice della funzione.

• La posizione di indice nella stringa in cui inizia la corrispondenza.

• La stringa completa.