Mouse  - AS3

Il nome del cursore nativo.

Indica se il computer o il dispositivo è provvisto di un cursore persistente.

La proprietà supportsCursor è true sulla maggior parte dei computer desktop e false sulla maggior parte dei dispositivi mobili.

Nota: gli eventi del mouse possono essere inviati indipendentemente dal fatto che questa proprietà sia o meno true. Gli eventi del mouse possono tuttavia avere un comportamento diverso a seconda delle caratteristiche fisiche del dispositivo di puntamento.

Elementi API correlati

import flash.events.*;
import flash.display.*;
import flash.ui.Mouse;
import flash.text.TextField;

var supportsCursorTxt:TextField = new TextField();
supportsCursorTxt.width = 200;
supportsCursorTxt.border = true;
addChild(supportsCursorTxt);

addEventListener (MouseEvent.CLICK, getScreenKeyboardType);

function getScreenKeyboardType(e:MouseEvent):void{
    supportsCursorTxt.text= "Supports Cursor is : " + String(flash.ui.Mouse.supportsCursor);

}

if(Mouse.supportsCursor) {
    //Game acts as before
} else {
    if(Capabilities.touchscreenType == TouchscreenType.STYLUS ){
        //The Game has to change so that the character is chasing the location of the stylus as 
        //it's dragged around. Some of the animations will have to change
    }else if(Capabilities.touchscreenType = TouchscreenType.FINGER){
        //Same as above, except that the hit-area is larger for a finger.
    }else{
        //There's no pointing device at all. The developer designs some sort of custom cursor to 
        //be controlled with key presses or similar input
    }
}

Indica se la configurazione corrente supporta i cursori nativi.

Nasconde il puntatore. Il puntatore è visibile per impostazione predefinita.

Nota: Mouse.hide() deve essere chiamato una sola volta, indipendentemente dal numero di chiamate Mouse.show() precedenti.

Elementi API correlati

Registra un cursore nativo con il nome specificato e con i dati forniti.

Parametri

Visualizza il puntatore. Il puntatore è visibile per impostazione predefinita.

Nota: Mouse.show() deve essere chiamato una sola volta, indipendentemente dal numero di chiamate Mouse.hide() precedenti.

Elementi API correlati

De-registra il cursore nativo con il nome specificato.

Parametri

1. Dichiarate le seguenti proprietà di istanza: cursor del tipo CustomCursor, child del tipo CustomButton e gutter del tipo uint.
2. Assegnate child a una nuova istanza CustomButton, impostarne le coordinate x e y su 10 pixel ciascuna e quindi aggiungere l'istanza all'elenco di visualizzazione. La classe CustomButton sostituisce le proprietà downState, upState, overState e hitTestState di SimpleButton. Ciascuna di queste proprietà crea un'istanza di oggetto ButtonDisplayState che disegna un quadrato diverso a seconda dello stato dell'istanza child.
3. L'istanza child viene quindi utilizzata per aggiungere un listener di eventi MOUSE_OVER e un metodo di listener mouseOverHandler(), insieme a un listener di eventi MOUSE_OUT e al metodo associato mouseOutHandler().
4. I listener di eventi funzionano nel modo seguente:
   • mouseOverHandler: nasconde il puntatore "normale" e aggiunge un listener MOUSE_MOVE, che elabora gli spostamenti del mouse mediante mouseMoveHandler() (descritto di seguito).
   • mouseOutHandler: quando il mouse si sposta all'esterno del pulsante personalizzato, viene visualizzato il puntatore "normale", il listener di eventi MOUSE_MOVE viene rimosso e la visibilità del cursore personalizzato viene impostata su false.
   • mouseMoveHandler: sposta il cursore personalizzato in qualsiasi punto venga spostato il puntatore e imposta la visibilità del cursore personalizzato su true.
5. Nella funzione di costruzione MouseExample, la proprietà cursor viene assegnata a un nuovo oggetto CustomCursor e quindi viene aggiunta all'elenco di visualizzazione mediante addChild(). La classe CustomCursor disegna un quadratino di colore vicino al nero al posto del puntatore "normale" ogni qualvolta il mouse si trova sopra child.
6. Viene aggiunto un quarto listener di eventi del tipo MOUSE_LEAVE, con il metodo associato mouseLeaveHandler(). In questo metodo (chiamato se il mouse esce dallo stage), mouseOutHandler() viene passato a un nuovo oggetto listener mouseMove, che essenzialmente rimuove il puntatore in modo che non rimanga sullo stage.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.ui.Mouse;
    import flash.events.*;

    public class MouseExample extends Sprite {
         private var cursor:CustomCursor;
         private var child:CustomButton;
         private var gutter:uint = 10;

        public function MouseExample() {
            child = new CustomButton();
            child.x = gutter;
            child.y = gutter;
            addChild(child);

            child.addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
            child.addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);

            cursor = new CustomCursor();
            addChild(cursor);

            stage.addEventListener(Event.MOUSE_LEAVE, mouseLeaveHandler);
        }

        private function mouseOverHandler(event:MouseEvent):void {
            trace("mouseOverHandler");
            Mouse.hide();
            child.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function mouseOutHandler(event:MouseEvent):void {
            trace("mouseOutHandler");
            Mouse.show();
            child.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            cursor.visible = false;
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            cursor.x = event.localX;
            cursor.y = event.localY;
            event.updateAfterEvent();
            cursor.visible = true;
        }

        private function mouseLeaveHandler(event:Event):void {
            trace("mouseLeaveHandler");
            mouseOutHandler(new MouseEvent(MouseEvent.MOUSE_MOVE));
        }
    }
}

import flash.display.Shape;
import flash.display.SimpleButton;
    
class CustomButton extends SimpleButton {
    var upColor:uint = 0xFFCC00;
    var overColor:uint = 0xCCFF00;
    var downColor:uint = 0x00CCFF;
    var size:uint = 80;
    
    public function CustomButton() {
        downState = new ButtonDisplayState(downColor, size+10);
        overState = new ButtonDisplayState(overColor, size);
        upState = new ButtonDisplayState(upColor, size);
        hitTestState = new ButtonDisplayState(upColor, size);
    }
}

class ButtonDisplayState extends Shape {
    var bgColor:uint;
    var size:uint;
    
    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size = size;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}
    
class CustomCursor extends Shape {
    var bgColor:uint = 0x333333;
    var size:uint = 10;
    
    public function CustomCursor() {
        visible = false;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}