GlowFilter  - AS3

Il valore di trasparenza alfa del colore. I valori validi sono compresi tra 0 e 1. Ad esempio, 0.25 imposta un valore di trasparenza del 25%. Il valore predefinito è 1.

La quantità di sfocatura orizzontale. I valori validi sono compresi tra 0 e 255 (virgola mobile). Il valore predefinito è 6. I valori che sono potenze di 2 (come 2, 4, 8, 16 e 32) vengono ottimizzati per eseguire il rendering più rapidamente di altri valori.

La quantità di sfocatura verticale. I valori validi sono compresi tra 0 e 255 (virgola mobile). Il valore predefinito è 6. I valori che sono potenze di 2 (come 2, 4, 8, 16 e 32) vengono ottimizzati per eseguire il rendering più rapidamente di altri valori.

Il colore del bagliore. I valori validi sono espressi nel formato esadecimale 0x RRGGBB. Il valore predefinito è 0xFF0000.

Specifica se il bagliore è interno. Il valore true indica un bagliore interno. Il valore predefinito è false, che indica un bagliore esterno (ovvero un bagliore attorno ai bordi esterni dell'oggetto).

Specifica se l'oggetto presenta un effetto di foratura. Un valore true rende trasparente il riempimento dell'oggetto e rivela il colore di sfondo del documento. Il valore predefinito è false (nessun effetto di foratura).

Il numero di applicazioni del filtro. Il valore predefinito è BitmapFilterQuality.LOW, che equivale ad applicare il filtro una volta. Il valore BitmapFilterQuality.MEDIUM applica il filtro due volte; il valore BitmapFilterQuality.HIGH lo applica tre volte. Il rendering dei filtri con valori bassi avviene più rapidamente.

Per la maggior parte delle applicazioni è sufficiente un valore quality basso, medio o alto. Benché sia possibile utilizzare valori numerici aggiuntivi fino a 15 per ottenere effetti diversi, il rendering dei valori elevati avviene più lentamente. Anziché aumentare il valore di quality, spesso è possibile ottenere un effetto simile (e con un rendering più veloce) semplicemente incrementando i valori delle proprietà blurX e blurY.

Elementi API correlati

L'intensità dell'impressione o applicazione. Più elevato è il valore, maggiore è la quantità di colore impressa e maggiore è il contrasto tra il bagliore e lo sfondo. I valori validi sono compresi tra 0 e 255. Il valore predefinito è 2.

Inizializza una nuova istanza GlowFilter con i parametri specificati.

Elementi API correlati

Restituisce una copia di questo oggetto filtro.

1. Importare le classi richieste.
2. Dichiarate tre proprietà utilizzate nella funzione draw(), che utilizza i metodi della classe Graphics a cui si accede tramite la proprietà graphics di Sprite per disegnare un quadrato arancione.
3. Create la funzione di costruzione che esegue le seguenti operazioni:
   • Chiama la funzione draw per creare un rettangolo.
   • Crea un oggetto BitmapFilter glowFilter e gli assegna i valori restituiti dalla funzione getBitmapFilter().
   • Assegna l'array di valori dell'oggetto glowFilter alla proprietà filters dell'oggetto di visualizzazione principale (root). In questo caso, tutti gli oggetti di visualizzazione secondari dell'oggetto root ereditano le proprietà del filtro bagliore. Pertanto, il rettangolo creato nella funzione draw() visualizza le proprietà del filtro bagliore.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.GlowFilter;

    public class GlowFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function GlowFilterExample() {
        //draw the rectangle using the draw() function below
            draw();
            
        //assign the values from getBitmapFilter function below
        //to a BitmapFilter object "glowFilter"
            var glowFilter:BitmapFilter = getBitmapFilter();
            
        //populate the filters property of the root display object with the array of values
        //from the glowFilter object.
            filters = [ glowFilter ];
        }

        private function getBitmapFilter():BitmapFilter {
            var color:Number = 0x33CCFF;
            var alpha:Number = 0.8;
            var blurX:Number = 35;
            var blurY:Number = 35;
            var strength:Number = 2;
            var inner:Boolean = false;
            var knockout:Boolean = false;
            var quality:Number = BitmapFilterQuality.HIGH;

            return new GlowFilter(color,
                                  alpha,
                                  blurX,
                                  blurY,
                                  strength,
                                  quality,
                                  inner,
                                  knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}