URLLoader  - AS3

Indica il numero di byte che sono stati caricati fino a quel momento durante l'operazione di caricamento.

Indica il numero totale di byte dei dati scaricati. Questa proprietà contiene 0 mentre l'operazione di caricamento è in corso e viene compilata al termine dell'operazione. Inoltre, un'intestazione Content-Length mancante causa l'indeterminazione di bytesTotal.

I dati ricevuti dall'operazione di caricamento. Questa proprietà viene compilata solo quando l'operazione di caricamento è stata completata. Il formato dei dati dipende dall'impostazione della proprietà dataFormat:

Se la proprietà dataFormat è URLLoaderDataFormat.TEXT, i dati ricevuti sono costituiti da una stringa che contiene il testo del file caricato.

Se la proprietà dataFormat è URLLoaderDataFormat.BINARY, i dati ricevuti sono costituiti da un oggetto ByteArray che contiene i dati binari originari.

Se la proprietà dataFormat è URLLoaderDataFormat.VARIABLES, i dati ricevuti sono costituiti da un oggetto URLVariables che contiene le variabili con codifica URL.

Elementi API correlati

//params.txt is a local file that includes: firstName=Tom&lastName=Jones
var lbl:TextField = new TextField();
var urlRequest:URLRequest = new URLRequest("params.txt");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    lbl.text = urlLoader.data.lastName + "," + urlLoader.data.firstName;
    addChild(lbl);
}

Controlla se i dati scaricati vengono ricevuti sotto forma di testo (URLLoaderDataFormat.TEXT), dati binari originari (URLLoaderDataFormat.BINARY) o variabili con codifica URL (URLLoaderDataFormat.VARIABLES).

Se il valore della proprietà dataFormat è URLLoaderDataFormat.TEXT, i dati ricevuti sono costituiti da una stringa che contiene il testo del file caricato.

Se il valore della proprietà dataFormat è URLLoaderDataFormat.BINARY, i dati ricevuti sono costituiti da un oggetto ByteArray che contiene i dati binari originari.

Se il valore della proprietà dataFormat è URLLoaderDataFormat.VARIABLES, i dati ricevuti sono costituiti da un oggetto URLVariables che contiene le variabili con codifica URL.

Il valore predefinito è URLLoaderDataFormat.TEXT.

Elementi API correlati

var PATH:String = "lorem.txt";
var urlRequest:URLRequest = new URLRequest(PATH);
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT; // default
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    textArea.text = urlLoader.data;
}

Crea un oggetto URLLoader.

Elementi API correlati

Registra un oggetto listener di eventi con un oggetto EventDispatcher, in modo che il listener riceva la notifica di un evento. Potete registrare listener di eventi in tutti i nodi dell'elenco di visualizzazione per un tipo di evento, una fase e una priorità specifiche.

Una volta registrato un listener di eventi, non potete modificarne la priorità mediante chiamate aggiuntive a addEventListener(). Per modificare la priorità di un listener dovete chiamare innanzitutto removeListener(). In seguito potete registrare nuovamente il listener con il nuovo livello di priorità.

Tenete presente che, dopo la registrazione del listener, le successive chiamate a addEventListener() con un valore type o useCapture diverso determinano la creazione di un'altra registrazione per il listener. Ad esempio, se registrate un listener inizialmente con useCapture impostato su true, l'intercettazione avviene solo durante la fase di cattura. Se chiamate di nuovo addEventListener() utilizzando lo stesso oggetto listener ma impostando useCapture su false, ottenete due listener separati: uno rileva gli eventi durante la fase di cattura e l'altro durante la fasi target e di bubbling.

Non potete registrare un listener di eventi solo per la fase target o per la fase di bubbling. Queste fasi vengono accoppiate durante la registrazione perché la propagazione è valida solo per gli antenati del nodo target.

Se il listener di eventi non è più necessario, rimovetelo con una chiamata a removeEventListener() per evitare problemi di memoria. I listener di eventi non vengono eliminati automaticamente dalla memoria perché il garbage collector non rimuove il listener fintantoché esiste l'oggetto che effettua l'invio (a meno che il parametro useWeakReference non sia impostato su true).

Se copiate un'istanza EventDispatcher, i listener di eventi associati all'istanza non vengono copiati (se un nodo appena creato necessita di un listener di eventi, dovete associarlo dopo avere creato il nodo). Se invece spostate un'istanza EventDispatcher, insieme a questa vengono spostati anche i listener di eventi associati.

Se il listener di eventi viene registrato su un nodo mentre questo sta elaborando un evento, il listener di eventi non viene attivato durante la fase corrente ma può esserlo durante una fase successiva del flusso di eventi, ad esempio la fase di bubbling.

Se un listener di eventi viene rimosso da un nodo mentre questo sta elaborando un evento, il listener continua a essere attivato dalle azioni in corso. Dopo che è stato rimosso, il listener di eventi non viene più richiamato (a meno che non venga registrato nuovamente per elaborazioni future).

Parametri

function(evt:Event):void

Chiude l'operazione di caricamento in corso. Tutte le operazioni di caricamento in corso vengono immediatamente terminate. Se al momento non è in corso lo streaming di un URL, viene generato un errore di streaming non valido.

Invia e carica i dati da un URL specificato. I dati possono essere ricevuti sotto forma di testo, dati binari originari o variabili con codifica URL, a seconda del valore che è stato impostato per la proprietà dataFormat. Il valore predefinito per la proprietà dataFormat è text. Per inviare dati all'URL specificato, è possibile impostare la proprietà data nell'oggetto URLRequest.

Nota: se un file caricato contiene caratteri non ASCII come in molte lingue diverse dall'inglese, si consiglia di salvare il file con una codifica UTF-8 o UTF-16, in contrapposizione a un formato non codificato con Unicode come ASCII.

Un file SWF che si trova nella sandbox locale con file system potrebbe non caricare dati da o fornire dati a una risorsa presente nella sandbox di rete.

Per impostazione predefinita, il file SWF chiamante e l'URL da caricare devono trovarsi esattamente nello stesso dominio. Ad esempio, un file SWF sul sito www.adobe.com può caricare i dati solo dalle origini presenti in www.adobe.com. Per caricare dati da un dominio diverso, collocate un file dei criteri degli URL sul server sul quale si trovano i dati.

Non potete collegarvi alle porte comunemente riservate. Per un elenco completo di porte bloccate, vedete "Limitazioni delle API di connettività di rete" nella Guida per gli sviluppatori di ActionScript 3.0.

In Flash Player 10 e versioni successive, se utilizzate un Content-Type multipart (ad esempio "multipart/form-data") che contiene un caricamento (indicato da un parametro "filename" in un'intestazione "content-disposition" nel corpo POST), l'operazione POST è soggetta alle regole di sicurezza applicate ai caricamenti:

• L'operazione POST deve essere eseguita come risposta a un'azione compiuta dall'utente, come un clic del mouse o la pressione di un tasto.
• Se l'operazione POST è tra più domini (il target POST non si trova sullo stesso server del file SWF che invia la richiesta POST), il server di destinazione deve fornire un file di criteri URL che consenta l'accesso tra più domini.

Inoltre, per qualsiasi Content-Type multipart, la sintassi deve essere valida (in conformità agli standard RFC2046). Se la sintassi non è valida, l'operazione POST è soggetta alle regole di sicurezza applicate ai caricamenti.

Per ulteriori informazioni sulla sicurezza, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .

Parametri

Altre informazioni

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;
  
    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;    
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();
            
            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);    
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }    
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

Inviato dopo che tutti i dati ricevuti sono stati decodificati e collocati nella proprietà data dell'oggetto URLLoader. È possibile accedere ai dati ricevuti solo quando questo evento è stato inviato.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato se una chiamata al metodo load() tenta di accedere ai dati via HTTP e Adobe AIR è in grado di rilevare e restituire il codice di stato della richiesta.

La costante HTTPStatusEvent.HTTP_RESPONSE_STATUS definisce il valore della proprietà type di un oggetto evento httpResponseStatus.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato se una chiamata a URLLoader.load() tenta di accedere ai dati via HTTP. Per il contenuto in esecuzione in Flash Player, questo evento viene inviato solo se l'ambiente Flash Player corrente è in grado di rilevare e restituire il codice di stato per la richiesta. (Alcuni ambienti browser potrebbero non essere in grado di fornire queste informazioni). L'evento httpStatus (se presente) viene inviato prima di (e in aggiunta a) qualsiasi evento complete o error.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato se una chiamata a URLLoader.load() produce un errore irreversibile che interrompe lo scaricamento.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato quando l'operazione di scaricamento inizia in seguito a una chiamata al metodo URLLoader.load().

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato quando vengono ricevuti i dati mentre è in corso l'operazione di scaricamento.

Con un oggetto URLLoader non è possibile accedere ai dati fino a quando i dati non sono stati completamente ricevuti. Pertanto, l'evento di avanzamento funge solo da notifica dell'avanzamento dello scaricamento. Per accedere ai dati prima di averli completamente scaricati, utilizzate un oggetto URLStream.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato se una chiamata al metodo URLLoader.load() tenta di caricare dati da un server al di fuori della funzione di sicurezza sandbox. Inviato anche se una chiamata a URLLoader.load() tenta di caricare un file SWZ e il certificato non è valido o la stringa digest non corrisponde al componente.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Nota: per provare l'esempio, collocate un file denominato urlLoaderExample.txt nella stessa directory del file SWF. Il file deve contenere solo la riga di testo seguente: answer=42&question=unknown

Il codice di esempio esegue le seguenti operazioni:

1. La funzione di costruzione crea un'istanza URLLoader di nome loader e un'istanza URLRequest di nome request, che contiene la posizione e il nome del file da caricare.
2. L'oggetto loader viene passato al metodo configureListeners() che aggiunge i listener per ognuno degli eventi URLLoader supportati.
3. Quindi, l'oggetto request viene passato a loader.load(), che carica il file di testo.
4. Quando URLLoader ha terminato il caricamento del file di testo, si attiva l'evento Event.COMPLETE, che a sua volta attiva il metodo completeHandler(). Il metodo completeHandler() crea un oggetto URLVariables dal testo caricato dal file. L'oggetto URLVariables converte le coppie nome/valore con codifica URL in proprietà ActionScript per facilitare la gestione dei dati caricati.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        
        private loader:URLoader;
        public function URLLoaderExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}