CapsStyle - Guida di riferimento alle API Adobe ActionScript® 3 (AS3 )

Pacchetto	flash.display
Classe	public final class CapsStyle
Ereditarietà	CapsStyle Object

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9

La classe CapsStyle è un'enumerazione di valori costanti che specificano lo stile di estremità da utilizzare nelle linee di disegno. Le costanti vengono fornite per essere utilizzate come valori del parametro caps del metodo flash.display.Graphics.lineStyle(). Potete specificare i tre tipi di estremità seguenti:

I tre tipi di estremità: NONE, ROUND e SQUARE.

Vedere gli esempi

Elementi API correlati

flash.display.Graphics.lineStyle()

Proprietà pubbliche

Nascondi proprietà pubbliche ereditate

Mostra proprietà pubbliche ereditate

	Proprietà		Definito da
		constructor : Object Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto.	Object

Metodi pubblici

Nascondi metodi pubblici ereditati

Mostra metodi pubblici ereditati

	Metodo		Definito da
		hasOwnProperty(name:String):Boolean Indica se per un oggetto è definita una proprietà specifica.	Object
		isPrototypeOf(theClass:Object):Boolean Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro.	Object
		propertyIsEnumerable(name:String):Boolean Indica se la proprietà specificata esiste ed è enumerabile.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche.	Object
		toLocaleString():String Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate.	Object
		toString():String Restituisce la rappresentazione in formato stringa dell'oggetto specificato.	Object
		valueOf():Object Restituisce il valore di base dell'oggetto specificato.	Object

Costanti pubbliche

	Costante		Definito da
		NONE : String = "none" [statico] Utilizzato per non specificare alcuna estremità nel parametro caps del metodo flash.display.Graphics.lineStyle().	CapsStyle
		ROUND : String = "round" [statico] Utilizzato per specificare estremità arrotondate nel parametro caps del metodo flash.display.Graphics.lineStyle().	CapsStyle
		SQUARE : String = "square" [statico] Utilizzato per specificare estremità quadrate nel parametro caps del metodo flash.display.Graphics.lineStyle().	CapsStyle

Descrizione delle costanti

NONE

Costante

public static const NONE:String = "none"

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9

Utilizzato per non specificare alcuna estremità nel parametro caps del metodo flash.display.Graphics.lineStyle().

ROUND

Costante

public static const ROUND:String = "round"

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9

Utilizzato per specificare estremità arrotondate nel parametro caps del metodo flash.display.Graphics.lineStyle().

SQUARE

Costante

public static const SQUARE:String = "square"

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9

Utilizzato per specificare estremità quadrate nel parametro caps del metodo flash.display.Graphics.lineStyle().

Esempi Come utilizzare questo esempio

CapsStyleExample.as

L'esempio seguente utilizza la classe CapsStyleExample per disegnare tre linee parallele, ognuna con un diverso stile di estremità.

Di seguito sono riportate le proprietà di ciascuna linea:
- La lunghezza della linea è impostata su 80 pixel.
- Il colore del bordo è impostato su arancione.
- La dimensione del bordo è impostata su 30 pixel.
- Il colore di evidenziazione è impostato su grigio.
- La dimensione dell'evidenziazione è impostata su 0 pixel.
- L'alfa è impostato su 1; cioè è uniforme.
- L'approssimazione dei pixel è impostata su false (i tratti non sono approssimati ai pixel pieni).
- La modalità scala della linea è impostata su normale (lo spessore viene modificato in scala).
- Lo stile di spigolo delle estremità del bordo è impostato su MITER.
- Il limite della giunzione è impostato su 1, che indica che la giunzione viene troncata vicino alla linea.
La funzione di costruzione della classe crea tre linee verticali a partire da x = 0, y = 0 chiamando il metodo drawLine() tre volte con tre diversi stili di estremità della linea (nessuno, arrotondato e quadrato). Ognuna delle tre chiamate al metodo drawLine() utilizza lo stile di estremità e le proprietà elencate in precedenza per disegnare una linea verticale e l'evidenziazione a essa associata. Le chiamate dapprima creano un nuovo oggetto Shape child, quindi utilizzano i metodi della classe Graphics per impostare lo stile di linea e disegnare le linee e le evidenziazioni. Ogni istanza child viene aggiunta all'elenco di visualizzazione e disegnata sullo stage.
I segmenti di linee collegati vengono quindi ridisegnati mediante il metodo refreshLayout() in corrispondenza di y = 80 pixel e a partire da x = 80 pixel, con una separazione di 25 pixel tra i segmenti di linea.

package {
    import flash.display.CapsStyle;
    import flash.display.DisplayObject;
    import flash.display.Graphics;
    import flash.display.JointStyle;
    import flash.display.LineScaleMode;
    import flash.display.Shape;
    import flash.display.Sprite;

    public class CapsStyleExample extends Sprite {
        private var lineLength:uint            = 80;
        private var borderColor:uint           = 0xFFCC00;
        private var borderSize:uint            = 30;
        private var highlightColor:uint        = 0x666666;
        private var highlightSize:uint         = 0;
        private var gutter:uint                = 25;
        private var borderAlpha:uint           = 1;
        private var borderPixelHinting:Boolean = false;
        private var borderScaleMode:String     = LineScaleMode.NORMAL;
        private var borderJointStyle:String    = JointStyle.MITER;
        private var borderMiterLimit:uint      = 1;

        public function CapsStyleExample() {
            drawLine(CapsStyle.NONE);
            drawLine(CapsStyle.ROUND);
            drawLine(CapsStyle.SQUARE);
            refreshLayout();
        }

        private function drawLine(capsStyle:String):void {
            var child:Shape = new Shape();
            child.graphics.lineStyle(borderSize,
                                     borderColor,
                                     borderAlpha,
                                     borderPixelHinting,
                                     borderScaleMode,
                                     capsStyle,
                                     borderJointStyle,
                                     borderMiterLimit);
            child.graphics.lineTo(0, 0);
            child.graphics.lineTo(0, lineLength);
            child.graphics.endFill();

            child.graphics.moveTo(0, 0);
            child.graphics.lineStyle(highlightSize, highlightColor);
            child.graphics.lineTo(0, 0);
            child.graphics.lineTo(0, lineLength);

            addChild(child);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject;
            var lastChild:DisplayObject = getChildAt(0);
            lastChild.x = lineLength;
            lastChild.y = lineLength;
            for (var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = gutter + lastChild.x + lastChild.width;
                child.y = lineLength;
                lastChild = child;
            }
        }
    }
}

Note legali | Informativa sulla privacy online

CapsStyle - AS3

Classi x

NONE

ROUND

SQUARE