JSON  - AS3

Accetta una stringa in formato JSON e restituisce un oggetto ActionScript che rappresenta tale valore. Oggetti, array, stringhe, numeri, valori booleani e valori null JSON vengono associati ai valori ActionScript corrispondenti, come illustrato di seguito:

Il parametro reviver è una funzione che accetta due parametri: una chiave e un valore. Potete utilizzare questa funzione per trasformare o filtrare ogni coppia chiave/valore quando viene analizzata. Se specificate una funzione reviver, nell'output della funzione parse() viene restituito il valore trasformato o filtrato per ogni coppia, anziché l'analisi predefinita. Se la funzione reviver restituisce undefined per una coppia, la proprietà viene eliminata dal risultato finale.

Quando l'argomento passato al parametro reviver non è una funzione, ActionScript genera un TypeError con l'ID errore kJSONInvalidReviver. Inserisce inoltre un messaggio di errore localizzato.

Se la funzione parse() rileva chiavi duplicate all'interno di un oggetto, la chiave duplicata rilevata per ultima fornisce il valore per tutte le occorrenze precedenti di tale chiave.

Parametri

Restituisce una stringa, in formato JSON, che rappresenta un valore ActionScript. Il metodo stringify può accettare tre parametri.

Il parametro value è obbligatorio. Questo parametro è un valore ActionScript. In genere, si tratta di un oggetto o un array, ma può anche essere una stringa, un valore booleano, un numero o un valore null.

Il parametro opzionale replacer può essere una funzione o un array di stringhe o numeri. Se si tratta di una funzione, questa accetta due parametri: una chiave e un valore. Potete utilizzare questa funzione per trasformare o filtrare ogni coppia chiave/valore quando viene analizzata. Se specificate una funzione replacer, nell'output della funzione parse() viene restituito il valore trasformato o filtrato per ogni coppia, anziché l'analisi predefinita. Se la funzione replacer restituisce undefined per una coppia, la proprietà viene eliminata dal risultato finale. Se replacer è un array, viene utilizzato come filtro per definire quali proprietà saranno incluse nell'output.

Quando l'argomento passato al parametro replacer non è un array o una funzione, ActionScript genera un TypeError con l'ID errore kJSONInvalidReplacer. Inserisce inoltre un messaggio di errore localizzato.

Il parametro opzionale space è una stringa o un numero che consente l'inserimento di uno spazio vuoto nella stringa restituita per migliorare la leggibilità. Le voci negli oggetti e negli array JSON generati sono separate da un gap derivato dal parametro space. La larghezza di questo gap è sempre compresa tra 0 e 10 caratteri. Se lo spazio è una stringa, il gap derivato corrisponde ai primi dieci caratteri di tale stringa. Se lo spazio è un numero x non negativo, il gap è uno spazio di x caratteri, fino a un massimo di dieci spazi. Quando l'argomento passato al parametro space non è una stringa o un numero, viene convertito in una stringa che sarà utilizzata come gap nell'output. Procede dopo l'esecuzione.

Quando il metodo stringify() rileva una struttura ciclica, genera un TypeError con ID errore kJSONCyclicStructure. Inserisce inoltre un messaggio di errore localizzato.

Parametri

1. La funzione di costruzione di JSONExample assegna una stringa al membro text della superclasse e inizializza un contatore interno.
2. Inoltre, la classe definisce un array che può contenere oggetti JSONExample che sono stati esportati in JSON.
3. JSONExample definisce anche un metodo toJSON() e un metodo revive(). Il metodo toJSON() viene chiamato da JSON.stringify() per serializzare gli oggetti JSONExample su JSON. Il metodo revive() può essere chiamato dai metodi JSON.parse() per ripristinare l'oggetto JSONExample completo. Questo ripristino viene ottenuto utilizzando un determinato ID per recuperare l'oggetto originale dall'array di oggetti revivable.
4. Lo script che usa la definizione di classe crea un oggetto che contiene due oggetti TextField e un oggetto JSONExample. Inoltre, crea un array di oggetti revivable per la memorizzazione degli oggetti TextField che sono stati esportati in JSON.
5. La funzione replacer di JSON.stringify() filtra gli oggetti TextField dalla stringa JSON. Al posto di ogni oggetto rimosso, replacer fornisce un marcatore con un ID che può essere usato in seguito per recuperare l'oggetto. Gli oggetti JSONExample, al contrario, vengono passati in base alla loro codifica JSON nativa.
6. La funzione reviver del metodo parse() ricrea l'oggetto originale recuperando tutti gli oggetti TextField e JSONExample con riferimenti.

 
 package {
    import flash.text.TextField;
    public class JSONExample extends TextField
    {
        static var nextId = 10000;
        static var revivable_objects:Array = [];
            public var id;

        public function JSONExample(s:String){
            super.text = s;
            id = ++nextId;
        }
        public function toJSON(k):*
        {
            // To be called internally by the JSON.stringify() method.
            // Save the original object internally.
            // Write out only a generated ID and the text value.
            revivable_objects[id] = this;
            return {"classJSONExample":{"reviveId":id,"contents":this.text}};
        }
        public static function revive(id:int):JSONExample
        {
            // For explicit use in the JSON.parse() method.
            // Revives the object using the ID obtained from the JSON string.
            return revivable_objects[id];
        }
    }
}

import flash.text.TextField;

var lastId = 20000;
var tf1:TextField = new TextField();
tf1.text = "Lorem ipsum";
var tf2:TextField = new TextField();
tf2.text = "Laughing cows";
var nt:JSONExample = new JSONExample("It was the best of times; it was the worst of times.");

var obj:Object = {a:tf1, b:nt, c:tf2};
var revivable_objects:Array = new Array();

var json_out = JSON.stringify(obj, function(k,v){
        if (v is JSONExample)
        {
            // Send JSONExample objects to the JSON output.
            // Note that stringify() calls JSONExample.toJSON() to serialize this object.
            return v;
        }
        if (v is TextField)
        {
            // Remove TextField objects from the JSON output.
            // Save the original object for reviving later.
            // Return a new object containing an identification marker
            // and the original object's revival ID.
            revivable_objects[++lastId] = v;
            return {"classTextField":{"reviveId":lastId}};
        }
        return v;
    }
);
               
trace("json_out: " + json_out);

var json_in = JSON.parse(json_out, function(k,v) {
        if ("classTextField" in v) { // special marker tag from stringify() replacer code
            // Retrieve the original object based on the ID stored in the stringify() replacer function.
            var id = v["classTextField"].reviveId;
            return revivable_objects[id];
        } else if ("classJSONExample" in v){
            // Retrieve the original object based on the ID generated in JSONExample.toJSON().
            return JSONExample.revive(v["classJSONExample"].reviveId);
        }
        return v;
    }
);

if (json_in.a)
{
    if (json_in.a.hasOwnProperty("text"))
        {
            trace("json_in.a: " + json_in.a.text);
        }
}
if (json_in.b)
{
    if (json_in.b.hasOwnProperty("text"))
        {
            trace("json_in.b: " + json_in.b.text);
        }
}

if (json_in.c)
{
    if (json_in.c.hasOwnProperty("text"))
        {
            trace("json_in.c: " + json_in.c.text);
        }
}