Object  - AS3

Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie. Wanneer een object een instantie van een klasse is, bevat de eigenschap constructor een verwijzing naar het klasseobject. Wanneer een object is gemaakt met een constructorfunctie, bevat de eigenschap constructor een verwijzing naar de constructorfunctie. Haal een constructorfunctie en een constructormethode van een klasse niet door elkaar. Een constructorfunctie is een object Function dat wordt gebruikt om objecten te maken en biedt een alternatief voor het trefwoord class dat wordt gebruikt om klassen te definiëren.

Wanneer u het trefwoord class gebruikt om een klasse te definiëren, wordt aan het prototypeobject van de klasse een eigenschap met de naam constructor toegewezen, die een verwijzing naar het klasseobject bevat. Een instantie van de klasse overerft deze eigenschap van het prototypeobject. De volgende code maakt bijvoorbeeld de nieuwe klasse A en een klasseinstantie met de naam myA:

     dynamic class A {}
     trace(A.prototype.constructor);      // [class A]
     trace(A.prototype.constructor == A); // true
     var myA:A = new A();
     trace(myA.constructor == A);         // true

Gevorderde gebruikers kunnen voor het trefwoord function kiezen in plaats van voor het trefwoord class om een object Function te definiëren dat als een sjabloon kan worden gebruikt voor het maken van objecten. Een dergelijke functie wordt een constructorfunctie genoemd omdat u deze samen met de operator new kunt gebruiken om objecten te maken. Wanneer u het trefwoord function gebruikt om een constructorfunctie te maken, wordt aan het prototypeobject een eigenschap met de naam constructor toegewezen, die een verwijzing naar de constructorfunctie bevat. Wanneer u vervolgens de constructorfunctie gebruikt om een object te maken, overerft het object de eigenschap constructor van het prototypeobject van de constructorfunctie. De volgende code maakt bijvoorbeeld de nieuwe constructorfunctie f en een object met de naam myF:

     function f() {}
     trace(f.prototype.constructor);      // function Function() {}
     trace(f.prototype.constructor == f); // true
     var myF = new f();
     trace(myF.constructor == f);         // true

Opmerking: de eigenschap constructor is beschrijfbaar, wat inhoudt dat de gebruikerscode zijn waarde door middel van een toewijzigingsinstructie kan wijzigen. Het wijzigen van de waarde van constructor wordt niet aangeraden, maar wanneer u code schrijft die afhankelijk is van de waarde van de eigenschap constructor, moet u ervoor zorgen dat de waarde niet wordt hersteld. De waarde kan alleen worden gewijzigd wanneer via het prototypeobject toegang wordt verkregen tot de eigenschap (bijvoorbeeld className.prototype.constructor).

Als u toegang krijgt tot de eigenschap constructor en in de strikte modus compileert, wordt een fout weergegeven tijdens het compileren omdat de eigenschap constructor afhankelijk is van het object prototype, een runtime-entiteit. Als u de standaardmodus gebruikt of als de klassebeschrijving "dynamisch" opgeeft, wordt de code geretourneerd zonder dat een fout wordt gegenereerd.

Verwante API-elementen

Een verwijzing naar het prototypeobject van een klasse of functieobject. De eigenschap prototype wordt automatisch gemaakt en gekoppeld aan de klasse of functieobject die u maakt. Deze eigenschap is statisch in die zin dat deze specifiek is voor de klasse of functie die u maakt. Wanneer u bijvoorbeeld een klasse maakt, wordt de waarde van de eigenschap prototype gedeeld door alle instanties van de klasse en is deze alleen toegankelijk als een klasse-eigenschap. Instanties van de klasse hebben niet direct toegang tot de eigenschap prototype.

Een prototypeobject van een klasse is een speciale instantie van de klasse die een methode biedt waarmee een status door alle instanties van een klasse kan worden gedeeld. Wanneer bij uitvoering een eigenschap niet wordt gevonden op een klasse-instantie, wordt de gedelegeerde (het prototypeobject van de klasse) voor die eigenschap gecontroleerd. Wanneer het prototype-object de eigenschap niet bevat, gaat het proces door via het controleren van de gedelegeerde van het prototype-object op een steeds hoger niveau in de hiërarchie, totdat Flash-runtime de eigenschap vindt.

Opmerking: in ActionScript 3.0 is prototypeovererving niet het belangrijkste mechanisme voor overerving. Klasseovererving, dat werkt via de overerving van vaste eigenschappen in klassedefinities, is het belangrijkste overervingsmechanisme in ActionScript 3.0.

Maakt een object Object gemaakt en slaat een verwijzing naar de constructormethode van het object op in de constructoreigenschap van het object.

Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd. Deze methode retourneert true wanneer het doelobject een eigenschap bevat die overeenkomt met de tekenreeks die via de parameter name is opgegeven, anders wordt false geretourneerd. De volgende typen eigenschappen zorgen ervoor dat deze methode true retourneert voor objecten die instanties van een klasse zijn (in tegenstelling tot klasseobjecten):

• Vaste eigenschappen van een instantie - variabelen, constanten of methoden die zijn gedefinieerd door de klasse van een object die niet statisch zijn;
• Overerfde vaste eigenschappen van een instantie - variabelen, constanten of methoden die door de klasse van een object worden overerfd;
• Dynamische eigenschappen - eigenschappen die aan een object zijn toegevoegd nadat deze is geïnstantieerd (buiten zijn klassedefinitie). Wanneer u dynamische eigenschappen wilt toevoegen, moet de definiërende klasse van het object gedeclareerd zijn met het trefwoord dynamic.

De volgende typen eigenschappen zorgen ervoor dat deze methode false retourneert voor objecten die instanties van een klasse zijn:

• Statische eigenschappen - variabelen, constanten of methoden die zijn gedefinieerd met het trefwoord static in een definiërende klasse van een object of een van zijn superklassen;
• Eigenschappen van prototype - eigenschappen die zijn gedefinieerd voor een prototypeobject dat deel is van de prototypeketen van het object. In ActionScript 3.0, wordt de prototypeketen niet gebruikt voor klasseovererving, maar bestaat nog wel als een alternatieve overervingsmethode. Een instantie van de klasse Array heeft bijvoorbeeld toegang tot de methode valueOf(), omdat deze bestaat in Object.prototype en deze is deel van de prototypeketen voor de klasse Array. Hoewel u valueOf() kunt gebruiken voor een instantie van Array, is de geretourneerde waarde van hasOwnProperty("valueOf") voor die instantie false.

ActionScript 3.0 bevat ook klasseobjecten, dit zijn directe representaties van klassedefinities. Wanneer de methode hasOwnProperty() wordt aangeroepen voor klasseobjecten, retourneert deze alleen true wanneer een eigenschap een statische eigenschap is die voor dat klasseobject is gedefinieerd. Wanneer u bijvoorbeeld een subklasse van Array maakt met de naam CustomArray en vervolgens een statische eigenschap in CustomArray definieert met de naam foo, retourneert een aanroep van CustomArray.hasOwnProperty("foo") de waarde true. Voor de statische eigenschap DESCENDING die is gedefinieerd in de klasse Array, maar een aanroep van CustomArray.hasOwnProperty("DESCENDING") retourneert false.

Opmerking: methoden van de klasse Object worden dynamisch gemaakt in het prototype van Object. Wanneer u deze methode opnieuw wilt definiëren in een subklasse van Object, moet u het trefwoord override niet gebruiken. Bijvoorbeeld, een subklasse van Object implementeert de functie hasOwnProperty():Boolean in plaats van dat deze de basisklasse overschrijft.

Parameters

Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven. Deze methode retourneert true wanneer het object zich in de prototypeketen van het object bevindt dat met de parameter theClass is opgegeven. De methode retourneert false wanneer het doelobject niet aanwezig is in de prototypeketen van het object theClass, maar ook wanneer de parameter theClass geen object is.

Opmerking: methoden van de klasse Object worden dynamisch gemaakt in het prototype van Object. Wanneer u deze methode opnieuw wilt definiëren in een subklasse van Object, moet u het trefwoord override niet gebruiken. Bijvoorbeeld, een subklasse van Object implementeert de functie isPrototypeOf():Boolean in plaats van dat deze de basisklasse overschrijft.

Parameters

Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd. Indien true, bestaat de eigenschap en kan deze worden gebruikt in een lus for..in worden opgesomd. De eigenschap moet in het doelobject bestaan, omdat deze methode niet in de prototypeketen van het doelobject zoekt.

Eigenschappen die u maakt, kunnen worden opgesomd, maar ingebouwde eigenschappen kunnen gewoonlijk niet worden opgesomd.

Opmerking: methoden van de klasse Object worden dynamisch gemaakt in het prototype van Object. Wanneer u deze methode opnieuw wilt definiëren in een subklasse van Object, moet u het trefwoord override niet gebruiken. Bijvoorbeeld, een subklasse van Object implementeert de functie propertyIsEnumerable():Boolean in plaats van dat deze de basisklasse overschrijft.

Parameters

Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in. De eigenschap moet in het doelobject bestaan, omdat deze methode niet in de prototypeketen van het doelobject zoekt.

Parameters

Verwante API-elementen

Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies.

De standaardimplementatie van deze methode voert geen locatiespecifieke formattering uit en retourneert dezelfde tekenreeks als toString. Subklassen moeten, indien geschikt, hun eigen implementatie voor landinstellingen behouden.

Opmerking: methoden van de klasse Object worden dynamisch gemaakt in het prototype van Object. Wanneer u deze methode opnieuw wilt definiëren in een subklasse van Object, moet u het trefwoord override niet gebruiken. Bijvoorbeeld, een subklasse van Object implementeert de function toLocaleString():String in plaats van dat deze de basisklasse overschrijft.

Verwante API-elementen

Retourneert een tekenreeksrepresentatie van het opgegeven object.

Opmerking: methoden van de klasse Object worden dynamisch gemaakt in het prototype van Object. Wanneer u deze methode opnieuw wilt definiëren in een subklasse van Object, moet u het trefwoord override niet gebruiken. Bijvoorbeeld, een subklasse van Object implementeert de functie toString():String in plaats van dat deze de basisklasse overschrijft.

Retourneert de primitieve waarde van het opgegeven object. Wanneer het object geen primitieve waarde heeft, wordt het object zelf geretourneerd.

Opmerking: methoden van de klasse Object worden dynamisch gemaakt in het prototype van Object. Wanneer u deze methode opnieuw wilt definiëren in een subklasse van Object, moet u het trefwoord override niet gebruiken. Bijvoorbeeld, een subklasse van Object implementeert de functie valueOf():Object in plaats van dat deze de basisklasse overschrijft.

Verwante API-elementen

Het voorbeeld maakt de value-objecten firstInitObj en secondInitObj. De aangepaste klasse Circle accepteert en doorloopt de objecten value terwijl deze de overeenkomende interne eigenschappen zodanig instelt dat ze overeenkomen met de instellingen die zijn gedefinieerd in het object value.

package {
    import flash.display.Sprite;

    public class ObjectExample extends Sprite {
        public function ObjectExample() {
            var firstInitObj:Object = new Object();
            firstInitObj.bgColor = 0xFF0000;
            firstInitObj.radius = 25;
            firstInitObj.xCenter = 25;
            firstInitObj.yCenter = 25;
                        
            var firstCircle:Circle = new Circle(firstInitObj);
            addChild(firstCircle);
            firstCircle.x = 50;
            firstCircle.y = 50;

            var secondInitObj:Object = {bgColor:0xCCCCCC, radius:50, xCenter:50, yCenter:50};

            var secondCircle:Circle = new Circle(secondInitObj);            
            addChild(secondCircle);
            secondCircle.x = 100;
            secondCircle.y = 100;
        }
        
    }
}

import flash.display.Shape;
    
class Circle extends Shape {
    public var bgColor:Number = 0xFFFFFF;
    public var radius:Number = 0;
    public var xCenter:Number = 0;
    public var yCenter:Number = 0;
        
    public function Circle(initObj:Object) {
        for(var i:String in initObj) {
            this[i] = initObj[i];
        }
        draw();
    }
        
    public function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawCircle(xCenter, yCenter, radius);
        graphics.endFill();
    }
}