Inizializzazione delle variabili XML

Flash Player 9 e versioni successive, Adobe AIR 1.0 e versioni successive

Potete assegnare un letterale XML a un oggetto XML nel modo descritto di seguito:

var myXML:XML =  
    <order> 
        <item id='1'> 
            <menuName>burger</menuName> 
            <price>3.95</price> 
        </item> 
        <item id='2'> 
            <menuName>fries</menuName> 
            <price>1.45</price> 
        </item> 
    </order>

Come illustrato nello snippet di codice seguente, potete usare anche la funzione di costruzione new per creare un'istanza di un oggetto XML partendo da una stringa che contiene dati XML:

var str:String = "<order><item id='1'><menuName>burger</menuName>" 
                            + "<price>3.95</price></item></order>"; 
var myXML:XML = new XML(str);

Se i dati XML della stringa non hanno una sintassi corretta (se manca, ad esempio, un tag di chiusura), viene generato un errore in fase di runtime.

Si possono anche passare dati in base al riferimento (da altre variabili) a un oggetto XML, come illustrato nell'esempio seguente:

var tagname:String = "item";  
var attributename:String = "id";  
var attributevalue:String = "5";  
var content:String = "Chicken";  
var x:XML = <{tagname} {attributename}={attributevalue}>{content}</{tagname}>;  
trace(x.toXMLString()) 
    // Output: <item id="5">Chicken</item>

Per caricare dei dati XML da un URL, usate la classe URLLoader, come illustrato nell'esempio seguente:

import flash.events.Event; 
import flash.net.URLLoader; 
import flash.net.URLRequest; 
 
var externalXML:XML; 
var loader:URLLoader = new URLLoader(); 
var request:URLRequest = new URLRequest("xmlFile.xml"); 
loader.load(request); 
loader.addEventListener(Event.COMPLETE, onComplete); 
 
function onComplete(event:Event):void 
{ 
    var loader:URLLoader = event.target as URLLoader; 
    if (loader != null) 
    { 
        externalXML = new XML(loader.data); 
        trace(externalXML.toXMLString()); 
    } 
    else 
    { 
        trace("loader is not a URLLoader!"); 
    } 
}

Per leggere i dati XML da una connessione socket, usate la classe XMLSocket. Per ulteriori informazioni, vedete la classe XMLSocket nella Guida di riferimento di Adobe ActionScript 3.0 per la piattaforma Adobe Flash .