GradientGlowFilter  - AS3

Un array di valori di trasparenza alfa per i colori corrispondenti nell'array colors. I valori validi per ciascun elemento dell'array sono compresi tra 0 e 1. Ad esempio, 0,25 imposta il valore di trasparenza alfa sul 25%.

Non è possibile cambiare la proprietà alphas mediante la modifica diretta dei relativi valori. Al contrario, è necessario ottenere un riferimento a alphas, modificarlo e quindi impostare alphas sul riferimento.

Le proprietà colors, alphas e ratios sono correlate. Il primo elemento dell'array colors corrisponde al primo elemento dell'array alphas e dell'array ratios, e così via.

Elementi API correlati

L'angolo, espresso in gradi. I valori validi sono compresi tra 0 e 360. Il valore predefinito è 45.

Il valore angle rappresenta l'angolazione della fonte di luce teorica che cade sull'oggetto e determina la posizione dell'effetto rispetto all'oggetto. Se distance è impostata su 0, l'effetto non è spostato rispetto all'oggetto e pertanto la proprietà angle non ha alcun effetto.

La quantità di sfocatura orizzontale. I valori validi sono compresi tra 0 e 255. Un valore di sfocatura pari a 1 o inferiore indica che l'immagine viene copiata senza alterazioni. Il valore predefinito è 4. I valori che sono potenze di 2 (come 2, 4, 8, 16 e 32) vengono ottimizzati per eseguire il rendering più rapidamente di altri valori.

La quantità di sfocatura verticale. I valori validi sono compresi tra 0 e 255. Un valore di sfocatura pari a 1 o inferiore indica che l'immagine viene copiata senza alterazioni. Il valore predefinito è 4. I valori che sono potenze di 2 (come 2, 4, 8, 16 e 32) vengono ottimizzati per eseguire il rendering più rapidamente di altri valori.

Un array di colori che definisce un gradiente. Ad esempio il rosso è 0xFF0000, il blu è 0x0000FF e così via.

Non è possibile cambiare la proprietà colors mediante la modifica diretta dei relativi valori. È necessario invece ottenere un riferimento a colors, modificarlo e quindi impostare colors sul riferimento.

Le proprietà colors, alphas e ratios sono correlate. Il primo elemento dell'array colors corrisponde al primo elemento dell'array alphas e dell'array ratios, e così via.

Elementi API correlati

La distanza di offset del bagliore. Il valore predefinito è 4.

Specifica se l'oggetto presenta un effetto di foratura. L'effetto di foratura rende trasparente il riempimento dell'oggetto e rivela il colore di sfondo del documento. Il valore true specifica un effetto di foratura; il valore predefinito è false (nessun effetto di foratura).

Il numero di applicazioni del filtro. Il valore predefinito è BitmapFilterQuality.LOW, che equivale ad applicare il filtro una volta. Il valore BitmapFilterQuality.MEDIUM applica il filtro due volte; il valore BitmapFilterQuality.HIGH lo applica tre volte. Il rendering dei filtri con valori bassi avviene più rapidamente.

Per la maggior parte delle applicazioni è sufficiente un valore quality basso, medio o alto. Benché sia possibile utilizzare valori numerici aggiuntivi fino a 15 per ottenere effetti diversi, il rendering dei valori elevati avviene più lentamente. Anziché aumentare il valore di quality, spesso è possibile ottenere un effetto simile (e con un rendering più veloce) semplicemente incrementando i valori delle proprietà blurX e blurY.

Elementi API correlati

Un array di rapporti di distribuzione del colore per i colori corrispondenti nell'array colors. I valori validi sono compresi tra 0 e 255.

Non è possibile cambiare la proprietà ratios mediante la modifica diretta dei relativi valori. È necessario invece ottenere un riferimento a ratios, modificarlo e quindi impostare ratios sul riferimento.

Le proprietà colors, alphas e ratios sono correlate. Il primo elemento dell'array colors corrisponde al primo elemento dell'array alphas e dell'array ratios, e così via.

Immaginate il filtro bagliore con gradiente come un bagliore che si diffonde dal centro dell'oggetto (se il valore di distance è impostato su 0); i gradienti sono strisce di colori che si fondono l'uno nell'altro. Il primo colore dell'array colors è il colore più esterno del bagliore. L'ultimo colore è il colore più interno del bagliore.

Ogni valore dell'array ratios determina la posizione del colore sul raggio del gradiente, in cui 0 e 255 rappresentano rispettivamente il punto più esterno e più interno del gradiente. I valori del rapporto possono variare da 0 a 255 pixel, aumentando di valore; ad esempio [0, 64, 128, 200, 255]. I valori compresi tra 0 e 128 appaiono sui bordi esterni del bagliore. I valori compresi tra 129 e 255 appaiono nell'area interna del bagliore. A seconda dei valori del rapporto dei colori e del valore type del filtro, i colori del filtro possono essere oscurati dall'oggetto a cui il filtro è applicato.

Nel codice e nell'immagine seguente viene applicato un filtro a un clip filmato con un cerchio nero, impostando il tipo su "full". A scopo di esemplificazione, il primo colore dell'array colors, il rosa, ha un valore alpha pari a 1, pertanto è visibile rispetto allo sfondo bianco (nella pratica si tende a non visualizzare il primo colore in questo modo). L'ultimo colore dell'array, il giallo, oscura il cerchio nero a cui è applicato il filtro:

	var colors:Array = [0xFFCCFF, 0x0000FF, 0x9900FF, 0xFF0000, 0xFFFF00];
	var alphas:Array = [1, 1, 1, 1, 1];
	var ratios:Array = [0, 32, 64, 128, 225];
	var myGGF:GradientGlowFilter = new GradientGlowFilter(0, 0, colors, alphas, ratios, 50, 50, 1, 2, "full", false);
	

Per ottenere un effetto uniforme sullo sfondo del documento quando si imposta il valore type su "outer" o "full", impostate il primo colore dell'array sullo stesso colore dello sfondo del documento o il valore di alfa del primo colore su 0; entrambe le tecniche consentono di fondere il filtro con lo sfondo.

Se effettuate due piccole modifiche al codice, l'effetto del bagliore può essere molto diverso, anche con gli stessi array ratios e colors. Impostate il valore di alfa del primo colore dell'array su 0 per consentire la fusione del filtro con lo sfondo bianco del documento e impostate la proprietà type su "outer" o "inner". Osservate i risultati mostrati nelle immagini seguenti.

Tenere presente che l'applicazione dei colori nel gradiente varia a seconda dei valori delle proprietà blurX, blurY, strength e quality nonché dei valori ratios.

Elementi API correlati

L'intensità dell'impressione o applicazione. Più elevato è il valore, maggiore è la quantità di colore impressa e maggiore è il contrasto tra il bagliore e lo sfondo. I valori validi sono compresi tra 0 e 255. Un valore pari a 0 indica che il filtro non è applicato. Il valore predefinito è 1.

La posizione dell'effetto filtro. I valori possibili sono costanti di flash.filters.BitmapFilterType:

• BitmapFilterType.OUTER - Bagliore applicato al bordo esterno dell'oggetto.
• BitmapFilterType.INNER - Bagliore applicato al bordo interno dell'oggetto; impostazione predefinita.
• BitmapFilterType.FULL - Bagliore applicato sopra l'oggetto.

Inizializza il filtro con i parametri specificati.

Restituisce una copia di questo oggetto filtro.

1. Importare le classi richieste.
2. Dichiarate le variabili globali utilizzate per definire il quadrato e il filtro.
3. Create la funzione di costruzione che esegue le seguenti operazioni:
   • Chiama il metodo draw(), che utilizza i metodi della classe Graphics a cui si accede tramite la proprietà graphics di Sprite per disegnare un quadrato.
   • Crea un oggetto BitmapFilter denominato filter e assegna ad esso il valore restituito da una chiamata a getBitmapFilter(), che crea il filtro.
   • Crea un nuovo array denominato myFilters e aggiunge filter ad esso.
   • Assegna myFilters alla proprietà filters dell'oggetto GradientGlowFilterExample. In questo modo vengono applicati tutti i filtri presenti in myFilters; in questo caso solo filter.

package {
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;
    import flash.filters.GradientGlowFilter;
    import flash.display.Sprite;

    public class GradientGlowFilterExample extends Sprite {
        private var bgColor:uint = 0xCCCCCC;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        private var distance:Number  = 0;
        private var angleInDegrees:Number = 45;
        private var colors:Array     = [0xFFFFFF, 0xFF0000, 0xFFFF00, 0x00CCFF];
        private var alphas:Array     = [0, 1, 1, 1];
        private var ratios:Array     = [0, 63, 126, 255];
        private var blurX:Number     = 50;
        private var blurY:Number     = 50;
        private var strength:Number  = 2.5;
        private var quality:Number   = BitmapFilterQuality.HIGH;
        private var type:String      = BitmapFilterType.OUTER;
        private var knockout:Boolean = false;

        public function GradientGlowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            return new GradientGlowFilter(distance,
                                          angleInDegrees,
                                          colors,
                                          alphas,
                                          ratios,
                                          blurX,
                                          blurY,
                                          strength,
                                          quality,
                                          type,
                                          knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}