TextFormat  - AS3

Indica l'allineamento del paragrafo. I valori validi sono costanti di TextFormatAlign.

Il valore predefinito è TextFormatAlign.LEFT.

Elementi API correlati

Indica il rientro del blocco di testo espresso in punti. Il rientro del blocco viene applicato all'intero blocco di testo, ovvero a tutte le righe. Al contrario, il rientro normale (TextFormat.indent) agisce solo sulla prima riga di ogni paragrafo. Se la proprietà è null, per l'oggetto TextFormat non è specificato il rientro del blocco di testo (il valore del rientro è 0).

Indica se il testo è in grassetto. Il valore predefinito è null e indica che il grassetto non viene utilizzato. Il valore true indica che il testo è in grassetto.

Indica se il testo fa parte di un elenco puntato. In un elenco puntato, ogni paragrafo di testo è rientrato. A sinistra della prima riga di ogni paragrafo è visualizzato un punto o un simbolo equivalente. Il valore predefinito è null e indica che non viene utilizzato alcun elenco puntato.

Indica il colore del testo. Un numero che contiene tre componenti RGB a 8 bit; ad esempio, 0xFF0000 corrisponde al rosso e 0x00FF00 corrisponde al verde. Il valore predefinito è null e indica che Flash Player utilizza il colore nero (0x000000).

Il nome del carattere del testo a cui è applicata questa formattazione, sotto forma di stringa. Il valore predefinito è null e indica che Flash Player utilizza il carattere Times New Roman per il testo.

Indica il rientro esistente tra il margine sinistro e il primo carattere del paragrafo. Il valore predefinito è null e indica che non viene utilizzato alcun rientro.

Elementi API correlati

Indica se il testo con questa formattazione è corsivo. Il valore predefinito è null e indica che il corsivo non viene utilizzato.

Un valore booleano che indica se la crenatura è attivata (true) o meno (false). La crenatura consente di regolare i pixel tra alcune coppie di caratteri per migliorare la leggibilità e dovrebbe essere utilizzata soltanto in caso di necessità, ad esempio per le intestazioni con caratteri di grandi dimensioni. La crenatura è supportata solo per i caratteri incorporati.

Alcuni caratteri, quali Verdana, e i caratteri a spaziatura fissa, come Courier New, non supportano la crenatura.

Il valore predefinito è null e indica che la crenatura non è abilitata.

Un numero intero che rappresenta la quantità di spazio verticale in pixel (definita interlinea) presente tra le righe. Il valore predefinito è null e indica che viene utilizzata un'interlinea pari a 0.

Il margine sinistro del paragrafo, espresso in pixel. Il valore predefinito è null e indica che il margine sinistro è pari a 0 pixel.

Numero intero che rappresenta la quantità di spazio distribuito uniformemente tra tutti i caratteri. Il valore specifica il numero di pixel aggiunti all'avanzamento dopo ogni carattere. Il valore predefinito è null e indica che viene utilizzata una spaziatura tra lettere pari a 0 pixel. È possibile utilizzare valori decimali quali 1,75.

Il margine destro del paragrafo, espresso in pixel. Il valore predefinito è null e indica che il margine destro è pari a 0 pixel.

Le dimensioni in pixel del testo con questa formattazione. Il valore predefinito è null e indica che viene utilizzata una dimensione pari a 12.

Specifica gli spazi di tabulazione personalizzati sotto forma di un array di numeri interi non negativi. Ogni spazio di tabulazione è specificato in pixel. Se non vengono specificati spazi di tabulazione personalizzati (null), lo spazio di tabulazione predefinito è 4 (larghezza media dei caratteri).

Indica la finestra target in cui viene visualizzato il collegamento ipertestuale. Se la finestra target è una stringa vuota, il testo viene visualizzato nella finestra target predefinita _self. È possibile scegliere un nome personalizzato o uno dei quattro seguenti: _self specifica il frame corrente nella finestra corrente, _blank indica una nuova finestra, _parent specifica l'elemento principale del frame corrente, mentre _top indica il frame di primo livello nella finestra corrente. Se la proprietà TextFormat.url è una stringa vuota o è null, è comunque possibile ottenerla o impostarla ma la proprietà non avrà effetto.

Elementi API correlati

Indica se il testo che utilizza questa formattazione è sottolineato (true) o meno (false). Questa sottolineatura è simile a quella ottenuta mediante il tag <U>, ma quest'ultimo non rappresenta una vera e propria sottolineatura poiché non salta i discendenti in modo corretto. Il valore predefinito è null e indica che la sottolineatura non viene utilizzata.

Indica l'URL di destinazione per il testo con questa formattazione. Se url è una stringa vuota, il testo non ha un collegamento ipertestuale. Il valore predefinito è null, che indica che il testo non ha un collegamento ipertestuale.

Nota: per far sì che il collegamento ipertestuale funzioni, il testo con la formattazione assegnata deve essere impostato con la proprietà htmlText.

Elementi API correlati

Crea un oggetto TextFormat con tutte le proprietà specificate. È possibile modificare successivamente le proprietà dell'oggetto TextFormat per modificare la formattazione dei campi di testo.

È possibile impostare qualunque parametro su null per indicare che è undefined. Tutti i parametri sono opzionali; un parametro omesso viene considerato null.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.text.TextFormatAlign;
    
    public class TextFormat_constructorExample extends Sprite {
        private var contentTextField:TextField = new TextField();
        private var formatTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();
        
        public function TextFormat_constructorExample() {
            contentTextField.x = 10;
            contentTextField.y = 10;
            contentTextField.background = true;
            contentTextField.border = true;
            contentTextField.multiline = true;
            contentTextField.wordWrap = true;
            contentTextField.selectable = false;
            contentTextField.width = 250;
            contentTextField.height = 120; 
  
            contentTextField.htmlText = "<p>The TextFormat class represents character formatting "
                + "information. Use the TextFormat class to create specific text formatting "
                + "for text fields." + 
                " </p><br>" + "\tTab One" + "\tTab Two<br>";
              
            formatTextField.x = 10;
            formatTextField.y = 140;
            formatTextField.background = true;
            formatTextField.border = true;
            formatTextField.autoSize = TextFieldAutoSize.LEFT;
            
            formatTextField.text = "align: right\n" + "blockIndent: 10 pixels\n" + "bold:\n" + "bullet:\n" + "color: red\n"
                                + "font: Arial\n" + "indent: 20 pixels\n" + "italic:\n" + "leading: 5 spaces\n" 
                                + "leftMargin: 20 pixels\n" + "letterSpacing: 4 pixels\n" + "rightMargin: 20 pixels\n" 
                                + "size: 16 point\n" + "target: new window\n" + "tabStops: 50 and 150 pixel\n" 
                                + "underline:\n" + "url: Adobe Flex page\n";

            formatTextField.addEventListener(MouseEvent.CLICK, formatTextFieldClickHandler);
            
            contentTextField.addEventListener(MouseEvent.CLICK, contentTextFieldClickHandler);
            
            this.addChild(contentTextField);
            this.addChild(formatTextField);
        }

        private function formatTextFieldClickHandler(e:MouseEvent):void {
                var value:String= "";
                var i:uint = 0;
                var index:int = formatTextField.getLineIndexAtPoint(e.localX, e.localY);
                var line:String = formatTextField.getLineText(index);;

                line = line.substr(0, (line.indexOf(":")));

                switch(line) {
                    case "align":
                        newFormat.align = TextFormatAlign.RIGHT;
                        break;
                    case "blockIndent":
                        newFormat.blockIndent = 10;
                        break;
                    case "bold":
                        newFormat.bold = true;
                        break;
                    case "bullet":
                        newFormat.bullet = true;
                        break;
                    case "color":
                        newFormat.color = 0xFF0000;        
                        break;
                    case "font":
                        newFormat.font = "Arial";
                        break;
                    case "indent":
                        newFormat.indent = 20;
                        break;
                    case "italic":
                        newFormat.italic = true;
                        break;
                    case "leading":
                        newFormat.leading = 5;
                        break;
                    case "leftMargin":
                        newFormat.leftMargin = 20;
                        break;
                    case "letterSpacing":
                        newFormat.letterSpacing = 4;
                        break;
                    case "rightMargin":
                        newFormat.rightMargin = 20;
                        break;
                    case "size":
                        newFormat.size = 16;
                        break;
                    case "tabStops":                
                        newFormat.tabStops = [50, 150];
                        break;
                    case "target":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        newFormat.target = "_blank";
                        break;    
                    case "underline":
                        newFormat.underline = true;
                        break;
                    case "url":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        break;
                }    

                contentTextField.setTextFormat(newFormat);
        }

        private function contentTextFieldClickHandler(e:MouseEvent):void {
            contentTextField.setTextFormat(contentTextField.defaultTextFormat);
            newFormat = contentTextField.defaultTextFormat;
        }
    }
}

1. Viene creata una proprietà label di tipo TextField.
2. La funzione di costruzione della classe chiama la funzione configureLabel().
3. La funzione configureLabel() crea innanzitutto un nuovo oggetto TextField e lo assegna alla proprietà label, quindi imposta i relativi parametri nel modo seguente:
   • Campo di testo giustificato a sinistra
   • Riempimento di sfondo abilitato
   • Bordo abilitato.
4. Quindi, configureLabel() crea la variabile locale format e la assegna a una nuova istanza TextFormat con i parametri impostati nel modo seguente:
   • Tipo di carattere = Verdana
   • Colore del carattere = rosso uniforme
   • Dimensioni del carattere = 10
   • Sottolineatura = true
5. La proprietà defaultTextFormat dell'etichetta viene impostata su format e l'istanza label viene aggiunta all'elenco di visualizzazione, nel quale viene inizialmente visualizzato un campo di testo privo di testo (un quadratino con sfondo bianco) sullo stage.
6. Infine, nella funzione di costruzione, il testo dell'etichetta viene impostato per la visualizzazione del testo "Hello World and welcome to the show", con le coordinate x = 0, y = 0, mediante una chiamata a setLabel().

 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFormatExample extends Sprite {
        private var label:TextField;

        public function TextFormatExample() {
            configureLabel();
            setLabel("Hello World and welcome to the show");
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}