URLRequestMethod - Guida di riferimento alle API Adobe ActionScript® 3 (AS3 )

Pacchetto	flash.net
Classe	public final class URLRequestMethod
Ereditarietà	URLRequestMethod Object

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

La classe URLRequestMethod fornisce dei valori che specificano se l'oggetto URLRequest deve utilizzare il metodo POST o il metodo GET quando invia dati a un server.

Vedere gli esempi

Elementi API correlati

URLRequest
URLVariables

Proprietà pubbliche

Nascondi proprietà pubbliche ereditate

Mostra proprietà pubbliche ereditate

	Proprietà		Definito da
		constructor : Object Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto.	Object

Metodi pubblici

Nascondi metodi pubblici ereditati

Mostra metodi pubblici ereditati

	Metodo		Definito da
		hasOwnProperty(name:String):Boolean Indica se per un oggetto è definita una proprietà specifica.	Object
		isPrototypeOf(theClass:Object):Boolean Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro.	Object
		propertyIsEnumerable(name:String):Boolean Indica se la proprietà specificata esiste ed è enumerabile.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche.	Object
		toLocaleString():String Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate.	Object
		toString():String Restituisce la rappresentazione in formato stringa dell'oggetto specificato.	Object
		valueOf():Object Restituisce il valore di base dell'oggetto specificato.	Object

Costanti pubbliche

	Costante		Definito da
		DELETE : String = "DELETE" [statico] Specifica che l'oggetto URLRequest è di tipo DELETE.	URLRequestMethod
		GET : String = "GET" [statico] Specifica che l'oggetto URLRequest è di tipo GET.	URLRequestMethod
		HEAD : String = "HEAD" [statico] Specifica che l'oggetto URLRequest è di tipo HEAD.	URLRequestMethod
		OPTIONS : String = "OPTIONS" [statico] Specifica che l'oggetto URLRequest è di tipo OPTIONS.	URLRequestMethod
		POST : String = "POST" [statico] Specifica che l'oggetto URLRequest è di tipo POST.	URLRequestMethod
		PUT : String = "PUT" [statico] Specifica che l'oggetto URLRequest è di tipo PUT.	URLRequestMethod

Descrizione delle costanti

DELETE

Costante

public static const DELETE:String = "DELETE"

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0

Specifica che l'oggetto URLRequest è di tipo DELETE.

GET

Costante

public static const GET:String = "GET"

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Specifica che l'oggetto URLRequest è di tipo GET.

HEAD

Costante

public static const HEAD:String = "HEAD"

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0

Specifica che l'oggetto URLRequest è di tipo HEAD.

OPTIONS

Costante

public static const OPTIONS:String = "OPTIONS"

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0

Specifica che l'oggetto URLRequest è di tipo OPTIONS.

POST

Costante

public static const POST:String = "POST"

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Specifica che l'oggetto URLRequest è di tipo POST.

Nota: per i contenuti in esecuzione in Adobe AIR, quando utilizza la funzione navigateToURL(), il runtime considera un oggetto URLRequest che utilizza il metodo POST (ovvero la cui proprietà method è impostata su URLRequestMethod.POST) come se utilizzasse il metodo GET.

PUT

Costante

public static const PUT:String = "PUT"

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0

Specifica che l'oggetto URLRequest è di tipo PUT.

Esempi Come utilizzare questo esempio

URLRequestMethodExample.as

Nel seguente esempio vengono caricati e visualizzati i dati trovati in un file di testo locale. Inoltre, vengono tracciate le informazioni relative alla gestione dell'evento.

Nota: per provare l'esempio, collocate un file denominato example.txt nella stessa directory del file SWF. Deve trattarsi di un semplice file di testo che contiene poche parole o righe di testo.

Il codice di esempio esegue le seguenti operazioni:

La funzione di costruzione crea un'istanza URLLoader di nome loader.
L'oggetto loader viene passato al metodo configureListeners() che aggiunge i listener per ognuno degli eventi URLLoader supportati.
Viene creata un'istanza URLRequest di nome request, che specifica il nome del file da caricare.
La proprietà method della richiesta viene impostata su URLRequestMethod.POST.
Quindi, l'oggetto request viene passato a loader.load(), che carica il file di testo.
Quando URLLoader ha terminato il caricamento del file di testo, si attiva l'evento Event.COMPLETE, che a sua volta attiva il metodo completeHandler(). Il metodo completeHandler() traccia semplicemente la proprietà data, il contenuto del file di testo.



package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestMethodExample extends Sprite {
        private var loader:URLLoader;
        
        public function URLRequestMethodExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("example.txt");
            
            request.method = URLRequestMethod.POST;
            loader.load(request);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}

Note legali | Informativa sulla privacy online

URLRequestMethod - AS3

Classi x

DELETE

GET

HEAD

OPTIONS

POST

PUT