MouseEvent  - AS3

Indica se il tasto Alt è attivo (true) o inattivo (false). Supportato solo in Windows. Negli altri sistemi operativi, questa proprietà è sempre impostata su false.

Indica se il pulsante principale del mouse è premuto (true) o no (false).

Indica se l'evento mouse down fa parte o meno di una sequenza di più clic. Questo parametro corrisponderà a zero per tutti gli eventi associati al mouse diversi da MouseEvent.mouseDown, MouseEvent.mouseUp, MouseEvent.middleMouseDown, MouseEvent.middleMouseUp, MouseEvent.rightMouseDown e MouseEvent.rightMouseUp. L'intercettazione di singoli clic, doppi clic o sequenze di più clic è possibile mediante il parametro clickCount. Ad esempio, gli eventi iniziali MouseEvent.mouseDown e MouseEvent.mouseUp avranno un parametro clickCount di 1, mentre i successivi eventi MouseEvent.mouseDown e MouseEvent.mouseUp in una sequenza di doppio clic avranno un parametro clickCount di 2. Se il mouse si muove a sufficienza o se la sequenza di più clic viene interrotta per qualsiasi ragione, il successivo evento MouseEvent.mouseDown avrà un parametro clickCount di 1. L'evento doubleClick continuerà ad essere attivato come di consueto.

Indica se il tasto Comando è attivato (solo Mac).

Il valore della proprietà commandKey corrisponde a quello della proprietà ctrlKey in Mac. Restituisce sempre false in Windows o Linux.

Indica se il comando Ctrl è attivato in Mac, Windows e Linux.

In Windows o Linux, indica se il tasto Ctrl è attivo (true) o inattivo (false). In Macintosh, indica se il tasto Ctrl o il tasto Comando è attivato.

Indica il numero di righe da scorrere per ogni unità di rotazione della rotella del mouse. Un valore delta positivo indica uno scorrimento verso l'alto; un valore negativo indica uno scorrimento verso il basso. I valori tipici sono compresi tra 1 e 3, ma una rotazione più veloce può generare valori più grandi. Questa impostazione dipende dal dispositivo e dal sistema operativo e generalmente può essere configurata dall'utente. Questa proprietà si applica solo all'evento MouseEvent.mouseWheel.

Se è true, la proprietà relatedObject viene impostata su null per motivi riconducibili alle sandbox. Se il valore nominale di relatedObject è un riferimento a DisplayObject in un'altra sandbox, relatedObject viene impostato su null a meno che non vi sia autorizzazione in entrambe le direzioni attraverso questa sandbox. L'autorizzazione si stabilisce chiamando Security.allowDomain() da un file SWF o fornendo un file di criteri dal server di un file di immagine e impostando la proprietà LoaderContext.checkPolicyFile quando si carica l'immagine.

Elementi API correlati

Quando il blocco del mouse è disattivato, la coordinata orizzontale in corrispondenza della quale l'evento si è verificato in relazione allo sprite contenitore. Per disattivare il blocco del mouse, impostate Stage.mouseLock su false.

Quando il blocco del mouse è attivato, localX e localY sono 0. Utilizzate movementX e movementY per determinare i cambiamenti di posizione del mouse quando il blocco del mouse è attivo.

Elementi API correlati

Quando il blocco del mouse è disattivato, la coordinata verticale in corrispondenza della quale l'evento si è verificato in relazione allo sprite contenitore. Per disattivare il blocco del mouse, impostate Stage.mouseLock su false.

Quando il blocco del mouse è attivato, localX e localY sono 0. Utilizzate movementX e movementY per determinare i cambiamenti di posizione del mouse quando il blocco del mouse è attivo.

Elementi API correlati

Quando il blocco del mouse è attivo, è il cambiamento di posizione del mouse nella direzione X dopo l'ultimo evento del mouse. Per attivare il blocco del mouse, impostate Stage.mouseLock su true.

Quando il blocco del mouse è attivo:

• localX e localY contengono 0.
• movementX e movementY contengono valori delta.
• movementX e movementY non vengono mai trasformati in base alla trasformazione dello stage. In altre parole, rimangono sempre nelle coordinate dello schermo.

movementX e movementY sono 0 quando Stage.mouseLock è false.

Elementi API correlati

Quando il blocco del mouse è attivo, è il cambiamento di posizione del mouse nella direzione Y dopo l'ultimo evento del mouse. Per attivare il blocco del mouse, impostate Stage.mouseLock su true.

Quando il blocco del mouse è attivo:

• localX e localY contengono 0.
• movementX e movementY contengono valori delta.
• movementX e movementY non vengono mai trasformati in base alla trasformazione dello stage. In altre parole, rimangono sempre nelle coordinate dello schermo.

movementX e movementY sono 0 quando Stage.mouseLock è false.

Elementi API correlati

Un riferimento a un oggetto dell'elenco di visualizzazione relativo all'evento. Ad esempio, quando si verifica un evento mouseOut, relatedObject rappresenta l'oggetto dell'elenco di visualizzazione a cui punta ora il dispositivo di puntamento. Questa proprietà si applica agli eventi mouseOut, mouseOver, rollOut e rollOver.

Il valore di questa proprietà può essere null in due casi: se non vi è un oggetto correlato oppure se esiste un oggetto correlato ma si trova in una sandbox a cui non si può accedere. Per individuare il motivo, utilizzate la proprietà isRelatedObjectInaccessible().

Elementi API correlati

Indica se il tasto Maiusc è attivo (true) o inattivo (false).

La coordinata orizzontale in cui si è verificato l'evento nelle coordinate globali dello stage. Questa proprietà viene calcolata quando viene impostata la proprietà localX.

La coordinata verticale in cui si è verificato l'evento nelle coordinate globali dello stage. Questa proprietà viene calcolata quando viene impostata la proprietà localY.

Crea un oggetto Event contenente informazioni relative agli eventi associati al mouse. Gli oggetti evento vengono passati ai listener di eventi come parametri.

Crea una copia dell'oggetto MouseEvent e imposta il valore di ogni proprietà in modo che corrisponda a quello dell'originale.

Restituisce una stringa che contiene tutte le proprietà dell'oggetto MouseEvent. La stringa ha il seguente formato:

[MouseEvent type= valore bubbles= valore cancelable= valore ... delta= valore]

Indica a Flash Player o ad Adobe AIR di eseguire il rendering al termine dell'elaborazione dell'evento se l'elenco di visualizzazione è stato modificato.

Definisce il valore della proprietà type di un oggetto evento click.

Questo evento ha le seguenti proprietà:

Elementi API correlati

La costante MouseEvent.CONTEXT_MENU definisce il valore della proprietà typedi un oggetto evento contextMenu.

Questo evento ha le seguenti proprietà:

Definisce il valore della proprietà type di un oggetto evento doubleClick. La proprietà doubleClickEnabled deve essere true perché un oggetto possa generare l'evento doubleClick.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento middleClick.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento middleMouseDown.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento middleMouseUp.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento mouseDown.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento mouseMove.

Questo evento ha le seguenti proprietà:

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;

    public class MouseEvent_MOUSE_MOVEExample extends Sprite {
        private var innerRect:Sprite = new Sprite();
        
        public function MouseEvent_MOUSE_MOVEExample() {

            graphics.lineStyle(3, 0xFF0000, 1);
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            innerRect.graphics.lineStyle(1, 0x00FF00, 1);
            innerRect.graphics.beginFill(0xFFFFFF);
            innerRect.graphics.drawRect(10, 10, 200, 200);
            innerRect.graphics.endFill();
            innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
            innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
            addChild(innerRect);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            graphics.moveTo(event.stageX, event.stageY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }
    
        private function mouseMoveHandler(event:MouseEvent):void {
            graphics.lineTo(event.stageX, event.stageY);
        }    
    
        private function mouseUpHandler(event:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function innerRectMouseDownHandler(event:MouseEvent):void {
            innerRect.graphics.moveTo(event.localX, event.localY);
            innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    
        private function innerRectMouseMoveHandler(event:MouseEvent):void {
            innerRect.graphics.lineTo(event.localX, event.localY);
        }    
    
        private function innerRectMouseUpHandler(event:MouseEvent):void {
            innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    }
}

Definisce il valore della proprietà type di un oggetto evento mouseOut.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento mouseOver.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento mouseUp.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento mouseWheel.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento releaseOutside.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento rightClick.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento rightMouseDown.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento rightMouseUp.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento rollOut.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Definisce il valore della proprietà type di un oggetto evento rollOver.

Questo evento ha le seguenti proprietà:

Elementi API correlati

1. Nell'esempio vengono dichiarate le proprietà per le dimensioni (100 x 100 pixel) e il colore di sfondo (arancione) da utilizzare successivamente durante il disegno del quadrato.
2. La funzione di costruzione crea un nuovo oggetto ChildSprite child. La relativa funzione di costruzione disegna innanzitutto un quadrato arancione di 100 x 100 pixel in corrispondenza delle coordinate (0,0) chiamando il relativo metodo draw() e aggiungendo quindi sette listener/subscriber di eventi.
   • click / clickHandler(): inviato quando si fa clic con il pulsante sinistro del mouse sul quadrato.
   • doubleClick / doubleClickHandler(): inviato quando si fa doppio clic con il pulsante sinistro del mouse sul quadrato.
   • mouseDown / mouseDownHandler(): quando si fa clic sull'oggetto ChildSprite (il quadrato arancione), viene visualizzato un messaggio trace() sullo schermo, quindi viene chiamato ChildSprite.draw(), che disegna un quadrato giallo scuro al posto di quello blu chiaro disegnato in mouseOverHandler(). Il metodo mouseDownHandler() aggiunge inoltre un listener di eventi mouseMove e il subscriber di mouseMoveHandler() (descritto di seguito), che elabora i movimenti del mouse. Viene quindi chiamato il metodo startDrag(), che consente di trascinare l'oggetto Sprite.
   • mouseOut / mouseOutHandler(): inviato ogni volta che il puntatore esce dall'area del quadrato. Il metodo draw() viene chiamato per ripristinare le dimensioni e il colore normali del quadrato.
   • mouseOver / mouseOverHandler(): inviato quando il puntatore del mouse si trova sopra il quadrato. Questo metodo ridisegna il quadrato, che diventa più grande e con il colore di sfondo giallo scuro.
   • mouseUp / mouseUpHandler(): quando l'utente rilascia il pulsante del mouse, il listener di eventi mouseMove viene rimosso e viene chiamato stopDrag, che blocca il quadrato in posizione.
   • mouseMove/mouseMoveHandler(): chiamati nell'ambito della funzione mouseDownHandler() e inviati quando l'utente preme il pulsante sinistro del mouse e trascina il quadrato.
   • mouseWheel / mouseWheelHandler(): inviato quando viene azionata la rotella del mouse sopra il quadrato.
3. L'istanza ChildSprite child viene quindi aggiunta all'elenco di visualizzazione tramite addChild(), che disegna immediatamente il quadrato arancione.

Note:

• La classe MouseEventExample deve essere al livello principale del documento.
• Alcuni dei metodi di eventi sopra elencati dichiarano una variabile sprite locale, a cui viene assegnato l'inserimento di event.target nel tipo Sprite.

package {
    import flash.display.Sprite;

    public class MouseEventExample extends Sprite {
        private var size:uint = 100;
        private var bgColor:uint = 0xFFCC00;

        public function MouseEventExample() {
            var child:ChildSprite = new ChildSprite();
            addChild(child);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
    private var size:uint = 50;
    private var overSize:uint = 60;
    private var backgroundColor:uint = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;

    public function ChildSprite() {
        draw(size, size, backgroundColor);
            doubleClickEnabled = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
        addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
        addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
        addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
    }

    private function draw(w:uint, h:uint, bgColor:uint):void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler");
    }

    private function doubleClickHandler(event:MouseEvent):void {
        trace("doubleClickHandler");
    }

    private function mouseDownHandler(event:MouseEvent):void {
        trace("mouseDownHandler");
        draw(overSize, overSize, downColor);

        var sprite:Sprite = Sprite(event.target);
        sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.startDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
        trace("mouseMoveHandler");
        event.updateAfterEvent();
    }

    private function mouseOutHandler(event:MouseEvent):void {
        trace("mouseOutHandler");
        draw(size, size, backgroundColor);
    }

    private function mouseOverHandler(event:MouseEvent):void {
        trace("mouseOverHandler");
        draw(overSize, overSize, overColor);
    }

    private function mouseWheelHandler(event:MouseEvent):void {
        trace("mouseWheelHandler delta: " + event.delta);
    }

    private function mouseUpHandler(event:MouseEvent):void {
        trace("mouseUpHandler");
        var sprite:Sprite = Sprite(event.target);
        sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.stopDrag();
        draw(overSize, overSize, overColor);
    }
}