TextLineMetrics  - AS3

Il valore ascent del testo è la lunghezza dalla base all'estremità superiore dell'altezza della riga, espressa in pixel. Vedete la misura "Ascent" nel diagramma della panoramica di questa classe.

Elementi API correlati

Il valore descent del testo è la lunghezza dalla base all'estremità inferiore della riga, espressa in pixel. Vedete la misura "Descent" nel diagramma della panoramica di questa classe.

Elementi API correlati

L'altezza del testo delle righe selezionate (non necessariamente di tutto il testo), espressa in pixel. L'altezza della riga di testo non include l'altezza del margine. Vedete la misura "Line height" nel diagramma della panoramica di questa classe.

Elementi API correlati

Il valore leading è la misura della distanza verticale tra le righe di testo. Vedete la misura "Leading" nel diagramma della panoramica di questa classe.

Elementi API correlati

Il valore larghezza rappresenta la larghezza del testo delle righe selezionate (non necessariamente di tutto il testo), espressa in pixel. La larghezza della riga di testo non è uguale alla larghezza del campo di testo, ma rappresenta la larghezza del campo di testo, meno la larghezza del margine centrale di 4 pixel (2 pixel su ciascun lato). Vedete la misura "Text Line width" nel diagramma della panoramica di questa classe.

Elementi API correlati

Il valore x è la posizione sinistra del primo carattere espressa in pixel. Questo valore include le larghezze del margine, dell'eventuale rientro e del margine di larghezza. Vedete "Text Line x-position" nel diagramma della panoramica di questa classe.

Elementi API correlati

Crea un oggetto TextLineMetrics. L'oggetto TextLineMetrics contiene le informazioni relative alle metriche del testo di una riga di testo in un campo. Gli oggetti di questa classe vengono restituiti dal metodo flash.text.TextField.getLineMetrics().

Vedete il diagramma nella panoramica di questa classe per una spiegazione delle proprietà in contesto.

Elementi API correlati

1. Create una proprietà denominata label del tipo TextField.
2. La funzione di costruzione chiama configureAssets(), che esegue le seguenti operazioni:
   • Imposta l'allineamento dello stage in alto a sinistra e senza scala.
   • Crea un nuovo oggetto TextField denominato label.
   • Abilita lo sfondo di label e imposta il bianco come colore.
   • Consente la distribuzione del testo di label su più righe mediante la funzione di a capo automatico.
   • Assegna il risultato di una chiamata a getLabelText() alla proprietà text di label. Il metodo getLabelText() crea una variabile di tipo XML e la assegna a un nodo XML denominato body, che viene compilato con una frase lunga.
   • Aggiunge label all'elenco di visualizzazione mediante addChild().
3. Viene quindi aggiunto un metodo listener per gli eventi resize eseguiti sullo stage e viene denominato resizeHandler(). Ogni volta che vengono modificate le dimensioni della finestra di Flash Player, viene inviato l'evento RESIZE e vengono eseguite le seguenti operazioni:
   • Viene chiamato il metodo draw() per garantire che label venga visualizzata al centro dello stage e sia racchiusa da un buffer di 10 pixel.
   • setTimeout() quindi esegue showMetrics() dopo un breve ritardo. Il ritardo viene aggiunto in quanto la metrica relativa alla riga non viene aggiornata fino al completamento dell'evento RESIZE e al ridisegno completo dello stage.
   • showMetrics() assegna una variabile TextLineMetrics denominata metrics al risultato di una chiamata a getLineMetrics() e questa variabile viene quindi passata a una nuova istanza di un'istanza LineMetricsReader denominata reader. Le due variabili vengono quindi utilizzate all'interno di chiamate a trace() per la stampa della prima (e unica) riga di label e delle informazioni fornite dall'istanza LineMetricsReader mediante il relativo metodo toString().
4. La funzione di costruzione forza l'invio singolo dell'evento resize per forzare il disegno corretto di label al primo caricamento del file SWF.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.text.TextField;
    import flash.text.TextLineMetrics;
    import flash.utils.setTimeout;

    public class TextLineMetricsExample extends Sprite {
        private var gutter:int = 10;
        private var label:TextField;

        public function TextLineMetricsExample() {
            configureAssets();
            configureListeners();
            resizeHandler(new Event(Event.RESIZE));
        }

        private function showMetrics():void {
            var metrics:TextLineMetrics = label.getLineMetrics(0);
            var reader:LineMetricsReader = new LineMetricsReader(metrics);
            trace("lineText: " + label.getLineText(0));
            trace("metrics: " + reader);
        }

        private function configureAssets():void {
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;

            label = new TextField();
            label.background = true;
            label.backgroundColor = 0xFFFFFF;
            label.multiline = true;
            label.wordWrap = true;
            label.text = getLabelText();
            addChild(label);
        }

        private function configureListeners():void {
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function resizeHandler(event:Event):void {
            draw();
            setTimeout(showMetrics, 100);
        }

        private function draw():void {
            label.x = gutter;
            label.y = gutter;
            label.width = stage.stageWidth - (gutter * 2);
            label.height = stage.stageHeight - (gutter * 2);
        }

        private function getLabelText():String {
            var text:XML = <body>The Flex product line enables developers to build rich Internet applications that blend the responsiveness of desktop software, the cross-platform reach of the web, and the expressiveness of the Flash Platform.</body>
            return text.toString();
        }
    }
}

import flash.text.TextLineMetrics;

class LineMetricsReader {
    private var metrics:TextLineMetrics;

    public function LineMetricsReader(metrics:TextLineMetrics) {
        this.metrics = metrics;
    }

    public function toString():String {
        return "[TextLineMetrics ascent:" + metrics.ascent
            + ", descent:" + metrics.descent
            + ", leading:" + metrics.leading
            + ", width:" + metrics.width
            + ", height:" + metrics.height
            + ", x:" + metrics.x
            + "]";
    }
}