AccessibilityImplementation  - AS3

Indica un codice di errore. Gli errori sono indicati fuori banda, anziché nei valori restituiti. Per indicare un errore, impostate la proprietà errno su uno dei codici di errore documentati nell'appendice Costanti AccessibilityImplementation. Fa in modo che il valore restituito venga ignorato. La proprietà errno di AccessibilityImplementation viene sempre azzerata (imposta a zero) dal lettore prima che venga chiamato qualsiasi metodo AccessibilityImplementation.

Elementi API correlati

Utilizzato per creare uno stub di accessibilità dei componenti. Se un componente viene rilasciato senza implementazione di sicurezza, Adobe consiglia di aggiungere uno stub di accessibilità dei componenti. Lo stub fa sì che Flash Player, ai fini dell'accessibilità, tratti il componente come semplice elemento grafico anziché esporre la struttura interna di pulsanti, campi di testo e così via all'interno del componente.

Per creare uno stub di accessibilità dei componente, create la sottoclasse AccImpl necessaria, sostituendo lo stub della proprietà con il valore true.

Elementi API correlati

Funzione di costruzione statica. Non create direttamente un'istanza di AccessibilityImplementation chiamandone la funzione di costruzione. Al contrario, create nuove implementazioni di accessibilità estendendo la classe mx.accessibility.AccImpl per ogni nuovo componente.

Elementi API correlati

Un metodo IAccessible che esegue l'azione predefinita associata al componente che questa AccessibilityImplementation rappresenta o di uno dei suoi elementi secondari.

Implementate questo metodo solo se AccessibilityImplementation rappresenta un elemento dell'interfaccia utente che ha un'azione predefinita nel modello MSAA.

Se state implementando accDoDefaultAction() solo per AccessibilityImplementation, oppure solo per i suo i elementi secondari, in alcuni casi dovrete indicare che non è presente un'azione predefinita per il childID particolare che è stato passato. Per farlo, impostate la proprietà errno su E_MEMBERNOTFOUND.

Parametri

     override public function accDoDefaultAction(childID:uint):void
     {
         if (childID > 0)
             ListBase(master).selectedIndex = childID - 1;
     }

Il metodo MSAA per restituire un oggetto DisplayObject o Rectangle che specifica il rettangolo di delimitazione di un elemento secondario nella AccessibilityImplementation.

Questo metodo non viene mai chiamato con un childID pari a zero. Se AccessibilityImplementation non conterrà mai elementi secondari, non dovete implementare questo metodo. Se AccessibilityImplementation può contenere elementi secondari, questo metodo è obbligatorio.

Solitamente potete soddisfare i requisiti di questo metodo restituendo un oggetto che rappresenta l'elemento secondario stesso. Questo accorgimento funziona a condizione che l'elemento secondario sia un DisplayObject. In questi casi dovete semplicemente restituire il DisplayObject che corrisponde al nome di istanza associato con l'oggetto visivi appropriato nell'elenco di visualizzazione.

Se un elemento secondario non è idoneo per l'impiego della tecnica appena descritta, potete calcolare voi stessi il rettangolo di delimitazione e restituire un oggetto Rectangle con le proprietà x, y, width e height. I membri x e y specificano l'angolo superiore destro del rettangolo di delimitazione, mentre i membri width e height ne specificano le dimensioni. Tutti e quattro i membri devono essere espressi in unità dei pixel dello stage e devono essere relativi all'origine del componente rappresentato da AccessibilityImplementation. Le proprietà x e y possono avere valori negativi, poiché l'origine di un DisplayObject non è necessariamente nel suo angolo superiore sinistro.

Se l'elemento secondario specificato da childID non è visibile (ovvero, get_accState per tale elemento restituirebbe un valore contenente STATE_SYSTEM_INVISIBLE), potete restituire null da accLocation. Potete anche restituire un oggetto Rectangle che rappresenta le coordinate in corrispondenza delle quali l'elemento secondario apparirebbe se fosse visibile.

Parametri

Altre informazioni

Elementi API correlati

     override public function accLocation(childID:uint):*
     
     {
         var listBase:ListBase = ListBase(master);
     
         var index:uint = childID - 1;
         
         if (index < listBase.verticalScrollPosition ||
             index >= listBase.verticalScrollPosition + listBase.rowCount)
         {
             return null;
         }
         var item:Object = getItemAt(index);
     
         return listBase.itemToItemRenderer(item);
     }
     

Metodo IAccessible per modificare la selezione nel componente rappresentato da questo AccessibilityImplementation.

Il parametro childID sarà sempre diverso da zero. Questo metodo viene sempre applicato a un elemento secondario anziché al componente generale, la cui selezione viene invece gestita da Flash Player.

Il parametro selFlag è un bitfield che consiste di una o più costanti di flag di selezione e consente a un client MSAA di indicare come l'elemento al quale childID fa riferimento deve essere selezionato oppure deve ricevere lo stato di attivazione. Le informazioni che seguono descrivono le costanti del flag di selezione e quello che comunicano all'implementazione di accessibilità. Ai fini pratici, la maggior parte delle implementazioni di questo metodo nelle implementazioni di accessibilità che ereditano dalla classe Flex mx.accessibility.ListBaseAccImpl ignorano la costante selFlag e invece ricorrono al comportamento di selezione da tastiera del componente per gestire la selezione multipla.

Il parametro selFlag può contenere o meno il flag SELFLAG_TAKEFOCUS. Se lo contiene, dovete impostare l'attivazione secondaria sul childID specificato e, a meno che non sia presente anche SELFLAG_EXTENDSELECTION, definire quell'elemento secondario come ancoraggio di selezione. In caso contrario, l'attivazione secondaria e l'ancoraggio di selezione rimarrebbero invariati, nononstante il fatto che molti dei flag aggiuntivi descritti di seguito potrebbero modificare la selezione.

L'argomento selFlag conterrà sempre uno dei seguenti quattro flag, che indicano il tipo di modifica di selezione desiderato:

• SELFLAG_TAKESELECTION: annulla qualsiasi selezione corrente e imposta la selezione sul childID specificato.

• SELFLAG_EXTENDSELECTION: calcola l'intervallo di elementi secondari tra l'ancoraggio di selezione (incluso) e il childID specificato. Se SELFLAG_ADDSELECTION è presente, aggiungete tutti questi elementi secondari alla selezione. Se SELFLAG_REMOVESELECTION è presente, rimuovete tutti questi elementi secondari dalla selezione. Se né SELFLAG_ADDSELECTION né SELFLAG_REMOVESELECTION sono presenti, tutti gli elementi secondari devono assumere lo stato di selezione dell'ancoraggio di selezione: se quest'ultimo è selezionato, aggiungeteli alla selezione, altrimenti rimuoveteli dalla selezione.

• SELFLAG_ADDSELECTION (senza SELFLAG_EXTENDSELECTION): aggiungete il childID specificato alla selezione.

• SELFLAG_REMOVESELECTION (senza SELFLAG_EXTENDSELECTION): rimuovete il childID specificato dalla selezione.

Tenete presente che per un componente non multi-selezionabile, gli unici valori di parametro selFlag validi sono SELFLAG_TAKEFOCUS e SELFLAG_TAKESELECTION. In teoria potreste anche scegliere di supportare SELFLAG_REMOVESELECTION per un componente non multi-selezionabile che consentisse all'utente di imporre una selezione null, ma in pratica la maggior parte dei componenti non multi-selezionabili non si comporta in questo modo e i client MSAA non tentano questo tipo di operazione.

Se incontrate dei flag che sembrano non validi, impostate errno su E_INVALIDARG.

Infine, notate che quando accSelect viene chiamato, Flash Player verifica che abbia lo stato di attivazione host (l'attivazione della finestra della relativa applicazione contenitore) e che il componente abbia lo stato di attivazione in Flash Player.

Parametri

Altre informazioni

Elementi API correlati

override public function accSelect(selFlag:uint, childID:uint):void
     {
         
         var listBase:ListBase = ListBase(master);
         
         var index:uint = childID - 1;
         
         if (index >= 0 && index < listBase.dataProvider.length)
             listBase.selectedIndex = index;
     }
     

Metodo MSAA per restituire l'azione predefinita del componente che questa AccessibilityImplementation rappresenta o di uno dei suoi elementi secondari.

Implementate questo metodo solo se AccessibilityImplementation rappresenta un elemento dell'interfaccia utente che ha un'azione predefinita nel modello MSAA; assicuratevi che venga restituita esattamente la stringa specificata dal modello MSAA. Ad esempio, la stringa di azione predefinita per un componente Button è "Press".

Se state implementando get_accDefaultAction solo per AccessibilityImplementation, oppure solo per i suo i elementi secondari, in alcuni casi dovrete indicare che non è presente un'azione predefinita per il childID particolare che è stato passato. Potete farlo semplicemente restituendo null.

Parametri

Altre informazioni

Elementi API correlati

override public function get_accDefaultAction(childID:uint):String
     {
         if (childID == 0)
             return null;
     
         return "Double Click";
     }

Metodo MSAA per restituire l'ID intero senza firma dell'elemento secondario (se presente) che ha lo stato di attivazione all'interno del componente. Se nessun elemento secondario ha lo stato di attivazione secondario, il metodo restituisce zero.

Altre informazioni

Elementi API correlati

override public function get_accFocus():uint
     {
     var index:uint = ListBase(master).selectedIndex;
     
     return index >= 0 ? index + 1 : 0;
     }

Metodo MSAA per restituire il nome del componente che questa AccessibilityImplementation rappresenta o di uno dei suoi elementi secondari.

Nel caso di AccessibilityImplementation (childID == 0), se questo metodo non è implementato o non restituisce un valore, Flash Player utilizza il valore della proprietà AccessibilityProperties.name, se è presente.

Per le AccessibilityImplementation che possono avere elementi secondari, questo metodo deve essere implementato e deve restituire un valore stringa quando childID è diverso da zero.

A seconda del tipo di elemento dell'interfaccia utente, i nomi in MSAA possono avere due significati: nome assegnato dall'autore o effettivo contenuto testuale dell'elemento. Solitamente, una AccessibilityImplementation ricade nella prima categoria. La sua proprietà name è un nome assegnato dall'autore. Gli elementi secondari rientrano invece nella seconda categoria. I loro nomi indicano il relativo contenuto testuale.

Quando la proprietà name di una AccessibilityImplementation corrisponde al nome assegnato dall'autore, vi sono due modi in cui i componenti possono acquisire i nomi dagli autori. Il primo riguarda i nomi presenti nel componente stesso; ad esempio, un componente casella di controllo potrebbe includere un'etichetta di testo da utilizzare come nome. Il secondo modo, un'opzione di riserva rispetto al primo, riguarda i nomi specificati nell'interfaccia utente e utilizzati in AccessibilityProperties.name. Questa opzione alternativa consente agli utenti di specificare i nomi così come farebbero per qualunque altro oggetto Sprite o MovieClip.

In pratica sono dunque disponibili tre possibilità per AccessibilityImplementation (childID == zero):

• Nome assegnato dall'autore nel componente. Il metodo get_accName deve essere implementato e deve restituire un valore stringa contenente il nome di AccessibilityImplementation quando childID è uguale a zero. Se childID è zero ma AccessibilityImplementation è priva di nome, get_accName deve restituire una stringa vuota per impedire al lettore di ricorrere alla proprietà AccessibilityProperties.name.

• Nome assegnato dall'autore all'interfaccia utente. Se le AccessibilityImplementation possono avere elementi secondari, il metodo get_accName deve essere implementato ma non deve restituire un valore quando childID è uguale a zero. Se AccessibilityImplementation non conterrà mai elementi secondari, get_accName non deve essere implementato.

• Nome corrispondente al contenuto. Il metodo get_accName deve essere implementato e deve restituire un valore stringa appropriato quando childID è uguale a zero. Se childID è zero ma AccessibilityImplementation è priva di nome, get_accName deve restituire una stringa vuota per impedire al lettore di ricorrere alla proprietà AccessibilityProperties.name.

Per gli elementi secondari (se AccessibilityImplementation può averne) vale sempre il terzo caso. Il metodo get_accName deve essere implementato e deve restituire un valore stringa appropriato quando childID è diverso da zero.

Parametri

Altre informazioni

Elementi API correlati

override public function get_accName(childID:uint):String
     {
         // Start with the name of the component's parent form 
          // if the component is contained within a form
         var accName:String = UIComponentAccImpl.getFormName(master);
     
         // If the element requested is the component itself, 
         // append the value of any assigned accessibilityProperties.name    
         if (childID == 0 && master.accessibilityProperties 
             && master.accessibilityProperties.name 
                 && master.accessibilityProperties.name != "")
             accName += master.accessibilityProperties.name + " ";
     
         // Append the value of the childIDs name 
     // returned by the component-specific override 
     // of the mx.accessibility.AccImpl.getName() utility function,
         // and append the component's status returned by the 
     // component-specific override of the 
     // mx.accessibility.AccImpl.getStatusName() utility function
         accName += getName(childID) + getStatusName();
     
     // Return the assembled String if it is neither empty nor null, 
     // otherwise return null
         return (accName != null && accName != "") ? accName : null;
     }

Metodo MSAA per restituire il ruolo di sistema del componente che questa AccessibilityImplementation rappresenta o di uno dei suoi elementi secondari. I ruoli di sistema sono predefiniti per tutti i componenti in MSAA.

Parametri

Altre informazioni

Elementi API correlati

Metodo MSAA per restituire un array contenente gli ID di tutti gli elementi secondari selezionati. L'array restituito può contenere zero, uno o più ID, tutti numeri interi senza segno.

Altre informazioni

Elementi API correlati

     override public function get_accSelection():Array
     {
         var accSelection:Array = [];
     
         var selectedIndices:Array = ListBase(master).selectedIndices;
         
         var n:int = selectedIndices.length;
         for (var i:int = 0; i < n; i++)
         {
             accSelection[i] = selectedIndices[i] + 1;
         }
         
         return accSelection;
     }
     

Metodo IAccessible per restituire lo stato runtime corrente del componente che questa AccessibilityImplementation rappresenta o di uno dei suoi elementi secondari.

Una combinazione di zero, una o più delle costanti di stato oggetto predefinite per i componenti in MSAA. Quando più di uno stato è applicabile, le costanti di stato devono essere combinate in un bitfield utilizzando |, l'operatore OR bit a bit.

Per indicare che nessuna di queste costanti di stato è applicabile, questo metodo deve restituire zero.

Non dovrebbe essere necessario controllare o segnalare gli stati STATE_SYSTEM_FOCUSABLE e STATE_SYSTEM_FOCUSED. Flash Player gestisce automaticamente questi stati.

Parametri

Altre informazioni

Elementi API correlati

     override public function get_accState(childID:uint):uint
     {
         var accState:uint = getState(childID);
     
         if (childID > 0) 
         {
             var listBase:ListBase = ListBase(master);
     
             var index:uint = childID - 1;
     
             // For returning states (OffScreen and Invisible)
             // when the list Item is not in the displayed rows.
             if (index < listBase.verticalScrollPosition ||
                 index >= listBase.verticalScrollPosition + listBase.rowCount)
             {
                 accState |= (STATE_SYSTEM_OFFSCREEN |
                              STATE_SYSTEM_INVISIBLE);
             }
             else
             {
                 accState |= STATE_SYSTEM_SELECTABLE;
     
                 var item:Object = getItemAt(index);
     
                 var renderer:IListItemRenderer =
                     listBase.itemToItemRenderer(item);
     
                 if (renderer != null && listBase.isItemSelected(renderer.data))
                     accState |= STATE_SYSTEM_SELECTED | STATE_SYSTEM_FOCUSED;
             }
         }
     
         return accState;
     }

Metodo MSAA per restituire il valore runtime del componente che questa AccessibilityImplementation rappresenta o di uno dei suoi elementi secondari.

Implementate questo metodo solo se AccessibilityImplementation rappresenta un elemento dell'interfaccia utente che ha un valore nel modello MSAA. Tenete presente che alcuni elementi dell'interfaccia utente che presentano un "valore" apparente in realtà espongono questo valore in modi differenti, ad esempio get_accName (testo, ad esempio), get_accState (caselle di controllo, ad esempio) o get_accSelection (caselle di riepilogo, ad esempio).

Se state implementando get_accValue solo per AccessibilityImplementation, oppure solo per i suo i elementi secondari, in alcuni casi dovrete indicare che non è presente un concetto di valore per il childID particolare che è stato passato. Potete farlo semplicemente restituendo null.

Parametri

Altre informazioni

Elementi API correlati

override public function get_accValue(childID:uint):String
     {
         var accValue:String;
         
         var listBase:ListBase = ListBase(master);
         
         var index:int = listBase.selectedIndex;
         if (childID == 0)
         {
             if (index > -1)
             {
                 var item:Object = getItemAt(index);
     
                 if (item is String)
                 {
                     accValue = item + " " + (index + 1) + " of " + listBase.dataProvider.length;
                 }
                 else
                 {
                     accValue = listBase.itemToLabel(item) + " " + (index + 1) +
                                " of " + listBase.dataProvider.length;
                 }
             }
         }
     
         return accValue;
     }

Restituisce un array contenente gli ID interi senza firma di tutti gli elementi secondari di AccessibilityImplementation.

La lunghezza dell'array può essere zero. Gli ID dell'array devono apparire nello stesso ordine logico degli elementi secondari che rappresentano. Se AccessibilityImplementation può contenere elementi secondari, questo metodo è obbligatorio, altrimenti non va implementato.

Quando assegnate dei childID agli elementi secondari, utilizzate uno schema che garantisca il mantenimento dell'univocità in ogni istanza di AccessibilityImplementation. I childID non devono essere necessariamente contigui e il loro ordine non deve corrispondere all'ordine logico degli elementi secondari. Dovete impostare il lavoro in modo da non riutilizzare i childID; se un elemento secondario viene eliminato, il suo ID non deve più essere utilizzato per tutta la durata dell'istanza AccessibilityImplementation. Tenete presente che, a causa delle scelte di implementazione nel codice di Flash Player, si può verificare un comportamento indesiderato se utilizzate un numero di childID superiore a un milione.

     override public function getChildIDArray():Array
     {
         var childIDs:Array = [];
     
         if (ListBase(master).dataProvider)
         {
             var n:uint = ListBase(master).dataProvider.length;
             for (var i:int = 0; i < n; i++)
             {
                 childIDs[i] = i + 1;
             }
         }
         return childIDs;
     }
     

Restituisce true o false per indicare se un oggetto di testo che presenta un rettangolo di delimitazione specificato da valori x, y, width e height deve essere considerato un'etichetta per il componente rappresentato da questa AccessibilityImplementation.

Le coordinate x e y sono relative all'angolo superiore sinistro del componente al quale si applica AccessibilityImplementation, e possono essere negativi. Tutte le coordinate sono espresse in unità dei pixel dello stage.

Questo metodo consente ai componenti accessibili di adattarsi alla ricerca delle relazioni di assegnazione automatica delle etichette in Flash Player, in base alle quali un testo esterno a un oggetto può fornire il nome all'oggetto. Questo metodo viene reso disponibile perché è prevedibile che i criteri per il riconoscimento delle etichette differiscano da componente a componente. Se implementate questo metodo, dovete cercare di utilizzare criteri geometrici simili a quelli utilizzati nel codice del lettore per i pulsanti e i campi di testo. Tali criteri sono i seguenti:

• Per i pulsanti, qualsiasi testo che rientra completamente nel pulsante viene considerato un'etichetta.
• Per i campi di testo, qualsiasi testo vicino al limite superiore e allineato a sinistra oppure vicino al limite sinistro viene considerato un'etichetta.

Se il componente rappresentato da AccessibilityImplementation non deve mai participare alle relazioni di assegnazione automatica delle etichette, non implementate isLabeledBy. Tale soluzione equivale a restituire sempre false. Un caso in cui isLabeledBy non deve essere implementato è quello in cui AccessibilityImplementation ricade nella categoria "nome assegnato dall'autore all'interno del componente" precedentemente descritto alla voce get_accName.

Tenete presente che questo metodo non è basato su alcun metodo IAccessible; è specifico di Flash.

Parametri