Matrix  - AS3

Il valore che determina il posizionamento dei pixel lungo l'asse x durante il ridimensionamento o la rotazione di un'immagine.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.a);  // 1

myMatrix.a = 2;
trace(myMatrix.a);  // 2

Il valore che determina il posizionamento dei pixel lungo l'asse y durante la rotazione o l'inclinazione di un'immagine.

import flash.geom.Matrix;
 
var myMatrix:Matrix = new Matrix();
trace(myMatrix.b);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.b = Math.tan(radians);
trace(myMatrix.b);  // 0.5773502691896257

Il valore che determina il posizionamento dei pixel lungo l'asse x durante la rotazione o l'inclinazione di un'immagine.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.c);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.c = Math.tan(radians);
trace(myMatrix.c);  // 0.5773502691896257

Il valore che determina il posizionamento dei pixel lungo l'asse y durante il ridimensionamento o la rotazione di un'immagine.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.d);  // 1

myMatrix.d = 2;
trace(myMatrix.d);  // 2

La distanza in base alla quale viene convertito ogni punto lungo l'asse x.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.tx);  // 0

myMatrix.tx = 50;  // 50
trace(myMatrix.tx);

La distanza in base alla quale viene convertito ogni punto lungo l'asse y.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.ty);  // 0

myMatrix.ty = 50;
trace(myMatrix.ty);  // 50

Crea un nuovo oggetto Matrix con i parametri specificati. Nella notazione della matrice, le proprietà vengono organizzate nel modo seguente:

Se non specificate parametri per la funzione di costruzione new Matrix(), viene creata una matrice di identità con i valori seguenti:

a = 1

b = 0

c = 0

d = 1

tx = 0

ty = 0

Nella notazione della matrice, la matrice di identità sarà simile alla seguente:

import flash.geom.Matrix;

var matrix_1:Matrix = new Matrix();
trace(matrix_1);  // (a=1, b=0, c=0, d=1, tx=0, ty=0)

var matrix_2:Matrix = new Matrix(1, 2, 3, 4, 5, 6);
trace(matrix_2);  // (a=1, b=2, c=3, d=4, tx=5, ty=6)

Restituisce un nuovo oggetto Matrix, clone di questa matrice, con una copia esatta dell'oggetto contenuto.

Concatena una matrice con la matrice corrente, combinando gli effetti geometrici delle due matrici. In termini matematici, il concatenamento di due matrici equivale alla loro combinazione mediante la moltiplicazione di matrici.

Se ad esempio la matrice m1 modifica in scala un oggetto in base a un fattore 4 e la matrice m2 ruota un oggetto di 1,5707963267949 radianti (Math.PI/2), m1.concat(m2) trasforma m1 in una matrice che modifica in scala un oggetto in base a un fattore 4 e lo ruota di Math.PI/2 radianti.

Questo metodo sostituisce la matrice di origine con la matrice concatenata. Se desiderate concatenare due matrici senza modificare le due matrici di origine, copiate per prima cosa la matrice di origine con il metodo clone(), come illustrato nella sezione relativa agli esempi di classi.

Parametri

Copia un oggetto Vector3D in una colonna specifica dell'oggetto Matrix3D chiamante.

Parametri

Copia una colonna specifica dell'oggetto Matrix chiamante nell'oggetto Vector3D. L'elemento w dell'oggetto Vector3D non viene modificato.

Parametri

Copia tutti i dati di matrice dall'oggetto Point di origine all'oggetto Matrix chiamante.

Parametri

Copia un oggetto Vector3D in una riga specifica dell'oggetto Matrix chiamante.

Parametri

Copia una riga specifica dell'oggetto Matrix chiamante nell'oggetto Vector3D. L'elemento w dell'oggetto Vector3D non viene modificato.

Parametri

Comprende parametri per la modifica in scala, la rotazione e la conversione. Quando viene applicato a una matrice, ne imposta i valori in base a tali parametri.

Il metodo createBox() consente di ottenere la stessa matrice che si otterrebbe applicando in successione i metodi identity(), rotate(), scale() e translate(). Ad esempio, mat1.createBox(2,2, Math.PI/4, 100, 100) ha lo stesso effetto di:

     import flash.geom.Matrix;
     
     var mat1:Matrix = new Matrix();
     mat1.identity();
     mat1.rotate(Math.PI/4);
     mat1.scale(2,2);
     mat1.translate(10,20);
     

Parametri

Altri esempi

Elementi API correlati

package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_createBox extends Sprite
    {
        public function Matrix_createBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createBox(1, 2, Math.PI/4, 50, 100);
             trace(myMatrix.toString());  
             // (a=0.7071067811865476, b=1.414213562373095, c=-0.7071067811865475, 
             //  d=1.4142135623730951, tx=50, ty=100)
             
             var rectangleShape:Shape = createRectangle(20, 80, 0xFF0000);   
             addChild(rectangleShape);
              
             var rectangleTrans:Transform = new Transform(rectangleShape);
             rectangleTrans.matrix = myMatrix;
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

Crea lo stile di matrice specifico previsto dai metodi beginGradientFill() e lineGradientStyle() della classe Graphics. La larghezza e l'altezza vengono modificate in scala in base alla coppia scaleX/scaleY e i valori tx/ty vengono spostati della metà della larghezza e dell'altezza.

Considerate ad esempio un gradiente con le seguenti caratteristiche:

• GradientType.LINEAR
• Due colori, verde e blu, con gli array ratios impostati su [0, 255]
• SpreadMethod.PAD
• InterpolationMethod.LINEAR_RGB

Le figure seguenti mostrano dei gradienti in cui la matrice è stata definita con il metodo createGradientBox() con varie impostazioni dei parametri:

Impostazioni di createGradientBox()	Gradiente risultante
width = 25; height = 25; rotation = 0; tx = 0; ty = 0;
width = 25; height = 25; rotation = 0; tx = 25; ty = 0;
width = 50; height = 50; rotation = 0; tx = 0; ty = 0;
width = 50; height = 50; rotation = Math.PI / 4; // 45 degrees tx = 0; ty = 0;

Parametri

Altri esempi

Elementi API correlati

package
{
    import flash.display.GradientType;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    
    public class Matrix_createGradientBox extends Sprite
    {
        public function Matrix_createGradientBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());          // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createGradientBox(200, 200, 0, 50, 50);
             trace(myMatrix.toString());          // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)
             
             var colors:Array = [0xFF0000, 0x0000FF];
             var alphas:Array = [100, 100];
             var ratios:Array = [0, 0xFF];
             
             this.graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
             this.graphics.drawRect(0, 0, 300, 200);
        }
    }
}

Dato un punto nello spazio di coordinate pre-trasformazione, questo metodo restituisce le coordinate di tale punto dopo l'avvenuta trasformazione. A differenza della trasformazione standard applicata mediante il metodo transformPoint(), la trasformazione del metodo deltaTransformPoint() non prende in considerazione i parametri di conversione tx e ty.

Parametri

Imposta ogni proprietà della matrice su un valore che determina una trasformazione null. Un oggetto trasformato applicando una matrice di identità è identico all'originale.

Dopo la chiamata del metodo identity(), le proprietà della matrice risultante sono le seguenti: a =1, b =0, c =0, d =1, tx =0, ty =0.

Nella notazione della matrice, la matrice di identità sarà simile alla seguente:

Esegue la trasformazione opposta rispetto alla matrice originale. Per annullare la trasformazione eseguita con l'applicazione della matrice originale è possibile applicare una matrice invertita a un oggetto.

package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_invert extends Sprite
    {
        public function Matrix_invert()
        {
            var rect0:Shape = createRectangle(20, 80, 0xFF0000);   
            var rect1:Shape = createRectangle(20, 80, 0x00FF00);   
            var rect2:Shape = createRectangle(20, 80, 0x0000FF);
            var rect3:Shape = createRectangle(20, 80, 0x000000);
            
            var trans0:Transform = new Transform(rect0);
            var trans1:Transform = new Transform(rect1);
            var trans2:Transform = new Transform(rect2);
            var trans3:Transform = new Transform(rect3);
             
            var doubleScaleMatrix:Matrix = new Matrix(2, 0, 0, 2, 0, 0);
            trans0.matrix = doubleScaleMatrix;
            trace(doubleScaleMatrix.toString());  // (a=2, b=0, c=0, d=2, tx=0, ty=0)
             
            var noScaleMatrix:Matrix = new Matrix(1, 0, 0, 1, 0, 0);
            trans1.matrix = noScaleMatrix;
            rect1.x = 50;
            trace(noScaleMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
            var halfScaleMatrix:Matrix = doubleScaleMatrix.clone();
            halfScaleMatrix.invert();
            trans2.matrix = halfScaleMatrix;
            rect2.x = 100;
            trace(halfScaleMatrix.toString());  // (a=0.5, b=0, c=0, d=0.5, tx=0, ty=0)
             
            var originalAndInverseMatrix:Matrix = doubleScaleMatrix.clone();
            originalAndInverseMatrix.concat(halfScaleMatrix);
            trans3.matrix = originalAndInverseMatrix;
            rect3.x = 150;
            trace(originalAndInverseMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)            
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

Applica una trasformazione di rotazione all'oggetto Matrix.

Il metodo rotate() modifica le proprietà a, b, c e d dell'oggetto Matrix. Nella notazione della matrice, questo equivale a concatenare la matrice corrente con:

Parametri

Altri esempi

Applica una trasformazione in scala alla matrice. L'asse x viene moltiplicato per sx, l'asse y per sy.

Il metodo scale() modifica le proprietà a e d dell'oggetto Matrix. Nella notazione della matrice, questo equivale a concatenare la matrice corrente con la seguente matrice:

Parametri

Altri esempi

Imposta i membri dell'oggetto Matrix sui valori specificati.

Parametri

Restituisce un valore di testo che elenca le proprietà dell'oggetto Matrix.

Restituisce il risultato dell'applicazione al punto specificato della trasformazione geometrica rappresentata dall'oggetto Matrix.

Parametri

Converte la matrice lungo gli assi x e y come specificato dai parametri dx e dy.

Parametri

Altri esempi

1. L'applicazione crea un nuovo oggetto Matrix myMatrix e utilizza il metodo trace() per produrre i valori predefiniti delle proprietà per l'oggetto myMatrix.
2. L'applicazione chiama createGradientBox() con le proprietà width e height impostate su 200 pixel, senza effetto di rotazione e con la distanza per la conversione lungo gli assi x e y impostata su 50 pixel.
3. L'applicazione stampa di nuovo l'oggetto myMatrix per mostrare la modifica dopo la chiamata a createGradientBox().
4. L'applicazione imposta tre variabili per controllare il riempimento del riquadro con gradiente:
   • colors: imposta i colori con gradiente tra rosso uniforme e blu uniforme.
   • alphas: imposta l'opacità su uniforme.
   • ratios: imposta la distribuzione dei colori in modo che sia uguale sia per il rosso che per il blu.
5. L'applicazione chiama il metodo Graphics beginGradientFill(), che agisce sull'oggetto myMatrix, e chiama il metodo lineTo(), producendo come risultato il riquadro contenente il riempimento con gradiente.

package {
    import flash.geom.Matrix;
    import flash.display.Sprite;
    import flash.display.GradientType;

    public class MatrixExample extends Sprite {

        public function MatrixExample() {
            var myMatrix:Matrix = new Matrix();
            trace(myMatrix.toString());    // (a=1, b=0, c=0, d=1, tx=0, ty=0)

            myMatrix.createGradientBox(200, 200, 0, 50, 50);
            trace(myMatrix.toString());    // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)

            var colors:Array = [0xFF0000, 0x0000FF];
            var alphas:Array = [1, 1];
            var ratios:Array = [0, 0xFF];
            graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
            graphics.lineTo(0, 300);
            graphics.lineTo(300, 300);
            graphics.lineTo(300, 0);
            graphics.lineTo(0, 0);
        }
    }
}