DisplayObjectContainer  - AS3

Determina se gli elementi secondari dell'oggetto sono abilitati o meno per il mouse o per il dispositivo di input dell'utente. Se un oggetto è abilitato, l'utente può interagire con esso mediante il mouse o il dispositivo di input dell'utente. Il valore predefinito è true.

Questa proprietà è utile quando create un pulsante con un'istanza della classe Sprite (anziché utilizzare la classe SimpleButton). Quando usate un'istanza Sprite per creare un pulsante, potete scegliere di decorare il pulsante utilizzando il metodo addChild() per aggiungere ulteriori istanze Sprite. Questo processo può produrre un comportamento imprevisto degli eventi del mouse perché le istanze Sprite che aggiungete come elementi secondari possono diventare l'oggetto target di un evento mouse invece dell'istanza principale. Per fare sì che solo l'istanza principale possa essere l'oggetto target degli eventi del mouse, potete impostare la proprietà mouseChildren dell'istanza principale su false.

Nessun evento viene inviato impostando questa proprietà. Dovete utilizzare il metodo addEventListener() per creare la funzionalità interattiva.

Elementi API correlati

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
container.name = "container";
addChild(container);

var circle:Sprite = new Sprite();
circle.name = "circle";
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);

container.addChild(circle);

container.mouseChildren = false;

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace(event.target.name); // container
}

Restituisce il numero di elementi secondari di questo oggetto.

Altre informazioni

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Determina se gli elementi secondari dell'oggetto sono abilitati per la tabulazione. Abilita o disabilita la tabulazione per gli elementi secondari dell'oggetto. Il valore predefinito è true.

Nota: non utilizzate la proprietà tabChildren con Flex. Usate invece la proprietà mx.core.UIComponent.hasFocusableChildren.

import flash.display.Sprite;

var container:Sprite = new Sprite();
container.tabChildren = false;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.tabIndex = 1;

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);
circle2.tabIndex = 0;

container.addChild(circle1);
container.addChild(circle2);

Restituisce un oggetto TextSnapshot per questa istanza DisplayObjectContainer.

Elementi API correlati

trace(this.textSnapshot.getText(0, this.textSnapshot.charCount));

Una chiamata alla funzione di costruzione new DisplayObjectContainer() genera un'eccezione ArgumentError. È invece possibile chiamare funzioni di costruzione per le seguenti sottoclassi di DisplayObjectContainer:

• new Loader()
• new Sprite()
• new MovieClip()

Aggiunge un'istanza secondaria DisplayObject a questa istanza DisplayObjectContainer. L'istanza secondaria viene aggiunta al livello principale (primo) di tutti gli altri elementi secondari di questa istanza DisplayObjectContainer. Per aggiungere un elemento secondario in una posizione specifica, utilizzate il metodo, addChildAt().

Se aggiungete un oggetto secondario che ha già un contenitore di oggetto di visualizzazione diverso come elemento principale, l'oggetto viene rimosso dall'elenco degli elementi secondari dell'altro contenitore.

Nota: il comando stage.addChild() può causare problemi con un file SWF pubblicato, tra cui problemi di sicurezza e conflitti con altri file SWF caricati. In un'istanza del runtime Flash è presente un solo stage, indipendentemente dal numero di file SWF caricati nel runtime. In generale, quindi, gli oggetti non devono assolutamente essere aggiunti direttamente allo stage. Il solo oggetto che lo stage deve contenere è l'oggetto radice. Create un DisplayObjectContainer che conterrà tutti gli elementi dell'elenco di visualizzazione. Quindi, se necessario, aggiungete allo stage tale istanza DisplayObjectContainer.

Parametri

Altri esempi

Altre informazioni

Elementi API correlati

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Aggiunge un'istanza secondaria DisplayObject a questa istanza DisplayObjectContainer. L'istanza viene aggiunta nella posizione di indice specificata. L'indice 0 corrisponde all'ultimo livello di profondità dell'elenco di visualizzazione di questo oggetto DisplayObjectContainer.

L'esempio seguente mostra tre oggetti di visualizzazione (a, b e c) rispettivamente nelle posizioni di indice 0, 2 e 1:

Se aggiungete un oggetto secondario che ha già un contenitore di oggetto di visualizzazione diverso come elemento principale, l'oggetto viene rimosso dall'elenco degli elementi secondari dell'altro contenitore.

Parametri

Altri esempi

Altre informazioni

Elementi API correlati

import flash.display.Sprite;

var container:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
var circle2:Sprite = new Sprite();

container.addChild(circle1);
container.addChildAt(circle2, 0);

trace(container.getChildAt(0) == circle2); // true
trace(container.getChildAt(1) == circle1); // true

Indica se le restrizioni di sicurezza possono determinare l'omissione di eventuali oggetti di visualizzazione dall'elenco restituito dalla chiamata al metodo DisplayObjectContainer.getObjectsUnderPoint() con il punto point specificato. Per impostazione predefinita, il contenuto di un dominio non può accedere agli oggetti di un altro dominio a meno che l'operazione non venga consentita mediante una chiamata al metodo Security.allowDomain(). Per ulteriori informazioni sulla sicurezza, consultate l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .

Il parametro point è nello spazio di coordinate dello stage, che può essere diverso dallo spazio di coordinate del contenitore di oggetto di visualizzazione (a meno che quest'ultimo non sia lo stage). Per convertire dei punti tra questi due spazi di coordinate, potete utilizzare i metodi globalToLocal() e localToGlobal().

Parametri

Elementi API correlati

import flash.display.Sprite;
import flash.display.Loader;
import flash.system.LoaderContext;
import flash.net.URLRequest;
import flash.events.Event;
import flash.geom.Point;

var container:Sprite = new Sprite();

var urlReq:URLRequest = new URLRequest("http://localhost/RemoteFile.swf");
var ldr:Loader = new Loader();
var context:LoaderContext = new LoaderContext();
context.checkPolicyFile = false;
ldr.load(urlReq, context);

ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, loaded);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);

function loaded(event:Event):void {
    var pt:Point = new Point(1, 1);
    trace(container.areInaccessibleObjectsUnderPoint(pt)); // true
}

function urlNotFound(event:Event):void {
    trace("The URL was not found."); 
}

Determina se l'oggetto di visualizzazione specificato è un elemento secondario dell'istanza DisplayObjectContainer oppure è l'istanza stessa. La ricerca comprende l'intero elenco di visualizzazione, inclusa questa istanza DisplayObjectContainer. Gli elementi secondari di secondo livello, di terzo livello e così via restituiscono tutti true.

Parametri

import flash.display.Sprite;

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();
var sprite4:Sprite = new Sprite();

sprite1.addChild(sprite2);
sprite2.addChild(sprite3);

trace(sprite1.contains(sprite1)); // true
trace(sprite1.contains(sprite2)); // true
trace(sprite1.contains(sprite3)); // true
trace(sprite1.contains(sprite4)); // false

Restituisce l'istanza dell'oggetto di visualizzazione secondario che si trova in corrispondenza della posizione di indice specificata.

Parametri

Altri esempi

Elementi API correlati

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();

container.addChild(sprite1);
container.addChild(sprite2);
container.addChildAt(sprite3, 0);

trace(container.getChildAt(0) == sprite3); // true
trace(container.getChildAt(1) == sprite1); // true
trace(container.getChildAt(2) == sprite2); // true

Restituisce l'oggetto di visualizzazione secondario al quale corrisponde il nome specificato. Se più di un oggetto di visualizzazione secondario ha il nome specificato, il metodo restituisce il primo oggetto dell'elenco degli elementi secondari.

Il metodo getChildAt() è più veloce di getChildByName(). Il metodo getChildAt() accede a un elemento secondario di un array memorizzato in cache, mentre getChildByName() deve leggere un elenco collegato per accedere a un elemento secondario.

Parametri

Altri esempi

Altre informazioni

Elementi API correlati

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Restituisce la posizione di indice di un'istanza DisplayObject child.

Parametri

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Restituisce un array di oggetti che si trovano sotto il punto specificato e sono elementi secondari (di uno o più livelli inferiori) di questa istanza DisplayObjectContainer. Gli oggetti secondari non accessibili per motivi di sicurezza vengono omessi dall'array restituito. Per determinare se questa restrizione di sicurezza influisce sull'array restituito, chiamare il metodo areInaccessibleObjectsUnderPoint().

Il parametro point è nello spazio di coordinate dello stage, che può essere diverso dallo spazio di coordinate del contenitore di oggetto di visualizzazione (a meno che quest'ultimo non sia lo stage). Per convertire dei punti tra questi due spazi di coordinate, potete utilizzare i metodi globalToLocal() e localToGlobal().

Parametri

Elementi API correlati

import flash.display.Sprite;
import flash.geom.Point;

var container:Sprite = new Sprite();

var square1:Sprite = new Sprite();
square1.graphics.beginFill(0xFFCC00);
square1.graphics.drawRect(0, 0, 40, 40);

var square2:Sprite = new Sprite();
square2.graphics.beginFill(0x00CCFF);
square2.graphics.drawRect(20, 0, 30, 40);

container.addChild(square1);
container.addChild(square2);

var pt:Point = new Point(10, 20);
var objects:Array = container.getObjectsUnderPoint(pt); 
trace(objects.length); // 1

pt = new Point(35, 20);
objects = container.getObjectsUnderPoint(pt);
trace(objects.length);  // 2

Rimuove l'istanza DisplayObject child specificata dall'elenco degli elementi secondari dell'istanza DisplayObjectContainer. La proprietà parent dell'istanza secondaria rimossa viene impostata su null e l'oggetto viene rimosso dal garbage collector se non esistono altri riferimenti all'istanza secondaria. Le posizioni di indice di tutti gli oggetti di visualizzazione che si trovano sopra l'istanza secondaria in DisplayObjectContainer vengono diminuite di 1.

Il garbage collector riassegna lo spazio in memoria inutilizzato. Quando una variabile o un oggetto non sono più associati a un riferimento attivo o memorizzati da qualche parte, il garbage collector li rimuove e libera lo spazio di memoria che occupavano, se non risultano altri riferimenti ad essi.

Parametri

 
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);

container.addChild(circle1);
container.addChild(circle2);

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    container.removeChild(DisplayObject(event.target)); 
}

Rimuove un'istanza DisplayObject secondaria dalla posizione index specificata nell'elenco degli elementi secondari di DisplayObjectContainer. La proprietà parent dell'istanza secondaria rimossa viene impostata su null e l'oggetto viene rimosso dal garbage collector se non esistono altri riferimenti all'istanza secondaria. Le posizioni di indice di tutti gli oggetti di visualizzazione che si trovano sopra l'istanza secondaria in DisplayObjectContainer vengono diminuite di 1.

Il garbage collector riassegna lo spazio in memoria inutilizzato. Quando una variabile o un oggetto non sono più associati a un riferimento attivo o memorizzati da qualche parte, il garbage collector li rimuove e libera lo spazio di memoria che occupavano, se non risultano altri riferimenti ad essi.

Parametri

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.numChildren) // 2
container.removeChildAt(0); 
trace(container.numChildren) // 1
trace(container.getChildAt(0).name); // sprite2

Rimuove tutte le istanze DisplayObject secondarie dall'elenco degli elementi secondari dell'istanza DisplayObjectContainer. La proprietà parent delle istanze secondarie rimosse viene impostata su null e gli oggetti vengono rimossi dal garbage collector se non esistono altri riferimenti alle istanze secondarie.

Il garbage collector riassegna lo spazio in memoria inutilizzato. Quando una variabile o un oggetto non sono più associati a un riferimento attivo o memorizzati da qualche parte, il garbage collector li rimuove e libera lo spazio di memoria che occupavano, se non risultano altri riferimenti ad essi.

Parametri

Cambia la posizione di un elemento secondario nel contenitore di oggetto di visualizzazione. Questa operazione influisce sulla stratificazione degli oggetti secondari. L'esempio seguente mostra tre oggetti di visualizzazione (a, b e c) rispettivamente nelle posizioni di indice 0, 1 e 2:

Quando utilizzate il metodo setChildIndex() e specificate una posizione di indice già occupata, le uniche posizioni che cambiano sono quelle comprese tra la posizione precedente e la nuova posizione dell'oggetto di visualizzazione. Tutte le altre rimangono uguali. Se un elemento secondario viene spostato in un indice INFERIORE al relativo indice corrente, tutti gli elementi secondari intermedi AUMENTANO di 1 per quanto riguarda il riferimento di indice. Se un elemento secondario viene spostato in un indice SUPERIORE al relativo indice corrente, tutti gli elementi secondari intermedi DIMINUISCONO di 1 per quanto riguarda il riferimento di indice. Ad esempio, se il contenitore di oggetto di visualizzazione dell'esempio precedente si chiama container, potete scambiare la posizione degli oggetti di visualizzazione con etichetta a e b chiamando il codice seguente:

container.setChildIndex(container.getChildAt(1), 0);

Questo codice determina la seguente disposizione degli oggetti:

Parametri

Elementi API correlati

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFF0000);
circle1.graphics.drawCircle(40, 40, 40);
circle1.addEventListener(MouseEvent.CLICK, clicked);
 
var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00FF00);
circle2.graphics.drawCircle(100, 40, 40);
circle2.addEventListener(MouseEvent.CLICK, clicked);
 
var circle3:Sprite = new Sprite();
circle3.graphics.beginFill(0x0000FF);
circle3.graphics.drawCircle(70, 80, 40);
circle3.addEventListener(MouseEvent.CLICK, clicked);
 
container.addChild(circle1);
container.addChild(circle2);
container.addChild(circle3);
addChild(container);
 
function clicked(event:MouseEvent):void {
    var circle:Sprite = Sprite(event.target);
    var topPosition:uint = container.numChildren - 1;
    container.setChildIndex(circle, topPosition);
}

Interrompe in modo ricorsivo l’esecuzione della linea temporale di qualsiasi MovieClips che ha origine in questo oggetto.

Gli oggetti di visualizzazione secondari che appartengono a una sandbox alla quale il codice di esecuzione non ha accesso vengono ignorati.

Nota: la riproduzione multimediale in streaming controllata mediante un oggetto NetStream non verrà interrotta.

Scambia lo z-order (ordine di profondità) degli oggetti secondari specificati. Tutti gli altri oggetti secondari del contenitore di oggetto di visualizzazione rimangono nelle stesse posizioni di indice.

Parametri

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2

container.swapChildren(sprite1, sprite2);

trace(container.getChildAt(0).name); // sprite2
trace(container.getChildAt(1).name); // sprite1

Scambia lo z-order (ordine di profondità) degli oggetti secondari nelle due posizioni di indice specificate nell'elenco degli elementi secondari. Tutti gli altri oggetti secondari del contenitore di oggetto di visualizzazione rimangono nelle stesse posizioni di indice.

Parametri

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";
var sprite3:Sprite = new Sprite();
sprite3.name = "sprite3";

container.addChild(sprite1);
container.addChild(sprite2);
container.addChild(sprite3);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite3

container.swapChildrenAt(0, 2);

trace(container.getChildAt(0).name); // sprite3
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite1

1. La funzione di costruzione chiama il metodo configureAssets().
2. Il metodo configureAssets() crea gli oggetti Sprite child e lastChild.
3. Un ciclo for crea i cinque quadrati arancioni e li posiziona uno dopo l'altro.
4. Ogni volta che viene creato un oggetto CustomSprite object, la relativa funzione di costruzione chiama il metodo draw() dell'oggetto CustomSprite, che crea un quadrato da 50 x 50 pixel chiamando i metodi beginFill(), drawRect() e endFill() della classe Graphics. Il metodo addChild() aggiunge ciascun quadrato all'elenco di visualizzazione.

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;

    public class DisplayObjectContainerExample extends Sprite {
        private var gutter:uint     = 5;
        private var childCount:uint = 5;

        public function DisplayObjectContainerExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var child:Sprite = new CustomSprite();
            var lastChild:Sprite = child;
            for (var i:uint = 1; i <= childCount; i++) {
                child = new CustomSprite();
                child.x = lastChild.x + lastChild.width + gutter;
                addChild(child);
                lastChild = child;
            }
        }
    }
}

import flash.display.Sprite;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0xFFCC00;

    public function CustomSprite() {
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }
}