| Pakket | flash.text.engine |
| Klasse | public final class FontDescription |
| Overerving | FontDescription  Object |
| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Er wordt een object FontDescription toegepast op een object ElementFormat, dat dan weer wordt toegepast op een ContentElement in een TextBlock. Nadat een FontDescription-object is toegepast op een ElementFormat-object, wordt de eigenschap locked van het ElementFormat-object ingesteld op true. De eigenschappen van een vergrendeld FontDescription-object kunnen niet worden gewijzigd. Gebruik daarom de methode clone() om een niet-vergrendelde kopie van het object te maken, die u vervolgens kunt aanpassen en toewijzen aan het ElementFormat-object.
Opmerking: FTE (Flash Text Engine) biedt geen ondersteuning voor Type 1-lettertypen of bitmaplettertypen zoals Type 3, ATC, sfnt-wrapped CID of Naked CID.
Verwante API-elementen
Overerfde openbare eigenschappen verbergen
Overerfde openbare eigenschappen weergeven| Eigenschap | Gedefinieerd door | ||
|---|---|---|---|
| cffHinting : String
Het type CFF-hinting dat wordt gebruikt voor deze tekst. | FontDescription | ||
 | constructor : Object
Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie. | Object | |
| fontLookup : String
Geeft aan hoe het lettertype moet worden opgezocht. | FontDescription | ||
| fontName : String
De naam van het te gebruiken lettertype of een door komma's gescheiden lijst met namen van lettertypen. | FontDescription | ||
| fontPosture : String
Geeft de letterpositie aan. | FontDescription | ||
| fontWeight : String
Geeft het lettergewicht aan. | FontDescription | ||
| locked : Boolean
Hiermee wordt aangegeven of het FontDescription-object al dan niet is vergrendeld. | FontDescription | ||
| renderingMode : String
De renderingmodus voor deze tekst. | FontDescription | ||
| Methode | Gedefinieerd door | ||
|---|---|---|---|
FontDescription(fontName:String = "_serif", fontWeight:String = "normal", fontPosture:String = "normal", fontLookup:String = "device", renderingMode:String = "cff", cffHinting:String = "horizontalStem")
Maakt een FontDescription-object. | FontDescription | ||
Hiermee wordt een niet-vergrendelde, gekloonde kopie van het object FontDescription gemaakt. | FontDescription | ||
|
Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd. | Object | |
[statisch]
Retourneert de waarde True als een bruikbaar apparaatlettertype met de opgegeven fontName, fontWeight en fontPosture beschikbaar is. | FontDescription | ||
[statisch]
Retourneert true als een ingesloten lettertype beschikbaar is met de opgegeven fontName, fontWeight en fontPosture waarbij Font.fontType flash.text.FontType.EMBEDDED_CFF is. | FontDescription | ||
|
Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven. | Object | |
|
Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd. | Object | |
|
Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in. | Object | |
|
Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies. | Object | |
|
Retourneert een tekenreeksrepresentatie van het opgegeven object. | Object | |
|
Retourneert de primitieve waarde van het opgegeven object. | Object | |
cffHinting | eigenschap |
cffHinting:String| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Het type CFF-hinting dat wordt gebruikt voor deze tekst. Gebruik CFFHinting-constanten voor deze eigenschap. Deze eigenschap is alleen van toepassing wanneer de eigenschap RenderingMode van de tekst is ingesteld op RenderingMode.CFF.
Het type of CFF-hinting (Compact Font Format) bepaalt of de Flash-runtime sterke horizontale stammen al dan niet passend maakt op een subpixelraster.
Alleen van toepassing op ingesloten lettertypen.
De standaardwaarde is CFFHinting.HORIZONTAL_STEM.
Voor de eigenschap CFFHinting kunt u de volgende constanten van de CFFHinting-klasse gebruiken:
| Tekenreekswaarde | Beschrijving |
|---|---|
CFFHinting.NONE | Geeft geen CFF-hinting aan. Horizontale stammen in de glyphs worden niet passend gemaakt op het subpixelraster. Deze instelling is geschikt voor animaties en grote lettertypen. |
CFFHinting.HORIZONTAL_STEM | Geeft CFF-hinting aan. Sterke horizontale stammen worden passend gemaakt op het subpixelraster van het scherm. Als u deze instelling wilt gebruiken, moet u de eigenschap RenderingMode instellen op RenderingMode.CFF. |
Implementatie
public function get cffHinting():String public function set cffHinting(value:String):voidGegenereerde uitzondering
ArgumentError — Indien ingesteld op een waarde die geen lid is van CFFHinting.
| |
IllegalOperationError — Als het instellen gebeurt nadat het FontDescription-object is vergrendeld (locked is true).
|
Verwante API-elementen
fontLookup | eigenschap |
fontLookup:String| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Geeft aan hoe het lettertype moet worden opgezocht.
De standaardwaarde is FontLookup.DEVICE.
Wanneer u waarden voor deze eigenschap wilt instellen, gebruikt u de volgende tekenreekswaarden:
| Tekenreekswaarde | Beschrijving |
|---|---|
FontLookup.DEVICE | Het runtimeprogramma zoekt in het lokale systeem naar een apparaatlettertype met de opgegeven name om de tekst weer te geven. |
FontLookup.EMBEDDED_CFF | Het runtimeprogramma zoekt naar een ingesloten CFF-lettertype met de opgegeven name om de tekst weer te geven. Alleen lettertypen van het type flash.text.Font.fontType.EMBEDDED_CFF komen in aanmerking. Als het opgegeven CFF-lettertype niet is ingesloten in de toepassing, probeert het runtimeprogramma een ander apparaatlettertype te gebruiken voor elke glyph. Deze methode is minder efficiënt dan direct een apparaatlettertype selecteren. |
Implementatie
public function get fontLookup():String public function set fontLookup(value:String):voidGegenereerde uitzondering
IllegalOperationError — Als het instellen gebeurt nadat het FontDescription-object is vergrendeld (locked is true).
|
Verwante API-elementen
fontName | eigenschap |
fontName:String| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5 |
De naam van het te gebruiken lettertype of een door komma's gescheiden lijst met namen van lettertypen. Het runtimeprogramma geeft het element weer met het eerste beschikbare lettertype in de lijst. De combinatie 'Arial, Helvetica, _sans' zorgt er bijvoorbeeld voor dat de speler eerst zoekt naar Arial, dan naar Helvetica (als Arial niet is gevonden) en vervolgens naar _sans (als de eerste twee lettertypen niet zijn gevonden).
De Flash-runtime ondersteunt drie algemene apparaatlettertypen: _sans (voor sans serif-lettertypen), _serif (voor serif-lettertypen) en _typewriter (voor monospace-lettertypen). Deze worden aan specifieke apparaatlettertypen toegewezen, afhankelijk van het platform.
De standaardwaarde is '_serif'.
De Flash-runtime beschikt over reservelettertypen voor glyphs die niet in het geselecteerde lettertype zijn gevonden. Als de glyph niet gevonden is in het lettertype, probeert het runtimeprogramma de glyph weer te geven met een ander apparaatlettertype dat de glyph wel bevat, onafhankelijk van het feit of het gebruikte lettertype ingesloten is of een apparaatlettertype is.
Implementatie
public function get fontName():String public function set fontName(value:String):voidGegenereerde uitzondering
IllegalOperationError — Als het instellen gebeurt nadat het FontDescription-object is vergrendeld (locked is true).
|
Verwante API-elementen
fontPosture | eigenschap |
fontPosture:String| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Geeft de letterpositie aan.
De standaardwaarde is FontPosture.NORMAL.
Als u waarden wilt instellen voor deze eigenschap, gebruikt u de volgende constanten van de FontPosture-klasse:
| Waarde | Beschrijving |
|---|---|
FontPosture.NORMAL | Normale tekenstand. |
FontPosture.ITALIC | Cursieve tekenstand. |
Implementatie
public function get fontPosture():String public function set fontPosture(value:String):voidGegenereerde uitzondering
ArgumentError — Indien ingesteld op een waarde die geen lid is van FontPosture.
| |
IllegalOperationError — Als het instellen gebeurt nadat het FontDescription-object is vergrendeld (locked is true).
|
Verwante API-elementen
fontWeight | eigenschap |
fontWeight:String| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Geeft het lettergewicht aan.
De standaardwaarde is FontWeight.NORMAL.
Als u waarden wilt instellen voor deze eigenschap, gebruikt u de volgende constanten van de FontWeight-klasse:
| Tekenreekswaarde | Beschrijving |
|---|---|
FontWeight.NORMAL | Normaal tekengewicht. |
FontWeight.BOLD | Vet tekengewicht. |
Implementatie
public function get fontWeight():String public function set fontWeight(value:String):voidGegenereerde uitzondering
ArgumentError — Indien ingesteld op een waarde die geen lid is van FontWeight.
| |
IllegalOperationError — Als het instellen gebeurt nadat het FontDescription-object is vergrendeld (locked is true).
|
Verwante API-elementen
locked | eigenschap |
locked:Boolean| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5., Flash Lite 4 |
Hiermee wordt aangegeven of het FontDescription-object al dan niet is vergrendeld. true betekent dat het object FontDescription niet kan worden gewijzigd. Roep FontDescription.clone() aan om een niet-vergrendelde versie van het object FontDescription te maken.
Implementatie
public function get locked():Boolean public function set locked(value:Boolean):voidGegenereerde uitzondering
IllegalOperationError — Als het instellen gebeurt nadat het FontDescription-object is vergrendeld (locked is true).
|
renderingMode | eigenschap |
renderingMode:String| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5, Flash Lite 4 |
De renderingmodus voor deze tekst. Gebruikt RenderingMode-constanten voor deze eigenschap.
Alleen van toepassing op ingesloten lettertypen.
De standaardwaarde is RenderingMode.CFF.
Als u waarden wilt instellen voor deze eigenschap, gebruikt u de volgende constanten van de RenderingMode-klasse:
| Tekenreekswaarde | Beschrijving |
|---|---|
RenderingMode.NORMAL | Past de normale tekstrendering toe, die overeenkomt met het type rendering van Flash Player 7 en eerdere versies. |
RenderingMode.CFF | Hiermee wordt CFF-rendering (Compact Font Format) toegepast, waardoor de tekst beter leesbaar wordt. (Dit kenmerk was voor het eerst beschikbaar in Flash Player 10.) Bij CFF-rendering kunnen kleine lettertypen met zeer hoge kwaliteit worden weergegeven. |
Implementatie
public function get renderingMode():String public function set renderingMode(value:String):voidGegenereerde uitzondering
ArgumentError — Indien ingesteld op een waarde die geen lid is van RenderingMode.
| |
IllegalOperationError — Als het instellen gebeurt nadat het FontDescription-object is vergrendeld (locked is true).
|
Verwante API-elementen
FontDescription | () | Constructor |
public function FontDescription(fontName:String = "_serif", fontWeight:String = "normal", fontPosture:String = "normal", fontLookup:String = "device", renderingMode:String = "cff", cffHinting:String = "horizontalStem")| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Maakt een FontDescription-object.
ParametersfontName:String (default = "_serif") | |
fontWeight:String (default = "normal") | |
fontPosture:String (default = "normal") | |
fontLookup:String (default = "device") | |
renderingMode:String (default = "cff")RenderingMode-constanten voor deze eigenschap.
| |
cffHinting:String (default = "horizontalStem")CFFHinting-constanten voor deze eigenschap.
|
Gegenereerde uitzondering
ArgumentError — De opgegeven fontWeight is geen lid van FontWeight.
| |
ArgumentError — De opgegeven fontPosture is geen lid van FontPosture.
| |
ArgumentError — De opgegeven fontLookup is geen lid van FontLookup.
| |
ArgumentError — De opgegeven renderingMode is geen lid van RenderingMode.
| |
ArgumentError — De opgegeven cffHinting is geen lid van CFFHinting.
|
clone | () | methode |
public function clone():FontDescription| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Hiermee wordt een niet-vergrendelde, gekloonde kopie van het object FontDescription gemaakt.
Geretourneerde waardeFontDescription — Een niet-vergrendelde kopie van het FontDescription-object.
|
Voorbeeld ( Hoe dit voorbeeld te gebruiken )
In dit voorbeeld wordt een FontDescription-object gemaakt, wordt daaraan een apparaatlettertype toegewezen, worden diverse lettertype-eigenschappen ingesteld en wordt het nieuwe object toegewezen aan een ElementFormat-object. Het nieuwe object wordt hierbij vergrendeld. Er wordt een nieuw TextElement gemaakt met ElementFormat. TextElement wordt gebruikt als inhoud voor een TextBlock. Van het TextBlock wordt een regel tekst gemaakt.
Als u het object FontDescription wilt wijzigen, controleert u eerst de eigenschap locked van het object. Als deze eigenschap is ingesteld op true, gebruikt u de methode clone() om een niet-vergrendelde kopie van het object FontDescription te maken. Vervolgens wijzigt u de eigenschappen van de kopie en wijst u deze toe aan een nieuw object ElementFormat. Vervolgens koppelt u het nieuwe object ElementFormat aan het TextBlock. Wanneer de regels opnieuw worden afgebroken, gelden de nieuwe lettertype-instellingen voor de nieuwe regels.
package {
import flash.display.Sprite;
import flash.text.engine.*;
public class FontDescription_cloneExample extends Sprite {
private var fd:FontDescription;
private var fd2:FontDescription;
public function FontDescription_cloneExample():void {
fd = new FontDescription();
fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
fd.fontName = "Palatino";
fd.fontWeight = flash.text.engine.FontWeight.BOLD;
fd.fontPosture = flash.text.engine.FontPosture.ITALIC;
var ef1:ElementFormat = new ElementFormat(fd);
var str:String = "This is flash text 0123456789";
var tb:TextBlock = new TextBlock();
var te1:TextElement = new TextElement(str, ef1);
tb.content = te1;
var line1:TextLine = tb.createTextLine(null, 600);
addChild(line1);
fd2 = (fd.locked) ? fd.clone() : fd;
fd2.fontWeight = flash.text.engine.FontWeight.NORMAL;
var ef2:ElementFormat = new ElementFormat(fd2);
tb.content.elementFormat=ef2;
var line2:TextLine = tb.createTextLine(null, 600);
addChild(line2);
}
}
}
isDeviceFontCompatible | () | methode |
public static function isDeviceFontCompatible(fontName:String, fontWeight:String, fontPosture:String):Boolean| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10.1, AIR 2 |
Retourneert de waarde True als een bruikbaar apparaatlettertype met de opgegeven fontName, fontWeight en fontPosture beschikbaar is.
De flash.text.engine-klassen kunnen alleen OpenType- en TrueType-apparaatlettertypen gebruiken. Als u een lettertype gebruikt dat is gebaseerd op een oudere lettertypetechnologie, valt het runtimeprogramma glyph voor glyph terug op apparaatlettertypen om de tekst weer te geven
Parameters
fontName:String — De naam van het apparaatlettertype dat moet worden gecontroleerd.
| |
fontWeight:String — Geeft het lettergewicht aan. Gebruik FontWeight.
| |
fontPosture:String — Geeft de letterpositie aan. Gebruik FontPosture.
|
Boolean — True als er een compatibel apparaatlettertype beschikbaar is, anders False.
|
Gegenereerde uitzondering
ArgumentError — De opgegeven fontWeight is geen lid van FontWeight.
| |
ArgumentError — De opgegeven fontPosture is geen lid van FontPosture.
|
Verwante API-elementen
isFontCompatible | () | methode |
public static function isFontCompatible(fontName:String, fontWeight:String, fontPosture:String):Boolean| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Is true als een ingesloten lettertype beschikbaar is met de opgegeven fontName, fontWeight en fontPosture waarbij Font.fontType flash.text.FontType.EMBEDDED_CFF is. Vanaf Flash Player 10 kunnen twee ingesloten lettertypen worden weergegeven in de inhoud van een toepassing. Normale ingesloten lettertypen worden alleen door TextField gebruikt. CFF ingesloten lettertypen worden alleen gebruikt door de flash.text.engine-klassen. De twee typen onderscheiden zich van elkaar door de eigenschap fontType van de Font-klasse, zoals geretourneerd door de functie enumerateFonts().
De flash.text.engine-klassen kunnen een lettertype van het type EMBEDDED niet gebruiken. Als fontLookup is ingesteld op FontLookup.EMBEDDED_CFF en het enige lettertype dat tijdens runtime beschikbaar is met de opgegeven naam, gewicht en positie van het type EMBEDDED is, valt het runtimeprogramma glyph voor glyph terug op apparaatlettertypen om de tekst weer te geven, alsof er geen ingesloten lettertypen beschikbaar zijn met de opgegeven naam en stijl.
Als zowel lettertype EMBEDDED als EMBEDDED_CFF beschikbaar zijn met dezelfde naam, gewicht en positie, wordt het lettertype EMBEDDED_CFF geselecteerd en wordt tekst weergegeven met het lettertype EMBEDDED_CFF.
Parameters
fontName:String — De naam van het ingesloten lettertype dat moet worden gecontroleerd.
| |
fontWeight:String — Geeft het lettergewicht aan. Gebruik FontWeight.
| |
fontPosture:String — Geeft de letterpositie aan. Gebruik FontPosture.
|
Boolean — true als er een compatibel ingesloten lettertype beschikbaar is, anders false.
|
Gegenereerde uitzondering
ArgumentError — De opgegeven fontWeight is geen lid van FontWeight.
| |
ArgumentError — De opgegeven fontPosture is geen lid van FontPosture.
|
Verwante API-elementen
In dit voorbeeld wordt een FontDescription-object gemaakt, wordt daaraan een apparaatlettertype toegewezen, worden diverse lettertype-eigenschappen ingesteld en wordt het nieuwe object toegewezen aan een ElementFormat-object. Extra tekenopmaak wordt toegepast in ElementFormat. Er wordt een nieuw TextElement gemaakt met ElementFormat. TextElement wordt gebruikt als inhoud voor een TextBlock. Van het TextBlock wordt een regel tekst gemaakt.
package {
import flash.display.Sprite;
import flash.text.engine.*;
public class FontDescriptionExample extends Sprite {
public function FontDescriptionExample():void {
var fd:FontDescription = new FontDescription();
fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
fd.fontName = "Palatino";
fd.fontWeight = flash.text.engine.FontWeight.BOLD;
fd.fontPosture = flash.text.engine.FontPosture.ITALIC;
var ef1:ElementFormat = new ElementFormat(fd);
ef1.fontSize = 30;
ef1.color = 0xFF0000;
var str:String = "This is flash text 0123456789";
var tb:TextBlock = new TextBlock();
var te1:TextElement = new TextElement(str, ef1);
tb.content = te1;
var line1:TextLine = tb.createTextLine(null, 600);
addChild(line1);
}
}
}
Wed Jun 13 2018, 11:42 AM Z