TextLine  - AS3

Specifica il numero di pixel dalla linea di base all'estremità superiore dell'altezza della riga, espressa in pixel. Per un oggetto TextLine che contiene solo un elemento grafico, ascent è impostato su 0.

Il numero di atomi nella riga, che corrisponde al numero di elementi invisibili, inclusi spazi ed elementi grafici.

Specifica il numero di pixel dalla linea di base alla estremità inferiore massima dei caratteri discendenti nella riga. Per un oggetto TextLine che contiene solo un elemento grafico, descent è impostato su 0.

Indica se la riga di testo contiene elementi grafici.

Elementi API correlati

Indica se la riga di testo contiene tabulazioni.

Un vettore contenente gli oggetti TextLineMirrorRegion associati alla riga oppure null se non sono presenti.

Elementi API correlati

Il successivo oggetto TextLine in TextBlock, oppure null se la riga corrente è l'ultima riga nel blocco o la validità della riga è TextLineValidity.STATIC.

Elementi API correlati

Il precedente oggetto TextLine in TextBlock, oppure null se questa è la prima riga nel blocco o la validità della riga è TextLineValidity.STATIC.

Elementi API correlati

La lunghezza del testo originario nel blocco di testo che è diventato la riga, inclusi i caratteri U+FDEF che rappresentano gli elementi grafici ed eventuali spazi finali che fanno parte della riga, ma che non vengono visualizzati.

Elementi API correlati

La larghezza specificata per il metodo TextBlock.createTextLine() al momento della creazione della riga. Questo valore è utile quando dovete decidere se una modifica richiede di applicare di nuovo l'interruzione di riga.

Elementi API correlati

L'oggetto TextBlock contenente questa riga di testo, oppure null se la validità della riga è TextLineValidity.STATIC; indica che la connessione tra la riga e TextBlock è stata interrotta.

Elementi API correlati

L'indice del primo carattere della riga nel testo originario del blocco di testo.

Elementi API correlati

L'altezza logica della riga di testo, che è uguale ad ascent + descent. Per ottenere l'altezza rilevata, potete accedere alla proprietà ereditata height.

Il valore viene calcolato in base alla differenza tra le linee di base che delimitano la riga, sia ideogrammi dall'alto in basso o ascendenti/discendenti, a seconda che TextBlock.baselineZero sia o meno un ideogramma. Gli elementi grafici non vengono considerati quando si calcolano queste linee di base.

Elementi API correlati

La larghezza logica della riga di testo, che corrisponde alla larghezza utilizzata dal motore di testo per il layout della riga. Potete accedere alla proprietà width ereditata per ottenere la larghezza effettiva del riquadro di delimitazione di tutti i pixel disegnati.

Elementi API correlati

 
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.FontPosture;

    public class TextLine_textWidthExample extends Sprite {
        
        public function TextLine_textWidthExample() {
            
            var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
            var yPos:Number = 20;
            var fontDescription:FontDescription = new FontDescription();
            var textBlock:TextBlock = new TextBlock();
            fontDescription.fontPosture = FontPosture.NORMAL;
            var format:ElementFormat = new ElementFormat(fontDescription, 12);
            var textElement:TextElement = new TextElement(str, format);
            textBlock.content = textElement;
            createLine(textBlock, yPos);
            var fontDescriptionItalic = fontDescription.clone();
            fontDescriptionItalic.fontPosture = FontPosture.ITALIC;
            var formatItalic = new ElementFormat(fontDescriptionItalic, 12);
            textElement = new TextElement(str, formatItalic);
            textBlock.content = textElement;
            createLine(textBlock, yPos + 20);
        }

        private function createLine(textBlock:TextBlock, yPos:Number):void {
            var textLine:TextLine = textBlock.createTextLine (null, 500);
            trace("specifiedWidth is: " + textLine.specifiedWidth);
            trace("textWidth is: " + textLine.textWidth);
            trace("width is: " + textLine.width);
            addChild(textLine);
            textLine.x = 15;
            textLine.y = yPos;     
        }
    }
}

Specifica il numero di pixel dalla linea di base all'estremità superiore del carattere o dell'immagine più alta della riga.

Specifica il numero di pixel dalla linea di base all'estremità inferiore massima del carattere o dell'immagine discendente più bassa della riga.

L'altezza logica totale della riga di testo, che è uguale a totalAscent + totalDescent.

La larghezza della riga, se non è stata giustificata. Per il testo non giustificato, questo valore è lo stesso di textWidth. Per il testo giustificato, questo valore corrisponde alla lunghezza che avrebbe avuto il testo senza giustificazione e textWidth rappresenta la larghezza effettiva della riga. Quando, ad esempio, la stringa seguente viene giustificata e inviata a TextBlock.createTextLine() con una larghezza 500, la larghezza effettiva sarà 500 mentre quella non giustificata sarà pari a 268,9921875.

Elementi API correlati

     import flash.display.Sprite;
     import flash.text.engine.TextBlock;
     import flash.text.engine.TextElement;
     import flash.text.engine.TextLine;
     import flash.text.engine.FontDescription;
     import flash.text.engine.ElementFormat;
     import flash.text.engine.SpaceJustifier;
     import flash.text.engine.LineJustification;

     var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
     var fontDescription:FontDescription = new FontDescription();
     var textBlock:TextBlock = new TextBlock();
     var format:ElementFormat = new ElementFormat(fontDescription, 12);
     var textElement:TextElement = new TextElement(str, format);
     textBlock.content = textElement;
     var spaceJustifier:SpaceJustifier = new SpaceJustifier("en", LineJustification.ALL_INCLUDING_LAST);
     textBlock.textJustifier = spaceJustifier;
     var textLine:TextLine = textBlock.createTextLine(null, 500);
     textLine.y = 20;

     addChild(textLine);
     trace("textWidth value is: " + textLine.textWidth);        // 500.00244140625
     trace("unjustifiedTextWidth is: " + textLine.unjustifiedTextWidth); // 268.9921875
     

Fornisce un modo per consentire all'applicazione di associare dati arbitrari con la riga di testo.

Specifica la validità corrente della riga di testo. I valori per questa proprietà sono reperibili nei membri della classe TextLineValidity. Di seguito sono riportate le regole per l'impostazione di questa proprietà:

Una riga viene considerata USER_INVALID se la validità è impostata su una stringa qualsiasi che non è membro di TextLineValidity. USER_INVALID è un'astrazione usata qui per rappresentare un tale valore qualsiasi.

Quando il contenuto di TextBlock viene modificato, il runtime Flash contrassegna le righe di testo interessate, la riga precedente e tutte le righe seguenti come INVALID. La riga precedente deve essere contrassegnata come non valida quando una modifica consente alla riga precedente di incorporare parte del contenuto che in origine era sulla prima riga interessata.

Le nuove righe interrotte sono sempre VALID. Il runtime Flash potrebbe modificare lo stato delle righe successive da VALID a POSSIBLY_INVALID o INVALID. Potrebbe modificare le righe POSSIBLY_INVALID in VALID se le interruzioni di riga corrispondono oppure in INVALID se non corrispondono.

Il codice dell'applicazione può contrassegnare le righe VALID come INVALID o USER_INVALID e contrassegnare le righe USER_INVALID come VALID. Il codice dell'applicazione non può contrassegnare le righe come POSSIBLY_INVALID.

Il codice dell'applicazione può contrassegnare qualsiasi riga come STATIC. In questo caso, il membro block diventa null. Tutti gli elementi grafici in una riga di testo STATIC vengono rimossi e ne viene riassegnata l'appartenenza, se fanno parte di una nuova riga di testo separata mediante interruzione dal blocco di testo da cui è derivata in origine la riga di testo STATIC.

Elementi API correlati

Scarica il contenuto sottostante di TextLine come stringa XML. Ciò può essere utile nelle prove automatiche e include testo, formattazione e informazioni sul layout.

Di seguito è descritto l'output:

	 [LINE]
	 <line ascent=[Number] descent=[Number] rotation=[int]>
	 	<elements>
	 		[0-N ELEMENT]
	 	</elements>
	 	<clusters>
	 		[0-N CLUSTER]
	 	</clusters>
	 </line>
	 
	 [ELEMENT]
	 <glyph isEmbedded=[Boolean] fontName=[String] isBold=[Boolean] isItalic=[Boolean] gid=[int] pointSize=[Number] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <graphic child=[int] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <embeddedRun x=[Number] y=[Number]>
	 	[LINE]
	 </embeddedRun>
	 
	 [CLUSTER]
	 <cluster xLeft=[Number] xCenter=[Number] xRight=[Number] cursorOnLeft=[Boolean] cursorOnRight=[Boolean] wordBoundaryOnLeft=[Boolean] wordBoundaryOnRight=[Boolean]/>
	 

Nota: il contenuto e il formato dell'output di questo metodo potrebbero essere modificati in futuro. Adobe non garantisce la compatibilità retroattiva per questo metodo.

Elementi API correlati

Questo metodo è sconsigliato e non ha alcun effetto. I dati atomici sono compressi e non sono un fattore significativo per gestire l'efficienza della memoria.

Elementi API correlati

Ottiene il livello bidirezionale dell'atomo nella posizione di indice specificata. Determinato da una combinazione di TextBlock.bidiLevel e di proprietà bidirezionali Unicode dei caratteri che compongono la riga.

Se, ad esempio, iniziate un blocco di testo con testo in ebraico, impostate TextBlock.bidiLevel su 1, stabilendo una direzione predefinita da destra a sinistra. Se all'interno del testo è presente una citazione in inglese (da sinistra a destra), AtomBidiLevel è impostato su 2. Se all'interno del testo in inglese è presente un frammento in arabo (da destra a sinistra), AtomBidiLevel in tal caso è impostato su 3. Se all'interno del testo in arabo è incluso un numero (da sinistra a destra), l'impostazione di AtomBidiLevel per il numero è 4. Non importa in quale riga si trovano gli atomi; quelli in ebraico sono AtomBidiLevel 1, quelli in inglese AtomBidiLevel 2, quelli in arabo AtomBidiLevel 3 e gli atomi relativi ai numeri sono AtomBidiLevel 4.

Parametri

Elementi API correlati

Ottiene i limiti dell'atomo nella posizione di indice specificata relativa alla riga di testo. I limiti dell'atomo specificato sono composti dalla relativa posizione orizzontale nella riga (x), dalla posizione verticale nella riga (y), dalla larghezza (w) e dall'altezza (h). Tutti i valori sono espressi in pixel.

Parametri

Ottiene il centro dell'atomo misurato lungo la linea di base nella posizione di indice specificata.

Parametri

Ottiene il grafico dell'atomo nella posizione di indice specificata, oppure null se l'atomo è un carattere.

Parametri

Restituisce l'indice dell'atomo contenente il carattere specificato dal parametro charIndex, oppure -1 se il carattere non incide su alcun atomo nella riga. Il parametro charIndex è relativo all'intero contenuto del blocco di testo contenente la riga.

Parametri

Restituisce l'indice dell'atomo nel punto specificato dai parametri x e y, oppure -1 se non esiste un atomo in corrispondenza di quel punto.

Questo metodo accetta le coordinate globali, in modo da facilitarne l'utilizzo con le proprietà MouseEvent.stageX e MouseEvent.stageY.

Parametri

Ottiene l'indice iniziale del blocco di testo dell'atomo nella posizione di indice specificata.

Parametri

Ottiene l'indice finale del blocco di testo dell'atomo nella posizione di indice specificata.

Parametri

Ottiene la rotazione dell'atomo nella posizione di indice specificata. Per questa proprietà vengono utilizzate le costanti TextRotation. La rotazione dell'atomo corrisponde alla somma delle rotazioni dell'elemento e della riga. L'uso primario è l'impostazione dell'orientamento dell'accento circonflesso (cursore) quando interagisce con una TextLine.

Parametri

Elementi API correlati

Indica se è presente un limite di parole a sinistra dell'atomo nella posizione di indice specificata. I limiti delle parole sono determinati in base alle proprietà Unicode dei caratteri che hanno contribuito alla composizione della riga.

Parametri

Ottiene la posizione della linea di base specificata, in relazione a TextBlock.baselineZero.

Parametri

Elementi API correlati

Restituisce il primo oggetto TextLineMirrorRegion sulla riga la cui proprietà mirror corrisponde a quella specificata dal parametro mirror; oppure null se non esiste una corrispondenza.

Anche un unico oggetto TextElement può produrre più oggetti TextLineMirrorRegion su una o più righe, a seconda del livello bidirezionale e dell'interruzione di riga. Le proprietà nextRegion e previousRegion collegano tutte le aree speculari generate da un unico elemento di testo.

Parametri

Elementi API correlati

La larghezza massima richiesta di una riga di testo, espressa in pixel. Il metodo TextBlock.createTextLine() utilizza questa costante come valore predefinito per il parametro width, se non specificate un valore.

Elementi API correlati

1. Aggiungete il componente NumericStepper alla libreria.
2. Salvate questo codice come TextLineExample.as nella stessa directory del FLA.
3. Impostate Class nella finestra Proprietà del FLA su TextLineExample.

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    import flash.text.engine.FontPosture;
    import flash.text.engine.FontWeight;
    import fl.controls.NumericStepper;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class TextLineExample extends Sprite {
        
        private var atomStepper:NumericStepper = new NumericStepper();
        private var atomDataContainer:Sprite;
        private var fontDescriptionItalic:FontDescription = new FontDescription("Arial", FontWeight.NORMAL, FontPosture.ITALIC);
        private var fontDescriptionNormal:FontDescription = new FontDescription("Arial", FontWeight.NORMAL , FontPosture.NORMAL);
        private var textBlock:TextBlock = new TextBlock();
        private var textLine:TextLine;
        
        public function TextLineExample():void {
            
            var myText:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. From the text block, " +
            "the createTextLine() method created these lines, 300 pixels wide, "  +
            "for display." ;
            
            atomStepper.minimum = 0;
            atomStepper.value = 0;
            atomStepper.width = 50;
            addChild(atomStepper);
            atomStepper.x = 20;
            atomStepper.y = 120;
            atomStepper.addEventListener(Event.CHANGE, nsChange);
            
            var directions:String = "Click up / down arrows to frame atoms in text block above.";
            
            var formatItalic:ElementFormat = new ElementFormat(fontDescriptionItalic);
            formatItalic.fontSize = 12;
            var textElement1:TextElement = new TextElement(directions, formatItalic);
            textBlock.content = textElement1;
            createLines(textBlock, 15, 160, 400, this);
            
            var formatNormal:ElementFormat = new ElementFormat(fontDescriptionNormal);
            formatNormal.fontSize = 16;
            var textElement2:TextElement = new TextElement(myText, formatNormal);
            textBlock.content = textElement2;
            createLines(textBlock, 15.0, 20.0, 300, this);
            textLine = textBlock.firstLine;
            atomStepper.maximum = textLine.atomCount - 1;
            showAtom(textLine, 0);
        }
            
        private function nsChange(event:Event):void
        {
            removeAtom(textLine);
            if (atomStepper.value == textLine.atomCount - 1)
            {
                if(textLine != textBlock.lastLine)
                {
                    textLine = textLine.nextLine;
                    atomStepper.maximum = textLine.atomCount - 1;
                    atomStepper.value = 0;
                }
            }
            showAtom(textLine, atomStepper.value);
        }
            
        private function createLines(textBlock, startX, startY, width, container)
        {
            var textLine:TextLine = textBlock.createTextLine (null, width);
            while (textLine)
            {
                textLine.x = startX;
                textLine.y = startY;
                startY += textLine.height + 2;
                container.addChild(textLine);
                textLine = textBlock.createTextLine (textLine, width);
            }
        }
            
        private function showAtom(textLine, i):void
        {
            var box:Sprite = new Sprite();
            var mcGraphics = box.graphics;
            var bounds:Rectangle = textLine.getAtomBounds(i);
            mcGraphics.lineStyle(1, 0xFF0000, 1.0);
            mcGraphics.drawRect(bounds.left, bounds.top, bounds.width, bounds.height);
            textLine.userData = textLine.addChild(box);
            displayAtomData(textLine,i);
        }
            
        private function displayAtomData(textLine, i)
        {
            if(atomDataContainer != null)
                removeChild(atomDataContainer);
            atomDataContainer=new Sprite();
            var format = new ElementFormat(fontDescriptionNormal);
            format.color = 0x00000FF;
            var n:int = 0;
            var nxtY:Number = 0;
            var atomInfo:String = "value of getAtomBidiLevel() is: " + textLine.getAtomBidiLevel(i)+"\n"
            +"value of getAtomCenter() is: " + textLine.getAtomCenter(i)+"\n"
            +"value of getAtomIndexAtCharIndex() is: " + textLine.getAtomIndexAtCharIndex(i)+"\n"
            +"value of getAtomTextBlockBeginIndex() is: " + textLine.getAtomTextBlockBeginIndex(i)+"\n"
            +"value of getAtomTextBlockEndIndex() is: " + textLine.getAtomTextBlockEndIndex(i)+"\n"
            +"value of getAtomTextRotation() is: " + textLine.getAtomTextRotation(i)+"\n";
            var atomtextBlock:TextBlock = new TextBlock();
            var textElement3:TextElement = new TextElement(atomInfo, format);
            atomtextBlock.content = textElement3;
            createLines(atomtextBlock,20,200,500, atomDataContainer)
            addChild(atomDataContainer);
        }
            
        private function removeAtom(textLine):void
        {
            textLine.removeChild(textLine.userData);
        }
    }    
}