Assemblaggio e trasformazione di oggetti XML

Flash Player 9 e versioni successive, Adobe AIR 1.0 e versioni successive

Usate il metodo prependChild() o il metodo appendChild() per aggiungere una proprietà all'inizio o alla fine dell'elenco proprietà di un oggetto XML, come illustrato nell'esempio seguente: 

var x1:XML = <p>Line 1</p>  
var x2:XML = <p>Line 2</p>  
var x:XML = <body></body> 
x = x.appendChild(x1); 
x = x.appendChild(x2); 
x = x.prependChild(<p>Line 0</p>); 
    // x == <body><p>Line 0</p><p>Line 1</p><p>Line 2</p></body>

Usate il metodo insertChildBefore() o il metodo insertChildAfter() per aggiungere una proprietà prima o dopo la proprietà specificata, nel modo seguente: 

var x:XML =  
    <body> 
        <p>Paragraph 1</p>  
        <p>Paragraph 2</p> 
    </body> 
var newNode:XML = <p>Paragraph 1.5</p>  
x = x.insertChildAfter(x.p[0], newNode) 
x = x.insertChildBefore(x.p[2], <p>Paragraph 1.75</p>)

Come illustrato dall'esempio seguente, potete anche utilizzare gli operatori parentesi graffe ( { e } ) per passare dati in base al riferimento (da altre variabili) durante la costruzione di oggetti XML: 

var ids:Array = [121, 122, 123];  
var names:Array = [["Murphy","Pat"], ["Thibaut","Jean"], ["Smith","Vijay"]] 
var x:XML = new XML("<employeeList></employeeList>"); 
 
for (var i:int = 0; i < 3; i++) 
{ 
    var newnode:XML = new XML();  
    newnode = 
        <employee id={ids[i]}> 
            <last>{names[i][0]}</last> 
            <first>{names[i][1]}</first> 
        </employee>; 
 
    x = x.appendChild(newnode) 
}

Si possono assegnare proprietà e attributi a un oggetto XML usando l'operatore = , come nell'esempio seguente: 

var x:XML =  
    <employee> 
        <lastname>Smith</lastname> 
    </employee> 
x.firstname = "Jean"; 
x.@id = "239";

In questo modo x dell'oggetto XML viene impostato su: 

<employee id="239"> 
    <lastname>Smith</lastname> 
    <firstname>Jean</firstname> 
</employee>

È possibile usare gli operatori + e += per concatenare oggetti XMLList: 

var x1:XML = <a>test1</a>  
var x2:XML = <b>test2</b>  
var xList:XMLList = x1 + x2; 
xList += <c>test3</c>

In questo modo xList dell'oggetto XMLList viene impostato su: 

<a>test1</a> 
<b>test2</b> 
<c>test3</c>