Sprite  - AS3

Specifica la modalità pulsante di questo sprite. Se è true, questo sprite si comporta come un pulsante, ovvero attiva la visualizzazione del cursore a forma di mano quando il puntatore passa sopra lo sprite. Può ricevere un evento click se viene premuto il tasto Invio o la barra spaziatrice quando lo sprite è l'elemento attivo. Potete annullare la visualizzazione del puntatore a forma di mano impostando la proprietà useHandCursor su false, in modo da visualizzare il puntatore standard.

Benché sia meglio utilizzare la classe SimpleButton per creare dei pulsanti, la proprietà buttonMode consente di conferire a uno sprite alcune caratteristiche simili a quelle di un pulsante. Per includere uno sprite nell'ordine di tabulazione, impostate la proprietà tabEnabled (ereditata dalla classe InteractiveObject e impostata sul valore predefinito false) su true. Inoltre, dovete scegliere se gli elementi secondari dello sprite devono essere abilitati per l'input dell'utente. La maggior parte dei pulsanti non abilita l'interattività con l'input dell'utente per gli elementi secondari, perché ciò ha l'effetto di confondere il flusso degli eventi. Per disabilitare l'interattività con l'input dell'utente per tutti gli oggetti secondari, dovete impostare la proprietà mouseChildren (ereditata dalla classe DisplayObjectContainer) su false.

Se utilizzate la proprietà buttonMode con la classe MovieClip (che è una sottoclasse di Sprite), il pulsante potrebbe presentare una funzionalità più estesa. Se includonote dei fotogrammi con le etichette _up, _over e _down, Flash Player fornisce le modifiche di stato automatiche (caratteristica simile a quella disponibile nelle versioni precedenti di ActionScript per i clip filmato utilizzati come pulsanti). Queste modifiche di stato automatiche non sono disponibili per gli sprite, che sono sprovvisti di linea temporale e quindi non hanno fotogrammi cui assegnare un'etichetta.

Elementi API correlati

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Specifica l'oggetto di visualizzazione sopra il quale viene trascinato lo sprite o sul quale viene rilasciato.

Elementi API correlati

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Specifica l'oggetto Graphics che appartiene a questo oggetto Sprite, in cui possono essere eseguiti i comandi di disegno vettoriale.

import flash.display.Sprite;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);
addChild(circle);

Definisce un altro sprite come area attiva di uno sprite. Se la proprietà hitArea non esiste oppure è null o undefined, lo sprite stesso viene utilizzato come area attiva. Il valore della proprietà hitArea può fungere da riferimento per un oggetto Sprite.

Potete modificare la proprietà hitArea in qualsiasi momento; lo sprite modificato utilizza immediatamente il nuovo comportamento dell'area attiva. Non è necessario che lo sprite designato come area attiva sia visibile; la sua forma grafica, anche non visibile, viene rilevata come area attiva.

Nota: dovete impostare su false la proprietà mouseEnabled dello sprite designato come area attiva. In caso contrario, il pulsante sprite potrebbe non funzionare perché non riceverebbe gli eventi dell'input dell'utente, che sarebbero invece ricevuti dallo sprite designato come area attiva.

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var square:Sprite = new Sprite();
square.graphics.beginFill(0xCCFF00);
square.graphics.drawRect(200, 0, 100, 100);

circle.hitArea = square;
square.mouseEnabled = false;

circle.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void{
    trace(event.target == circle); // true
    trace(event.target == square); // false
}

addChild(circle);
addChild(square);

Controlla il suono nello sprite.

Nota: questa proprietà non ha effetto sul contenuto HTML in un oggetto HTMLControl (in Adobe AIR).

Elementi API correlati

import flash.display.Sprite;
import flash.display.Loader;
import flash.events.IOErrorEvent;
import flash.events.MouseEvent;
import flash.net.URLRequest;
import flash.text.TextField;
import flash.media.SoundTransform;

var container:Sprite = new Sprite();
addChild(container);

var ldr:Loader = new Loader;
var urlReq:URLRequest = new URLRequest("SoundPlayer.swf");
ldr.load(urlReq);

container.addChild(ldr);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);
            
var tf:TextField = new TextField();
tf.htmlText = "<a href = 'event:Mute'>Mute / Unmute</a>";
addChild(tf);

var mySoundTransform:SoundTransform = new SoundTransform();
mySoundTransform.volume = 1;

tf.addEventListener(MouseEvent.CLICK, mute);

function mute(event:MouseEvent):void {    
    if (mySoundTransform.volume == 0) {
        mySoundTransform.volume = 1;
    } else {
        mySoundTransform.volume = 0;        
    }
    container.soundTransform = mySoundTransform;
}

function urlNotFound(event:IOErrorEvent):void {
    trace("The URL was not found."); 
}

Un valore booleano che indica se viene visualizzato un cursore a forma di mano quando il puntatore passa sopra uno sprite in cui la proprietà buttonMode è impostata su true. Il valore predefinito della proprietà useHandCursor è true. Se useHandCursor è impostata su true, viene visualizzato il puntatore a forma di mano quando il puntatore passa sopra uno sprite pulsante. Se useHandCursor è false, viene utilizzato il puntatore a forma di freccia.

Potete modificare la proprietà useHandCursor in qualsiasi momento; allo sprite modificato viene immediatamente associato il nuovo aspetto del cursore.

Nota: in Flex o Flash Builder, se lo sprite contiene degli sprite secondari, può essere opportuno impostare la proprietà mouseChildren su false. Ad esempio, se desiderate che un cursore a forma di mano venga visualizzato su un controllo Flex <mx:Label>, impostate le proprietà useHandCursor e buttonMode su true e la proprietà mouseChildren su false.

Elementi API correlati

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.useHandCursor = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = true;
circle2.useHandCursor = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Crea una nuova istanza Sprite. Dopo aver creato l'istanza Sprite, chiamate il metodo DisplayObjectContainer.addChild() o DisplayObjectContainer.addChildAt() per aggiungere lo sprite a un DisplayObjectContainer principale.

Consente all'utente di trascinare lo sprite specificato. È possibile trascinare lo sprite fino a quando il trascinamento non viene interrotto esplicitamente mediante una chiamata a Sprite.stopDrag() o non viene reso trascinabile un altro sprite. È possibile trascinare un solo sprite alla volta.

Gli oggetti di visualizzazione tridimensionali seguono il puntatore e Sprite.startDrag() sposta l'oggetto all'interno del pannello tridimensionale definito dall'oggetto di visualizzazione. Oppure, se l'oggetto di visualizzazione è un oggetto bidimensionale e un elemento secondario di un oggetto tridimensionale, l'oggetto bidimensionale si sposta all'interno del pannello tridimensionale definito dall'oggetto principale tridimensionale.

Parametri

Elementi API correlati

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Consente all'utente di trascinare lo sprite specificato su un dispositivo abilitato per il tocco. Lo sprite può essere trascinato fino a quando tale operazione non viene interrotta esplicitamente mediante una chiamata al metodo Sprite.stopTouchDrag() o non viene reso trascinabile un altro sprite. È possibile trascinare un solo sprite alla volta.

Gli oggetti di visualizzazione tridimensionali seguono il puntatore e Sprite.startTouchDrag() sposta l'oggetto all'interno del pannello tridimensionale definito dall'oggetto di visualizzazione. Oppure, se l'oggetto di visualizzazione è un oggetto bidimensionale e un elemento secondario di un oggetto tridimensionale, l'oggetto bidimensionale si sposta all'interno del pannello tridimensionale definito dall'oggetto principale tridimensionale.

Parametri

Elementi API correlati

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

Termina il metodo startDrag(). Uno sprite che è stato reso trascinabile mediante il metodo startDrag() rimane tale finché non viene aggiunto un metodo stopDrag() o fino a quando un altro sprite non diventa trascinabile. È possibile trascinare un solo sprite alla volta.

Elementi API correlati

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Termina il metodo startTouchDrag(), utilizzato con i dispositivi abilitati per il tocco. Uno sprite reso trascinabile mediante il metodo startTouchDrag() rimane tale finché non viene aggiunto un metodo stopTouchDrag() o fino a quando un altro sprite non diventa trascinabile. È possibile trascinare un solo sprite alla volta.

Parametri

Elementi API correlati

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

1. Dichiarate la proprietà size (100 x 100 pixel) e il colore di sfondo (arancione) da utilizzare successivamente durante il disegno del quadrato.
2. La funzione di costruzione crea quindi un oggetto Sprite child e lo utilizza per aggiungere due listener di eventi e i metodi a essi associati: mouseDownHandler() e mouseUpHandler().
3. L'oggetto Sprite child viene quindi passato al metodo draw(), che disegna il quadrato arancione.
4. L'elemento secondario viene inserito nell'elenco di visualizzazione da una chiamata al metodo addChild().
5. I listener di eventi funzionano nel modo seguente:
   • mouseDownHandler(): quando l'utente fa clic sull'oggetto Sprite, il metodo aggiunge un listener di eventi mouseMove (il metodo mouseMoveHandler()) che elabora i movimenti del mouse. Viene quindi chiamato il metodo startDrag(), che consente di trascinare l'oggetto Sprite.
   • mouseUpHandler(): quando il pulsante del mouse viene rilasciato, il listener di eventi mouseMove viene rimosso e viene chiamato il metodo stopDrag().
   • mouseMoveHandler: fintanto che il pulsante sinistro del mouse viene tenuto premuto, questo metodo indica a Flash Player di ridisegnare continuamente il quadrato arancione.

Nota: ognuno dei metodi dei listener di eventi dichiara una variabile sprite locale, che viene assegnata alla proprietà target dell'evento.

package {
    import flash.display.Sprite;
    import flash.events.*;

    public class SpriteExample extends Sprite {
        private var size:uint    = 100;
        private var bgColor:uint = 0xFFCC00;

        public function SpriteExample() {
            var child:Sprite = new Sprite();
            child.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            child.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
            draw(child);
            addChild(child);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            trace("mouseDownHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.startDrag();
        }

        private function mouseUpHandler(event:MouseEvent):void {
            trace("mouseUpHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.stopDrag();
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            event.updateAfterEvent();
        }

        private function draw(sprite:Sprite):void {
            sprite.graphics.beginFill(bgColor);
            sprite.graphics.drawRect(0, 0, size, size);
            sprite.graphics.endFill();
        }
    }
}