| Pacchetto | flash.ui |
| Classe | public final class MouseCursorData |
| Ereditarietà | MouseCursorData  Object |
| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.2, AIR 2.6 |
Per visualizzare il cursore, utilizzate la funzione Mouse.registerCursor(). Per restituire il controllo dell'immagine del cursore al sistema operativo, chiamate Mouse.unregisterCursor(). Chiamate Mouse.supportsNativeCursor per verificare se i cursori nativi sono supportati nel computer corrente.
La dimensione massima del cursore è di 32x32 pixel. La trasparenza è supportata nella maggior parte dei sistemi operativi.
Un cursore del mouse nativo viene implementato direttamente tramite il meccanismo di gestione del cursore del sistema operativo ed è un mezzo più efficiente per visualizzare un cursore con aspetto personalizzato rispetto all'uso di un oggetto di visualizzazione. Potete animare il cursore fornendo più di un'immagine alla proprietà data e impostando la frequenza dei fotogrammi.
Il cursore viene visualizzato solo all'interno dei limiti dello stage. Al di fuori dello stage, il controllo dell'immagine del cursore torna al sistema operativo.
Altre informazioni
Elementi API correlati
Nascondi proprietà pubbliche ereditate
Mostra proprietà pubbliche ereditate| Proprietà | Definito da | ||
|---|---|---|---|
 | constructor : Object
Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto. | Object | |
| data : Vector.<BitmapData>
Un vettore di oggetti BitmapData contenente l'immagine o le immagini del cursore. | MouseCursorData | ||
| frameRate : Number
La frequenza fotogrammi per l'animazione del cursore. | MouseCursorData | ||
| hotSpot : Point
Il punto attivo del cursore in pixel. | MouseCursorData | ||
| Metodo | Definito da | ||
|---|---|---|---|
Crea un oggetto MouseCursorData. | MouseCursorData | ||
|
Indica se per un oggetto è definita una proprietà specifica. | Object | |
|
Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro. | Object | |
|
Indica se la proprietà specificata esiste ed è enumerabile. | Object | |
|
Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche. | Object | |
|
Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate. | Object | |
|
Restituisce la rappresentazione in formato stringa dell'oggetto specificato. | Object | |
|
Restituisce il valore di base dell'oggetto specificato. | Object | |
data | proprietà |
data:Vector.<BitmapData>| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.2, AIR 2.6 |
Un vettore di oggetti BitmapData contenente l'immagine o le immagini del cursore.
Fornite più di un'immagine e impostate la proprietà framerate per animare il cursore.
La dimensione massima del cursore è di 32x32 pixel.
Implementazione
public function get data():Vector.<BitmapData> public function set data(value:Vector.<BitmapData>):voidframeRate | proprietà |
frameRate:Number| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.2, AIR 2.6 |
La frequenza fotogrammi per l'animazione del cursore.
Fornite più di un'immagine nella proprietà data e impostate la frequenza fotogrammi su un valore maggiore di 0 per animare il cursore. La frequenza fotogrammi può differire dalla frequenza fotogrammi SWF corrente.
Implementazione
public function get frameRate():Number public function set frameRate(value:Number):voidhotSpot | proprietà |
hotSpot:Point| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.2, AIR 2.6 |
Il punto attivo del cursore in pixel.
Il punto attivo è il punto del cursore sul quale vengono registrati i clic del mouse. Per impostazione predefinita, il punto attivo è l'angolo superiore sinistro (0,0).
Implementazione
public function get hotSpot():Point public function set hotSpot(value:Point):voidMouseCursorData | () | Funzione di costruzione |
public function MouseCursorData()| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.2, AIR 2.6 |
Crea un oggetto MouseCursorData.
Per visualizzare il cursore, chiamata la funzione Mouse.registerCursor().
Elementi API correlati
Nell'esempio vengono utilizzati i comandi di disegno disponibili tramite la classe Graphics per creare otto immagini ruotate di una freccia. Queste immagini vengono inserite in un vettore e assegnate alla proprietà data dell'oggetto MouseCursorData. (Nota: per i cursori potete anche usare immagini bitmap pre-renderizzate.)
package {
import flash.display.Sprite;
import flash.display.Shape;
import flash.display.BitmapData;
import flash.display.GraphicsPath;
import flash.ui.MouseCursorData;
import flash.ui.Mouse;
import flash.geom.Matrix;
public class MouseCursorDataExample extends Sprite {
//Graphics path data for an arrow
private var cursorPoints:Vector.<Number> = new <Number>[0,8, 16,8, 16,0, 24,12, 16,24, 16,16, 0,16, 0,8];
private var cursorDrawCommands:Vector.<int> = new <int>[1,2,2,2,2,2,2,2];
public function MouseCursorDataExample() {
var mouseCursorData:MouseCursorData = new MouseCursorData();
mouseCursorData.data = makeCursorImages();
mouseCursorData.frameRate = 1;
Mouse.registerCursor( "spinningArrow", mouseCursorData );
Mouse.cursor = "spinningArrow";
}
//Returns a Vector containing 8 cursor images
private function makeCursorImages():Vector.<BitmapData>
{
var cursorData:Vector.<BitmapData> = new Vector.<BitmapData>();
var cursorShape:Shape = new Shape();
cursorShape.graphics.beginFill( 0xff5555, .75 );
cursorShape.graphics.lineStyle( 1 );
cursorShape.graphics.drawPath( cursorDrawCommands, cursorPoints );
cursorShape.graphics.endFill();
var transformer:Matrix = new Matrix();
//Rotate and draw the arrow shape to a BitmapData object for each of 8 frames
for( var i:int = 0; i < 8; i++ )
{
var cursorFrame:BitmapData = new BitmapData( 32, 32, true, 0 );
cursorFrame.draw( cursorShape, transformer );
cursorData.push( cursorFrame );
transformer.translate(-15,-15);
transformer.rotate( 0.785398163 );
transformer.translate(15,15);
}
return cursorData;
}
}
}
Tue Jun 12 2018, 02:44 PM Z