URLRequest  - AS3

Specifica se le richieste di autenticazione devono essere gestite (true) o meno (false) per questa richiesta. Se false, i problemi di autenticazione restituiscono un errore HTTP.

I metodi di autenticazione supportati sono:

• Windows: HTTP Basic/Digest, Windows Integrated Authentication (compresi NTLM e Kerberos), SSL Certificate Authentication.
• Mac: HTTP Standard/Digest, NTLM, SSL Certificate Authentication.

Nota: i metodi FileReference.upload(), FileReference.download() e HTMLLoader.load() non supportano la proprietà URLRequest.authenticate.

Il valore predefinito è true.

Elementi API correlati

Specifica se i dati di risposta corretti devono essere memorizzati nella cache per questa richiesta. Quando è true, l'applicazione AIR utilizza la cache HTTP del sistema operativo.

Nota: il metodo HTMLLoader.load() non supporta la proprietà URLRequest.cacheResponse.

Il valore predefinito è true.

Elementi API correlati

Il tipo MIME del contenuto nella proprietà data.

Il valore predefinito è application/x-www-form-urlencoded.

Nota: i metodi FileReference.upload(), FileReference.download() e HTMLLoader.load() non supportano la proprietà URLRequest.contentType.

Quando inviate una richiesta POST, i valori delle proprietà contentType e data devono corrispondere correttamente. Il valore della proprietà contentType indica ai server come interpretare il valore della proprietà data.

• Se il valore della proprietà data è un oggetto URLVariables, il valore di contentType deve essere application/x-www-form-urlencoded.
• Se il valore della proprietà data è di qualsiasi altro tipo, il valore di contentType dovrebbe indicare il tipo di dati POST da inviare (si tratta dei dati binari o in formato stringa contenuti nel valore della proprietà data).
• Per FileReference.upload(), il Content-Type della richiesta viene impostato automaticamente su multipart/form-data e il valore della proprietà contentType viene ignorato.

In Flash Player 10 e versioni successive, se utilizzate un Content-Type multipart (ad esempio "multipart/form-data") che contiene un caricamento (indicato da un parametro "filename" in un'intestazione "content-disposition" nel corpo POST), l'operazione POST è soggetta alle regole di sicurezza applicate ai caricamenti:

• L'operazione POST deve essere eseguita come risposta a un'azione compiuta dall'utente, come un clic del mouse o la pressione di un tasto.
• Se l'operazione POST è tra più domini (il target POST non si trova sullo stesso server del file SWF che invia la richiesta POST), il server di destinazione deve fornire un file di criteri URL che consenta l'accesso tra più domini.

Inoltre, per qualsiasi Content-Type multipart, la sintassi deve essere valida (in conformità agli standard RFC2046). Se la sintassi non è valida, l'operazione POST è soggetta alle regole di sicurezza applicate ai caricamenti.

Elementi API correlati

Un oggetto che contiene i dati da trasmettere con la richiesta URL.

Questa proprietà viene utilizzata insieme alla proprietà method . Quando il valore di method è GET, il valore di data viene aggiunto al valore di URLRequest.url, utilizzando la sintassi della stringa di query HTTP. Quando il valore di method è POST (o qualsiasi valore diverso da GET), il valore di data viene trasmesso nel corpo della richiesta HTTP.

L'API URLRequest offre il supporto POST binario e il supporto per le variabili con codifica URL, oltre al supporto per le stringhe. L'oggetto dati può essere un oggetto ByteArray, URLVariables o String.

Il modo di utilizzo dei dati dipende dal tipo degli oggetti utilizzati:

• Se l'oggetto è un oggetto ByteArray, i dati binari dell'oggetto ByteArray vengono utilizzati come dati POST. Per GET, i dati di tipo ByteArray non sono supportati. Anche per FileReference.upload() e FileReference.download() i dati di tipo ByteArray non sono supportati.
• Se l'oggetto è un oggetto URLVariables e il metodo è POST, le variabili vengono codificate utilizzando il formato x-www-form-urlencoded e la stringa risultante viene utilizzata come dati POST. Un'eccezione è rappresentata da una chiamata a FileReference.upload(), in cui le variabili vengono inviate sotto forma di campi separati in un post multipart/form-data.
• Se l'oggetto è un oggetto URLVariables e il metodo è GET, l'oggetto URLVariables definisce le variabili da inviare con l'oggetto URLRequest.
• In caso contrario, l'oggetto viene convertito in una stringa, che viene utilizzata come dati POST o GET.

Questi dati vengono inviati fino a quando un metodo, ad esempio navigateToURL() o FileReference.upload(), utilizza l'oggetto URLRequest.

Nota: il valore di contentType deve corrispondere al tipo di dati nella proprietà data. Fate riferimento alla nota nella descrizione della proprietà contentType.

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

Una stringa che identifica in modo univoco il componente piattaforma Adobe firmato da memorizzare nella (o recuperare dalla) cache di Flash Player. Un componente della piattaforma Adobe è un file con firma (un file SWZ) che include contenuti SWF inseriti permanentemente nella cache della macchina di un utente. Tutti i file SWZ sono firmati da Adobe. Un digest corrisponde a un singolo file memorizzato nella cache; se modificate il file in qualche modo, il relativo digest cambia in modo imprevedibile. Mediante un digest, potete verificare il file memorizzato nella cache in più domini. Due file con lo stesso digest sono lo stesso file, mentre due file con digest diversi non sono lo stesso file. Un file non può (praticamente) essere creato per effettuare lo "spoofing" di un digest e fingere di essere un altro digest.

Il digest si basa sull'algoritmo di digest messaggi SHA-256 (lunghezza di 64 caratteri in formato esadecimale).

Ad esempio, Flex SDK comprende un SWZ per la struttura Flex (e fornisce la stringa digest per quel file SWZ). Potete inserire questo SWZ sul server web e caricarlo nel file SWF (utilizzando il metodo load() di un oggetto URLLoader). Se il computer di un utente finale ha già il file SWZ corrispondente inserito nella cache, l'applicazione utilizza il file SWZ presente nella cache. Un file SWZ corrisponde se il digest a quello fornito dall'utente. Altrimenti, l'applicazione scarica il file SWZ dall'URL specificato.

Impostate solo il parametro digest in un oggetto URLRequest utilizzato in una chiamata al metodo URLLoader.load() per caricare un file SWZ. Se la proprietà digest di un oggetto URLRequest viene impostata quando lo si utilizza in altri metodi, l'applicazione solleva un'eccezione IOError.

 
var myURLReq:URLRequest = new URLRequest();
myURLReq.url = "http://yourdomain/users/jdoe/test01/_rsc/Automated/AssetCaching_rsc/test01/rsl.swz";
myURLReq.digest = "3B0AA28C7A990385E044D80F5637FB036317BB41E044D80F5637FB036317BB41";
var myURLLoader:URLLoader = new URLLoader();
myURLLoader.dataFormat = URLLoaderDataFormat.BINARY;
myURLLoader.addEventListener("complete", onC);

myURLLoad.load(myURLReq);

function onC(e) {
    var someLoader:Loader = new Loader();
    addChild(someLoader);
    someLoader.loadBytes((ByteArray)(myURLLoad.data)); 
}

Specifica se i reindirizzamenti devono essere seguiti (true) o meno (false).

Nota: i metodi FileReference.upload(), FileReference.download() e HTMLLoader.load() non supportano la proprietà URLRequest.followRedirects.

Il valore predefinito è true.

Elementi API correlati

Specifica il valore del timeout di inattività (in millisecondi) per questa richiesta.

Il timeout di inattività è la quantità di tempo di attesa di una risposta dal server da parte del client, dopo l'apertura della connessione, prima di abbandonare la richiesta.

Nota: il metodo HTMLLoader.load() non supporta la proprietà URLRequest.idleTimeout. La classe HTMLLoader definisce la relativa proprietà idleTimeout.

Il valore predefinito è initialized from the URLRequestDefaults.idleTimeout property.

Elementi API correlati

Specifica se lo stack di protocollo HTTP deve gestire i cookie per questa richiesta. Quando è true, alla richiesta vengono aggiunti dei cookie e i cookie di risposta vengono memorizzati. Se è false, alla richiesta non vengono aggiunti cookie e i cookie di risposta non vengono memorizzati, ma gli utenti possono gestire autonomamente i cookie manipolando direttamente le intestazioni. Nota: in Windows, non potete aggiungere manualmente cookie a una richiesta di URL quando manageCookies è impostato su true. In altri sistemi operativi, l'aggiunta di cookie a una richiesta è consentita, indipendentemente dall'impostazione di manageCookies su true o su false. Se consentito, potete aggiungere manualmente cookie a una richiesta inserendo un oggetto URLRequestHeader contenente i dati del cookie all'array requestHeaders.

In Mac OS, i cookie sono condivisi con Safari. Per cancellare i cookie in Mac OS:

1. Aprite Safari.
2. Selezionate Safari > Preferenze e fate clic sul pannello Sicurezza.
3. Fate clic sul pulsante Mostra cookie.
4. Fate sul pulsante Rimuovi tutto.

Per cancellare i cookie in Windows:

1. Aprite l'applicazione Proprietà Internet del Pannello di controllo, quindi fate clic sulla scheda Generale.
2. Fate clic sul pulsante Cancella cookie.

Il valore predefinito è true.

Elementi API correlati

Controlla il metodo di invio dei form HTTP.

Per il contenuto SWF in esecuzione in Flash Player (nel browser), questa proprietà è limitata alle operazioni GET o POST, e i valori validi sono URLRequestMethod.GET o URLRequestMethod.POST.

Per il contenuto in esecuzione in Adobe AIR, potete utilizzare qualsiasi valore di stringa se il contenuto si trova nella sandbox di sicurezza dell'applicazione. Diversamente, come per il contenuto in esecuzione in Flash Player, potete utilizzare solo operazioni GET o POST.

Per i contenuti in esecuzione in Adobe AIR, quando utilizzate la funzione navigateToURL(), il runtime considera un oggetto URLRequest che utilizza il metodo POST (ovvero un oggetto la cui proprietà method è impostata su URLRequestMethod.POST) come se utilizzasse il metodo GET.

Nota: se il contenuto è in esecuzione in Flash Player e il modulo a cui fate riferimento è privo di corpo, l'applicazione usa automaticamente un'operazione GET, anche se il metodo è impostato su URLRequestMethod.POST. Per questo motivo, si consiglia di includere sempre un corpo fittizio per assicurare che venga utilizzato il metodo corretto.

Il valore predefinito è URLRequestMethod.GET.

Altre informazioni

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

L'array di intestazioni di richiesta HTTP da aggiungere alla richiesta HTTP. L'array è composto da oggetti URLRequestHeader. Ogni oggetto nell'array deve essere un oggetto URLRequestHeader che contiene una stringa nome e un valore stringa, come nell'esempio seguente:

     var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
     

Flash Player e il runtime di AIR impongono alcune limitazioni alle intestazioni delle richieste; per ulteriori informazioni, vedete la descrizione della classe URLRequestHeader.

Non tutti i metodi che accettano parametri URLRequest supportano la proprietà requestHeaders; consultate la documentazione relativa al metodo chiamato. I metodi FileReference.upload() eFileReference.download(), ad esempio, non supportano la proprietà URLRequest.requestHeaders.

A causa delle limitazioni del browser, le intestazioni delle richieste HTTP personalizzate sono supportate solo per le richieste POST e non per le richieste GET.

Elementi API correlati

L'URL da richiedere.

Assicuratevi di codificare tutti i caratteri che sono descritti come potenzialmente pericolosi nella specifica Uniform Resource Locator (http://www.faqs.org/rfcs/rfc1738.html) o che sono riservati nello schema URL dell'oggetto URLRequest (quando non vengono utilizzati per il relativo scopo riservato). Ad esempio, utilizzate "%25" per il simbolo di percentuale (%) e "%23" per il simbolo di numero (#), come in "http://www.example.com/orderForm.cfm?item=%23B-3&discount=50%25".

Per impostazione predefinita, l'URL deve trovarsi nello stesso dominio del file chiamante, a meno che il contenuto non venga eseguito nella sandbox di sicurezza dell'applicazione di Adobe AIR . Se dovete caricare dati da un dominio diverso, collocate un file dei criteri degli URL sul server che ospita i dati. Per ulteriori informazioni, vedete la descrizione della classe URLRequest.

Per il contenuto in esecuzione in Adobe AIR, i file nella sandbox di sicurezza dell'applicazione (file installati con l'applicazione AIR) possono accedere agli URL mediante uno qualunque degli schemi URL seguenti:

• http e https
• file
• app-storage
• app

Nota: IPv6 (Protocollo Internet versione 6) è supportato in AIR e in Flash Player 9.0.115.0 e versioni successive. IPv6 è una versione del protocollo Internet che supporta gli indirizzi a 128 bit (rappresenta un miglioramento rispetto al precedente protocollo IPv4 che supportava indirizzi a 32 bit). Potrebbe essere necessario attivare Ipv6 sulle interfacce di rete. Per maggiori informazioni, vedete la guida del sistema operativo sul quale si trovano i dati. Se il sistema host supporta IPv6 è possibile specificare il valore letterale numerico IPv6 degli URL racchiusi tra parentesi quadre ([]), come nel seguente esempio.

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

Altri esempi

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.load(urlRequest);
addChild(loader);

Specifica se la cache locale deve essere consultata prima che URLRequest recuperi i dati.

Nota: il metodo HTMLLoader.load() non supporta la proprietà URLRequest.useCache.

Il valore predefinito è true.

Elementi API correlati

Specifica la stringa agente utente da utilizzare nella richiesta HTTP.

Il valore predefinito è la stessa stringa agente utente utilizzata da Flash Player, che è diversa in Mac, in Linux e in Windows.

Nota: questa proprietà non influisce sulla stringa agente utente quando l'oggetto URLRequest viene utilizzato con il metodo load() di un oggetto HTMLLoader. Per impostare la stringa agente utente di un oggetto HTMLLoader, impostate la proprietà userAgent dell'oggetto HTMLLoader o impostate la proprietà statica URLRequestDefaults.userAgent.

Elementi API correlati

Crea un oggetto URLRequest. Se System.useCodePage è true, la richiesta viene codificata utilizzando la tabella codici di sistema, anziché Unicode. Se System.useCodePage è false, la richiesta viene codificata utilizzando Unicode, anziché la tabella codici di sistema.

Elementi API correlati

// Requires
// - Button symbol on Stage (or a display object, such as a MovieClip) with instance name "buttonSymbol"
//
buttonSymbol.addEventListener(MouseEvent.CLICK, buttonSymbol_click);
 
function buttonSymbol_click(evt:MouseEvent):void {
    var req:URLRequest = new URLRequest("http://www.adobe.com/");
    navigateToURL(req, "_blank");
}

Consente la sostituzione di un URL reindirizzato da un’URLRequest di origine con una porzione dell’URL di una nuova URLRequest. Quando una richiesta iniziale viene reindirizzata, è possibile inviare le richieste successive direttamente alla posizione del server reindirizzato.

Una volta completata la URLRequest iniziale, se HTTPStatusEvent.redirected è true, è possibile richiamare questo metodo utilizzando la richiesta iniziale come sourceRequest. Per impostazione predefinita, viene utilizzato il dominio dell’URL reindirizzato al posto del dominio dell’URL URLRequest. URLRequest.url deve essere impostato prima di richiamare il metodo. Il metodo deve essere richiamato prima che venga caricata la URLRequest. Facoltativamente, se il parametro wholeURL è true, l’intero URL senza il nome del file dell’URLRequest di origine viene sostituito con l’intero URL senza il nome del file finale in questa URLRequest. Inoltre, il chiamante può facoltativamente fornire una stringa o un’espressione regolare nel parametro pattern. Lo schema viene cercato e sostituito con la stringa del parametro replace. Tale ricerca e sostituzione si verifica dopo la sostituzione dell’URL.

Parametri

Elementi API correlati

Per provare l'esempio, collocate un file di nome XMLFile.xmf nella stessa directory del file SWF.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {
        private var loader:URLLoader;
        
        public function URLRequestExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}