BitmapFilter - Guida di riferimento alle API Adobe ActionScript® 3 (AS3 )

Pacchetto	flash.filters
Classe	public class BitmapFilter
Ereditarietà	BitmapFilter Object
Sottoclassi	BevelFilter, BlurFilter, ColorMatrixFilter, ConvolutionFilter, DisplacementMapFilter, DropShadowFilter, GlowFilter, GradientBevelFilter, GradientGlowFilter, ShaderFilter

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9

La classe BitmapFilter è la classe base per tutti gli effetti di filtro immagine.

Le classi BevelFilter, BlurFilter, ColorMatrixFilter, ConvolutionFilter, DisplacementMapFilter, DropShadowFilter, GlowFilter, GradientBevelFilter e GradientGlowFilter estendono tutte la classe BitmapFilter. Questi effetti filtro si possono applicare a qualsiasi oggetto di visualizzazione.

La classe BitmapFilter non può essere istanziata né estesa direttamente.

Vedere gli esempi

Proprietà pubbliche

Nascondi proprietà pubbliche ereditate

Mostra proprietà pubbliche ereditate

	Proprietà		Definito da
		constructor : Object Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto.	Object

Metodi pubblici

Nascondi metodi pubblici ereditati

Mostra metodi pubblici ereditati

	Metodo		Definito da
		clone():BitmapFilter Restituisce un oggetto BitmapFilter che è la copia esatta dell'oggetto BitmapFilter originale.	BitmapFilter
		hasOwnProperty(name:String):Boolean Indica se per un oggetto è definita una proprietà specifica.	Object
		isPrototypeOf(theClass:Object):Boolean Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro.	Object
		propertyIsEnumerable(name:String):Boolean Indica se la proprietà specificata esiste ed è enumerabile.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche.	Object
		toLocaleString():String Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate.	Object
		toString():String Restituisce la rappresentazione in formato stringa dell'oggetto specificato.	Object
		valueOf():Object Restituisce il valore di base dell'oggetto specificato.	Object

Descrizione dei metodi

clone

()

metodo

public function clone():BitmapFilter

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9

Restituisce un oggetto BitmapFilter che è la copia esatta dell'oggetto BitmapFilter originale.

Restituisce

BitmapFilter — Un oggetto BitmapFilter.

Esempi Come utilizzare questo esempio

BitmapFilterExample.as

Nell'esempio seguente viene descritto come è possibile applicare diversi filtri a un oggetto DisplayObject specifico e tenerne traccia mediante la proprietà filters.

package {
    import flash.display.Sprite;
    import flash.filters.*;

    public class BitmapFilterExample extends Sprite {
        public function BitmapFilterExample() {
            trace(this.filters.length);             // 0

            var tmpFilters:Array = this.filters;
            tmpFilters.push(FilterFactory.createFilter(FilterFactory.BEVEL_FILTER));
            tmpFilters.push(FilterFactory.createFilter(FilterFactory.GLOW_FILTER));
            this.filters = tmpFilters;

            trace(this.filters.length);             // 2
            trace(this.filters[0] is BitmapFilter); // true
            trace(this.filters[0] is BevelFilter);  // true
            trace(this.filters[1] is BitmapFilter); // true
            trace(this.filters[1] is GlowFilter);   // true
        }
    }
}

import flash.filters.*;
class FilterFactory {
    public static var BEVEL_FILTER:String = "BevelFilter";
    public static var BevelFilterConstructor:Class = BevelFilter;

    public static var BLUR_FILTER:String = "BlurFilter";
    public static var BlurFilterConstructor:Class = BlurFilter;

    public static var COLOR_MATRIX_FILTER:String = "ColorMatrixFilter";
    public static var ColorMatrixFilterConstructor:Class = ColorMatrixFilter;

    public static var CONVOLUTION_FILTER:String = "ConvolutionFilter";
    public static var ConvolutionFilterConstructor:Class = ConvolutionFilter;

    public static var DISPLACEMENT_MAP_FILTER:String = "DisplacementMapFilter";
    public static var DisplacementMapFilterConstructor:Class = DisplacementMapFilter;

    public static var DROP_SHADOW_FILTER:String = "DropShadowFilter";
    public static var DropShadowFilterConstructor:Class = DropShadowFilter;

    public static var GLOW_FILTER:String = "GlowFilter";
    public static var GlowFilterConstructor:Class = GlowFilter;

    public static var GRADIENT_BEVEL_FILTER:String = "GradientBevelFilter";
    public static var GradientBevelFilterConstructor:Class = GradientBevelFilter;

    public static var GRADIENT_GLOW_FILTER:String = "GradientGlowFilter";
    public static var GradientGlowFilterConstructor:Class = GradientGlowFilter;

    public static function createFilter(type:String):BitmapFilter {
        return new FilterFactory[type + "Constructor"]();   
    }
}

Note legali | Informativa sulla privacy online

BitmapFilter - AS3

Classi x

clone