Sound  - AS3

Restituisce il numero di byte attualmente disponibili in questo oggetto Sound. Questa proprietà generalmente è utile solo per i file caricati dall'esterno.

Restituisce il numero totale di byte dell'oggetto Sound.

Fornisce l'accesso ai metadati contenuti in un file MP3.

I file audio MP3 possono contenere i tag ID3, che forniscono i metadati relativi a un file. Se un file audio MP3 caricato con il metodo Sound.load() contiene dei tag ID3, è possibile interrogare tali proprietà. Sono supportati solo i tag ID3 che utilizzano il set di caratteri UTF-8.

Flash Player 9 e versioni successive e AIR supportano i tag ID3 2.0, nello specifico 2.3 e 2.4. Le tabelle seguenti contengono l'elenco dei tag ID3 2.0 standard e del tipo di contenuto rappresentato dai tag. La proprietà Sound.id3 consente di accedere a questi tag tramite il formato my_sound.id3.COMM, my_sound.id3.TIME e così via. La prima tabella descrive i tag a cui si può accedere tramite il nome di proprietà ID3 2.0 o ActionScript. La seconda tabella descrive i tag ID3 supportati ma privi di proprietà predefinite in ActionScript.

La tabella seguente descrive i tag ID3 supportati ma privi di proprietà predefinite nella classe Sound. Per accedere a questi tag, chiamare mySound.id3.TFLT, mySound.id3.TIME e così via. NOTA: nessuno di questi tag è supportato in Flash Lite 4.

Quando utilizzate questa proprietà, tenete presente il modello di sicurezza di Flash Player:

• La proprietà id3 di un oggetto Sound è sempre consentita per i file SWF che si trovano nella stessa funzione di sicurezza sandbox del file audio. Per i file di altre sandbox esistono invece dei controlli di sicurezza.
• Quando caricate l'audio utilizzando il metodo load() della classe Sound è possibile specificare un parametro context, cioè un oggetto SoundLoaderContext. Se impostate la proprietà checkPolicyFile dell'oggetto SoundLoaderContext su true, Flash Player verifica la presenza di un file di criteri per gli URL sul server da cui viene caricato l'audio. Se esiste un file di criteri che consente l'accesso dal dominio del file SWF da caricare, il file può accedere alla proprietà id3 dell'oggetto Sound; in caso contrario, non vi può accedere.

Tuttavia, in Adobe AIR, il contenuto della funzione di sicurezza sandbox dell'applicazione (contenuto installato con l'applicazione AIR) non è interessato da queste limitazioni di sicurezza.

Per ulteriori informazioni sulla sicurezza, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.media.Sound;
    import flash.net.URLRequest;
    import flash.media.ID3Info;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.Event;

    public class Sound_id3Example extends Sprite {
        private var snd:Sound = new Sound();       
        private var myTextField:TextField = new TextField();

        public function Sound_id3Example() {
            snd.addEventListener(Event.ID3, id3Handler);
            snd.load(new URLRequest("mySound.mp3"));
        }
    
        private function id3Handler(event:Event):void {
            var id3:ID3Info = snd.id3;

            myTextField.autoSize = TextFieldAutoSize.LEFT;
            myTextField.border = true;

            myTextField.appendText("Received ID3 Info: \n");
              
            for (var propName:String in id3) {
                myTextField.appendText(propName + " = " + id3[propName] + "\n");
            }
 
            myTextField.appendText("\n" + "Artist: " + id3.artist + "\n");
            myTextField.appendText("Song name: " + id3.songName + "\n");
            myTextField.appendText("Album: " + id3.album + "\n\n"); 
 
            this.addChild(myTextField);
        }
    }
}

Restituisce lo stato di bufferizzazione dei file MP3 esterni. Se il valore è true, qualsiasi riproduzione in corso viene interrotta mentre l'oggetto attende altri dati.

Indica se la proprietà Sound.url è stata troncata. Quando il valore isURLInaccessible è true, il valore Sound.url corrisponde solo al dominio dell'URL finale dal quale il suono è stato caricato. Ad esempio, la proprietà viene troncata se il suono viene caricato da http://www.adobe.com/assets/hello.mp3 e la proprietà Sound.url ha il valore http://www.adobe.com. Il valore isURLInaccessible è true solo quando tutte le seguenti condizioni sono presenti:

• Si è verificato un reindirizzamento HTTP durante il caricamento del file sonoro.
• Il file SWF che chiama Sound.load() proviene da un dominio diverso dall'URL finale del file sonoro.
• Il file SWF che chiama Sound.load() non è autorizzato ad accedere al file sonoro. L'autorizzazione ad accedere al file sonoro viene concessa nello stesso modo dell'autorizzazione per la proprietà Sound.id3: definite un file di criteri e utilizzate la proprietà SoundLoaderContext.checkPolicyFile.

Nota: la proprietà isURLInaccessible è stata aggiunta per Flash Player 10.1 e AIR 2.0. Tuttavia, questa proprietà viene resa disponibile ai file SWF di tutte le versioni quando è supportata dal runtime di Flash. Di conseguenza, l'uso di alcuni tool di authoring in "modalità rigorosa" causa un errore di compilazione. Per ovviare all'errore, usate la sintassi indiretta mySound["isURLInaccessible"] o disattivate la modalità rigorosa. Se usate Flash Professional CS5 o Flex SDK 4.1, potete utilizzare e compilare questa API per i runtime rilasciati prima di Flash Player 10.1 e AIR 2.

Per il contenuto dell'applicazione AIR, il valore di questa proprietà è sempre false.

Elementi API correlati

La lunghezza in millisecondi del file audio corrente.

L'URL da cui è stato caricato l'audio. Questa proprietà è applicabile solo agli oggetti Sound caricati tramite il metodo Sound.load(). Per gli oggetti Sound associati a una risorsa audio di una libreria dei file SWF, il valore della proprietà url è null.

Quando si effettua la prima chiamata a Sound.load(), la proprietà url all'inizio ha valore null perché l'URL finale è ancora sconosciuto. La proprietà url avrà un valore non nullo non appena sarà inviato un evento open dall'oggetto Sound.

La proprietà url contiene l'URL finale assoluto da cui è stato caricato un file audio. Il valore di url in genere è uguale al valore passato al parametro stream di Sound.load(). Tuttavia, se a Sound.load() avete passato un URL relativo, il valore della proprietà url rappresenta l'URL assoluto. Inoltre, se la richiesta di URL originale viene reindirizzata da un server HTTP, il valore della proprietà url rispecchia l'URL finale da cui è stato effettivamente scaricato il file audio. Questa segnalazione di un URL assoluto e definitivo equivale al comportamento di LoaderInfo.url.

In alcuni casi, il valore della proprietà url viene troncato; per informazioni dettagliate, vedete la proprietà isURLInaccessible.

Elementi API correlati

Crea un nuovo oggetto Sound. Se viene passato un oggetto URLRequest valido alla funzione di costruzione Sound, questa effettua automaticamente la chiamata alla funzione load() per l'oggetto Sound. Se non viene passato un oggetto URLRequest valido alla funzione di costruzione Sound, è necessario che l'utente stesso effettui la chiamata alla funzione load() per l'oggetto Sound; in caso contrario, lo streaming non sarà caricato.

Una volta chiamata la funzione load() su un oggetto Sound, non è possibile caricare un file audio diverso in quell'oggetto Sound. Per caricare un file audio diverso, create un nuovo oggetto Sound.

Interrompe lo streaming e provoca l'arresto di tutte le operazioni di scaricamento dati. Dopo la chiamata al metodo close() non è più possibile leggere dati dallo streaming.

 
package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;    
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.errors.IOError;
    import flash.events.IOErrorEvent;

    public class Sound_closeExample extends Sprite {
        private var snd:Sound = new Sound();
        private var button:TextField = new TextField();
        private var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
        
        public function Sound_closeExample() {
            button.x = 10;
            button.y = 10;
            button.text = "START";
            button.border = true;
            button.background = true;
            button.selectable = false;
            button.autoSize = TextFieldAutoSize.LEFT;

            button.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(button);
        }

        private function clickHandler(e:MouseEvent):void {

            if(button.text == "START") {

                snd.load(req);
                snd.play();        

                snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);

                button.text = "STOP";
            }
            else if(button.text == "STOP") {
                    
                try {
                    snd.close();
                    button.text = "Wait for loaded stream to finish.";
                }
                catch (error:IOError) {
                    button.text = "Couldn't close stream " + error.message;    
                }
            }
        }
        
        private function errorHandler(event:IOErrorEvent):void {
                button.text = "Couldn't load the file " + event.text;
        }
    }
}

Estrae dati audio non elaborati da un oggetto Sound.

Questo metodo è progettato per essere utilizzato quando lavorate con audio generato dinamicamente, utilizzando una funzione assegnata all'evento sampleData per un oggetto Sound diverso. Ciò significa che il metodo può essere utilizzato per estrarre dati audio da un oggetto Sound. È quindi possibile scrivere i dati nell'array di byte che un altro oggetto Sound sta utilizzando per lo streaming dell'audio dinamico.

I dati audio vengono inseriti nell'array di byte di destinazione, a partire dalla posizione corrente dell'array di byte. I dati audio vengono sempre utilizzati come Stereo a 44100 Hz. Il tipo di campionamento è un valore a virgola mobile a 32 bit, che può essere convertito in un numero utilizzando ByteArray.readFloat().

Parametri

Elementi API correlati

var sourceSnd:Sound = new Sound();
var outputSnd:Sound = new Sound();
var urlReq:URLRequest = new URLRequest("test.mp3");

sourceSnd.load(urlReq);
sourceSnd.addEventListener(Event.COMPLETE, loaded);

function loaded(event:Event):void
{
    outputSnd.addEventListener(SampleDataEvent.SAMPLE_DATA, processSound);
    outputSnd.play();
}

function processSound(event:SampleDataEvent):void
{
    var bytes:ByteArray = new ByteArray();
    sourceSnd.extract(bytes, 4096);
    event.data.writeBytes(upOctave(bytes));
}

function upOctave(bytes:ByteArray):ByteArray
{
    var returnBytes:ByteArray = new ByteArray();
    bytes.position = 0;
    while(bytes.bytesAvailable > 0)
    {
        returnBytes.writeFloat(bytes.readFloat());
        returnBytes.writeFloat(bytes.readFloat());
        if (bytes.bytesAvailable > 0)
        {
            bytes.position += 8;
        }
    }
    return returnBytes;
}

Avvia il caricamento di un file MP3 esterno dall'URL specificato. Se alla funzione di costruzione Sound viene fornito un oggetto URLRequest valido, la funzione effettua automaticamente la chiamata a Sound.load(). La chiamata a Sound.load() deve essere effettuata dall'utente solo quando alla funzione di costruzione Sound non viene passato un oggetto URLRequest valido o viene passato un valore null.

Una volta chiamata la funzione load() su un oggetto Sound, non è possibile caricare un file audio diverso in quell'oggetto Sound. Per caricare un file audio diverso, create un nuovo oggetto Sound.

Quando utilizzate questo metodo, considerate il modello di sicurezza seguente:

• La chiamata a Sound.load() non è consentita se il file chiamante è nella sandbox locale con file system e l'audio è in una sandbox di rete.
• L'accesso da una sandbox locale affidabile o locale con collegamento di rete richiede l'autorizzazione dal sito Web tramite un file di criteri per gli URL.
• Non potete collegarvi alle porte comunemente riservate. Per un elenco completo di porte bloccate, vedete "Limitazioni delle API di connettività di rete" nella Guida per gli sviluppatori di ActionScript 3.0.
• È possibile impedire che un file SWF utilizzi questo metodo impostando il parametro allowNetworking dei tag object e embed nella pagina HTML che include il contenuto SWF.

In Flash Player 10 e versioni successive, se utilizzate un Content-Type multipart (ad esempio "multipart/form-data") che contiene un caricamento (indicato da un parametro "filename" in un'intestazione "content-disposition" nel corpo POST), l'operazione POST è soggetta alle regole di sicurezza applicate ai caricamenti:

• L'operazione POST deve essere eseguita come risposta a un'azione compiuta dall'utente, come un clic del mouse o la pressione di un tasto.
• Se l'operazione POST è tra più domini (il target POST non si trova sullo stesso server del file SWF che invia la richiesta POST), il server di destinazione deve fornire un file di criteri URL che consenta l'accesso tra più domini.

Inoltre, per qualsiasi Content-Type multipart, la sintassi deve essere valida (in conformità agli standard RFC2046). Se la sintassi non è valida, l'operazione POST è soggetta alle regole di sicurezza applicate ai caricamenti.

In Adobe AIR, il contenuto della sandbox di sicurezza dell'applicazione (contenuto installato con l'applicazione AIR) non è limitato da tali restrizioni di sicurezza.

Per ulteriori informazioni sulla sicurezza, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .

Parametri

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.ProgressEvent;
    import flash.events.IOErrorEvent;
    
    public class Sound_loadExample extends Sprite {
        private var snd:Sound = new Sound();
        private var statusTextField:TextField  = new TextField();

        public function Sound_loadExample(){

            statusTextField.autoSize = TextFieldAutoSize.LEFT;
            var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
            
            try {
            snd.load(req);
            
            snd.play();
            }
            catch (err:Error) {
                trace(err.message);
            }
 
            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            snd.addEventListener(ProgressEvent.PROGRESS, progressHandler);
                     
            this.addChild(statusTextField);
        }
    
        private function progressHandler(event:ProgressEvent):void {
            var loadTime:Number = event.bytesLoaded / event.bytesTotal;
            var LoadPercent:uint = Math.round(100 * loadTime);
              
            statusTextField.text = "Sound file's size in bytes: " + event.bytesTotal + "\n" 
                                 + "Bytes being loaded: " + event.bytesLoaded + "\n" 
                                 + "Percentage of sound file that is loaded " + LoadPercent + "%.\n";
        }
 
        private function errorHandler(errorEvent:IOErrorEvent):void {
            statusTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }
    }
}

Carica dati audio MP3 da un oggetto ByteArray a un oggetto Sound. I dati vengono letti dalla posizione ByteArray corrente fino alla posizione ByteArray alla fine della lunghezza di byte specificata. Se i dati audio MP3 contengono dati ID3, durante questa chiamata di funzione vengono inviati eventi ID3. Questa funzione genera un'eccezione se l'oggetto ByteArray non contiene dati sufficienti.

Parametri

Carica dati audio PCM 32-bit a virgola mobile da un oggetto ByteArray a un oggetto Sound. I dati vengono letti dalla posizione ByteArray corrente fino alla posizione ByteArray alla fine della lunghezza campione specificata moltiplicata per 1 canale o 2 canali se il flag stereo viene impostato al termine.

A partire da Flash Player 11.8, la quantità di dati audio che possono essere passati a questa funzione è limitata. Per le versioni SWF >= 21, questa funzione genera un’eccezione se la quantità di dati audio passata a questa funzione è superiore a 1800 secondi. Ovvero i campioni/la frequenza di campionamento deve essere minore o uguale a 1800. Per le versioni software precedenti alla 21, si verifica un errore nel runtime senza visualizzare messaggi se la quantità di dati audio passati supera il limite di 12000 secondi. Ciò viene reso disponibile solo per ragioni di compatibilità con le versioni precedenti.

Questa funzione solleva un’eccezione se l’oggetto ByteArray non contiene dati sufficienti.

Parametri

Genera un nuovo oggetto SoundChannel per la riproduzione dell'audio. Questo metodo restituisce un oggetto SoundChannel a cui è possibile accedere per interrompere l'audio e per controllare il volume (per controllare il volume, la panoramica e il bilanciamento, accedete all'oggetto SoundTransform assegnato al canale audio).

Parametri

Elementi API correlati

 
package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;
    import flash.media.Sound;;
    import flash.net.URLRequest;
    import flash.media.SoundChannel;
    import flash.events.ProgressEvent;
    import flash.events.Event;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.IOErrorEvent;
    
    public class Sound_playExample1 extends Sprite {
        private var snd:Sound = new Sound();
        private var channel:SoundChannel = new SoundChannel();
        private var infoTextField:TextField = new TextField();
    
        public function Sound_playExample1() {

            var req:URLRequest = new URLRequest("MySound.mp3");
            
            infoTextField.autoSize = TextFieldAutoSize.LEFT;
            infoTextField.text = "Please wait for the file to be loaded.\n" 
                                + "Then select from the bar to decide where the file should start.";
            
            snd.load(req);               
            channel = snd.play();

            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            snd.addEventListener(Event.COMPLETE, completeHandler);


            this.addChild(infoTextField);
        }

        private function completeHandler(event:Event):void {                
            infoTextField.text = "File is ready.";

            var bar:Sprite = new Sprite();

            bar.graphics.lineStyle(5, 0xFF0000);
            bar.graphics.moveTo(100, 100);
            bar.graphics.lineTo(200, 100);

            bar.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(bar);
        }
    
        private function clickHandler(event:MouseEvent):void {
            
                var position:uint = event.localX;
                var percent:uint = Math.round(position) - 100;   
                var cue:uint = (percent / 100) * snd.length;

                channel.stop();
                channel = snd.play(cue);    
        }

        private function errorHandler(errorEvent:IOErrorEvent):void {
            infoTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.media.Sound;
    import flash.net.URLRequest;

    public class Sound_playExample2 extends Sprite {
        private var button:Sprite = new Sprite(); 
        private var snd:Sound = new Sound();
            
        public function Sound_playExample2() {

            var req:URLRequest = new URLRequest("click.mp3");
            snd.load(req);               
     
            button.graphics.beginFill(0x00FF00);
            button.graphics.drawRect(10, 10, 50, 30);
            button.graphics.endFill();
     
            button.addEventListener(MouseEvent.CLICK, clickHandler);
            button.addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
     
            this.addChild(button);
        }

        private function clickHandler(event:MouseEvent):void {
            snd.play();            
        }

        private function doubleClickHandler(event:MouseEvent):void {
            snd.play(0, 2);        
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    
    public class Sound_playExample3 extends Sprite {
        private var snd:Sound = new Sound();
        private var channel:SoundChannel;
        private var statusTextField:TextField  = new TextField();

        public function Sound_playExample3(){

            statusTextField.autoSize = TextFieldAutoSize.LEFT;

           var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
            
            try {
                snd.load(req);
            
                channel = snd.play();
            }
            catch (err:Error) {
                trace(err.message);
            }
                    
            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            addEventListener(Event.ENTER_FRAME, enterFrameHandler);
            channel.addEventListener(Event.SOUND_COMPLETE, soundCompleteHandler);
                    
            this.addChild(statusTextField);
        }
    
        private function enterFrameHandler(event:Event):void {    
            var loadTime:Number = snd.bytesLoaded / snd.bytesTotal;
            var loadPercent:uint = Math.round(100 * loadTime);
            var estimatedLength:int = Math.ceil(snd.length / (loadTime));
            var playbackPercent:uint = Math.round(100 * (channel.position / estimatedLength));
      
            statusTextField.text = "Sound file's size is " + snd.bytesTotal + " bytes.\n" 
                                   + "Bytes being loaded: " + snd.bytesLoaded + "\n" 
                                   + "Percentage of sound file that is loaded " + loadPercent + "%.\n"
                                   + "Sound playback is " + playbackPercent + "% complete.";     
        }
 
        private function errorHandler(errorEvent:IOErrorEvent):void {
            statusTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }

        private function soundCompleteHandler(event:Event):void {
            statusTextField.text = "The sound has finished playing.";
            removeEventListener(Event.ENTER_FRAME, enterFrameHandler);
        }
    }
}

Inviato quando i dati sono stati caricati correttamente.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato da un oggetto Sound quando sono disponibili dati ID3 per il file audio MP3.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato quando si verifica un errore di input/output che impedisce l'operazione di caricamento.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato quando inizia un'operazione di caricamento.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato quando vengono ricevuti i dati nel corso di un'operazione di caricamento.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato quando il runtime richiede nuovi dati audio.

Questo evento ha le seguenti proprietà:

var mySound:Sound = new Sound();
function sineWaveGenerator(event:SampleDataEvent):void {
    for ( var c:int=0; c<8192; c++ ) {
        event.data.writeFloat(Math.sin((Number(c+event.position)/Math.PI/2))*0.25);
        event.data.writeFloat(Math.sin((Number(c+event.position)/Math.PI/2))*0.25);
    }
}

mySound.addEventListener(SampleDataEvent.SAMPLE_DATA,sineWaveGenerator);
mySound.play();

Elementi API correlati