BevelFilter  - AS3

L'angolo della smussatura. I valori validi sono compresi tra 0 e 360°. L'impostazione predefinita è 45°.

Il valore angle rappresenta l'angolazione della fonte di luce teorica che cade sull'oggetto e determina la posizione dell'effetto rispetto all'oggetto. Se la proprietà distance è impostata su 0, l'effetto non è spostato rispetto all'oggetto e pertanto la proprietà angle non ha alcun effetto.

La quantità di sfocatura orizzontale espressa in pixel. I valori validi sono compresi tra 0 e 255 (virgola mobile). Il valore predefinito è 4. I valori che sono potenze di 2 (come 2, 4, 8, 16 e 32) vengono ottimizzati per eseguire il rendering più rapidamente di altri valori.

La quantità di sfocatura verticale espressa in pixel. I valori validi sono compresi tra 0 e 255 (virgola mobile). Il valore predefinito è 4. I valori che sono potenze di 2 (come 2, 4, 8, 16 e 32) vengono ottimizzati per eseguire il rendering più rapidamente di altri valori.

La distanza di offset della smussatura. I valori validi sono espressi in pixel (virgola mobile). Il valore predefinito è 4.

Il valore di trasparenza alfa del colore di evidenziazione. Il valore viene specificato sotto forma di valore normalizzato compreso tra 0 e 1. Ad esempio, 0.25 imposta un valore di trasparenza del 25%. Il valore predefinito è 1.

Il colore di evidenziazione della smussatura. I valori validi sono espressi nel formato esadecimale 0xRRGGBB. Il valore predefinito è 0xFFFFFF.

Applica un effetto di foratura (true) che rende trasparente il riempimento dell'oggetto e rivela il colore di sfondo del documento. Il valore predefinito è false (nessuna foratura).

Il numero di applicazioni del filtro. Il valore predefinito è BitmapFilterQuality.LOW, che equivale ad applicare il filtro una volta. Il valore BitmapFilterQuality.MEDIUM applica il filtro due volte; il valore BitmapFilterQuality.HIGH lo applica tre volte. Il rendering dei filtri con valori bassi avviene più rapidamente.

Per la maggior parte delle applicazioni è sufficiente un valore quality basso, medio o alto. Benché sia possibile utilizzare valori numerici aggiuntivi fino a 15 per ottenere effetti diversi, il rendering dei valori elevati avviene più lentamente. Anziché aumentare il valore di quality, spesso è possibile ottenere un effetto simile (e con un rendering più veloce) semplicemente incrementando i valori delle proprietà blurX e blurY.

Per specificare i valori della proprietà quality è possibile utilizzare le seguenti costanti di BitmapFilterQuality:

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

Il valore di trasparenza alfa del colore d'ombra. Il valore viene specificato sotto forma di valore normalizzato compreso tra 0 e 1. Ad esempio, 0.25 imposta un valore di trasparenza del 25%. Il valore predefinito è 1.

Il colore d'ombra della smussatura. I valori validi sono espressi nel formato esadecimale 0xRRGGBB. Il valore predefinito è 0x000000.

L'intensità dell'impressione o applicazione. I valori validi sono compresi tra 0 e 255. Più elevato è il valore, maggiore è la quantità di colore impressa e maggiore è il contrasto tra lo smusso e lo sfondo. Il valore predefinito è 1.

La posizione della smussatura sull'oggetto. Le smussature interne ed esterne vengono collocate sul bordo interno o esterno; la smussatura completa viene collocata su tutto l'oggetto. I valori validi sono le costanti di BitmapFilterType:

• BitmapFilterType.INNER
• BitmapFilterType.OUTER
• BitmapFilterType.FULL

Inizializza una nuova istanza BevelFilter con i parametri specificati.

Elementi API correlati

Restituisce una copia di questo oggetto filtro.

1. Importare le classi richieste.
2. Dichiarate tre proprietà utilizzate nella funzione draw(), che disegna l'oggetto a cui viene applicato il filtro di smussatura.
3. Create la funzione di costruzione BevelFilterExample(), che esegue le seguenti operazioni:
   • Chiama la funzione draw(), che viene dichiarata successivamente.
   • Dichiara la variabile filter come oggetto BitmapFilter e la assegna al valore restituito di una chiamata a getBitmapFilter().
   • Crea un nuovo oggetto Array myFilters e aggiunge filter all'array, quindi assegna myFilters alla proprietà filters dell'oggetto BevelFilterExample. In questo modo vengono applicati tutti i filtri presenti in myFilters; in questo caso solo filter.
4. Create la funzione getBitmapFilter per creare e impostare le proprietà per il filtro.
5. Create la funzione draw(). Questa funzione utilizza i metodi della classe Graphics, a cui si accede tramite la proprietà graphics della classe Sprite, per disegnare il quadrato.

package {
    import flash.display.Sprite;
    import flash.filters.BevelFilter;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;

    public class BevelFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BevelFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var distance:Number       = 5;
            var angleInDegrees:Number = 45;
            var highlightColor:Number = 0xFFFF00;
            var highlightAlpha:Number = 0.8;
            var shadowColor:Number    = 0x0000FF;
            var shadowAlpha:Number    = 0.8;
            var blurX:Number          = 5;
            var blurY:Number          = 5;
            var strength:Number       = 5;
            var quality:Number        = BitmapFilterQuality.HIGH;
            var type:String           = BitmapFilterType.INNER;
            var knockout:Boolean      = false;

            return new BevelFilter(distance,
                                   angleInDegrees,
                                   highlightColor,
                                   highlightAlpha,
                                   shadowColor,
                                   shadowAlpha,
                                   blurX,
                                   blurY,
                                   strength,
                                   quality,
                                   type,
                                   knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}