SimpleButton  - AS3

Specifica un oggetto di visualizzazione che viene utilizzato come oggetto visivo per lo stato "Giù" del pulsante (lo stato in cui si trova il pulsante quando l'utente seleziona l'oggetto hitTestState).

Elementi API correlati

Un valore booleano che specifica se un pulsante è abilitato. Quando un pulsante è disabilitato, ovvero con la proprietà enabled impostata su false, è visibile ma non selezionabile con un clic. Il valore predefinito è true. Questa proprietà è particolarmente utile se desiderate disabilitare parte della navigazione; ad esempio, potete disabilitare un pulsante nella pagina visualizzata in modo che non sia possibile selezionarlo e ricaricare la pagina.

Nota: per impedire eventi mouseClick su un pulsante, impostate entrambe le proprietà enabled e mouseEnabled su false.

Specifica un oggetto di visualizzazione che viene utilizzato come oggetto di rilevamento del contatto per il pulsante. Per un pulsante semplice, impostate la proprietà hitTestState sullo stesso oggetto di visualizzazione della proprietà overState. Se non impostate la proprietà hitTestState, l'oggetto SimpleButton è inattivo, ovvero non risponde agli eventi di input dell'utente.

Elementi API correlati

Specifica un oggetto di visualizzazione che viene utilizzato come oggetto visivo per lo stato Sopra del pulsante (lo stato in cui si trova il pulsante quando il puntatore è posizionato sopra di esso).

Elementi API correlati

L'oggetto SoundTransform assegnato a questo pulsante. Gli oggetti SoundTransform comprendono proprietà per impostare il volume, la panoramica e l'assegnazione dell'altoparlante sinistro e destro. Questo oggetto SoundTransform viene applicato a tutti gli stati del pulsante. Ha effetto solo sui suoni incorporati.

Elementi API correlati

Indica se altri oggetti di visualizzazione del tipo SimpleButton o MovieClip possono ricevere gli eventi di rilascio dell'input dell'utente. La proprietà trackAsMenu consente di creare menu. Potete impostare la proprietà trackAsMenu su qualunque oggetto SimpleButton o MovieClip. Se la proprietà trackAsMenu non esiste, il comportamento predefinito è false.

Potete modificare la proprietà trackAsMenu in qualsiasi momento; al pulsante modificato viene immediatamente associato il nuovo comportamento.

Specifica un oggetto di visualizzazione che viene utilizzato come oggetto visivo per lo stato Su del pulsante (lo stato in cui si trova il pulsante quando il puntatore non è posizionato sopra di esso).

Elementi API correlati

Un valore booleano che, se impostato su true, indica se il cursore a forma di mano viene visualizzato quando il puntatore passa sopra un pulsante. Se la proprietà è impostata su false, viene invece visualizzato il puntatore a forma di freccia. Il valore predefinito è true.

È possibile modificare la proprietà useHandCursor in qualsiasi momento; il pulsante modificato utilizza immediatamente il nuovo comportamento del cursore.

Crea una nuova istanza SimpleButton. Uno qualunque oppure tutti gli oggetti di visualizzazione che rappresentano i vari stati del pulsante possono essere impostati come parametri della funzione di costruzione.

1. Nella funzione di costruzione SimpleButtonExample(), viene creato un nuovo oggetto CustomSimpleButton di tipo SimpleButton e chiamato button, che chiama il metodo di costruzione CustomSimpleButton. L'oggetto button viene aggiunto all'elenco di visualizzazione. Il colore e le dimensioni del pulsante vengono determinate nelle operazioni descritte di seguito.
2. Nella classe CustomSimpleButton vengono dichiarate le proprietà di istanza che vengono successivamente utilizzate per controllare le dimensioni e il colore di sfondo di button, in base allo stato in cui si trova (arancione nello stato normale, giallo scuro nello stato di passaggio di mouse e blu chiaro nello stato di pressione del mouse). In tutti gli stati di button, le dimensioni del quadrato sono impostate su 80 pixel utilizzando la proprietà size.
3. La funzione di costruzione per la classe CustomSimpleButton imposta le proprietà downState, overState, upState, hitTestState e useHandCursor con quattro istanze della classe ButtonDisplayState.
4. Nella classe ButtonDisplayState, la funzione di costruzione imposta il valore delle dimensioni e del colore di sfondo del quadrato e chiama il metodo draw().
5. Il metodo draw() ridisegna il quadrato con le dimensioni e il colore di sfondo impostati nella funzione di costruzione in base allo stato del pulsante.

package {
    import flash.display.Sprite;

    public class SimpleButtonExample extends Sprite {
        public function SimpleButtonExample() {
            var button:CustomSimpleButton = new CustomSimpleButton();
            addChild(button);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Shape;
import flash.display.SimpleButton;

class CustomSimpleButton extends SimpleButton {
    private var upColor:uint   = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;
    private var size:uint      = 80;

    public function CustomSimpleButton() {
        downState      = new ButtonDisplayState(downColor, size);
        overState      = new ButtonDisplayState(overColor, size);
        upState        = new ButtonDisplayState(upColor, size);
        hitTestState   = new ButtonDisplayState(upColor, size * 2);
        hitTestState.x = -(size / 4);
        hitTestState.y = hitTestState.x;
        useHandCursor  = true;
    }
}

class ButtonDisplayState extends Shape {
    private var bgColor:uint;
    private var size:uint;

    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size    = size;
        draw();
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}