TextBlock  - AS3

Specifica che desiderate migliorare l'aspetto dello schermo a scapito della fedeltà della stampa WYSIWYG (What-You-See-Is-What-You-Get). Per le piattaforme e i caratteri che non supportano il posizionamento dei glifi di sottopixel durante il rendering dei caratteri del dispositivo, ma supportano la modifica in scala non lineare, l'impostazione di questa proprietà su true consente di utilizzare quelle metriche, con un certo impatto sulla fedeltà della stampa WYSIWYG, specialmente per le piccole dimensioni in punti. La modifica in scala non lineare prevede la modifica in scala selettiva della larghezza dei singoli glifi per nascondere gli spiacevoli spazi causati dall'aggancio ai pixel.

Sulle piattaforme che non supportano il posizionamento dei glifi di sottopixel, questo flag viene ignorato.

Questo flag non ha effetto sul rendering dei caratteri incorporati

Il valore predefinito è true.

Il carattere utilizzato per determinare le linee di base per tutte le righe create dal blocco, indipendentemente dal loro contenuto. Le linee di base dipendono dal carattere e dalle dimensioni del carattere.

Il valore predefinito è null. Quando il carattere della linea di base è null, le dimensioni del carattere della linea di base vengono ignorate e la linea di base di una qualsiasi riga specificata si basano sul carattere e sulle dimensioni del testo più grande contenuto nella riga. Quando si specificano baselineFontDescription ebaselineFontSize, determinano le linee di base per tutte le righe nel blocco di testo, indipendentemente dal loro contenuto. Questa combinazione viene utilizzata spesso nella stampa tipografica asiatica.

Elementi API correlati

Le dimensioni del carattere utilizzate per calcolare le linee di base per le righe create dal blocco. Le linee di base dipendono dal carattere e dalle dimensioni del carattere.

Il valore predefinito è 12. Quando il carattere della linea di base è null, le dimensioni del carattere della linea di base vengono ignorate e la linea di base di una qualsiasi riga specificata si basano sul carattere e sulle dimensioni del testo più grande contenuto nella riga.

Elementi API correlati

Specifica quale linea di base deve essere in y=0 per le righe create da questo blocco. I valori validi per questa proprietà sono reperibili nei membri della classe TextBaseline.

Il valore predefinito è TextBaseline.ROMAN.

Per impostare i valori di questa proprietà, utilizzate i seguenti valori stringa:

Elementi API correlati

Specifica il livello di incorporamento paragrafo bidirezionale del blocco di testo. In generale, utilizzate 0 per i paragrafi LTR (inglese, giapponese, ecc.) e 1 per i paragrafi RTL (arabo, ebraico, ecc.) L'uso di valori diversi da 0 o 1 è riservato per casi speciali; per maggiori informazioni, vedete UAX#9, "Unicode Bidirectional Algorithm" (http://www.unicode.org/reports/tr9/).

Il valore predefinito è 0.

La modifica della proprietà bidiLevel comporta la modifica della validità di tutte le righe precedentemente interrotte in TextLineValidity.INVALID. Dopo la modifica di bidiLevel, la proprietà firstInvalidLine è uguale alla proprietà firstLine e dovete applicare di nuovo l'interruzione di tutte le righe in TextBlock.

Elementi API correlati

package {
    
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_bidiLevelExample extends Sprite {
        
        public function TextBlock_bidiLevelExample():void {             
            var fontSize:Number = 36;

            var format:ElementFormat = new ElementFormat();        
            format.fontDescription = new FontDescription("Adobe Hebrew");
            format.fontSize = fontSize;
            var y:Number = 0;
            var leading:Number = fontSize * 0.2;
            var text:String = "abc" + String.fromCharCode(0x05D0, 0x05D1, 0x05D2);

            var textBlock:TextBlock = new TextBlock();
            textBlock.content = new TextElement(text, format);
                        
            // bidiLevel even
            textBlock.bidiLevel = 0;
            var textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;
            textLine.y = y;
            y += textLine.descent;
            addChild(textLine);      
            
            // bidiLevel odd
            textBlock.content = new TextElement(text, format);
            textBlock.bidiLevel = 1;
            textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;          
            textLine.y = y;
            addChild(textLine);   
        }
    }
}

Contiene il contenuto del blocco di testo. Poiché ContentElement è una classe base, assegnate a content un'istanza di una sottoclasse ContentElement: TextElement, GraphicElement o GroupElement. Un oggetto TextElement contiene un elemento String, un oggetto GraphicElement contiene un elemento DisplayObject e GroupElement contiene un oggetto Vector che contiene uno o più oggetti TextElement, GraphicElement o altri oggetti GroupElement. Utilizzate TextElement per un paragrafo di testo omogeneo, GraphicElement per un grafico e GroupElement per una combinazione di elementi di testo e grafica oppure più istanze di questi elementi, nonché altri oggetti GroupElement.

Il valore predefinito è null.

La modifica della proprietà content comporta la modifica della validità di tutte le righe precedentemente create in TextLineValidity.INVALID. Dopo la modifica di content, la proprietà firstInvalidLine è uguale alla proprietà firstLine e dovete applicare di nuovo l'interruzione di tutte le righe in TextBlock.

Elementi API correlati

Identifica la prima riga nel blocco di testo in cui TextLine.validity non è uguale a TextLineValidity.VALID.

Il valore predefinito è null.

Elementi API correlati

Il primo oggetto TextLine in TextBlock, se presente.

Il valore predefinito è null.

Elementi API correlati

L'ultimo oggetto TextLine in TextBlock, se presente.

Il valore predefinito è null.

Elementi API correlati

Ruota le righe di testo nel blocco di testo come un'unità. Chiamate il metodo createTextLine() dopo l'impostazione di lineRotation, per rendere effettiva la modifica. Il valore predefinito è TextRotation.ROTATE_0.

La rotazione finale di qualsiasi glifo dipende dai valori di , ElementFormat.textRotation, ContentElement.textRotation e TextBlock.lineRotation.

TextBlock.lineRotation viene di solito utilizzato per il testo in lingua asiatica. Per creare un paragrafo di testo verticale in giapponese, procedete come segue:

1. Impostate la proprietà TextBlock.lineRotation su TextRotation.ROTATE_90.
2. Lasciate la proprietà ElementFormat.textRotation del contenuto impostata sul valore predefinito TextRotation.AUTO.

Utilizzate le seguenti costanti definite nella classe TextRotation per impostare il valore per questa proprietà:

Altri esempi

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.text.engine.FontDescription;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.TextRotation;
    import flash.text.engine.ElementFormat;
    
    public class TextBlock_lineRotationExample extends Sprite {
        
        public function TextBlock_lineRotationExample():void {
            var Japanese:String = String.fromCharCode(
                0x5185, 0x95A3, 0x5E9C, 0x304C, 0x300C, 0x653F, 0x5E9C, 0x30A4,
                0x30F3, 0x30BF, 0x30FC, 0x30CD, 0x30C3, 0x30C8, 0x30C6, 0x30EC, 
                0x30D3, 0x300D, 0x306E, 0x52D5, 0x753B, 0x914D, 0x4FE1, 0x5411, 
                0x3051, 0x306B, 0x30A2, 0x30C9, 0x30D3, 0x30B7, 0x30B9, 0x30C6, 
                0x30E0, 0x30BA, 0x793E, 0x306E
            ) +
            "FMS 2" +
            String.fromCharCode(0x3092, 0x63A1, 0x7528, 0x3059, 0x308B, 0x3068, 
                0x767a, 0x8868, 0x3057, 0x307e, 0x3057, 0x305F, 0x3002);

            var fontDescription:FontDescription = new FontDescription("MS Mincho");
            var format:ElementFormat = new ElementFormat();
            format.fontSize = 15;
            format.fontDescription = fontDescription;
                        
            var textElement:TextElement = new TextElement(Japanese, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement;
            textBlock.lineRotation = TextRotation.ROTATE_90;

            var linePosition:Number = this.stage.stageWidth - 120;
            var previousLine:TextLine = null;
        
            while (true) {
                var textLine:TextLine = textBlock.createTextLine(
                    previousLine, 
                    300);
                if (textLine == null) 
                    break;
                textLine.y = 30;    
                textLine.x = linePosition;
                linePosition -= 24;
                addChild(textLine);                
                previousLine = textLine;
            }        
        }
    }
}

Specifica le tabulazioni per il testo contenuto nel blocco di testo, sotto forma di vettore di oggetti TabStop.

Il valore predefinito è null; questo significa che le tabulazioni non sono specificate. Se non è stata specificata alcuna tabulazione (oppure il punto di inserimento si trova al di là dell'ultima tabulazione specificata), il runtime crea delle tabulazioni di mezzo pollice per impostazione predefinita.

Quando viene impostata la proprietà tabStops, TextBlock crea una copia dell'oggetto Vector per uso interno. La modifica dell'oggetto Vector originale o dei suoi contenuti non influisce su TextBlock. Quando si esegue una query sulla proprietà tabStops, viene restituita una copia dell'oggetto Vector interno. Ancora una volta, la modifica dell'oggetto Vector restituito o dei suoi contenuti non influisce su TextBlock.

Elementi API correlati

Specifica l'oggetto TextJustifier da utilizzare durante la creazione delle righe.

Il valore predefinito è un oggetto TextJustifier creato per impostazione predefinita.

Quando viene impostata la proprietà textJustifier, TextBlock esegue una copia dell'oggetto per uso interno. La modifica dell'oggetto originale non influisce su TextBlock. Quando si esegue una query sulla proprietà textJustifier, viene restituita una copia dell'oggetto interno. Anche in questo caso, la modifica dell'oggetto restituito non ha effetti su TextBlock.

Altri esempi

Elementi API correlati

Indica il risultato di un'operazione createTextLine(). La modifica del contenuto del blocco invalida le precedenti interruzioni di riga e reimposta questa proprietà su null.

Il valore predefinito è null.

I valori per questa proprietà sono reperibili in TextLineCreationResult

Elementi API correlati

Fornisce un modo per consentire all'applicazione di associare dati arbitrari con il blocco di testo. I dati possono essere costituiti da informazioni che fanno riferimento al contenuto, ad esempio una data di revisione o il nome dell'autore, oppure da dati memorizzati nella cache che utilizzate durante l'elaborazione.

Crea un oggetto TextBlock

Elementi API correlati

Indica al blocco di testo di creare una riga di testo dal proprio contenuto, a partire dal punto specificato dal parametro previousLine fino al punto specificato dal parametro width. La riga di testo è un oggetto TextLine, che potete aggiungere all'elenco di visualizzazione.

L'interruzione di righe in un intervallo di un blocco di testo che contiene già interruzioni può modificare la validità delle righe all'interno e oltre l'area in cui viene inserita un'interruzione. Lo stato delle righe può cambiare da VALID in INVALID o POSSIBLY_INVALID. Se una riga appena interrotta si allinea perfettamente con una riga precedentemente interrotta con lo stato POSSIBLY_INVALID, quella riga precedentemente interrotta e tutte le righe successive con lo stato POSSIBLY_INVALID vengono riconvertite nello stato VALID. La validità delle righe impostate su valori che non sono membri di TextLineValidity non viene modificata in VALID, ma potrebbe esserlo in INVALID. Controllate la proprietà firstInvalidLine dopo qualsiasi modifica del blocco di testo per verificare se iniziare o continuare ad applicare di nuovo le interruzioni delle righe di testo.

Potete creare interruzioni di parole artificiali includendo nel testo il carattere spazio di larghezza zero (ZWSP, Zero Width Space) Unicode. Ciò può essere utile per le lingue, come il tailandese, che richiedono un dizionario per l'interruzione di riga corretta. Il runtime Flash non include questo tipo di dizionario.

Per ridurre i sovraccarichi di memoria, dopo la creazione di tutte le righe richieste, a meno che sia prevista la necessità di interromperle di nuovo ripetutamente a causa, ad esempio, del ridimensionamento del contenitore, l'utente dovrà chiamare il metodo releaseLineCreationData() per consentire al blocco di testo di eliminare i dati temporanei associati all'interruzione di riga.

Parametri

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_createTextLineExample extends Sprite {
        
        public function TextBlock_createTextLineExample():void {
            
            var str:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. The createTextLine() method " +
            "then created these lines, 300 pixels wide, for display." ;
            
            var fontDescription:FontDescription = new FontDescription("Arial");
            var format:ElementFormat = new ElementFormat(fontDescription);
            format.fontSize = 16;
            var textElement:TextElement = new TextElement(str, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement; 
            createLines(textBlock); 
        }
        
        private function createLines(textBlock:TextBlock):void 
        {            
            var lineWidth:Number = 300;
            var xPos:Number = 15.0;
            var yPos:Number = 20.0;
            
            var textLine:TextLine = textBlock.createTextLine (null, lineWidth);
            while (textLine)
            {
                textLine.x = xPos;
                textLine.y = yPos;
                yPos += textLine.height + 2;
                addChild (textLine);
                textLine = textBlock.createTextLine (textLine, lineWidth);
            }
        }
    }
}

Scarica il contenuto sottostante di TextBlock come una stringa XML. Ciò può essere utile nelle prove automatiche e include testo, formattazione e informazioni sul layout.

Di seguito è descritto l'output:

	 >block<
	 	[0-N LINE]
	 >/block<
	 

Per una descrizione dell'output per ogni riga, vedete il metodo TextLine.dump().

Nota: il contenuto e il formato dell'output potrebbero essere modificati in futuro. Adobe non garantisce la compatibilità retroattiva di questo metodo.

Elementi API correlati

Trova l'indice del limite dell'atomo successivo a partire dall'indice del carattere specificato, escludendo il carattere nella posizione di indice specificata. I caratteri tra i limiti dell'atomo vengono combinati per formare un solo atomo in TextLine, ad esempio una "e" combinata con un accento acuto.

Parametri

Elementi API correlati

Trova l'indice del limite della parola successiva dall'indice del carattere specificato, escludendo il carattere nella posizione di indice specificata. I limiti delle parole sono determinati in base alle proprietà Unicode dei caratteri.

Parametri

Trova l'indice del limite dell'atomo precedente all'indice del carattere specificato, escludendo il carattere nella posizione di indice specificata. I caratteri tra i limiti dell'atomo vengono combinati per formare un solo atomo in TextLine, ad esempio una "e" combinata con un accento acuto.

Parametri

Elementi API correlati

Trova l'indice del limite della parola precedente all'indice del carattere specificato, escludendo il carattere nella posizione di indice specificata. I limiti delle parole sono determinati in base alle proprietà Unicode dei caratteri.

Parametri

Restituisce l'oggetto TextLine contenente il carattere specificato dal parametro charIndex.

Parametri

Indica al blocco di testo di riutilizzare una riga di testo esistente per creare una riga di testo dal proprio contenuto, a partire dal punto specificato dal parametro previousLine e fino al punto specificato dal parametro width. La riga di testo è un oggetto TextLine, che potete aggiungere all'elenco di visualizzazione. Il riutilizzo di una riga di testo esistente consente di migliorare le prestazioni, grazie alla ridotta creazione di oggetti.

L'oggetto textLine che viene ricreato viene rilasciato da qualsiasi blocco di testo in cui è eventualmente contenuto. Inoltre, tutte le proprietà, incluse quelle ereditate da DisplayObjectContainer, InteractiveObject e DisplayObject, vengono riportate ai valori predefiniti. Infine, tutti gli elementi secondari della riga vengono rimossi, compresi gli elementi grafici e altre decorazioni, e tutti i listener di eventi sulla riga vengono rimossi a loro volta. Per migliorare le prestazioni, la sola eccezione a questo ripristino completo è rappresentata dal fatto che la riga stessa non viene rimossa dal rispettivo elemento principale.

L'interruzione di righe in un intervallo di un blocco di testo che contiene già interruzioni può modificare la validità delle righe all'interno e oltre l'area in cui viene inserita un'interruzione. Lo stato delle righe può cambiare da VALID in INVALID o POSSIBLY_INVALID. Se una riga appena interrotta si allinea perfettamente con una riga precedentemente interrotta con lo stato POSSIBLY_INVALID, quella riga precedentemente interrotta e tutte le righe successive con lo stato POSSIBLY_INVALID vengono riconvertite nello stato VALID. La validità delle righe impostate su valori che non sono membri di TextLineValidity non viene modificata in VALID, ma potrebbe esserlo in INVALID. Controllate la proprietà firstInvalidLine dopo qualsiasi modifica del blocco di testo per verificare se iniziare o continuare ad applicare di nuovo le interruzioni delle righe di testo.

Potete creare interruzioni di parole artificiali includendo nel testo il carattere spazio di larghezza zero (ZWSP, Zero Width Space) Unicode. Ciò può essere utile per le lingue, come il tailandese, che richiedono un dizionario per l'interruzione di riga corretta. Il runtime Flash non include questo tipo di dizionario.

Per ridurre i sovraccarichi di memoria, dopo la creazione di tutte le righe richieste, a meno che sia prevista la necessità di interromperle di nuovo ripetutamente a causa, ad esempio, del ridimensionamento del contenitore, l'utente dovrà chiamare il metodo releaseLineCreationData() per consentire al blocco di testo di eliminare i dati temporanei associati all'interruzione di riga.

Parametri

Elementi API correlati

var elementFormat:ElementFormat = new ElementFormat();
elementFormat.fontDescription = new FontDescription("Arial");
elementFormat.fontSize = 48;

var textElement:TextElement = new TextElement("Text you'll never see", elementFormat)
var textBlock:TextBlock = new TextBlock(textElement);
var textLine:TextLine = textBlock.createTextLine();
textLine.x = 50;
textLine.y = 50;
addChild(textLine);

// Reuse the element format to preserve the text formatting
var elementTwo:TextElement = new TextElement("Text you see", elementFormat);  
textBlock.content = elementTwo;
textBlock.recreateTextLine(textLine);

// Set the position (and any other display object properties like alpha, children, etc.)
// otherwise, they're all set to default properties.
textLine.x = 50;  
textLine.y = 50;

Indica al blocco di testo di rilasciare tutti i dati temporanei associati alla creazione di righe di testo. Per ridurre al minimo l'occupazione della memoria da parte di un'applicazione, dopo aver completato la creazione delle righe di testo da un blocco di testo dovrete chiamare il metodo releaseLineCreationData(). Per ottimizzare, tuttavia, le prestazioni quando è necessario applicare di nuovo le interruzioni delle righe (ad esempio quando viene ridimensionato il contenitore), non chiamate il metodo releaseLineCreationData(). Il bilanciamento della memoria rispetto alle prestazioni è compito dell'applicazione.

Il processo consigliato per il testo che non si prevede di modificare è il seguente: inizializzate un blocco di testo, chiamate il metodo createTextLine() tutte le volte che è necessario per creare l'output desiderato, quindi chiamate il metodo releaseLineCreationData().

Elementi API correlati

Rimuove un intervallo di righe di testo dall'elenco di righe gestite da TextBlock. Consente di sottoporre le righe al processo di garbage-collection se non esistono altri riferimenti.

Imposta i membri textBlock, nextLine e previousLine delle righe rimosse su null. Imposta il valore validity delle righe rimosse e di tutte le righe che seguono quelle rimosse in TextBlock su TextLineValidity.INVALID.

Parametri

Elementi API correlati