SoundMixer  - AS3

Specifica la modalità di riproduzione audio di tutti gli oggetti Sound. Nei dispositivi mobili questa proprietà imposta le priorità del suono e il valore predefinito in base alla piattaforma. Negli ambienti desktop e TV, non esiste alcuna differenza funzionale tra le modalità audio e riproduzione.

I valori validi per questa proprietà sono definiti nella classe AudioPlaybackMode.

Nota In iOS, se un’applicazione imposta audioPlaybackMode=AudioPlaybackMode.VOICE, altre applicazioni non possono cambiarlo in AudioPlaybackMode.MEDIA.

Limitate il più possibile l’uso della modalità AudioPlaybackMode.VOICE e provate a passare alla modalità AudioPlaybackMode.MEDIA non appena potete dopo il termine della chiamata vocale, per consentire ad altre applicazioni di effettuare la riproduzione in modalità multimediale.

Quando modificate la modalità di riproduzione audio in iOS, le applicazioni native che riproducono musica effettuano una breve pausa.

Il valore predefinito è AudioPlaybackMode.MEDIA.

Elementi API correlati

Il numero di secondi per precaricare l'audio in streaming incorporato in un buffer prima dell'avvio dello streaming. Per un file SWF di un altro dominio non è possibile accedere ai dati dell'audio caricato (compreso il tempo di bufferizzazione), a meno che non venga implementato un file di criteri validi per domini diversi. Per ulteriori informazioni sulla sicurezza e sull'audio, vedete la descrizione della classe Sound. Per il codice di un file di un altro dominio non è possibile accedere ai dati dell'audio caricato (compreso il tempo di bufferizzazione) a meno che non venga implementato un file di criteri validi per domini diversi. Tuttavia, all'interno della sandbox di un'applicazione AIR, il codice può accedere ai dati dei file audio da qualsiasi origine. Per ulteriori informazioni sulla sicurezza e sull'audio, vedete la descrizione della classe Sound.

La proprietà SoundMixer.bufferTime incide solo sul tempo di bufferizzazione dell'audio in streaming incorporato in un file SWF ed è indipendente dagli oggetti Sound creati in modo dinamico (ovvero gli oggetti Sound creati in ActionScript). Il valore della proprietà SoundMixer.bufferTime non può sovrascrivere né impostare il valore predefinito del tempo di bufferizzazione specificato nell'oggetto SoundLoaderContext, che viene passato al metodo Sound.load().

Elementi API correlati

L'oggetto SoundTransform che controlla le proprietà audio globali. Gli oggetti SoundTransform comprendono proprietà per impostare il volume, la panoramica e l'assegnazione dell'altoparlante sinistro e destro. L'oggetto SoundTransform utilizzato in questa proprietà fornisce le impostazioni audio definitive che vengono applicate a tutti i suoni dopo l'applicazione delle eventuali impostazioni audio individuali.

Elementi API correlati

Attiva e disattiva la funzione vivavoce quando il dispositivo è in modalità voce. Per impostazione predefinita, gli smartphone usano l'auricolare per l'uscita audio quando la proprietà SoundMixer.audioPlaybackMode è impostata su AudioPlaybackMode.VOICE. La proprietà useSpeakerphoneForVoice permette di escludere l'output predefinito in modo da implementare un pulsante vivavoce in un'applicazione telefonica. Questa proprietà non ha effetto nelle modalità diverse da AudioPlaybackMode.VOICE. Negli ambienti desktop e TV, questa proprietà non ha effetto.

Nota In iOS, se l’applicazione ha impostato audioPlaybackMode=VOICE e un’altra applicazione sta riproducendo in modalità vocale, non potete impostare useSpeakerphoneForVoice=true.

Nota: in Android è necessario impostare l'elemento android.permission.MODIFY_AUDIO_SETTINGS nel descrittore dell'applicazione AIR, altrimenti la modifica di questo valore non ha alcun effetto. Inoltre, l'impostazione è quella globale del dispositivo. Le altre applicazioni in esecuzione sul dispositivo possono cambiare l'impostazione del dispositivo sottostante in qualsiasi momento.

Il valore predefinito è false.

Elementi API correlati

Determina se alcuni file audio non sono accessibili a causa delle restrizioni di sicurezza. Ad esempio, l'audio caricato da un dominio diverso da quello del contenuto che chiama questo metodo non è accessibile se il relativo server non dispone di un file di criteri URL che consente di accedere al dominio di tale dominio. L'audio può comunque essere caricato e riprodotto ma le operazioni di livello basso, quale l'acquisizione di metadati ID3 per l'audio, non possono essere eseguite se l'audio non è accessibile.

Per il contenuto di applicazioni AIR nella sandbox di sicurezza dell'applicazione, la chiamata a questo metodo restituisce sempre il valore false. Tutto l'audio, incluso quello caricato da altri domini, è accessibile al contenuto che si trova nella sandbox di sicurezza dell'applicazione.

Elementi API correlati

Scatta un'istantanea della forma d'onda corrente dell'audio e la inserisce nell'oggetto ByteArray specificato. I valori sono formattati come valori normalizzati a virgola mobile nell'intervallo compreso tra -1,0 e 1,0. L'oggetto ByteArray passato al parametro outputArray viene sovrascritto con i nuovi valori. Le dimensioni dell'oggetto ByteArray creato sono fissate in 512 valori a virgola mobile, di cui i primi 256 valori rappresentano il canale sinistro e gli altri 256 valori il canale destro.

Nota: questo metodo è soggetto a restrizioni di sicurezza per i file locali e a restrizioni per il caricamento di dati tra domini diversi. Se lavorate con file locali o con suoni caricati da un server appartenente a un dominio diverso da quello del contenuto chiamante, può essere necessario superare le restrizioni imposte dalla sandbox mediante un file di criteri validi per domini diversi. Per ulteriori informazioni, vedete la descrizione della classe Sound. Inoltre, questo metodo non può essere utilizzato per estrarre dati da flussi RTMP, anche se viene chiamato da contenuto residente nello stesso dominio del server RTMP.

questo metodo è supportato tramite RTMP in Flash Player 9.0.115.0 e versioni successive e in Adobe AIR. Potete controllare l'accesso agli streaming su Flash Media Server in uno script lato server. Per ulteriori informazioni vedete le proprietà Client.audioSampleAccess e Client.videoSampleAccess nel manuale Server-Side ActionScript Language Reference for Adobe Flash Media Server.

Parametri

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.Event;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.net.URLRequest;
    import flash.utils.ByteArray;
    import flash.text.TextField;

    public class SoundMixer_computeSpectrumExample extends Sprite {

        public function SoundMixer_computeSpectrumExample() {
            var snd:Sound = new Sound();
            var req:URLRequest = new URLRequest("Song1.mp3");
            snd.load(req);
            
            var channel:SoundChannel;
            channel = snd.play();
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
            channel.addEventListener(Event.SOUND_COMPLETE, onPlaybackComplete);
        }

        private function onEnterFrame(event:Event):void {
            var bytes:ByteArray = new ByteArray();
            const PLOT_HEIGHT:int = 200;
            const CHANNEL_LENGTH:int = 256;

            SoundMixer.computeSpectrum(bytes, false, 0);
            
            var g:Graphics = this.graphics;
            
            g.clear();
       
            g.lineStyle(0, 0x6600CC);
            g.beginFill(0x6600CC);
            g.moveTo(0, PLOT_HEIGHT);
            
            var n:Number = 0;
            
            for (var i:int = 0; i < CHANNEL_LENGTH; i++) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }

            g.lineTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            g.endFill();
 
            g.lineStyle(0, 0xCC0066);
            g.beginFill(0xCC0066, 0.5);
            g.moveTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            
            for (i = CHANNEL_LENGTH; i > 0; i--) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }
  
            g.lineTo(0, PLOT_HEIGHT);
            g.endFill();
        }
        
        private function onPlaybackComplete(event:Event):void {
            removeEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
    }
}

Interrompe la riproduzione di tutto l'audio.

>In Flash Professional, questo metodo non arresta l'indicatore di riproduzione. La riproduzione dei suoni impostati per la ripetizione riprende quando l'indicatore di riproduzione arriva nei fotogrammi in cui si trovano tali suoni.

Quando utilizzate questa proprietà, tenete presente il seguente modello di sicurezza:

• Per impostazione predefinita, quando chiamate il metodo SoundMixer.stopAll() vengono interrotti solo i suoni compresi nella stessa funzione di sicurezza sandbox dell'oggetto che chiama il metodo. Tutti i suoni la cui riproduzione non è stata avviata dalla stessa sandbox dell'oggetto chiamante non vengono interrotti.
• Quando caricate l'audio utilizzando il metodo load() della classe Sound è possibile specificare un parametro context, cioè un oggetto SoundLoaderContext. Se la proprietà checkPolicyFile dell'oggetto SoundLoaderContext viene impostata su true, Flash Player o Adobe AIR verifica la presenza di un file di criteri validi per domini diversi sul server da cui viene caricato l'audio. Se il file è presente sul server e consente l'interazione con il dominio del contenuto che effettua la chiamata, il file può interrompere l'audio caricato utilizzando il metodo SoundMixer.stopAll(); in caso contrario, non può eseguire questa operazione.

Tuttavia, in Adobe AIR, il contenuto della funzione di sicurezza sandbox dell'applicazione (contenuto installato con l'applicazione AIR) non è interessato da queste limitazioni di sicurezza.

Per ulteriori informazioni sulla sicurezza, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundLoaderContext;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.events.IOErrorEvent;

    public class SoundMixer_stopAllExample extends Sprite  {
        private var firstSound:Sound = new Sound();
        private var secondSound:Sound = new Sound();
        private var muteButton:TextField = new TextField();
        private var channel1:SoundChannel = new SoundChannel();
        
        public function SoundMixer_stopAllExample() {
            firstSound.load(new URLRequest("mySound.mp3"));
            secondSound.load(new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3"));

            firstSound.addEventListener(IOErrorEvent.IO_ERROR, firstSoundErrorHandler);
            secondSound.addEventListener(IOErrorEvent.IO_ERROR, secondSoundErrorHandler);
            
            channel1 = firstSound.play();
            secondSound.play();
            
            muteButton.autoSize = TextFieldAutoSize.LEFT;
            muteButton.border = true;
            muteButton.background = true;
            muteButton.text = "MUTE";
        
            muteButton.addEventListener(MouseEvent.CLICK, muteButtonClickHandler);         
        
            this.addChild(muteButton);
        }

        private function muteButtonClickHandler(event:MouseEvent):void {

            if(muteButton.text == "MUTE") {        
  
                if(SoundMixer.areSoundsInaccessible() == false) {
                    SoundMixer.stopAll();
                    muteButton.text = "click to play only one of sound.";
                }
                else {
                    muteButton.text = "The sounds are not accessible.";
                }
            }
           else {
                firstSound.play();        
                muteButton.text = "MUTE";
           }
        } 

        private function firstSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }

        private function secondSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }
    }
}