DisplacementMapFilter  - AS3

Specifica quale valore di trasparenza alfa deve essere utilizzato per gli spostamenti fuori dei limiti. Il valore viene specificato sotto forma di valore normalizzato compreso tra 0,0 e 1,0. Ad esempio, 0.25 imposta un valore di trasparenza del 25%. Il valore predefinito è 0. Utilizzate questa proprietà se la proprietà mode è impostata su DisplacementMapFilterMode.COLOR.

Specifica quale colore utilizzare per gli spostamenti fuori dei limiti. L'intervallo valido è compreso tra 0,0 e 1,0. I valori sono espressi in formato esadecimale. Il valore predefinito di color è 0. Utilizzate questa proprietà se la proprietà mode è impostata su DisplacementMapFilterMode.COLOR.

Descrive il canale di colore da utilizzare nell'immagine della mappa per spostare il risultato di x. I valori possibili sono costanti di BitmapDataChannel:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Elementi API correlati

Descrive il canale di colore da utilizzare nell'immagine della mappa per spostare il risultato di y. I valori possibili sono costanti di BitmapDataChannel:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Elementi API correlati

Un oggetto BitmapData contenente i dati della mappa di spostamento.

Elementi API correlati

Un valore che contiene l'offset dell'angolo superiore sinistro dell'oggetto di visualizzazione di destinazione rispetto all'angolo superiore sinistro dell'immagine della mappa.

Elementi API correlati

La modalità del filtro. I valori possibili sono costanti di DisplacementMapFilterMode:

• DisplacementMapFilter.Mode.WRAP - Applica il valore di spostamento all'altro lato dell'immagine di origine.
• DisplacementMapFilter.Mode.WRAP - Fissa il valore di spostamento al bordo dell'immagine di origine.
• DisplacementMapFilter.Mode.IGNORE - Se il valore di spostamento non è incluso nell'intervallo consentito, ignora lo spostamento e utilizza il pixel di origine.
• DisplacementMapFilter.Mode.COLOR - Se il valore di spostamento si trova all'esterno dell'immagine, sostituisce i valori delle proprietà color e alpha.

Elementi API correlati

Il moltiplicatore da utilizzare per modificare in scala il risultato dello spostamento di x dal calcolo della mappa.

Il moltiplicatore da utilizzare per modificare in scala il risultato dello spostamento di y dal calcolo della mappa.

Inizializza una nuova istanza DisplacementMapFilter con i parametri specificati.

Elementi API correlati

Restituisce una copia di questo oggetto filtro.

1. La classe definisce le variabili per il colore di sfondo, per l'etichetta del campo di testo e per le dimensioni e l'offset che saranno utilizzate nelle diverse funzioni.
2. La funzione di costruzione chiama il metodo draw(), che utilizza i metodi della classe Graphics per disegnare un quadrato con un riempimento con gradiente radiale. Notate che graphics è una proprietà dell'oggetto DisplacementMapFilterExample, che estende Sprite.
3. La funzione di costruzione chiama il metodo createLabel(), che crea un campo di testo per la visualizzazione del valore di labelText e lo aggiunge all'elenco di visualizzazione.
4. La funzione di costruzione chiama il metodo createFilter() che esegue le seguenti operazioni:
   • Crea una variabile denominata filter per l'oggetto Filter.
   • Chiama il metodo getDisplacementMapFilter() e assegna il relativo valore restituito alla variabile filter.
   • Passa filter alla proprietà filters dell'oggetto DisplacementFilterExample (la classe principale).
5. Il metodo getBitmapFilter() crea un oggetto BitmapData denominato mapBitmap a cui assegna i risultati del metodo createBitmapData(). L'oggetto mapBitmap, insieme ad altre variabili, definisce un nuovo filtro mappa di spostamento.
6. Il metodo createBitmapData() crea un nuovo oggetto BitmapData basato sul contenuto corrente dell'oggetto DisplacementMapFilterExample. Crea una nuova bitmap basata su bitmapData e la aggiunge allo stage.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.BitmapDataChannel;
    import flash.display.GradientType;
    import flash.display.SpreadMethod;
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.DisplacementMapFilter;
    import flash.filters.DisplacementMapFilterMode;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.text.TextField;
    
    public class DisplacementMapFilterExample extends Sprite {
        private var bgColor:uint     = 0xFFCC00;
        private var size:uint        = 200;
        private var offset:uint      = 90;
        private var labelText:String = "Watch the text bend with the displacement map";

        public function DisplacementMapFilterExample() {
            draw();
            createLabel();
            createFilter();
        }

        private function createFilter():void {
            var filter:BitmapFilter = getBitmapFilter();
            filters = new Array(filter);
        }

        private function getBitmapFilter():BitmapFilter {
            var mapBitmap:BitmapData = createBitmapData();
            var mapPoint:Point       = new Point(0, 0);
            var channels:uint        = BitmapDataChannel.RED;
            var componentX:uint      = channels;
            var componentY:uint      = channels;
            var scaleX:Number        = 0.5;
            var scaleY:Number        = -30;
            var mode:String          = DisplacementMapFilterMode.CLAMP;
            var color:uint           = 0;
            var alpha:Number         = 0;
            return new DisplacementMapFilter(mapBitmap,
                                             mapPoint,
                                             componentX,
                                             componentY,
                                             scaleX,
                                             scaleY,
                                             mode,
                                             color,
                                             alpha);
        }

        private function draw():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(size, size);
            graphics.beginGradientFill(GradientType.RADIAL,
                                       [0xFF0000, 0x0000FF],
                                       [100, 100],
                                       [55, 200],
                                       matrix,
                                       SpreadMethod.PAD);
            graphics.drawRect(0, 0, size, size);
        }

        private function createBitmapData():BitmapData {
            var bitmapData:BitmapData = new BitmapData(size, size, true, bgColor);
            bitmapData.draw(this, new Matrix());
            var bitmap:Bitmap = new Bitmap(bitmapData);
            bitmap.x = size;
            addChild(bitmap);
            return bitmapData;
        }

        private function createLabel():void {
            var tf:TextField = new TextField();
            tf.text = labelText;
            tf.y = offset;
            tf.width = size;
            addChild(tf);
        }
    }
}