DropShadowFilter  - AS3

Il valore di trasparenza alfa del colore d'ombra. I valori validi sono compresi tra 0,0 e 1,0. Ad esempio, 0.25 imposta un valore di trasparenza del 25%. Il valore predefinito è 1,0.

L'angolo dell'ombra. I valori validi sono compresi tra 0 e 360 gradi (virgola mobile). Il valore predefinito è 45.

La quantità di sfocatura orizzontale. I valori validi sono compresi tra 0 e 255,0 (virgola mobile). Il valore predefinito è 4,0.

La quantità di sfocatura verticale. I valori validi sono compresi tra 0 e 255,0 (virgola mobile). Il valore predefinito è 4,0.

Il colore dell'ombra. I valori validi sono espressi nel formato esadecimale 0xRRGGBB. Il valore predefinito è 0x000000.

La distanza di offset dell'ombra, in pixel. Il valore predefinito è 4,0 (virgola mobile).

Indica se l'oggetto è nascosto o meno. Il valore true indica che l'oggetto stesso non è disegnato e che è visibile solo l'ombra. Il valore predefinito è false (l'oggetto è visibile).

Indica se l'ombra è interna o meno. Il valore true indica un'ombra interna. Il valore predefinito è false, che indica un'ombra esterna, ovvero un'ombra attorno ai bordi esterni dell'oggetto.

Applica un effetto di foratura (true) che rende trasparente il riempimento dell'oggetto e rivela il colore di sfondo del documento. Il valore predefinito è false (nessuna foratura).

Il numero di applicazioni del filtro. Il valore predefinito è BitmapFilterQuality.LOW, che equivale ad applicare il filtro una volta. Il valore BitmapFilterQuality.MEDIUM applica il filtro due volte; il valore BitmapFilterQuality.HIGH lo applica tre volte. Il rendering dei filtri con valori bassi avviene più rapidamente.

Per la maggior parte delle applicazioni è sufficiente un valore quality basso, medio o alto. Benché sia possibile utilizzare valori numerici aggiuntivi fino a 15 per ottenere effetti diversi, il rendering dei valori elevati avviene più lentamente. Anziché aumentare il valore di quality, spesso è possibile ottenere un effetto simile (e con un rendering più veloce) semplicemente incrementando i valori delle proprietà blurX e blurY.

Elementi API correlati

L'intensità dell'impressione o applicazione. Più elevato è il valore, maggiore è la quantità di colore impressa e maggiore è il contrasto tra l'ombra e lo sfondo. I valori validi sono compresi tra 0 e 255,0. Il valore predefinito è 1.0.

Crea una nuova istanza DropShadowFilter con i parametri specificati.

Elementi API correlati

Restituisce una copia di questo oggetto filtro.

1. Dichiarate le tre proprietà utilizzate per disegnare il quadrato a cui è applicato il filtro.
2. Create la funzione di costruzione La funzione di costruzione chiama il metodo draw(), che utilizza i metodi della classe Graphics a cui si accede tramite la proprietà graphics di Sprite per disegnare un quadrato arancione.
3. Nella funzione di costruzione dichiarare una variabile filter come oggetto BitmapFilter e assegnarla al valore restituito di una chiamata a getBitmapFilter(). Il metodo getBitmapFilter() definisce il filtro filtro ombra esterna utilizzato.
4. Create un nuovo oggetto Array myFilters e aggiungete filter all'array. Assegnate l'array myFilters alla proprietà filters dell'oggetto DropShadowFilterExample. In questo modo vengono applicati tutti i filtri presenti in myFilters; in questo caso solo filter.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.DropShadowFilter;

    public class DropShadowFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function DropShadowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var color:Number = 0x000000;
            var angle:Number = 45;
            var alpha:Number = 0.8;
            var blurX:Number = 8;
            var blurY:Number = 8;
            var distance:Number = 15;
            var strength:Number = 0.65;
            var inner:Boolean = false;
            var knockout:Boolean = false;
            var quality:Number = BitmapFilterQuality.HIGH;
            return new DropShadowFilter(distance,
                                        angle,
                                        color,
                                        alpha,
                                        blurX,
                                        blurY,
                                        strength,
                                        quality,
                                        inner,
                                        knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}