Loader  - AS3

Contiene l'oggetto di visualizzazione principale del file SWF o del file di immagine (JPG, PNG o GIF) caricato mediante il metodo load() o loadBytes().

Elementi API correlati

Restituisce un oggetto LoaderInfo corrispondente all'oggetto che viene caricato. Gli oggetti LoaderInfo sono condivisi dall'oggetto Loader e dall'oggetto del contenuto caricato. L'oggetto LoaderInfo fornisce informazioni sullo stato del caricamento e statistiche sul file caricato.

Gli eventi correlati con il caricamento vengono inviati dall'oggetto LoaderInfo a cui fa riferimento la proprietà contentLoaderInfo dell'oggetto Loader. La proprietà contentLoaderInfo viene impostata su un oggetto LoaderInfo valido, anche prima che il contenuto venga caricato, per consentire di aggiungere dei listener di eventi all'oggetto prima del caricamento.

Per rilevare gli errori non rilevati che si verificano in un file SWF caricato, utilizzate la proprietà Loader.uncaughtErrorEvents, non la proprietà Loader.contentLoaderInfo.uncaughtErrorEvents.

Elementi API correlati

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_complete);
loader.load(urlRequest);
addChild(loader);
 
function loader_complete(evt:Event):void {
    var target_mc:Loader = evt.currentTarget.loader as Loader;
    target_mc.x = (stage.stageWidth - target_mc.width) / 2;
    target_mc.y = (stage.stageHeight - target_mc.height) / 2;
}

Un oggetto che invia un evento uncaughtError quando si verifica un errore non gestito nel file SWF caricato da questo oggetto Loader. Un errore non rilevato si verifica quando un errore viene generato esternamente a qualsiasi blocco try..catch o quando un oggetto ErrorEvent viene inviato senza listener registrati.

Notate che la proprietà uncaughtErrorEvents di un oggetto Loader invia eventi che si propagano attraverso tale oggetto, non eventi inviati direttamente. Non invia mai uncaughtErrorEvent nella fase target. Invia l'evento solo nelle fasi di cattura e bubbling. Per rilevare un errore non rilevato nel file SWF corrente (ovvero il file SWF in cui è definito l'oggetto Loader), utilizzate invece la proprietà LoaderInfo.uncaughtErrorEvents.

Se il contenuto caricato dall'oggetto Loader è un file SWF AVM1 (ActionScript 2), gli errori non rilevati nel file SWF AVM1 non generano un evento uncaughtError.

Elementi API correlati

package
{
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.UncaughtErrorEvent;
    import flash.net.URLRequest;

    public class LoaderUncaughtErrorEventExample extends Sprite
    {
        private var ldr:Loader;
        
        public function LoaderUncaughtErrorEventExample()
        {
            ldr = new Loader();
            ldr.load(new URLRequest("child.swf"));
            ldr.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
    }
}

Crea un oggetto Loader che può essere utilizzato per caricare file, ad esempio SWF, JPEG, GIF o PNG. Chiamate il metodo load() per caricare la risorsa come elemento secondario dell'istanza Loader. Quindi potete aggiungere l'oggetto Loader all'elenco di visualizzazione (ad esempio utilizzando il metodo addChild() di un'istanza DisplayObjectContainer). La risorsa appare sullo stage mentre viene caricata.

Potete anche utilizzare un'istanza Loader "fuori elenco", ovvero senza aggiungerla a un contenitore di oggetto di visualizzazione incluso nell'elenco di visualizzazione. In questa modalità, l'istanza Loader potrebbe essere utilizzata per caricare un file SWF che contiene moduli aggiuntivi di un'applicazione.

Per rilevare la fine del caricamento del file SWF, potete utilizzare gli eventi dell'oggetto LoaderInfo associato alla proprietà contentLoaderInfo dell'oggetto Loader. A quel punto potete eseguire il codice del file SWF del modulo per inizializzare e avviare il modulo. Nella modalità "fuori elenco", un'istanza Loader potrebbe essere utilizzata anche per caricare un file SWF che contiene componenti o risorse multimediali. Anche in questo caso potete utilizzare le notifiche di evento dell'oggetto LoaderInfo per rilevare la fine del caricamento dei componenti. A quel punto l'applicazione può iniziare a utilizzare i componenti e le risorse multimediali della libreria del file SWF creando istanze delle classi ActionScript 3.0 che rappresentano tali componenti e risorse.

Per determinare lo stato di un oggetto Loader, monitorate gli eventi seguenti che l'oggetto LoaderInfo ha associato alla proprietà contentLoaderInfo dell'oggetto Loader:

• L'evento open viene inviato quando inizia il caricamento.
• L'evento ioError o securityError viene inviato se il file non può essere caricato o se si verifica un errore durante il caricamento.
• L'evento progress viene inviato continuamente durante il caricamento del file.
• L'evento complete viene inviato al termine dello scaricamento di un file, ma prima che siano disponibili i metodi e le proprietà del clip filmato caricato.
• L'evento init viene inviato dopo che le proprietà e i metodi del file SWF caricato diventano accessibili, in modo da consentire la modifica del file SWF caricato. Questo evento viene inviato prima del gestore complete. Nei file SWF di streaming, l'evento init può essere inviato con largo anticipo rispetto all'evento complete. Nella maggior parte delle situazioni, utilizzate il gestore init.

Note (solo iOS): nelle applicazioni AIR in iOS, potete caricare soltanto un file SWF contenente ActionScript dal pacchetto applicazione. La restrizione include qualsiasi ActionScript, come ad esempio le risorse con i nomi delle classi esportate per ActionScript. Per caricare un file SWF, dovete utilizzare lo stesso dominio applicazione dell’SWF principale.

Nelle versioni di AIR precedenti alla 3.6, solo i file SWF che non contengono un codice byte ActionScript possono essere caricati, indipendentemente dal fatto che vengano caricati dal pacchetto applicazione o da una rete. In alternativa all’utilizzo di un file SWF esterno con ActionScript, potete creare una libreria SWC e collegarla al vostro SWF principale.

Queste restrizioni non si applicano quando un’applicazione è in esecuzione nel simulatore iOS (ipa-test-interpreter-simulator o ipa-debug-interpreter-simulator) o in modalità interprete (ipa-test-interpreter or ipa-debug-interpreter.)

Elementi API correlati

Annulla un'operazione del metodo load() attualmente in corso per l'istanza Loader.

Elementi API correlati

Carica un file SWF, JPEG, JPEG progressivo, GIF non animato o PNG in un oggetto che è un elemento secondario dell'oggetto Loader. Se caricate un file GIF animato, viene visualizzato solo il primo fotogramma. Poiché l'oggetto Loader può contenere un unico elemento secondario, una successiva richiesta load() interrompe la richiesta precedente, se è ancora in corso, e avvia un nuovo caricamento.

Nota: in AIR 1.5 e Flash Player 10, la dimensione massima di un'immagine caricata è di 8.191 pixel in larghezza o altezza, mentre il numero totale di pixel non può essere superiore a 16.777.215. (Quindi, se un'immagine caricata ha una larghezza di 8.191 pixel, può avere solo una lunghezza di 2.048 pixel.) In Flash Player 9 e versioni precedenti e in AIR 1.1 e versioni precedenti, la limitazione è di 2.880 pixel in altezza e 2.880 pixel in larghezza.

Un file SWF o un'immagine caricata in un oggetto Loader filmato eredita le proprietà di posizione, rotazione e scala degli oggetti di visualizzazione principali dell'oggetto Loader.

Utilizzate il metodo unload() per rimuovere i filmati o le immagini caricate con questo metodo o per annullare un'operazione di caricamento in corso.

Potete impedire che un file SWF utilizzi questo metodo impostando il parametro allowNetworking dei tag object ed embed nella pagina HTML che include il contenuto SWF.

Note iOS

Nelle applicazioni AIR in iOS, potete caricare soltanto un file SWF contenente ActionScript dal pacchetto applicazione. La restrizione include qualsiasi ActionScript, come ad esempio le risorse con i nomi delle classi esportate per ActionScript. Per caricare un file SWF, dovete utilizzare lo stesso dominio di applicazione dell’SWF principale, come illustrato nel seguente esempio:

     var loader:Loader = new Loader();
     var url:URLRequest = new URLRequest("swfs/SecondarySwf.swf");
     var loaderContext:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain, null);
     loader.load(url, loaderContext);

Inoltre, in iOS non potete caricare un file SWF contenente tutto il ByteCode ActionScript (ABC), quindi scaricarlo e ricaricarlo. Se tentate di eseguire questa operazione, il runtime genera l’errore 3764.

Nelle versioni di AIR precedenti alla 3.6, solo i file SWF che non contengono un codice byte ActionScript possono essere caricati, indipendentemente dal fatto che vengano caricati dal pacchetto applicazione o da una rete. In alternativa all’utilizzo di un file SWF esterno con ActionScript, potete creare una libreria SWC e collegarla al vostro SWF principale.

Queste restrizioni non si applicano quando un’applicazione è in esecuzione nel simulatore iOS (ipa-test-interpreter-simulator o ipa-debug-interpreter-simulator) o in modalità interprete (ipa-test-interpreter or ipa-debug-interpreter.)

Sicurezza del Loader

Quando utilizzate questo metodo, considerate il modello di sicurezza di Flash Player illustrato nella descrizione della classe Loader.

In Flash Player 10 e versioni successive, se utilizzate un Content-Type multipart (ad esempio "multipart/form-data") che contiene un caricamento (indicato da un parametro "filename" in un'intestazione "content-disposition" nel corpo POST), l'operazione POST è soggetta alle regole di sicurezza applicate ai caricamenti:

• L'operazione POST deve essere eseguita come risposta a un'azione compiuta dall'utente, come un clic del mouse o la pressione di un tasto.
• Se l'operazione POST è tra più domini (il target POST non si trova sullo stesso server del file SWF che invia la richiesta POST), il server di destinazione deve fornire un file di criteri URL che consenta l'accesso tra più domini.

Inoltre, per qualsiasi Content-Type in più parti, la sintassi deve essere valida (in conformità allo standard RFC2046). Se la sintassi non è valida, l'operazione POST è soggetta alle regole di sicurezza applicate ai caricamenti.

Per ulteriori informazioni sulla sicurezza, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .

Parametri

Altri esempi

Altre informazioni

Elementi API correlati

Carica dai dati binari memorizzati nell'oggetto ByteArray.

Il metodo loadBytes() è asincrono. Dovete attendere l'evento "init" prima di accedere alle proprietà dell'oggetto caricato.

Quando utilizzate questo metodo, considerate il modello di sicurezza di Flash Player illustrato nella descrizione della classe Loader.

Nota (solo iOS): nelle applicazioni AIR in iOS, potete caricare soltanto un file SWF contenente ActionScript dal pacchetto applicazione. La restrizione include qualsiasi ActionScript, come ad esempio le risorse con i nomi delle classi esportate per ActionScript. Per caricare un file SWF, dovete utilizzare lo stesso dominio applicazione dell’SWF principale.

Nelle versioni di AIR precedenti alla 3.6, la chiamata a questo metodo non produce alcun effetto in iOS.

Parametri

Altre informazioni

Elementi API correlati

Carica un'istanza IFilePromise.

Il metodo loadFilePromise accetta un oggetto IFilePromise e carica i dati binari. Se i dati sono in un flusso progressivo, ad esempio un video, attendete gli eventi "init" o progress prima di accedere alle proprietà dell'oggetto caricato. Altrimenti, attendete l'evento complete per essere sicuri che i dati siano stati interamente caricati.

Quando utilizzate questo metodo, considerate il modello di sicurezza di Flash Player illustrato nella descrizione della classe Loader.

Parametri

Elementi API correlati

Rimuove un elemento secondario di questo oggetto Loader caricato mediante il metodo load(). La proprietà dell'oggetto LoaderInfo associato viene reimpostata su null. L'elemento secondario non viene necessariamente eliminato perché altri oggetti potrebbero farvi riferimento, tuttavia cessa di essere un elemento secondario dell'oggetto Loader.

Durante la chiamata al metodo unload(), la proprietà contentLoaderInfo dell’oggetto del Loader è impostata su null. Tutte le risorse visive che sono state caricate con l’SWF vengono scaricate e rimosse dalla memoria. Le definizioni di classe di ActionScript nell’SWF caricato rimangono nella memoria e il codice che si trova nello stesso dominio applicazione del file SWF caricato può accedere alle istanze di tali classi e crearne di nuove.

Nota (solo iOS): per le versioni di AIR precedenti alla 3.6, questo metodo non ha effetto in iOS.

È buona norma, prima di scaricare un file SWF secondario, chiudere esplicitamente i flussi degli oggetti del file, ad esempio gli oggetti LocalConnection, NetConnection, NetStream e Sound. In caso contrario, la riproduzione dell'audio del file SWF secondario potrebbe continuare anche se il file è stato scaricato. Per chiudere i flussi del file, aggiungete un listener di eventi all'elemento secondario che rileva l'evento unload. Quando l'oggetto principale chiama Loader.unload(), l'evento unload viene inviato all'elemento secondario. Il codice di esempio seguente produce il risultato descritto:

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

Elementi API correlati

Tenta di scaricare il contenuto del file SWF secondario e interrompe l'esecuzione dei comandi dai file SWF caricati. Questo metodo tenta di scaricare file SWF caricati utilizzando Loader.load() o Loader.loadBytes() mediante la rimozione dei riferimenti agli oggetti EventDispatcher, NetConnection, Timer, Sound o Video del file SWF secondario. Di conseguenza, per il file SWF secondario e il relativo elenco di visualizzazione si verifica quanto segue:

• I suoni vengono interrotti.
• I listener di eventi dello stage vengono rimossi.
• I listener di eventi per enterFrame, frameConstructed, exitFrame, activate e deactivate vengono rimossi.
• I timer vengono interrotti.
• Le istanze Camera e Microphone vengono scollegate.
• I clip filmato vengono interrotti.

Durante la chiamata al metodo unloadAndStop(), la proprietà contentLoaderInfo dell’oggetto del Loader è impostata su null. Tutte le risorse visive che sono state caricate con l’SWF vengono scaricate e rimosse dalla memoria. Le definizioni di classe di ActionScript nell’SWF caricato rimangono nella memoria e il codice che si trova nello stesso dominio applicazione del file SWF caricato può accedere alle istanze di tali classi e crearne di nuove.

Nota (solo iOS): per le versioni di AIR precedenti alla 3.6, questo metodo non ha effetto in iOS.

Parametri

Elementi API correlati

1. Viene creata una proprietà url, che corrisponde alla posizione e al nome del file di immagine.
2. Nella funzione di costruzione LoaderExample viene creato un nuovo oggetto Loader di nome loader, che viene successivamente passato al metodo configureListeners(), descritto al punto 3.
3. La funzione di costruzione crea una nuova istanza di un oggetto URLRequest, request, passando url in modo che il nome e la posizione del file siano noti.
4. L'oggetto request viene quindi passato al metodo load() dell'oggetto loader, che carica l'immagine nell'elenco di visualizzazione.
5. Un listener di eventi clickHandler viene registrato per l'evento click del loader. In seguito a un clic del mouse, l'immagine caricata viene scaricata.
6. Il metodo configureListeners() aggiunge sette listener di eventi utilizzando i metodi seguenti:
   • Il metodo completeHandler() viene eseguito al termine del caricamento dell'immagine.
   • Il metodo httpStatusHandler() viene eseguito se l'immagine non viene caricata a livello locale e solo se la richiesta di rete viene resa disponibile e Flash Player è in grado di rilevarla.
   • Il metodo initHandler() viene eseguito prima del metodo completeHandler() e dopo il metodo progressHandler(). In genere, l'evento init risulta più utile quando si caricano dei file SWF.
   • Il metodo ioErrorHandler() viene eseguito se il file di immagine non è disponibile o accessibile.
   • Il metodo openHandler() viene eseguito alla prima apertura del file di immagine.
   • Il metodo progressHandler() viene eseguito quando inizia il caricamento del file di immagine e successivamente quando il caricamento è terminato.
   • Il metodo unLoadHandler() viene eseguito quando l'immagine viene scaricata utilizzando il metodo unload() quando l'utente fa clic sull'immagine.

Tenete presente quanto segue:

• Questo esempio richiede che un file di nome Image.gif venga aggiunto alla stessa directory del file SWF compilato. Utilizzate un'immagine con un'area che non ecceda le dimensioni del file SWF principale.
• Anche se questo esempio utilizza tutti gli eventi disponibili per l'oggetto LoaderInfo, nella maggior parte delle situazioni è richiesto solo un sottoinsieme. In particolare, quando caricate solo un file di immagine, l'evento complete (ed eventualmente l'errore ioError) è sufficiente quando si carica un'immagine locale.

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}