XMLNode

Pacchetto	flash.xml
Classe	public class XMLNode
Ereditarietà	XMLNode Object
Sottoclassi	XMLDocument

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

La classe XMLNode rappresenta l'oggetto XML precedente che era presente in ActionScript 2.0 ed è stato rinominato in ActionScript 3.0. In ActionScript 3.0, valutare come alternativa l'uso della nuova classe di primo livello XML e delle classi correlate, che supportano E4X (ECMAScript for XML). La classe XMLNode è stata inclusa per assicurare la compatibilità retroattiva.

Vedere gli esempi

Elementi API correlati

XML
flash.xml.XMLDocument

Proprietà pubbliche

Nascondi proprietà pubbliche ereditate

Mostra proprietà pubbliche ereditate

	Proprietà		Definito da
		attributes : Object Un oggetto che contiene tutti gli attributi dell'istanza XMLNode specificata.	XMLNode
		childNodes : Array [sola lettura] Un array degli elementi secondari dell'oggetto XMLNode specificato.	XMLNode
		constructor : Object Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto.	Object
		firstChild : XMLNode Valuta l'oggetto XMLDocument specificato e fa riferimento al primo elemento secondario nell'elenco degli elementi secondari del nodo principale.	XMLNode
		lastChild : XMLNode Un valore XMLNode che fa riferimento all'ultimo elemento secondario nell'elenco degli elementi secondari del nodo principale.	XMLNode
		localName : String [sola lettura] La parte di nome locale del nome del nodo XML.	XMLNode
		namespaceURI : String [sola lettura] Se il nodo XML ha un prefisso, namespaceURI è il valore della dichiarazione xmlns per questo prefisso (l'URI), solitamente denominato URI dello spazio dei nomi.	XMLNode
		nextSibling : XMLNode Un valore XMLNode che fa riferimento al successivo elemento di pari livello nell'elenco degli elementi secondari del nodo principale.	XMLNode
		nodeName : String Una stringa che rappresenta il nome del nodo dell'oggetto XMLNode.	XMLNode
		nodeType : uint Un valore nodeType costante: XMLNodeType.ELEMENT_NODE (per un elemento XML) o XMLNodeType.TEXT_NODE (per un nodo di testo).	XMLNode
		nodeValue : String Il valore node dell'oggetto XMLDocument.	XMLNode
		parentNode : XMLNode Un valore XMLNode che fa riferimento al nodo principale dell'oggetto XML specificato, oppure il valore null se per il nodo non esiste un elemento principale.	XMLNode
		prefix : String [sola lettura] La parte del prefisso del nome del nodo XML.	XMLNode
		previousSibling : XMLNode Un valore XMLNode che fa riferimento al precedente elemento di pari livello nell'elenco degli elementi secondari del nodo principale.	XMLNode

Metodi pubblici

Nascondi metodi pubblici ereditati

Mostra metodi pubblici ereditati

	Metodo		Definito da
		XMLNode(type:uint, value:String) Crea un nuovo oggetto XMLNode.	XMLNode
		appendChild(node:XMLNode):void Aggiunge il nodo specificato all'elenco degli elementi secondari dell'oggetto XML.	XMLNode
		cloneNode(deep:Boolean):XMLNode Crea e restituisce un nuovo nodo XML con tipo, nome, valore e attributi uguali all'oggetto XML.	XMLNode
		getNamespaceForPrefix(prefix:String):String Restituisce l'URI dello spazio dei nomi associato al prefisso specificato per il nodo.	XMLNode
		getPrefixForNamespace(ns:String):String Restituisce il prefisso che è associato all'URI dello spazio dei nomi specificato per il nodo.	XMLNode
		hasChildNodes():Boolean Indica che l'oggetto XMLNode specificato ha dei nodi secondari.	XMLNode
		hasOwnProperty(name:String):Boolean Indica se per un oggetto è definita una proprietà specifica.	Object
		insertBefore(node:XMLNode, before:XMLNode):void Inserisce un nuovo nodo secondario nell'elenco degli elementi secondari dell'oggetto XML, prima del nodo beforeNode.	XMLNode
		isPrototypeOf(theClass:Object):Boolean Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro.	Object
		propertyIsEnumerable(name:String):Boolean Indica se la proprietà specificata esiste ed è enumerabile.	Object
		removeNode():void Rimuove dall'elemento principale l'oggetto XML specificato.	XMLNode
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche.	Object
		toLocaleString():String Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate.	Object
		toString():String Valuta l'oggetto XMLNode specificato, crea una rappresentazione testuale della struttura XML, compresi il nodo, gli elementi secondari e gli attributi, e restituisce il risultato sotto forma di stringa.	XMLNode
		valueOf():Object Restituisce il valore di base dell'oggetto specificato.	Object

Descrizione delle proprietà

attributes

proprietà

attributes:Object

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Un oggetto che contiene tutti gli attributi dell'istanza XMLNode specificata. L'oggetto XMLNode.attributes contiene una variabile per ciascun attributo dell'istanza XMLNode. Dal momento che queste variabili vengono definite come parte dell'oggetto, a esse si fa generalmente riferimento come proprietà dell'oggetto. Il valore di ogni attributo viene memorizzato nella proprietà corrispondente sotto forma di stringa. Ad esempio, se è presente un attributo di nome color, è possibile recuperarne il valore specificando color come nome di proprietà, come illustrato nel codice seguente:

	 var myColor:String = doc.firstChild.attributes.color

Implementazione
public function get attributes():Object
public function set attributes(value:Object):void

childNodes

proprietà

childNodes:Array [sola lettura]

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Un array degli elementi secondari dell'oggetto XMLNode specificato. Ogni elemento dell'array è un riferimento a un oggetto XMLNode che rappresenta un nodo secondario. Si tratta di una proprietà di sola lettura e non può essere utilizzata per manipolare i nodi secondari. Usate i metodi appendChild(), insertBefore() e removeNode() per manipolare i nodi secondari.

Questa proprietà è undefined per i nodi di testo (nodeType == 3).

Implementazione
public function get childNodes():Array

Elementi API correlati

XMLNode.nodeType
XMLNode.appendChild()
XMLNode.insertBefore()
XMLNode.removeNode()

firstChild

proprietà

public var firstChild:XMLNode

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Valuta l'oggetto XMLDocument specificato e fa riferimento al primo elemento secondario nell'elenco degli elementi secondari del nodo principale. Questa proprietà è null se il nodo non ha elementi secondari. È undefined se il nodo è un nodo di testo. Questa è una proprietà di sola lettura e non può essere utilizzata per gestire nodi secondari; a tale scopo, utilizzate i metodi appendChild(), insertBefore() e removeNode().

Elementi API correlati

XMLNode.appendChild()
XMLNode.insertBefore()
XMLNode.removeNode()

lastChild

proprietà

public var lastChild:XMLNode

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Un valore XMLNode che fa riferimento all'ultimo elemento secondario nell'elenco degli elementi secondari del nodo principale. La proprietà XMLNode.lastChild è null se il nodo non ha elementi secondari. Questa proprietà non può essere utilizzata per gestire nodi secondari; a tale scopo, utilizzate i metodi appendChild(), insertBefore() e removeNode().

Elementi API correlati

XMLNode.appendChild()
XMLNode.insertBefore()
XMLNode.removeNode()

localName

proprietà

localName:String [sola lettura]

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

La parte di nome locale del nome del nodo XML. Questo è il nome dell'elemento senza prefisso dello spazio dei nomi. Ad esempio, il nodo <contact:mailbox/>bob@example.com</contact:mailbox> ha il nome locale "mailbox" e il prefisso "contact", che comprende il nome dell'elemento completo "contact.mailbox".

Il prefisso è accessibile tramite la proprietà prefix dell'oggetto nodo XML. La proprietà nodeName restituisce il nome completo (incluso il prefisso e il nome locale).

Implementazione
public function get localName():String

namespaceURI

proprietà

namespaceURI:String [sola lettura]

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Se il nodo XML ha un prefisso, namespaceURI è il valore della dichiarazione xmlns per questo prefisso (l'URI), solitamente denominato URI dello spazio dei nomi. La dichiarazione xmlns si trova nel nodo corrente o in un nodo superiore nella gerarchia XML.

Se il nodo XML non ha prefisso, il valore della proprietà namespaceURI dipende dal fatto che vi sia o meno uno spazio dei nomi predefinito (come in xmlns="http://www.example.com/"). In caso affermativo, il valore della proprietà namespaceURI è il valore dello spazio dei nomi predefinito. Se invece non vi è spazio dei nomi predefinito, la proprietà namespaceURI del nodo sarà una stringa vuota ("").

Notate che è possibile utilizzare il metodo getNamespaceForPrefix() per identificare lo spazio dei nomi associato a un prefisso specifico. La proprietà namespaceURI restituisce il prefisso associato al nome del nodo.

Implementazione
public function get namespaceURI():String

Elementi API correlati

getNamespaceForPrefix()
getPrefixForNamespace()

nextSibling

proprietà

public var nextSibling:XMLNode

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Un valore XMLNode che fa riferimento al successivo elemento di pari livello nell'elenco degli elementi secondari del nodo principale. Questa proprietà è null se il nodo non ha un successivo nodo di pari livello. Questa proprietà non può essere utilizzata per gestire nodi secondari; a tale scopo, utilizzate i metodi appendChild(), insertBefore() e removeNode().

Elementi API correlati

XMLNode.firstChild
XMLNode.appendChild()
XMLNode.insertBefore()
XMLNode.removeNode()

nodeName

proprietà

public var nodeName:String

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Una stringa che rappresenta il nome del nodo dell'oggetto XMLNode. Se l'oggetto XMLNode è un elemento XML (nodeType == 1), nodeName è il nome del tag che rappresenta il nodo nel file XML. Ad esempio, TITLE è la proprietà nodeName di un tag TITLE. Se l'oggetto XMLNode è un nodo di testo (nodeType == 3), nodeName è null.

Elementi API correlati

XMLNode.nodeType

nodeType

proprietà

public var nodeType:uint

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Un valore nodeType costante: XMLNodeType.ELEMENT_NODE (per un elemento XML) o XMLNodeType.TEXT_NODE (per un nodo di testo).

La proprietà nodeType è un valore numerico tratto dall'enumerazione NodeType nella specifica di livello 1 del W3C DOM: http://www.w3.org/tr/1998/REC-DOM-Level-1-19981001/level-one-core.html. La tabella seguente elenca i valori:

Valore intero	Costante definita
1	ELEMENT_NODE
3	TEXT_NODE
5	ENTITY_REFERENCE_NODE
7	PROCESSING_INSTRUCTION_NODE
9	DOCUMENT_NODE
11	DOCUMENT_FRAGMENT_NODE

In Flash Player, la classe XMLNode incorporata supporta solo XMLNodeType.ELEMENT_NODE e XMLNodeType.TEXT_NODE.

Elementi API correlati

XMLNodeType.TEXT_NODE
XMLNodeType.ELEMENT_NODE

nodeValue

proprietà

public var nodeValue:String

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Il valore node dell'oggetto XMLDocument. Se l'oggetto XMLDocument è un nodo di testo, nodeType è 3 e nodeValue è il testo del nodo. Se l'oggetto XMLDocument è un elemento XML (nodeType è 1), nodeValue è null e di sola lettura.

Elementi API correlati

XMLNode.nodeType

parentNode

proprietà

public var parentNode:XMLNode

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Un valore XMLNode che fa riferimento al nodo principale dell'oggetto XML specificato, oppure il valore null se per il nodo non esiste un elemento principale. Questa è una proprietà di sola lettura e non può essere utilizzata per gestire nodi secondari; a tale scopo, utilizzate i metodi appendChild(), insertBefore() e removeNode().

Elementi API correlati

XMLNode.appendChild()
XMLNode.insertBefore()
XMLNode.removeNode()

prefix

proprietà

prefix:String [sola lettura]

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

La parte del prefisso del nome del nodo XML. Ad esempio, il nodo <contact:mailbox/>bob@example.com</contact:mailbox> ha il nome locale "mailbox" e il prefisso "contact", che comprende il nome dell'elemento completo "contact.mailbox".

La proprietà nodeName di un oggetto nodo XML restituisce il nome completo (incluso il prefisso e il nome locale). La porzione nome locale del nome dell'elemento è accessibile tramite la proprietà localName.

Implementazione
public function get prefix():String

previousSibling

proprietà

public var previousSibling:XMLNode

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Un valore XMLNode che fa riferimento al precedente elemento di pari livello nell'elenco degli elementi secondari del nodo principale. La proprietà è null se il nodo non ha un precedente nodo di pari livello. Questa proprietà non può essere utilizzata per gestire nodi secondari; a tale scopo, utilizzate i metodi appendChild(), insertBefore() e removeNode().

Elementi API correlati

XMLNode.lastChild
XMLNode.appendChild()
XMLNode.insertBefore()
XMLNode.removeNode()

Descrizione della funzione di costruzione

()

Funzione di costruzione

public function XMLNode(type:uint, value:String)

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Crea un nuovo oggetto XMLNode. È necessario utilizzare la funzione di costruzione per creare un oggetto XMLNode prima di chiamare i metodi della classe XMLNode.

Nota: utilizzate i metodi createElement() e createTextNode() per aggiungere elementi e nodi di testo a una struttura ad albero di documenti XML.

Parametri

	`type:uint` — Il tipo di nodo: 1 (che indica un elemento XML) o 3 (che indica un nodo di testo).

	`value:String` — Il testo XML analizzato per creare il nuovo oggetto XMLNode.

Elementi API correlati

XMLDocument.createElement()
XMLDocument.createTextNode()

Descrizione dei metodi

appendChild

()

metodo

public function appendChild(node:XMLNode):void

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Aggiunge il nodo specificato all'elenco degli elementi secondari dell'oggetto XML. Questo metodo agisce direttamente sul nodo a cui fa riferimento il parametro childNode; non aggiunge una copia del nodo. Se il nodo da aggiungere esiste già in un'altra struttura ad albero, quando lo si aggiunge alla nuova posizione viene rimosso dalla posizione corrente. Se il parametro childNode fa riferimento a un nodo che esiste già in un'altra struttura ad albero XML, il nodo secondario viene collocato nella nuova struttura ad albero dopo che è stato rimosso dal relativo nodo principale esistente.

Parametri

node:XMLNode — Un valore XMLNode che rappresenta il nodo da spostare dalla posizione corrente all'elenco degli elementi secondari dell'oggetto my_xml.

Altre informazioni

L'approccio E4X all'elaborazione XML

cloneNode

()

metodo

public function cloneNode(deep:Boolean):XMLNode

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Crea e restituisce un nuovo nodo XML con tipo, nome, valore e attributi uguali all'oggetto XML. Se deep è impostato su true, tutti i nodi secondari vengono clonati in modo ricorsivo e generano una copia esatta della struttura ad albero dell'oggetto originale.

Il clone del nodo che viene restituito non è più associato alla struttura ad albero dell'elemento clonato. Di conseguenza, nextSibling, parentNode e previousSibling hanno un valore null. Se il parametro deep è impostato su false o se il nodo my_xml non ha nodi secondari, firstChild e lastChild sono a loro volta null.

Parametri

deep:Boolean — Un valore booleano; se impostato su true, l'elemento secondario dell'oggetto XML specificato viene clonato in modo ricorsivo.

Restituisce

XMLNode — Un oggetto XMLNode.

getNamespaceForPrefix

()

metodo

public function getNamespaceForPrefix(prefix:String):String

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Restituisce l'URI dello spazio dei nomi associato al prefisso specificato per il nodo. Per determinare l'URI, getPrefixForNamespace() esegue la ricerca sulla gerarchia XML partendo dal nodo, come opportuno, e restituisce l'URI dello spazio dei nomi della prima dichiarazione xmlns per il prefix indicato.

Se non si definisce lo spazio dei nomi per il prefisso specificato, il metodo restituisce null.

Se specificate una stringa vuota ("") come prefix ed esiste uno spazio dei nomi definito per il nodo (come in xmlns="http://www.example.com/"), il metodo restituisce l'URI dello spazio dei nomi predefinito.

Parametri

prefix:String — Prefisso per il quale il metodo restituisce lo spazio dei nomi associato.

Restituisce

String — Lo spazio dei nomi che viene associato al prefisso specificato.

Elementi API correlati

XMLNode.getPrefixForNamespace()
XMLNode.namespaceURI

getPrefixForNamespace

()

metodo

public function getPrefixForNamespace(ns:String):String

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Restituisce il prefisso che è associato all'URI dello spazio dei nomi specificato per il nodo. Per determinare il prefisso, getPrefixForNamespace() esegue la ricerca sulla gerarchia XML partendo dal nodo, come opportuno, e restituisce il prefisso della prima dichiarazione xmlns con un URI dello spazio dei nomi corrispondente a ns.

Se all'URI non è associato xmlns, il metodo restituisce null. Se è presente un'associazione xmlns per l'URI in questione ma tale assegnazione non è associata a un prefisso, il metodo restituisce una stringa vuota ("").

Parametri

ns:String — L'URI dello spazio dei nomi per il quale il metodo restituisce il prefisso associato.

Restituisce

String — Il prefisso associato allo spazio dei nomi specificato.

Elementi API correlati

XMLNode.getNamespaceForPrefix()
XMLNode.namespaceURI

hasChildNodes

()

metodo

public function hasChildNodes():Boolean

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Indica che l'oggetto XMLNode specificato ha dei nodi secondari. Questa proprietà è true se l'oggetto XMLNode specificato ha elementi secondari; false in caso contrario.

Restituisce

Boolean — Restituisce true se l'oggetto XMLNode specificato ha dei nodi secondari; false in caso contrario.

insertBefore

()

metodo

public function insertBefore(node:XMLNode, before:XMLNode):void

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Inserisce un nuovo nodo secondario nell'elenco degli elementi secondari dell'oggetto XML, prima del nodo beforeNode. Se il parametro beforeNode è undefined o null, il nodo viene aggiunto mediante il metodo appendChild(). Se beforeNode non è un elemento secondario di my_xml, l'inserimento dà esito negativo.

Parametri

	`node:XMLNode` — L'oggetto XMLNode da inserire.

	`before:XMLNode` — L'oggetto XMLNode prima del punto di inserimento per `childNode`.

Elementi API correlati

XMLNode.cloneNode()

removeNode

()

metodo

public function removeNode():void

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Rimuove dall'elemento principale l'oggetto XML specificato. Inoltre, elimina tutti gli elementi discendenti del nodo.

toString

()

metodo

public function toString():String

Versione linguaggio:

ActionScript 3.0

Versioni runtime:

AIR 1.0, Flash Player 9, Flash Lite 4

Valuta l'oggetto XMLNode specificato, crea una rappresentazione testuale della struttura XML, compresi il nodo, gli elementi secondari e gli attributi, e restituisce il risultato sotto forma di stringa.

Per gli oggetti XMLDocument di primo livello (quelli creati con la funzione di costruzione), il metodo XMLDocument.toString() genera la dichiarazione XML del documento (memorizzata nella proprietà XMLDocument.xmlDecl), seguita dalla dichiarazione DOCTYPE (memorizzata nella proprietà XMLDocument.docTypeDecl), seguita dalla rappresentazione testuale di tutti i nodi XML dell'oggetto. La dichiarazione XML non viene generata se la proprietà XMLDocument.xmlDecl è null. La dichiarazione DOCTYPE non viene generata se la proprietà XMLDocument.docTypeDecl è null.

Restituisce

String — La stringa che rappresenta l'oggetto XMLNode.

Elementi API correlati

XMLDocument.docTypeDecl
XMLDocument.xmlDecl

Esempi Come utilizzare questo esempio

XMLDocumentExample.as

L'esempio seguente utilizza le classi XMLDocument e XMLNode per analizzare e formattare un documento XML. Anziché caricare un file XML esterno, l'esempio utilizza la classe XML di livello principale per creare un documento XML e quindi analizzarlo.

package {
    import flash.display.Sprite;
    import flash.xml.XMLDocument;
    import flash.xml.XMLNode;
    import flash.xml.XMLNodeType;

    public class XMLDocumentExample extends Sprite {
        public function XMLDocumentExample() {
            var result:XMLDocument = new XMLDocument();
            result.ignoreWhite = true;
            result.parseXML(getXMLString());

            var books:Array = parseBooks(result.firstChild);
            trace("books: \n" + books);
        }

        private function parseBooks(node:XMLNode):Array {
            var books:Array = new Array();

            var kids:Array = node.childNodes;
            for each(var item:XMLNode in kids) {
                parseBook(item, books);
            }

            return books;
        }

        private function parseBook(node:XMLNode, books:Array):void {
            var item:Book = new Book();
            item.setPublisher(node.attributes.publisher);
            item.setName(node.attributes.name);
            books.push(item);
        }

        private function getXMLString():String {
            var list:XML = <books>
                                <book publisher="Addison-Wesley" name="Design Patterns" />
                                <book publisher="Addison-Wesley" name="The Pragmatic Programmer" />
                                <book publisher="Addison-Wesley" name="Test Driven Development" />
                                <book publisher="Addison-Wesley" name="Refactoring to Patterns" />
                                <book publisher="O'Reilly Media" name="The Cathedral & the Bazaar" />
                                <book publisher="O'Reilly Media" name="Unit Test Frameworks" />
                            </books>;
            return list.toXMLString();
        }
    }

}
class Book {
    private var publisher:String;
    private var name:String;

    public function setPublisher(publisher:String):void {
        this.publisher = publisher;
    }

    public function setName(name:String):void {
        this.name = name;
    }

    public function toString():String {
        return "[Book name: " + name + " publisher: " + publisher + "]\n";
    }
}

Note legali | Informativa sulla privacy online

XMLNode - AS3

Pacchettix

Elementi del linguaggio

Appendici

Pacchetto flash.xml

attributes

childNodes

firstChild

lastChild

localName

namespaceURI

nextSibling

nodeName

nodeType

nodeValue

parentNode

prefix

previousSibling

XMLNode

appendChild

cloneNode

getNamespaceForPrefix

getPrefixForNamespace

hasChildNodes

insertBefore

removeNode

toString