QName  - AS3

Il nome locale dell'oggetto QName.

L'URI (Uniform Resource Identifier) dell'oggetto QName.

Crea un oggetto QName che è la copia di un altro oggetto QName. Se il parametro passato alla funzione di costruzione è un oggetto QName, viene creata una copia dell'oggetto QName. Se il parametro non è un oggetto QName, il parametro viene convertito in una stringa e assegnato alla proprietà localName della nuova istanza QName. Se il parametro è undefined o non è specificato, viene creato un nuovo oggetto QName con la proprietà localName impostata sulla stringa vuota.

Nota: questa classe mostra due voci di costruzione poiché ogni forma accetta dei parametri diversi. La funzione di costruzione si comporta in modo diverso a seconda del tipo e del numero di parametri passati, come spiegato in dettaglio per ogni voce. ActionScript 3.0 non supporta l'overload dei metodi o delle funzioni di costruzione.

Crea un oggetto QName con un parametro URI tratto da un oggetto Namespace e un parametro localName tratto da un oggetto QName. Se uno dei due parametri non è del tipo di dati previsto, il parametro viene convertito in una stringa e assegnato alla proprietà corrispondente del nuovo oggetto QName. Ad esempio, se entrambi i parametri sono stringhe, viene restituito un nuovo oggetto QName con una proprietà uri impostata sul primo parametro e una proprietà localName impostata sul secondo. In altre parole, le permutazioni seguenti (insieme a molte altre) sono forme valide della funzione di costruzione:

QName (uri:Namespace, localName:String);
QName (uri:String, localName: QName);
QName (uri:String, localName: String);

Se passate null per il parametro uri, la proprietà uri del nuovo oggetto QName viene impostata su null.

Nota: questa classe mostra due voci di costruzione poiché ogni forma accetta dei parametri diversi. La funzione di costruzione si comporta in modo diverso a seconda del tipo e del numero di parametri passati, come spiegato in dettaglio per ogni voce. ActionScript 3.0 non supporta l'overload dei metodi o delle funzioni di costruzione.

Restituisce una stringa composta dall'URI e dal nome locale dell'oggetto QName, separati da "::".

Il formato dipende dalla proprietà uri dell'oggetto QName:

If uri == "" 
		toString returns localName
	else if uri == null
		toString returns *::localName 
	else
		toString returns uri::localName

Restituisce l'oggetto QName.

1. Creazione di un'istanza Namespace da utilizzare come input nella funzione di costruzione QName. Questo approccio è la soluzione ideale se si desidera utilizzare la proprietà Namespace.prefix in futuro per altre finalità.
2. Creazione di un'istanza QName assegnando un valore di stringa semplice al parametro uri nella funzione di costruzione QName.

Il codice esegue le seguenti operazioni:

1. Definisce una variabile XML denominata rssXML.
2. Crea un nuovo oggetto Namespace con il prefisso dc.
3. Crea un nuovo oggetto QName mediante l'oggetto Namespace e il nome locale creator.
4. Chiama il metodo showDescendants() che utilizza il metodo XML.descendants() per ottenere un'istanza XMLList contenente tutti gli elementi discendenti il cui nome completo corrisponde all'istanza QName data.
5. Visualizza il nome completo e il valore di testo di ogni elemento dell'elenco mediante un ciclo for each.
6. Crea un altro oggetto QName utilizzando un valore di stringa per il parametro uri e il nome locale date.
7. Chiama di nuovo il metodo showDescendants() per visualizzare il nome e il valore di testo degli elementi discendenti.

package
{
    import flash.display.Sprite;
    
    public class QNameExample extends Sprite
    {
        public function QNameExample()
        {
            var rssXML:XML =  <rdf:RDF
              xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
              xmlns="http://purl.org/rss/1.0/"
              xmlns:dc="http://purl.org/dc/elements/1.1/">
              <channel rdf:about="http://www.xml.com/cs/xml/query/q/19">
                <title>Test RSS</title>
                <link>http://www.adobe.com/</link>
                <description>This is a test RSS document.</description>
                <language>en-us</language>
                <items>
                  <rdf:Seq>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flash/"/>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flex/"/>
                  </rdf:Seq>
                </items>
              </channel>
              <item rdf:about="http://www.adobe.com/devnet/flash/">
                <title>Flash Developer Center</title>
                <link>http://www.adobe.com/devnet/flash/</link>
                <description>Welcome to the Flash Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-08-08</dc:date>    
              </item>
              <item rdf:about="http://www.adobe.com/devnet/flex/">
                <title>Flex Developer Center</title>
                <link>http://www.adobe.com/devnet/flex/</link>
                <description>Welcome to the Flex Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-10-16</dc:date>    
              </item>
            </rdf:RDF>;
            
            var dcNamespace:Namespace = new Namespace("dc", "http://purl.org/dc/elements/1.1/");
            var creatorQName:QName = new QName(dcNamespace, "creator");
            trace(creatorQName.uri); // http://purl.org/dc/elements/1.1/
            trace(creatorQName.localName); // creator
            
            showDescendants(rssXML, creatorQName);
            
            var dateQName:QName = new QName("http://purl.org/dc/elements/1.1/", "date");
            trace(dateQName.uri); // http://purl.org/dc/elements/1.1/
            trace(dateQName.localName); // date
            
            showDescendants(rssXML, dateQName);
        }
        
        public function showDescendants(xmlData:XML, qualifiedName:QName):void
        {
            var decendantList:XMLList = xmlData.descendants(qualifiedName);
            
            for each (var element:XML in decendantList)
            {
                trace(element.name()); // the fully qualified name, 
                                       // like "http://purl.org/dc/elements/1.1/::creator"
                trace(element); // the simple text value of each element, like "Adobe"
            }                
        }
    }
}