LocalConnection  - AS3

Indica l'oggetto su cui vengono chiamati i metodi di callback. L'oggetto predefinito è this, l'oggetto locale che si sta creando. È possibile impostare la proprietà client su un altro oggetto, e i metodi di callback vengono richiamati su tale oggetto.

Altri esempi

Una stringa che rappresenta il dominio della posizione del file corrente.

Nel contenuto in esecuzione nella funzione di sicurezza sandbox dell'applicazione in Adobe AIR (contenuto installato nell'applicazione AIR), il runtime utilizza la stringa app# seguita dall'ID applicazione per l'applicazione AIR (definito nel file di descrizione dell'applicazione) al posto del superdominio. Ad esempio, un connectionName per un'applicazione con l'ID applicazione com.example.air.MyApp connectionName viene risolto in "app#com.example.air.MyApp:connectionName".

Nei file SWF pubblicati per Flash Player 9 o versioni successive, la stringa restituita è il dominio esatto del file, compresi i sottodomini. Ad esempio, se il file si trova all'indirizzo www.adobe.com, questo comando restituisce "www.adobe.com".

Se il file è un file locale che risiede sul computer client in esecuzione in Flash Player, questo comando restituisce "localhost".

L'uso più comune di questa proprietà consiste nell'includere il nome del dominio dell'oggetto LocalConnection mittente come parametro per il metodo che si prevede di richiamare nell'oggetto LocalConnection ricevente, oppure di utilizzarla con LocalConnection.allowDomain() per accettare i comandi provenienti da un dominio specificato. Se abilitate la comunicazione solo tra oggetti LocalConnection che si trovano nello stesso dominio, probabilmente non è necessario utilizzare questa proprietà.

Elementi API correlati

Indica se l’oggetto LocalConnection è associato all’utente corrente (true) oppure è accessibile globalmente a tutti gli utenti del computer (false). Questa proprietà è applicabile solo al contenuto eseguito su Mac OS X; le altre piattaforme ignorano questo parametro. Le connessioni sui sistemi operativi Windows e Linux sono sempre configurate per utente.

In Flash Player 10.0.22 e versioni precedenti e in AIR 1.5.1 e versioni precedenti, tutti gli oggetti LocalConnection su Mac OS X hanno un ambito globale. Impostate sempre questa proprietà su true, a meno che dobbiate mantenere la compatibilità con versioni precedenti. Nelle versioni future, il valore predefinito di questa proprietà potrebbe essere cambiato in true.

Il valore predefinito è false.

La proprietà isSupported è impostata su true se la classe LocalConnection è supportata nella piattaforma corrente, altrimenti è impostata su false.

Crea un oggetto LocalConnection. È possibile utilizzare gli oggetti LocalConnection per abilitare la comunicazione tra file diversi che sono in esecuzione sullo stesso computer client.

Elementi API correlati

Specifica uno o più domini che possono inviare chiamate LocalConnection a questa istanza LocalConnection.

Non è possibile usare questo metodo per consentire ai file che risiedono sul dominio mediante protocolli non protetti di accedere ai file che risiedono sul dominio mediante un protocollo protetto (HTTPS); utilizzare invece il metodo allowInsecureDomain().

Utilizzate questo metodo per fare in modo che un file secondario proveniente da un dominio differente possa effettuare chiamate LocalConnection al file principale, senza conoscere il dominio finale dal quale proverrà il file secondario. Questa situazione può verificarsi ad esempio quando si utilizzano i reindirizzamenti per il bilanciamento del carico di lavoro o i server di terze parti. In tale situazione, utilizzate la proprietà url dell'oggetto LoaderInfo utilizzato per il caricamento per ottenere il dominio da usare con il metodo allowDomain(). Ad esempio, se usate un oggetto Loader per caricare un file secondario, una volta caricato il file, verificate la proprietà contentLoaderInfo.url dell'oggetto Loader ed estraete il dominio dalla stringa dell'URL. In tal caso, attendete che il file sia caricato, poiché il valore della proprietà contentLoaderInfo.url non è definitivo e corretto finché il file non è stato completamente caricato.

In realtà può verificarsi anche la situazione opposta: è possibile creare un file secondario impostato per accettare le chiamate LocalConnection dal proprio elemento principale ma di cui non conosce il dominio. In tal caso, implementate questo metodo verificando se l'argomento del dominio corrisponde al dominio della proprietà loaderInfo.url nel file Anche in questo caso è necessario analizzare il dominio fuori dell'URL completo contenuto in loaderInfo.url. In questo caso, non è necessario attendere il caricamento del file principale poiché sarà già stato completato al momento del caricamento dell'elemento secondario.

Quando utilizzate questo metodo, considerate il modello di sicurezza di Flash Player. Per impostazione predefinita, un oggetto LocalConnection è associato alla sandbox del file che l'ha creato e le chiamate su più domini agli oggetti LocalConnection non sono consentite, a meno che non sia stato chiamato il metodo LocalConnection.allowDomain() nel file ricevente. Tuttavia, in Adobe AIR, il contenuto della funzione di sicurezza sandbox dell'applicazione (contenuto installato con l'applicazione AIR) non è interessato da queste limitazioni di sicurezza.

Per ulteriori informazioni sulla sicurezza, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .

Nota: il metodo allowDomain() è stato modificato rispetto alla forma che aveva in ActionScript 1.0 e 2.0. Nelle versioni precedenti, allowDomain era un metodo di callback implementato dall'utente. In ActionScript 3.0, allowDomain() è un metodo incorporato di LocalConnection che viene chiamato. Grazie a questa modifica, allowDomain() funziona in modo molto simile a flash.system.Security.allowDomain().

Parametri

Altri esempi

Elementi API correlati

Specifica uno o più domini che possono inviare chiamate LocalConnection a questo oggetto LocalConnection.

Il metodo allowInsecureDomain() funziona in modo simile al metodo allowDomain(), con l'eccezione che il metodo allowInsecureDomain() consente anche ai file con un'origine diversa da HTTPS di inviare chiamate LocalConnection ai file SWF da un'origine HTTPS. Questa differenza è significativa solo se chiamate il metodo allowInsecureDomain() da un file che è stato caricato tramite HTTPS. È necessario chiamare il metodo allowInsecureDomain() anche se si oltrepassa un confine tra non HTTPS e HTTPS all'interno di uno stesso dominio; per impostazione predefinita, non sono mai consentite chiamate LocalConnection da file non HTTPS a file HTTPS, anche all'interno dello stesso dominio.

Non è consigliabile effettuare chiamate a allowInsecureDomain(), poiché ciò può compromettere il livello di sicurezza offerto da HTTPS. Quando caricate un file tramite HTTPS, potete essere ragionevolmente sicuri dell'integrità del file durante la distribuzione in rete. Se successivamente autorizzate un file non HTTPS a effettuare chiamate LocalConnection al file HTTPS, accetterete chiamate da un file che potrebbe essere stato manomesso durante la distribuzione. Questa situazione richiede generalmente un livello aggiuntivo di vigilanza, poiché non è possibile considerare attendibile l'autenticità delle chiamate LocalConnection provenienti dal file HTTPS.

Per impostazione predefinita, i file che risiedono su domini che utilizzano il protocollo HTTPS sono accessibili solo da altri file che risiedono su domini che utilizzano il protocollo HTTPS. Questa implementazione conserva l'integrità fornita dal protocollo HTTPS.

Non è consigliabile utilizzare questo metodo per ignorare il comportamento predefinito, poiché la sicurezza HTTPS viene compromessa. Tuttavia, può essere necessario utilizzarlo per consentire l'accesso ai file SWF HTTPS pubblicati per Flash Player 9 o versioni successive da parte dei file SWF HTTP pubblicati per Flash Player 6 o precedente.

Per ulteriori informazioni sulla sicurezza, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .

Parametri

Altri esempi

Elementi API correlati

Chiude (disconnette) un oggetto LocalConnection. Eseguite questo comando se non desiderate più che l'oggetto accetti i comandi: ad esempio, per eseguire un comando connect() che utilizza lo stesso parametro connectionName in un altro file SWF.

Elementi API correlati

Prepara un oggetto LocalConnection a ricevere i comandi inviati da un comando send() (dall'oggetto LocalConnection mittente). L'oggetto utilizzato con il metodo connect()viene definito oggetto LocalConnection ricevente. Gli oggetti mittenti e riceventi devono essere in esecuzione sullo stesso computer client.

Per evitare una condizione race, definite i metodi associati all'oggetto LocalConnection ricevente prima di chiamare questo metodo, come mostrato nell'esempio della classe LocalConnection.

Per impostazione predefinita, l'argomento connectionName viene risolto nel valore "superdomain:connectionName", dove superdomain è il superdominio del file che contiene il comando connect(). Ad esempio, se il file che contiene l'oggetto LocalConnection ricevente si trova in www.someDomain.com, connectionName risolve a "someDomain.com:connectionName". Se un file in esecuzione in Flash Player si trova sul computer client, il valore assegnato a superdomain è "localhost".

Nel contenuto in esecuzione nella funzione di sicurezza sandbox dell'applicazione in Adobe AIR (contenuto installato nell'applicazione AIR), il runtime utilizza la stringa app# seguita dall'ID applicazione per l'applicazione AIR (definito nel file di descrizione dell'applicazione) al posto del superdominio. Ad esempio, un connectionName per un'applicazione con l'ID applicazione com.example.air.MyApp connectionName viene risolto in "app#com.example.air.MyApp:connectionName".

Sempre per impostazione predefinita, Flash Player consente all'oggetto LocalConnection ricevente di accettare comandi solo dagli oggetti LocalConnection mittenti per cui anche il nome di connessione viene risolto nel valore "superdomain:connectionName". In questo modo, Flash Player rende più semplice la comunicazione tra i file di uno stesso dominio.

Se implementate la comunicazione solo tra file dello stesso dominio, specificate una stringa per connectionName che non inizi con un carattere di sottolineatura (_) e che non specifichi un nome di dominio (ad esempio, "myDomain:connectionName"). Utilizzate la stessa stringa del metodo connect(connectionName).

Se implementate la comunicazione solo tra file di domini diversi e specificate una stringa per connectionName che inizia con un carattere di sottolineatura (_), rendete il file con l'oggetto LocalConnection ricevente più portabile tra i domini. Di seguito sono illustrati i due casi possibili:

• Se la stringa per connectionName non inizia con un carattere di sottolineatura (_), viene aggiunto un prefisso composto dal superdominio e da un segno di due punti (ad esempio, "myDomain:connectionName"). Benché questo assicuri che la connessione non entri in conflitto con le connessioni con lo stesso nome di altri domini, tutti gli oggetti LocalConnection mittenti devono specificare questo superdominio (ad esempio, "myDomain:connectionName"). Se il file con l'oggetto LocalConnection ricevente viene spostato in un altro dominio, il lettore modifica il prefisso per rispecchiare il nuovo superdominio (ad esempio, "anotherDomain:connectionName"). Tutti gli oggetti LocalConnection mittenti devono quindi essere modificati manualmente in modo da puntare al nuovo superdominio.
• Se la stringa per connectionName inizia con un segno di sottolineatura (ad esempio, "_connectionName"), alla stringa non viene aggiunto un prefisso. Questo significa che gli oggetti LocalConnection riceventi e mittenti utilizzano stringhe identiche per connectionName. Se l'oggetto ricevente utilizza allowDomain() per specificare che vengano accettate le connessioni da qualunque dominio, il file con l'oggetto LocalConnection ricevente può essere spostato in un altro dominio senza modificare alcun oggetto LocalConnection mittente.

Per ulteriori informazioni, vedete la discussione nella panoramica delle classi, la discussione su connectionName in send() e le sezioni relative a allowDomain() e domain.

Nota: il carattere di due punti viene utilizzato come carattere speciale per separare il superdominio dalla stringa connectionName. Se una stringa per connectionName contiene un punto e virgola, non è valida.

Quando utilizzate questo metodo, considerate il modello di sicurezza di Flash Player. Per impostazione predefinita, un oggetto LocalConnection è associato alla sandbox del file che l'ha creato e le chiamate su più domini agli oggetti LocalConnection non sono consentite, a meno che non sia stato chiamato il metodo LocalConnection.allowDomain() nel file ricevente. È possibile impedire che un file utilizzi questo metodo impostando il parametro allowNetworking dei tag object ed embed nella pagina HTML che include il contenuto SWF.Tuttavia, in Adobe AIR, il contenuto della funzione di sicurezza sandbox dell'applicazione (contenuto installato con l'applicazione AIR) non è interessato da queste limitazioni di sicurezza.

Per ulteriori informazioni sulla sicurezza, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .

Parametri

Altri esempi

Elementi API correlati

Richiama il metodo denominato methodName su una connessione aperta con il metodo connect(connectionName) (nell'oggetto LocalConnection ricevente). L'oggetto utilizzato con il metodo send()viene definito oggetto LocalConnection mittente. I file SWF che contengono gli oggetti mittenti e riceventi devono essere in esecuzione sullo stesso computer client.

Esiste un limite di 40 kilobyte alla quantità di dati che è possibile passare come parametri a questo comando. Se send() restituisce ArgumentError ma la sintassi è corretta, provare a dividere le richieste send() in più comandi, ciascuno con meno di 40 KB di dati.

Come discusso nella voce relativa a connect(), il superdominio corrente viene aggiunto a connectionName per impostazione predefinita. Se implementate la comunicazione tra domini diversi, definite connectionName negli oggetti LocalConnection sia mittenti che riceventi in modo che a connectionName non venga aggiunto il superdominio corrente. È possibile ottenere questo risultato in uno dei due modi seguenti:

• Utilizzate un carattere di sottolineatura (_) all'inizio di connectionName negli oggetti LocalConnection sia mittenti che riceventi. Nel file che contiene l'oggetto ricevente, utilizzate LocalConnection.allowDomain() per specificare che vengano accettate le connessioni da qualunque dominio. Questa implementazione consente di memorizzare i file mittenti e riceventi di qualunque dominio.
• Includere il superdominio in connectionName nell'oggetto LocalConnection mittente: ad esempio, myDomain.com:myConnectionName. Nell'oggetto ricevente, utilizzate LocalConnection.allowDomain() per specificare che vengano accettate le connessioni provenienti dal superdominio specificato (in questo caso, myDomain.com) oppure quelle provenienti da qualsiasi dominio.

Nota: non è possibile specificare un superdominio in connectionName nell'oggetto LocalConnection ricevente; è possibile farlo solo nell'oggetto LocalConnection mittente.

Quando utilizzate questo metodo, considerate il modello di sicurezza di Flash Player. Per impostazione predefinita, un oggetto LocalConnection è associato alla sandbox del file che l'ha creato e le chiamate su più domini agli oggetti LocalConnection non sono consentite, a meno che non sia stato chiamato il metodo LocalConnection.allowDomain() nel file ricevente. Per il contenuto SWF in esecuzione nel browser, è possibile impedire a un file di utilizzare questo metodo impostando il parametro allowNetworking dei tag object ed embed nella pagina HTML in cui è presente il contenuto SWF. Tuttavia, in Adobe AIR, il contenuto della funzione di sicurezza sandbox dell'applicazione (contenuto installato con l'applicazione AIR) non è interessato da queste limitazioni di sicurezza.

Per ulteriori informazioni sulla sicurezza, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .

Parametri

Altri esempi

Elementi API correlati

Inviato quando viene generata un'eccezione in modo asincrono, cioè da un codice asincrono nativo.

Questo evento ha le seguenti proprietà:

Inviato se una chiamata a LocalConnection.send() tenta di inviare dati a una funzione di sicurezza sandbox diversa.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato quando un oggetto LocalConnection segnala il proprio stato. Se LocalConnection.send() riesce, nell'oggetto evento status il valore della proprietà level è "status"; se la chiamata non riesce, la proprietà level è "error". Se il file ricevente rifiuta la connessione, la chiamata può fallire senza che venga emessa una notifica al file mittente.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Nel file SWF LocalConnectionSenderExample viene creata un'istanza LocalConnection e, quando si preme il pulsante, il metodo call() viene utilizzato per chiamare il metodo lcHandler nel file SWF con il nome di connessione "myConnection", passando il contenuto di TextField come parametro.

Nel file SWF LocalConnectionReceiverExample, viene creata un'istanza LocalConnection e viene chiamato il metodo connect() per designare questo file SWF come destinatario dei messaggi che sono indirizzati alla connessione di nome "myConnection". Inoltre, questa classe include un metodo pubblico di nome lcHandler(); questo metodo è quello che viene chiamato dal file SWF LocalConnectionSenderExample. Quando viene chiamato, il testo che viene passato come parametro viene aggiunto a TextField sullo stage.

Nota: per provare l'esempio, entrambi i file SWF devono essere caricati contemporaneamente sullo stesso computer.

// Code in LocalConnectionSenderExample.as
package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.net.LocalConnection;
    import flash.text.TextField;
    import flash.text.TextFieldType;
    import flash.events.StatusEvent;
    import flash.text.TextFieldAutoSize;

    public class LocalConnectionSenderExample extends Sprite {
        private var conn:LocalConnection;
        
        // UI elements
        private var messageLabel:TextField;
        private var message:TextField;
        private var sendBtn:Sprite;
        
        public function LocalConnectionSenderExample() {
            buildUI();
            sendBtn.addEventListener(MouseEvent.CLICK, sendMessage);
            conn = new LocalConnection();
            conn.addEventListener(StatusEvent.STATUS, onStatus);
        }
        
        private function sendMessage(event:MouseEvent):void {
            conn.send("myConnection", "lcHandler", message.text);
        }
        
        private function onStatus(event:StatusEvent):void {
            switch (event.level) {
                case "status":
                    trace("LocalConnection.send() succeeded");
                    break;
                case "error":
                    trace("LocalConnection.send() failed");
                    break;
            }
        }
        
        private function buildUI():void {
            const hPadding:uint = 5;
            // messageLabel
            messageLabel = new TextField();
            messageLabel.x = 10;
            messageLabel.y = 10;
            messageLabel.text = "Text to send:";
            messageLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(messageLabel);
            
            // message
            message = new TextField();
            message.x = messageLabel.x + messageLabel.width + hPadding;
            message.y = 10;
            message.width = 120;
            message.height = 20;
            message.background = true;
            message.border = true;
            message.type = TextFieldType.INPUT;
            addChild(message);
            
            // sendBtn
            sendBtn = new Sprite();
            sendBtn.x = message.x + message.width + hPadding;
            sendBtn.y = 10;
            var sendLbl:TextField = new TextField();
            sendLbl.x = 1 + hPadding;
            sendLbl.y = 1;
            sendLbl.selectable = false;
            sendLbl.autoSize = TextFieldAutoSize.LEFT;
            sendLbl.text = "Send";
            sendBtn.addChild(sendLbl);
            sendBtn.graphics.lineStyle(1);
            sendBtn.graphics.beginFill(0xcccccc);
            sendBtn.graphics.drawRoundRect(0, 0, (sendLbl.width + 2 + hPadding + hPadding), (sendLbl.height + 2), 5, 5);
            sendBtn.graphics.endFill();
            addChild(sendBtn);
        }
    }
}