ColorMatrixFilter  - AS3

Un array di 20 elementi per la trasformazione di colore 4 x 5. La proprietà matrix non può essere modificata variandone direttamente il valore (ad esempio, myFilter.matrix[2] = 1;). È necessario invece ottenere un riferimento all'array, apportare la modifica al riferimento e reimpostare il valore.

Il filtro matrice colore separa ogni singolo pixel di origine nei relativi componenti di rosso, verde, blu e alfa sotto forma di srcR, srcG, srcB, srcA. Per calcolare il risultato di ciascuno dei quattro canali si moltiplica il valore di ogni pixel dell'immagine per i valori della matrice di trasformazione. In via facoltativa è possibile aggiungere a ogni risultato (il quinto elemento in ogni riga della matrice) un offset compreso tra -255 e 255. Il filtro ricombina ogni componente di colore in un singolo pixel e scrive il risultato. Nella formula seguente, i valori da [0] a [19] corrispondono agli elementi da 0 a 19 nell'array di 20 elementi che viene passato alla proprietà matrix:

	redResult   = (a[0]  * srcR) + (a[1]  * srcG) + (a[2]  * srcB) + (a[3]  * srcA) + a[4]
	greenResult = (a[5]  * srcR) + (a[6]  * srcG) + (a[7]  * srcB) + (a[8]  * srcA) + a[9]
	blueResult  = (a[10] * srcR) + (a[11] * srcG) + (a[12] * srcB) + (a[13] * srcA) + a[14]
	alphaResult = (a[15] * srcR) + (a[16] * srcG) + (a[17] * srcB) + (a[18] * srcA) + a[19]
	

Per ogni valore di colore dell'array, il valore 1 equivale all'invio del 100% di quel canale all'output, conservando il valore del canale di colore.

I calcoli vengono eseguiti su valori di colore non moltiplicati. Se l'elemento grafico di input è composto da valori di colore premoltiplicati, per questa operazione tali valori vengono automaticamente convertiti in valori di colore non moltiplicati.

Sono disponibili due modalità ottimizzate:

Solo alfa. Quando al filtro viene passata una matrice che regola solo il componente alfa, come illustrato di seguito, vengono ottimizzate le prestazioni del filtro:

	    1 0 0 0 0
	    0 1 0 0 0
	    0 0 1 0 0
	    0 0 0 N 0  (where N is between 0.0 and 1.0)
	

Versione più veloce. Disponibile solo con i processori abilitati per l'acceleratore SSE/AltiVec quali Intel^® Pentium^® 3 e versioni successive e Apple^® G4 e versioni successive. L'acceleratore viene utilizzato quando i valori da moltiplicare sono compresi tra -15,99 e 15,99 e i valori a[4], a[9], a[14] e a[19] da sommare sono compresi tra -8000 e 8000.

Inizializza una nuova istanza ColorMatrixFilter con i parametri specificati.

Restituisce una copia di questo oggetto filtro.

La funzione buildChild() crea un nuovo oggetto Loader denominato loader. Per ogni chiamata a buildChild(), associate un listener di eventi all'oggetto Loader per l'intercettazione degli eventi complete, che vengono gestiti dalla funzione passata a buildChild().

Le funzioni applyRed(), applyGreen() e applyBlue() utilizzano valori diversi per l'array matrix per ottenere effetti diversi.

Nota: per ottenere risultati ottimali, utilizzate un'immagine di circa 80 pixel di larghezza. Il nome e la posizione del file di immagine dovranno corrispondere al valore passato alla proprietà url. Ad esempio, il valore passato a url nell'esempio fa riferimento a un file di immagine denominato "Image.jpg" presente nella stessa directory del file SWF.

package {
    import flash.display.DisplayObject;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.filters.ColorMatrixFilter;
    import flash.net.URLRequest;

    public class ColorMatrixFilterExample extends Sprite {
        private var size:uint  = 140;
        private var url:String = "Image.jpg";

        public function ColorMatrixFilterExample() {
            buildChild(null);
            buildChild(applyRed);
            buildChild(applyGreen);
            buildChild(applyBlue);
        }

        private function buildChild(loadHandler:Function):void {
            var loader:Loader = new Loader();
            loader.x = numChildren * size;
            loader.y = size;
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            if (loadHandler != null) {
                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadHandler);
            }

            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function applyRed(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([1, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 0, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 0, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyGreen(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([0, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 1, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 0, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyBlue(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([0, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 0, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 1, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyFilter(child:DisplayObject, matrix:Array):void {
            var filter:ColorMatrixFilter = new ColorMatrixFilter(matrix);
            var filters:Array = new Array();
            filters.push(filter);
            child.filters = filters;
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}