XML  - AS3

Determina se i commenti XML vengono ignorati quando gli oggetti XML analizzano i dati XML di origine. Per impostazione predefinita, i commenti vengono ignorati (true). Per includere i commenti XML, impostate questa proprietà su false. La proprietà ignoreComments viene utilizzata solo durante l'analisi XML, non durante la chiamata a un metodo qualsiasi come myXMLObject.child(*).toXMLString(). Se l'XML di origine include dei nodi di commenti, vengono conservati o scartati durante l'analisi XML.

Elementi API correlati

XML.ignoreComments = false;
var xml1:XML = 
        <foo>
            <!-- comment -->
        </foo>;
trace(xml1.toXMLString()); // <foo><!-- comment --></foo>

XML.ignoreComments = true;
var xml2:XML = 
        <foo>
            <!-- example -->
        </foo>;
trace(xml2.toXMLString()); // <foo/>

Determina se le istruzioni di elaborazione XML vengono ignorate quando gli oggetti XML analizzano i dati XML di origine. Per impostazione predefinita, le istruzioni di elaborazione vengono ignorate (true). Per includere le istruzioni di elaborazione XML, impostate questa proprietà su false. La proprietà ignoreProcessingInstructions viene utilizzata solo durante l'analisi XML, non durante la chiamata a un metodo qualsiasi come myXMLObject.child(*).toXMLString(). Se l'XML di origine include dei nodi di istruzioni di elaborazione, vengono conservati o scartati durante l'analisi XML.

Elementi API correlati

XML.ignoreProcessingInstructions = false;
var xml1:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml1.toXMLString()); // <foo><?exampleInstruction ?></foo>

XML.ignoreProcessingInstructions = true;
var xml2:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml2.toXMLString()); // <foo/>

Determina se i caratteri di spazio all'inizio e alla fine dei nodi di testo vengono ignorati durante l'analisi. Per impostazione predefinita, lo spazio vuoto viene ignorato (true). Se un nodo di testo è composto al 100% da spazio vuoto e la proprietà ignoreWhitespace è impostata su true, il nodo non viene creato. Per mostrare lo spazio vuoto in un nodo di testo, impostate la proprietà ignoreWhitespace su false.

Quando create un oggetto XML, questo determina il valore corrente della proprietà ignoreWhitespace. Se si modifica il valore di ignoreWhitespace, il comportamento degli oggetti XML esistenti non cambia.

XML.ignoreWhitespace = false;
var xml1:XML = <foo>    </foo>;
trace(xml1.children().length()); // 1

XML.ignoreWhitespace = true;
var xml2:XML = <foo>    </foo>;
trace(xml2.children().length()); // 0

Determina la quantità di rientro applicato dai metodi toString() e toXMLString() quando la proprietà XML.prettyPrinting è impostata su true. Il rientro viene applicato con il carattere di spazio, non con il carattere di tabulazione. Il valore predefinito è 2.

Elementi API correlati

var xml:XML = <foo><bar/></foo>;
XML.prettyIndent = 0;
trace(xml.toXMLString());

XML.prettyIndent = 1;
trace(xml.toXMLString());

XML.prettyIndent = 2;
trace(xml.toXMLString());

Determina se i metodi toString() e toXMLString() normalizzano i caratteri di spazio vuoto tra alcuni tag. Il valore predefinito è true.

Elementi API correlati

var xml:XML = <foo><bar/></foo>;
XML.prettyPrinting = false;
trace(xml.toXMLString());

XML.prettyPrinting = true;
trace(xml.toXMLString());

Crea un nuovo oggetto XML. Dovete utilizzare la funzione di costruzione per creare un oggetto XML prima di chiamare i metodi della classe XML.

Utilizzate il metodo toXMLString() per restituire una rappresentazione in formato stringa dell'oggetto XML a prescindere dal tipo di contenuto (semplice o complesso) di quest'ultimo.

Altre informazioni

Elementi API correlati

//
// Requires:
//   - TextArea control UI component in the Flash Professional Library.
//
import fl.controls.TextArea;
 
var xml:XML;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
 
var urlLoader:URLLoader = new URLLoader();
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
var textArea:TextArea = new TextArea();
textArea.move(5, 5);
textArea.setSize(stage.stageWidth - 10, stage.stageHeight - 10);
addChild(textArea);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.currentTarget.data);
    textArea.text = xml.toXMLString();
}

var xml:XML;
var textArea:TextField = new TextField();
textArea.width = 300;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.target.data);
    textArea.text = xml.toXMLString();
    addChild(textArea);
}

Aggiunge uno spazio dei nomi al gruppo di spazi dei nomi validi per l'oggetto XML. Se lo spazio dei nomi esiste già negli spazi dei nomi validi dell'oggetto XML (con un prefisso che corrisponde a quello del parametro dato), il prefisso dello spazio dei nomi esistente viene impostato su undefined. Se il parametro di input è un oggetto Namespace, viene utilizzato direttamente. Se è un oggetto QName, l'URI del parametro di input viene utilizzato per creare un nuovo spazio dei nomi; in caso contrario, viene convertito in una stringa e da quest'ultima viene creato uno spazio dei nomi.

Parametri

Altre informazioni

var xml1:XML = <ns:foo xmlns:ns="www.example.com/ns" />;
var nsNamespace:Namespace = xml1.namespace();

var xml2:XML = <bar />;
xml2.addNamespace(nsNamespace);
trace(xml2.toXMLString()); // <bar xmlns:ns="www.example.com/ns"/>

Aggiunge l'elemento secondario dato alla fine delle proprietà dell'oggetto XML. Il metodo appendChild() accetta un oggetto XML, un oggetto XMLList o qualunque altro tipo di dati, che viene successivamente convertito in stringa.

Utilizzate l'operatore delete (XML) per rimuovere i nodi XML.

Parametri

Altri esempi

Altre informazioni

Elementi API correlati

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.appendChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>hello</p>
trace(xml.p[1].toXMLString()); // <p>world</p>

Restituisce il valore XML dell'attributo con il nome corrispondente al parametro attributeName. Gli attributi si trovano all'interno degli elementi XML. Nell'esempio seguente, l'elemento ha un attributo di nome "gender" con il valore "boy": <first gender="boy">John</first>.

Il parametro attributeName può essere di qualsiasi tipo di dati, tuttavia String è quello più comune. Quando si passa un oggetto diverso da un oggetto QName, il parametro attributeName utilizza il metodo toString() per convertire il parametro in una stringa.

Se vi occorre un riferimento a un nome completo, potete passare un oggetto QName. Un oggetto QName definisce uno spazio dei nomi e il nome locale, che serve per definire il nome completo di un attributo. Pertanto, una chiamata a attribute(qname) non equivale a una chiamata a attribute(qname.toString()).

Parametri

Altri esempi

Altre informazioni

Elementi API correlati

 var xml:XML = <ns:node xmlns:ns = "http://uri" ns:attr = '7' />       
 var qn:QName = new QName("http://uri", "attr");
 trace (xml.attribute(qn)); // 7

 var xml:XML = <example class="first" />
 trace(xml.attribute("class"));
 

Restituisce un elenco di valori di attributo per l'oggetto XML dato. Utilizzate il metodo name() con il metodo attributes() per restituire il nome di un attributo. L'uso di xml.attributes() equivale a xml.@*.

Altri esempi

Altre informazioni

Elementi API correlati

var xml:XML=<example id='123' color='blue'/>
trace(xml.attributes()[1].name()); //color

 
var xml:XML = <example id='123' color='blue'/>
var attNamesList:XMLList = xml.@*;

trace (attNamesList is XMLList); // true
trace (attNamesList.length()); // 2

for (var i:int = 0; i < attNamesList.length(); i++)
{ 
    trace (typeof (attNamesList[i])); // xml
    trace (attNamesList[i].nodeKind()); // attribute
    trace (attNamesList[i].name()); // id and color
} 

Elenca gli elementi secondari di un oggetto XML. Un elemento XML secondario è un elemento XML, un nodo di testo, un commento o un'istruzione di elaborazione.

Utilizzate il parametro propertyName per elencare il contenuto di un elemento XML secondario specifico. Ad esempio, per restituire il contenuto di un elemento secondario denominato <first>, chiamate child("first") sull'oggetto XML. Potete ottenere lo stesso risultato utilizzando il numero di indice dell'elemento secondario. Il numero di indice identifica la posizione dell'elemento secondario nell'elenco degli altri elementi XML secondari. Ad esempio, child(0) restituisce il primo elemento secondario in un elenco.

Utilizzate un asterisco (*) per produrre tutti gli elementi secondari in un documento XML. Ad esempio, doc.child("*").

Utilizzate il metodo length() con il parametro asterisco (*) del metodo child() per produrre il numero totale di elementi secondari. Ad esempio, numChildren = doc.child("*").length().

Parametri

Altri esempi

Altre informazioni

Elementi API correlati

var xml:XML = 
        <foo>
            <bar>text1</bar>
            <bar>text2</bar>
        </foo>;
trace(xml.child("bar").length());  // 2
trace(xml.child("bar")[0].toXMLString()); // <bar>text1</bar>
trace(xml.child("bar")[1].toXMLString()); // <bar>text2</bar>

Identifica la posizione di indice a base zero di questo oggetto XML nel contesto dei relativi elementi principali.

Altre informazioni

var xml:XML = 
            <foo>
                <bar />
                text
                <bob />
            </foo>;
trace(xml.bar.childIndex()); // 0
trace(xml.bob.childIndex()); // 2

Elenca gli elementi secondari dell'oggetto XML nella sequenza in cui compaiono. Un elemento XML secondario è un elemento XML, un nodo di testo, un commento o un'istruzione di elaborazione.

Altre informazioni

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var xml:XML = 
        <foo id="22">
            <bar>44</bar>
            text
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml.children().length()); // 4
trace(xml.children()[0].toXMLString()); // <bar>44</bar>
trace(xml.children()[1].toXMLString()); // text
trace(xml.children()[2].toXMLString()); // <!-- comment -->
trace(xml.children()[3].toXMLString()); // <?instruction ?>

Elenca le proprietà dell'oggetto XML che contengono commenti XML.

Altre informazioni

XML.ignoreComments = false;
var xml:XML = 
        <foo>
            <!-- example -->
            <!-- example2 -->
        </foo>;
trace(xml.comments().length()); // 2
trace(xml.comments()[1].toXMLString()); // <!-- example2 -->

Confronta l'oggetto XML con il parametro value dato.

Parametri

Altre informazioni

var xml:XML = 
        <order>
            <item>Rice</item>
            <item>Kung Pao Shrimp</item>
        </order>;
trace(xml.item[0].contains(<item>Rice</item>)); // true
trace(xml.item[1].contains(<item>Kung Pao Shrimp</item>)); // true
trace(xml.item[1].contains(<item>MSG</item>)); // false

Restituisce una copia dell'oggetto XML dato. La copia è un duplicato dell'intera struttura ad albero di nodi. L'oggetto XML copiato non ha un elemento principale e restituisce null se si tenta di chiamare il metodo parent().

Altre informazioni

var xml1:XML = <foo />;
var xml2:XML = xml1.copy();
xml2.appendChild(<bar />);
trace(xml1.bar.length()); // 0
trace(xml2.bar.length()); // 1

Restituisce un oggetto con le proprietà seguenti impostate sui valori predefiniti: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent e prettyPrinting. I valori predefiniti sono i seguenti:

• ignoreComments = true
• ignoreProcessingInstructions = true
• ignoreWhitespace = true
• prettyIndent = 2
• prettyPrinting = true

Nota: questo metodo non va applicato a un'istanza della classe XML, bensì a XML, come mostrato nel codice seguente: var df:Object = XML.defaultSettings().

Altre informazioni

Elementi API correlati

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

Restituisce tutti gli elementi discendenti (secondari, inferiori di due livelli, inferiori di tre livelli, e così via) dell'oggetto XML che hanno il parametro name dato. Il parametro name è opzionale. Il parametro name può essere un oggetto QName, un tipo di dati String o qualunque altro tipo di dati che viene successivamente convertito in un tipo di dati String.

Per restituire tutti gli elementi discendenti, utilizzate il parametro "*". Se non passate alcun parametro, viene passata la stringa "*" che restituisce tutti i discendenti dell'oggetto XML.

Parametri

Elementi API correlati

var xml:XML = 
  <enrollees>
    <student id="239">
        <class name="Algebra" />
        <class name="Spanish 2"/>
    </student>
    <student id="206">
        <class name="Trigonometry" />
        <class name="Spanish 2" />
    </student>
  </enrollees>
trace(xml.descendants("class")); 

XML.ignoreComments = false;
var xml:XML = 
        <body>
            <!-- comment -->
            text1
            <a>
                <b>text2</b>
            </a>
        </body>;
trace(xml.descendants("*").length()); // 5
trace(xml.descendants("*")[0]); // // <!-- comment -->
trace(xml.descendants("*")[1].toXMLString()); // text1
trace(xml.descendants("a").toXMLString()); // <a><b>text2</b></a>
trace(xml.descendants("b").toXMLString()); // <b>text2</b>

Elenca gli elementi di un oggetto XML. Un elemento è costituito da un tag iniziale e da un tag finale, come in <first></first>. Il parametro name è opzionale. Il parametro name può essere un oggetto QName, un tipo di dati String o qualunque altro tipo di dati che viene successivamente convertito in un tipo di dati String. Utilizzate il parametro name per elencare un elemento specifico. Nell'esempio seguente, l'elemento "first" restituisce "John": <first>John</first>.

Per elencare tutti gli elementi, utilizzate il parametro asterisco (*). L'asterisco è anche il parametro predefinito.

Utilizzate il metodo length() con il parametro asterisco per ottenere il numero totale di asterischi. Ad esempio, numElement = addressbook.elements("*").length().

Parametri

Altre informazioni

Elementi API correlati

var xml:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
            text
            <a>1</a>
            <b>2</b>
        </foo>;
trace(xml.elements("*").length()); // 2
trace(xml.elements("*")[0].toXMLString()); // <a>1</a>
trace(xml.elements("b").length()); // 1
trace(xml.elements("b")[0].toXMLString()); // <b>2</b>

var xml:XML =
 <student id="206">
    <class name="Trigonometry" />
    <class name="Spanish 2" />
 </student>
trace(xml.elements("class")); 

Verifica se nell'oggetto XML è presente del contenuto complesso. Un oggetto XML ha del contenuto complesso se contiene degli elementi secondari. Gli oggetti XML che rappresentano attributi, commenti, istruzioni di elaborazione e nodi di testo non hanno contenuto complesso. Tuttavia, è possibile considerare che in un oggetto che contiene questi elementi sia presente del contenuto complesso, nel caso abbia degli elementi secondari.

Altre informazioni

Elementi API correlati

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

Verifica se per l'oggetto la proprietà è specificata dal parametro p.

Parametri

Altre informazioni

var xml:XML = 
        <foo>
            <a />
            <a>
                <b>10</b>
            </a>
            <a>
                <b>11</b>
            </a>
        </foo>;
trace(xml.a.(hasOwnProperty("b") && b == "11")); 

trace(xml.a.(b == "11"));

var xml:XML = 
        <orders>
            <order id='1'>
                <item>toothbrush</item>
                <item>toothpaste</item>
            </order>
            <order>
                <returnItem>shoe polish</returnItem>
            </order>
        </orders>;
trace(xml.order.(hasOwnProperty("item") && item.contains("toothbrush"))); 

Verifica se nell'oggetto XML è presente del contenuto semplice. Un oggetto XML ha del contenuto semplice se rappresenta un nodo di testo, un nodo di attributi o un elemento XML privo di elementi secondari. Gli oggetti XML che rappresentano commenti e istruzioni di elaborazione non hanno contenuto semplice.

Altre informazioni

Elementi API correlati

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

Elenca gli spazi dei nomi per l'oggetto XML, in base all'elemento principale dell'oggetto.

Altre informazioni

Inserisce il parametro child2 dopo il parametro child1 in questo oggetto XML e restituisce l'oggetto risultante. Se il parametro child1 è null, il metodo inserisce il contenuto di child2 prima di tutti gli elementi secondari dell'oggetto XML (in altre parole, dopo none). Se child1 viene fornito ma non esiste nell'oggetto XML, l'oggetto XML non viene modificato e viene restituito undefined.

Se si chiama questo metodo su un elemento XML secondario che non è un elemento (testo, attributi, commenti, pi e così via), viene restituito undefined.

Utilizzate l'operatore delete (XML) per rimuovere i nodi XML.

Parametri

Altri esempi

Altre informazioni

Elementi API correlati

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildAfter(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

 <menu>
     <item>burger</item>
     <saleItem>fries</saleItem>
     <item>soda</item>
 </menu>

Inserisce il parametro child2 prima del parametro child1 in questo oggetto XML e restituisce l'oggetto risultante. Se il parametro child1 è null, il metodo inserisce il contenuto di child2 dopo tutti gli elementi secondari dell'oggetto XML (in altre parole, prima di none). Se child1 viene fornito ma non esiste nell'oggetto XML, l'oggetto XML non viene modificato e viene restituito undefined.

Se si chiama questo metodo su un elemento XML secondario che non è un elemento (testo, attributi, commenti, pi e così via), viene restituito undefined.

Utilizzate l'operatore delete (XML) per rimuovere i nodi XML.

Parametri

Altri esempi

Altre informazioni

Elementi API correlati

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildBefore(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

 <menu>
     <saleItem>fries</saleItem>
     <item>burger</item>
     <item>soda</item>
 </menu>

Per gli oggetti XML, questo metodo restituisce sempre l'intero 1. Il metodo length() della classe XMLList restituisce il valore 1 per un oggetto XMLList che contiene un solo valore.

Altre informazioni

Fornisce la porzione del nome locale del nome completo dell'oggetto XML.

Altre informazioni

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.localName()); // Envelope

Fornisce il nome completo per l'oggetto XML.

Altre informazioni

Elementi API correlati

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.name().localName); // Envelope
trace(xml.name().uri); // "http://www.w3.org/2001/12/soap-envelope"

var xml:XML = 
        <foo x="15" y="22">
            text
        </foo>;
        
trace(xml.name().localName); // foo
trace(xml.name().uri == ""); // true
trace(xml.children()[0]); // text
trace(xml.children()[0].name()); // null
trace(xml.attributes()[0]); // 15
trace(xml.attributes()[0].name()); // x

Se non specificate alcun parametro, fornisce lo spazio dei nomi associato al nome completo dell'oggetto XML. Se specificate un parametro prefix, il metodo restituisce lo spazio dei nomi che corrisponde al parametro prefix e che è nell'area di validità dell'oggetto XML. Se non viene trovato uno spazio dei nomi simile, il metodo restituisce undefined.

Parametri

Altre informazioni

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
var soap:Namespace = xml.namespace();
trace(soap.prefix); // soap
trace(soap.uri); // http://www.w3.org/2001/12/soap-envelope

var body:XML = xml.soap::Body[0];
trace(body.namespace().prefix); // soap
trace(xml.namespace().uri); // http://www.w3.org/2001/12/soap-envelope
trace(body.namespace("wx").uri); // "http://example.com/weather"

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">
                <!-- ... -->
        </rdf:RDF>;
                    
trace(xml.namespace()); // http://www.w3.org/1999/02/22-rdf-syntax-ns#
trace(xml.namespace("dc")); // http://purl.org/dc/elements/1.1/
trace(xml.namespace("foo")); // undefined

Elenca le dichiarazioni degli spazi dei nomi associate all'oggetto nel contesto del suo elemento principale.

Altre informazioni

Elementi API correlati

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">

            <!-- ... -->
            
        </rdf:RDF>;
                    
for (var i:uint = 0; i < xml.namespaceDeclarations().length; i++) {
    var ns:Namespace = xml.namespaceDeclarations()[i]; 
    var prefix:String = ns.prefix;
    if (prefix == "") {
        prefix = "(default)";
    }
    trace(prefix + ":" , ns.uri);
}

rdf: http://www.w3.org/1999/02/22-rdf-syntax-ns#
 dc: http://purl.org/dc/elements/1.1/
 (default): http://purl.org/rss/1.0/

Specifica il tipo di nodo: testo, commento, istruzione di elaborazione, attributo o elemento.

Altre informazioni

Elementi API correlati

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;

var xml:XML = 
    <example id="10">
        <!-- this is a comment -->
        <?test this is a pi ?>
        and some text
    </example>;

trace(xml.nodeKind()); // element
trace(xml.children()[0].nodeKind()); // comment
trace(xml.children()[1].nodeKind()); // processing-instruction
trace(xml.children()[2].nodeKind()); // text
trace(xml.@id[0].nodeKind()); // attribute

Per l'oggetto XML e tutti gli oggetti XML discendenti, unisce i nodi di testo adiacenti ed elimina i nodi di testo vuoti.

Altre informazioni

var xml:XML = <body></body>;
xml.appendChild("hello");
xml.appendChild(" world");
trace(xml.children().length()); // 2
xml.normalize();
trace(xml.children().length()); // 1

Restituisce l'elemento principale dell'oggetto XML. Se l'oggetto XML non ha un elemento principale, il metodo restituisce undefined.

Altri esempi

Altre informazioni

var xml:XML = 
    <body>
        <p id="p1">Hello</p>
        <p id="p2">Test:
            <ul>
                <li>1</li>
                <li>2</li>
            </ul>
        </p>
    </body>;
var node:XML = xml.p.ul.(li.contains("1"))[0]; // == <ul> ... </ul>
trace(node.parent().@id); // p2

Inserisce una copia dell'oggetto child fornito nell'elemento XML prima di qualunque proprietà XML esistente di tale elemento.

Utilizzate l'operatore delete (XML) per rimuovere i nodi XML.

Parametri

Altri esempi

Altre informazioni

Elementi API correlati

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.prependChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>world</p>
trace(xml.p[1].toXMLString()); // <p>hello</p>

Se specificate un parametro name, elenca tutti gli elementi secondari dell'oggetto XML che contengono le istruzioni di elaborazione con tale parametro name. In assenza di parametri, il metodo elenca tutti gli elementi secondari dell'oggetto XML che contengono delle eventuali istruzioni di elaborazione.

Parametri

Altre informazioni

XML.ignoreProcessingInstructions = false;
var xml:XML =
    <body>
            foo
            <?xml-stylesheet href="headlines.css" type="text/css" ?>
            <?instructionX ?>
            
    </body>;

trace(xml.processingInstructions().length()); // 2
trace(xml.processingInstructions()[0].name()); // xml-stylesheet

Verifica se la proprietà p fa parte del gruppo di proprietà di cui è possibile eseguire l'iterazione in un'istruzione for..in applicata all'oggetto XML. Restituisce true solo se toString(p) == "0".

Parametri

Altre informazioni

var xml:XML = 
        <body>
             <p>Hello</p>
               <p>World</p>
        </body>;

trace(xml.propertyIsEnumerable(0)); // true
trace(xml.propertyIsEnumerable(1)); // false

for (var propertyName:String in xml) {
    trace(xml[propertyName]);
}

var list:XMLList = xml.p;
trace(list.propertyIsEnumerable(0)); // true
trace(list.propertyIsEnumerable(1)); // true
trace(list.propertyIsEnumerable(2)); // false

for (var propertyName:String in list) { 
    trace(list[propertyName]);
}

Rimuove lo spazio dei nomi dato per l'oggetto e tutti i suoi elementi discendenti. Il metodo removeNamespaces() non rimuove uno spazio dei nomi se a esso fa riferimento il nome completo dell'oggetto o il nome completo degli attributi dell'oggetto.

Parametri

Altre informazioni

var xml:XML = 
    <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
        xmlns:dc="http://purl.org/dc/elements/1.1/" 
        xmlns="http://purl.org/rss/1.0/">
    
        <!-- ... -->
        
    </rdf:RDF>;

trace(xml.namespaceDeclarations().length); // 3
trace(xml.namespaceDeclarations()[0] is String); // 
var dc:Namespace = xml.namespace("dc");
xml.removeNamespace(dc);
trace(xml.namespaceDeclarations().length); // 2

Sostituisce le proprietà specificate dal parametro propertyName con il parametro value dato. Se nessuna proprietà corrisponde a propertyName, l'oggetto XML viene lasciato invariato.

Parametri

Altre informazioni

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace(1, <p>Bob</p>);
trace(xml);

 <body>
     <p>Hello</p>
     <p>Bob</p>
     <hr/>
 </body>
 

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("p", <p>Hi</p>); 
trace(xml);

 <body>
     <p>Hi</p>
     <hr/>
 </body>;
 

var xml:XML = 
    <ns:body xmlns:ns = "myNS">
        <ns:p>Hello</ns:p>
        <ns:p>World</ns:p>
        <hr/>
    </ns:body>;

var qname:QName = new QName("myNS", "p");
xml.replace(qname, <p>Bob</p>);
trace(xml);

 <ns:body xmlns:ns = "myNS">
     <p>Bob</p>
     <hr/>
 </ns:body>
 

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("*", <img src = "hello.jpg"/>);
trace(xml);

 <body>
     <img src="hello.jpg"/>
 </body>
 

Sostituisce le proprietà secondarie dell'oggetto XML con il gruppo specificato di proprietà XML fornito nel parametro value.

Parametri

Altre informazioni

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
    </body>;

var list:XMLList = xml.p;

xml.setChildren(<p>hello</p>);
trace(xml);

//    <body>
//        <p>hello</p>
//    </body>

xml.setChildren(list);
trace(xml);

//    <body>
//        <p>Hello</p>
//        <p>World</p>
//    </body>

Sostituisce il nome locale dell'oggetto XML con il parametro name dato.

Parametri

Altre informazioni

var xml:XML = 
    <ns:item xmlns:ns="http://example.com">
        toothbrush
    </ns:item>;
    
xml.setLocalName("orderItem");
trace(xml.toXMLString()); // <ns:orderItem xmlns:ns="http://example.com">toothbrush</ns:orderItem>

Imposta il nome dell'oggetto XML sul nome completo o sul nome di attributo dato.

Parametri

Altre informazioni

var xml:XML = 
    <item>
        toothbrush
    </item>;
    
xml.setName("orderItem");
trace(xml.toXMLString()); // <orderItem>toothbrush</orderItem>

Imposta lo spazio dei nomi associato all'oggetto XML.

Parametri

Altre informazioni

var xml1:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
            <!-- ... -->
        </soap:Envelope>;
var ns:Namespace = xml1.namespace("soap");

var xml2:XML = 
    <Envelope>
        <Body/>
    </Envelope>;
    
xml2.setNamespace(ns);

trace(xml2);

Imposta i valori per le proprietà XML seguenti: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent e prettyPrinting. Di seguito sono indicate le proprietà predefinite, che vengono applicate se non viene fornito alcun parametro setObj:

• XML.ignoreComments = true
• XML.ignoreProcessingInstructions = true
• XML.ignoreWhitespace = true
• XML.prettyIndent = 2
• XML.prettyPrinting = true

Nota: questo metodo non va applicato a un'istanza della classe XML, bensì a XML, come nel codice XML.setSettings().

Parametri

Altre informazioni

Elementi API correlati

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

Recupera le proprietà seguenti: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent e prettyPrinting.

Elementi API correlati

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

Restituisce un oggetto XMLList di tutte le proprietà XML dell'oggetto XML che rappresentano i nodi di testo XML.

Altre informazioni

var xml:XML =
        <body>
            text1
            <hr/>
            text2
        </body>;
trace(xml.text()[0]); // text1
trace(xml.text()[1]); // text2

Fornisce un metodo sostituibile per personalizzare la codifica JSON dei valori in un oggetto XLM.

Il metodo JSON.stringify() cerca un metodo toJSON() in ogni oggetto che ricerca. Se il metodo toJSON() viene rilevato, JSON.stringify() lo chiama per ogni valore che incontra, trasmettendo la chiave accoppiata al valore.

XLM fornisce un'implementazione predefinita di toJSON() che restituisce semplicemente il nome della classe. I clienti che desiderano esportare oggetti XLM in JSON devono fornire una loro implementazione. Potete eseguire questa operazione ridefinendo il metodo toJSON() sul prototipo della classe.

Il metodo toJSON() è in grado di restituire qualsiasi tipo di valore. Se viene restituito un oggetto, stringify() esegue la ricorsione all'interno di tale oggetto. Se toJSON() restituisce una stringa, stringify() non esegue alcuna ricorsione e continua la ricerca.

Parametri

Altre informazioni

Elementi API correlati

Restituisce la rappresentazione in formato stringa dell'oggetto XML. Le regole per questa conversione dipendono dal fatto che nell'oggetto XML sia presente del contenuto complesso o del contenuto semplice:

• Se nell'oggetto XML è presente un contenuto semplice, toString() restituisce il contenuto di formato String dell'oggetto XML senza gli elementi seguenti: il tag iniziale, gli attributi, le dichiarazioni degli spazi dei nomi e il tag finale.

• Se nell'oggetto XML è presente un contenuto complesso, toString() restituisce un oggetto String con codifica XML che rappresenta l'intero oggetto XML, compresi il tag iniziale, gli attributi, le dichiarazioni degli spazi dei nomi e il tag finale.

Per restituire ogni volta l'intero oggetto XML, utilizzate toXMLString().

Altri esempi

Elementi API correlati

var test:XML = <type name="Joe">example</type>;
trace(test.toString()); //example

var test:XML = 
<type name="Joe">
    <base name="Bob"></base>
    example
</type>;
trace(test.toString());
  // <type name="Joe">
  // <base name="Bob"/>
  // example
  // </type> 

Restituisce la rappresentazione in formato stringa dell'oggetto XML. A differenza del metodo toString(), il metodo toXMLString() restituisce sempre il tag iniziale, gli attributi e il tag finale dell'oggetto XML, a prescindere dal contenuto (semplice o complesso) dell'oggetto XML. Il metodo toString() esclude questi elementi negli oggetti XML con contenuto semplice.

Altri esempi

Altre informazioni

Elementi API correlati

var xml:XML =
        <p>hello</p>;
trace(xml); // hello
trace(xml.toXMLString()); // <p>hello</p>

Restituisce l'oggetto XML.

Altre informazioni

var xml:XML = <p>hello</p>;
trace(xml.valueOf() === xml); // true