String

Pakket	Hoofdniveau
Klasse	public final class String
Overerving	String Object

Runtimeversies:

Flash Player 9, AIR 1.0, Flash Lite 4

De klasse String is een gegevenstype dat een reeks tekens vertegenwoordigt. De klasse String kent methoden en eigenschappen waarmee u primitieve typen tekenreekswaarden kunt manipuleren. U kunt de waarde van objecten in een gegevenstype String omzetten met de functie String().

Omdat alle tekenreeksindexen op nul zijn gebaseerd, is de index van het laatste teken voor elke tekenreeks x gelijk aan x.length - 1.

U kunt elk van de methoden van de klasse String aanroepen met ofwel de constructormethode new String() om een nieuwe tekenreekswaarde te maken of door gewoon een letterlijke tekenreekswaarde toe te wijzen. Anders dan bij eerdere versies van ActionScript maakt het niet uit of u de constructor of de functie global gebruikt, of gewoon een letterlijke tekenreekswaarde toewijst. De volgende coderegels zijn gelijk:

 var str:String = new String("foo");
 var str:String = "foo";
 var str:String = String("foo");

Wanneer een tekenreeksvariabele op undefined wordt ingesteld, wordt in de Flash-runtime undefined tot null gebracht. Met de instructie:

 var s:String = undefined;

wordt de waarde dus op null ingesteld in plaats van undefined. Gebruik de functie String() wanneer u undefined moet gebruiken.

Bekijk de voorbeelden

Verwante API-elementen

String() algemene functie

Openbare eigenschappen

Overerfde openbare eigenschappen verbergen

Overerfde openbare eigenschappen weergeven

	Eigenschap		Gedefinieerd door
		constructor : Object Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie.	Object
		length : int [alleen-lezen] Een geheel getal dat het aantal tekens in het opgegeven object String opgeeft.	String

Openbare methoden

Overerfde openbare methoden verbergen

Overerfde openbare methoden weergeven

	Methode		Gedefinieerd door
		String(val:String) Maakt een nieuw object String dat naar de opgegeven tekenreeks wordt geïnitialiseerd.	String
		charAt(index:Number = 0):String Retourneert het teken op de positie die door de parameter index is opgegeven.	String
		charCodeAt(index:Number = 0):Number Retourneert de numerieke Unicode-tekencode van het teken op de opgegeven index.	String
		concat(... args):String Voegt de aangeboden argumenten aan het einde van het object String toe, waarbij deze indien nodig worden omgezet in tekenreeksen, en retourneert de resulterende tekenreeks.	String
		fromCharCode(... charCodes):String [statisch] Retourneert een tekenreeks die bestaat uit de tekens die worden vertegenwoordigd door de Unicode-tekencodes in de parameters.	String
		hasOwnProperty(name:String):Boolean Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd.	Object
		indexOf(val:String, startIndex:Number = 0):int Doorzoekt de tekenreeks en retourneert de positie van de eerste gevonden val op of na startIndex binnen de aanroeptekenreeks.	String
		isPrototypeOf(theClass:Object):Boolean Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven.	Object
		lastIndexOf(val:String, startIndex:Number = 0x7FFFFFFF):int Doorzoekt de tekenreeks van rechts naar links en retourneert de index van de laatste gevonden val voorafgaand aan startIndex.	String
		localeCompare(other:String, ... values):int Vergelijkt de sorteervolgorde van twee of meer tekenreeksen en retourneert het resultaat van de vergelijking als een geheel getal.	String
		match(pattern:*):Array Vergelijkt het opgegeven patroon met de tekenreeks.	String
		propertyIsEnumerable(name:String):Boolean Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd.	Object
		replace(pattern:*, repl:Object):String Vergelijkt het opgegeven patroon met de tekenreeks en retourneert een nieuwe tekenreeks waarin de eerste overeenkomst met het patroon is vervangen door de inhoud die door repl wordt opgegeven.	String
		search(pattern:*):int Zoekt naar het opgegeven patroon en retourneert de index van de eerste overeenkomende subtekenreeks.	String
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in.	Object
		slice(startIndex:Number = 0, endIndex:Number = 0x7fffffff):String Retourneert een tekenreeks die het startIndex-teken en alle tekens tot (niet tot en met) het endIndex-teken bevat.	String
		split(delimiter:*, limit:Number = 0x7fffffff):Array Splitst een object String op in een array van subtekenreeksen door het te scheiden waar de opgegeven parameter delimiter voorkomt.	String
		substr(startIndex:Number = 0, len:Number = 0x7fffffff):String Retourneert een subtekenreeks die bestaat uit de tekens die beginnen bij de opgegeven startIndex en met een lengte opgegeven door de parameter len.	String
		substring(startIndex:Number = 0, endIndex:Number = 0x7fffffff):String Retourneert een tekenreeks die bestaat uit het teken dat wordt opgegeven door startIndex en alle tekens tot endIndex - 1.	String
		toLocaleLowerCase():String Retourneert een kopie van deze tekenreeks, waarbij alle hoofdletters zijn omgezet in kleine letters.	String
		toLocaleString():String Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies.	Object
		toLocaleUpperCase():String Retourneert een kopie van deze tekenreeks, waarbij alle kleine letters zijn omgezet in hoofdletters.	String
		toLowerCase():String Retourneert een kopie van deze tekenreeks, waarbij alle hoofdletters zijn omgezet in kleine letters.	String
		toString():String Retourneert een tekenreeksrepresentatie van het opgegeven object.	Object
		toUpperCase():String Retourneert een kopie van deze tekenreeks, waarbij alle kleine letters zijn omgezet in hoofdletters.	String
		valueOf():String Retourneert de primitieve waarde van een instantie String.	String

Eigenschapdetails

length

eigenschap

length:int [alleen-lezen]

Runtimeversies:

Flash Player 9, AIR 1.0, Flash Lite 4

Een geheel getal dat het aantal tekens in het opgegeven object String opgeeft.

Omdat alle tekenreeksindexen op nul zijn gebaseerd, is de index van het laatste teken voor elke tekenreeks x gelijk aan x.length - 1.

Implementatie
public function get length():int

Constructordetails

()

Constructor

public function String(val:String)

Runtimeversies:

Flash Player 9, AIR 1.0, Flash Lite 4

Maakt een nieuw object String dat naar de opgegeven tekenreeks wordt geïnitialiseerd.

Opmerking: omdat letterlijke tekenreeksen minder overhead gebruiken dan objecten String en doorgaans gemakkelijker te gebruiken zijn, moet u letterlijke tekenreeksen gebruiken in plaats van de klasse String, tenzij u een goede reden hebt om een object String te gebruiken in plaats van een letterlijke tekenreeks.

Parameters

val:String — De beginwaarde van het nieuwe object String.

Methodedetails

charAt

()

methode

AS3 function charAt(index:Number = 0):String

Runtimeversies:

Flash Player 9, AIR 1.0, Flash Lite 4

Retourneert het teken op de positie die door de parameter index is opgegeven. Wanneer index niet een getal van 0 tot string.length - 1 is, wordt een lege tekenreeks geretourneerd.

Deze methode is vergelijkbaar met String.charCodeAt(), maar bij deze methode is de geretourneerde waarde een teken en geen tekencode voor een 16-bits geheel getal.

Parameters

index:Number (default = 0) — Een geheel getal waarmee de positie van een teken in de tekenreeks wordt opgegeven. Het eerste teken wordt aangegeven met 0 en het laatste teken met my_str.length - 1.

Geretourneerde waarde

String — Het teken in de opgegeven index. Of een lege tekenreeks wanneer de opgegeven index zich buiten het bereik van de indexen van deze tekenreeks bevindt.

Verwante API-elementen

charCodeAt()

charCodeAt

()

methode

AS3 function charCodeAt(index:Number = 0):Number

Runtimeversies:

Flash Player 9, AIR 1.0, Flash Lite 4

Retourneert de numerieke Unicode-tekencode van het teken op de opgegeven index. Wanneer index niet een getal van 0 tot string.length - 1 is, wordt NaN geretourneerd.

Deze methode is vergelijkbaar met String.charAt(), maar bij deze methode is de geretourneerde waarde een tekencode voor een 16-bits geheel getal en geen feitelijk teken.

Parameters

Geretourneerde waarde

Number — De Unicode-tekencode van het teken op de opgegeven index. Of NaN wanneer de index zich buiten het bereik van de indexen van deze tekenreeks bevindt.

Unicode-waarden worden gedefinieerd in de specificaties van de Unicode-tekendatabase

Verwante API-elementen

charAt()

concat

()

methode

AS3 function concat(... args):String

Runtimeversies:

Flash Player 9, AIR 1.0, Flash Lite 4

Voegt de aangeboden argumenten aan het einde van het object String toe, waarbij deze indien nodig worden omgezet in tekenreeksen, en retourneert de resulterende tekenreeks. De oorspronkelijke waarde van het bronobject String blijft ongewijzigd.

Parameters

... args — Nul of meer waarden die moeten worden samengevoegd.

Geretourneerde waarde

String — Een nieuwe tekenreeks die bestaat uit deze tekenreeks samengevoegd met de opgegeven parameters.

fromCharCode

()

methode

AS3 static function fromCharCode(... charCodes):String

Runtimeversies:

Flash Player 9, AIR 1.0, Flash Lite 4

Retourneert een tekenreeks die bestaat uit de tekens die worden vertegenwoordigd door de Unicode-tekencodes in de parameters.

Parameters

... charCodes — Een reeks decimale gehele getallen die Unicode-waarden vertegenwoordigen.

Unicode-waarden worden gedefinieerd in de specificaties van de Unicode-tekendatabase

Geretourneerde waarde

String — De tekenreekswaarde van de opgegeven Unicode-tekencodes.

indexOf

()

methode

AS3 function indexOf(val:String, startIndex:Number = 0):int

Runtimeversies:

Flash Player 9, AIR 1.0, Flash Lite 4

Doorzoekt de tekenreeks en retourneert de positie van de eerste gevonden instantie val op of na startIndex binnen de aanroeptekenreeks. Deze index is op nul gebaseerd. Dit betekent dat het eerste teken in een tekenreeks zich op index 0 bevindt en niet op index 1. Wanneer val niet wordt gevonden, retourneert de methode -1.

Parameters

	`val:String` — De subtekenreeks waarnaar moet worden gezocht.

	`startIndex:Number` (default = `0`) — Een optioneel geheel getal waarmee de beginindex van de zoekopdracht wordt opgegeven.

Geretourneerde waarde

int — De index van de eerste instantie van de opgegeven subtekenreeks of -1.

Verwante API-elementen

lastIndexOf()

lastIndexOf

()

methode

AS3 function lastIndexOf(val:String, startIndex:Number = 0x7FFFFFFF):int

Runtimeversies:

Flash Player 9, AIR 1.0, Flash Lite 4

Doorzoekt de tekenreeks van rechts naar links en retourneert de index van de laatste gevonden val voorafgaand aan startIndex. De index is op nul gebaseerd. Dat betekent dat het eerste teken zich op index 0 bevindt en het laatste teken op string.length - 1. Wanneer val niet wordt gevonden, retourneert de methode -1.

Parameters

	`val:String` — De tekenreeks waarnaar moet worden gezocht.

	`startIndex:Number` (default = `0x7FFFFFFF`) — Een optioneel geheel getal waarmee de beginindex voor het zoeken naar `val` wordt opgegeven. De standaardwaarde is de maximumwaarde die voor een index is toegestaan. Wanneer `startIndex` niet is opgegeven, begint de zoekopdracht bij het laatste item in de tekenreeks.

Geretourneerde waarde

int — De positie van de laatste instantie van de opgegeven subtekenreeks of -1 wanneer die niet wordt gevonden.

Verwante API-elementen

indexOf()

localeCompare

()

methode

AS3 function localeCompare(other:String, ... values):int

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Vergelijkt de sorteervolgorde van twee of meer tekenreeksen en retourneert het resultaat van de vergelijking als een geheel getal. Hoewel deze methode is bedoeld om de vergelijking af te handelen in overeenstemming met specifieke landinstellingen, produceert de implementatie van ActionScript 3.0 geen ander resultaat van andere tekenreeksvergelijkingen zoals de operators gelijk aan (==) of ongelijk aan (!= ). Wanneer de tekenreeksen gelijkwaardig zijn, is de geretourneerde waarde 0. Wanneer de oorspronkelijke tekenreekswaarde voorafgaat aan de tekenreekswaarde die wordt opgegeven door other, is de geretourneerde waarde een negatief geheel getal, waarvan de absolute waarde het aantal tekens vertegenwoordigt dat de twee tekenreekswaarden van elkaar scheidt. Wanneer de oorspronkelijke tekenreekswaarde volgt op other, is de geretourneerde waarde een positief geheel getal, waarvan de absolute waarde het aantal tekens vertegenwoordigt dat de twee tekenreekswaarden van elkaar scheidt.

Parameters

	`other:String` — Een tekenreekswaarde die moet worden vergeleken.

	`... values` — Optionele set van meer tekenreeksen die moeten worden vergeleken.

Geretourneerde waarde

int — De waarde 0 van de tekenreeksen zijn gelijk. Anders een negatieve integer wanneer de oorspronkelijke tekenreeks voorafgaat aan het tekenreeksargument en een positieve integer wanneer het tekenreeksargument voorafgaat aan de oorspronkelijke tekenreeks. In beide gevallen vertegenwoordigt de absolute waarde van het getal het verschil tussen de twee tekenreeksen.

match

()

methode

AS3 function match(pattern:*):Array

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Vergelijkt het opgegeven pattern met de tekenreeks.

Parameters

Geretourneerde waarde

Array — Een array van tekenreeksen bestaande uit alle subtekenreeksen in de tekenreeks die overeenkomt met het opgegeven pattern.

Wanneer pattern een reguliere expressie is en u een array wilt retourneren met meer dan één overeenkomende subtekenreeks, moet de markering g (global) worden ingesteld in de reguliere expressie:

Wanneer de markering g (global) niet is ingesteld, bevat de geretourneerde array niet meer dan één overeenkomst. De eigenschap lastIndex van de reguliere expressie blijft dan ongewijzigd.
Wanneer de markering g (global) wel is ingesteld, wordt met de methode de zoekopdracht gestart bij het begin van de tekenreeks (indexpositie 0). Wanneer een overeenkomende subtekenreeks een lege tekenreeks is (wat kan voorkomen bij een reguliere expressie zoals /x*/), wordt met de methode die lege tekenreeks toegevoegd aan de array van overeenkomsten, waarna verder wordt gezocht op de volgende indexpositie. De eigenschap lastIndex van de reguliere expressie wordt ingesteld op 0 nadat de methode is uitgevoerd.

Als de parameter pattern een reguliere expressie is waarbij de markering g (global) is ingesteld, retourneert de methode een lege array als er geen overeenkomst is gevonden. Als de parameter pattern een tekenreeks of een niet-globale reguliere expressie is en er geen overeenkomst is gevonden, retourneert de methode null. Wanneer u geen waarde (of een ongedefinieerde waarde) doorgeeft als parameter pattern, retourneert de methode null.

Verwante API-elementen

RegExp

replace

()

methode

AS3 function replace(pattern:*, repl:Object):String

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Het opgegeven pattern wordt vergeleken met de tekenreeks en er wordt een nieuwe tekenreeks geretourneerd waarin de eerste overeenkomst van pattern wordt vervangen door de inhoud die door repl wordt opgegeven. De parameter pattern kan een tekenreeks of een reguliere expressie zijn. De parameter repl kan een tekenreeks of een functie zijn. Bij een functie wordt de door de functie geretourneerde tekenreeks ingevoegd in plaats van de overeenkomst. De oorspronkelijke tekenreeks wordt niet gewijzigd.

In het volgende voorbeeld wordt alleen de eerste instantie van "sh" (hoofdlettergevoelig) vervangen:

    var myPattern:RegExp = /sh/;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // She sells seaschells by the seashore.

In het volgende voorbeeld worden alle instanties van "sh" (hoofdlettergevoelig) vervangen omdat de markering g (global) is ingesteld in de reguliere expressie:

    var myPattern:RegExp = /sh/g;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // She sells seaschells by the seaschore.

In het volgende voorbeeld worden alle instanties van "sh" vervangen omdat de markering g (global) is ingesteld in de reguliere expressie en de overeenkomsten niet hoofdlettergevoelig zijn omdat de markering i (ignoreCase) is ingesteld:

    var myPattern:RegExp = /sh/gi;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // sche sells seaschells by the seaschore.

Parameters

pattern:* — Het patroon dat moet overeenkomen. Dit kan elk type object zijn, maar doorgaans is het een tekenreeks of een reguliere expressie. Wanneer u een parameter pattern opgeeft die elk object kan zijn behalve een tekenreeks of reguliere expressie, wordt de methode toString() toegepast op de parameter en wordt de methode replace() uitgevoerd met gebruik van de resulterende tekenreeks als pattern.

repl:Object — Doorgaans de tekenreeks die wordt ingevoegd in plaats van de overeenkomende inhoud. U kunt echter ook een functie opgeven als deze parameter. Wanneer u een functie opgeeft, wordt de door de functie geretourneerde tekenreeks ingevoegd in plaats van de overeenkomende inhoud.

Wanneer u een tekenreeks opgeeft als parameter repl en een reguliere expressie opgeeft als pattern, kunt u de volgende speciale $ replacement codes gebruiken in de tekenreeks repl:

$ Code	Vervangingstekst
`$$`	`$`
`$&`	De overeenkomende subtekenreeks.
$`	Het gedeelte van de tekenreeks dat voorafgaat aan de overeenkomende subtekenreeks In deze code wordt het rechte enkele aanhalingsteken links (`) gebruikt, niet het rechte enkele aanhalingsteken (') of het gekrulde enkele aanhalingsteken links (‘).
`$'`	Het gedeelte van de tekenreeks die volgt na de overeenkomende subtekenreeks In deze code wordt het rechte enkele aanhalingsteken (') gebruikt.
`$`n	De ne vastgelegde overeenkomende groep tussen ronde haakjes, waarbij n een eencijferig getal van 1-9 is en `$`n niet wordt gevolgd door een decimaal cijfer.
`$`nn	De nne vastgelegde overeenkomende groep tussen ronde haakjes, waarbij nn een tweecijferig decimaal getal is (01-99). Wanneer de nne vastlegging ongedefinieerd is, is de vervangingstekst een lege tekenreeks.

Hierna wordt bijvoorbeeld het gebruik getoond van de vervangingscodes $2 en $1, die de eerste en tweede vastgelegde overeenkomende groep vertegenwoordigen:

var str:String = "flip-flop";
    var pattern:RegExp = /(\w+)-(\w+)/g;
    trace(str.replace(pattern, "$2-$1")); // flop-flip

Wanneer u een functie opgeeft als repl, geeft de methode replace() de volgende parameters door aan de functie:

Het overeenkomende gedeelte van de tekenreeks.
Vastgelegde overeenkomende groepen tussen ronde haakjes worden opgegeven als de volgende argumenten. Het aantal doorgegeven argumenten op deze wijze hangt af van het aantal overeenkomsten tussen ronde haakjes. U kunt het aantal overeenkomsten tussen ronde haakjes vaststellen door arguments.length - 3 binnen de functiecode te controleren.
De indexpositie in de tekenreeks waar de overeenkomst begint.
De volledige tekenreeks.

Overweeg bijvoorbeeld het volgende:

    var str1:String = "abc12 def34";
    var pattern:RegExp = /([a-z]+)([0-9]+)/;
    var str2:String = str1.replace(pattern, replFN);
    trace (str2);   // 12abc 34def
    
    function replFN():String {
      return arguments[2] + arguments[1];
    }

Het aanroepen van de methode replace() gebruikt een functie als parameter repl. De reguliere expressie (/([a-z]([0-9]/g) komt twee keer overeen. De eerste keer komt het patroon overeen met de subtekenreeks "abc12" en wordt de volgende lijst met argumenten doorgegeven aan de functie:

    {"abc12", "abc", "12", 0, "abc12 def34"}

De tweede keer komt het patroon overeen met de subtekenreeks "def23" en wordt de volgende lijst met argumenten doorgegeven aan de functie:

    {"def34", "def", "34", 6, "abc123 def34"}

Geretourneerde waarde

String — De resulterende tekenreeks. De brontekenreeks blijft ongewijzigd.

Verwante API-elementen

RegExp

search

()

methode

AS3 function search(pattern:*):int

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Zoekt naar het opgegeven pattern en retourneert de index van de eerste overeenkomende subtekenreeks. Wanneer geen overeenkomende subtekenreeks wordt gevonden, retourneert de methode -1.

Parameters

pattern:* — Het patroon dat moet overeenkomen. Dit kan elk type object zijn, maar doorgaans is het een tekenreeks of een reguliere expressie. Wanneer pattern geen reguliere expressie of tekenreeks is, zet de methode het om in een tekenreeks voordat de opdracht wordt uitgevoerd. Wanneer u een reguliere expressie opgeeft, negeert de methode de markering global ("g") van de reguliere expressie plus de eigenschap lastIndex van de reguliere expressie (en laat deze ongewijzigd). Wanneer u een ongedefinieerde waarde (of geen waarde) doorgeeft, retourneert de methode -1.

Geretourneerde waarde

int — De index van de eerste overeenkomende subtekenreeks of -1 wanneer er geen overeenkomst is. De index is op nul gebaseerd. Het eerste teken bevindt zich op index 0 en het laatste teken op string.length - 1.

Verwante API-elementen

RegExp

slice

()

methode

AS3 function slice(startIndex:Number = 0, endIndex:Number = 0x7fffffff):String

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Retourneert een tekenreeks die het startIndex-teken en alle tekens tot (niet tot en met) het endIndex-teken bevat. Het oorspronkelijke object String wordt niet gewijzigd. Wanneer de parameter endIndex niet is opgegeven, is het einde van de subtekenreeks het einde van de tekenreeks. Wanneer het door startIndex geïndexeerde teken overeenkomt met het door endIndex geïndexeerde teken of zich rechts van dat teken bevindt, wordt met deze methode een lege tekenreeks geretourneerd.

Parameters

	`startIndex:Number` (default = `0`) — De op nul gebaseerde index van het beginpunt voor het segment. Wanneer `startIndex` een negatief getal is, wordt het segment van rechts naar links gemaakt, waarbij -1 het laatste teken is.

	`endIndex:Number` (default = `0x7fffffff`) — Een geheel getal dat één groter is dan de index van het eindpunt voor het segment. Het teken dat wordt geïndexeerd door de parameter `endIndex` wordt niet opgenomen in de geëxtraheerde tekenreeks. Wanneer `endIndex` een negatief getal is, wordt het eindpunt bepaald door terug te tellen vanaf het einde van de tekenreeks, waarbij -1 het laatste teken is. De standaardwaarde is de maximumwaarde die voor een index is toegestaan. Wanneer deze parameter wordt weggelaten, wordt `String.length` gebruikt.

Geretourneerde waarde

String — Een subtekenreeks op basis van de opgegeven indexen.

Verwante API-elementen

substr()
substring()

split

()

methode

AS3 function split(delimiter:*, limit:Number = 0x7fffffff):Array

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Splitst een object String op in een array van subtekenreeksen door het te scheiden waar de opgegeven parameter delimiter voorkomt.

Wanneer de parameter delimiter een reguliere expressie is, wordt alleen de eerste overeenkomst op een bepaalde positie van de tekenreeks beschouwd, ook wanneer met terugzoeken een overeenkomende niet-lege subtekenreeks op die positie kon worden gevonden. Bijvoorbeeld:

     var str:String = "ab";
     var results:Array = str.split(/a*?/); // results == ["","b"]
     
     results = str.split(/a*/); // results == ["","b"].)

Wanneer de parameter delimiter een reguliere expressie is met groeperende ronde haakjes, worden bij elke overeenkomst van delimiter de resultaten (inclusief ongedefinieerde resultaten) van de groeperende ronde haakjes gesegmenteerd in de uitvoerarray. Bijvoorbeeld

     var str:String = "Thi5 is a tricky-66 example.";
     var re:RegExp = /(\d+)/;
     var results:Array = str.split(re);
         // results == ["Thi","5"," is a tricky-","66"," example."]

Wanneer de parameter limit is opgegeven, krijgt de geretourneerde array niet meer dan het aantal opgegeven elementen.

Wanneer delimiter een lege tekenreeks, een lege reguliere expressie of een reguliere expressie is die overeen kan komen met een lege tekenreeks, wordt elk enkel teken in de tekenreeks uitgevoerd als een element in de array.

Wanneer de parameter delimiter ongedefinieerd is, wordt de gehele tekenreeks opgenomen in het eerste element van de geretourneerde array.

Parameters

	`delimiter:*` — Het patroon dat opgeeft waar deze tekenreeks wordt gesplitst. Dit kan elk type object zijn, maar doorgaans is het een tekenreeks of een reguliere expressie. Wanneer `delimiter` geen reguliere expressie of tekenreeks is, zet de methode het om in een tekenreeks voordat de opdracht wordt uitgevoerd.

	`limit:Number` (default = `0x7fffffff`) — Het maximale aantal items dat in de array moet worden opgenomen. De standaardwaarde is de maximaal toegestane waarde.

Geretourneerde waarde

Array — Een array van subtekenreeksen.

Verwante API-elementen

Array.join()
RegExp

substr

()

methode

AS3 function substr(startIndex:Number = 0, len:Number = 0x7fffffff):String

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Retourneert een subtekenreeks die bestaat uit de tekens die beginnen bij de opgegeven startIndex en met een lengte opgegeven door len. De oorspronkelijke tekenreeks blijft ongewijzigd.

Parameters

	`startIndex:Number` (default = `0`) — Een geheel getal waarmee de index wordt aangegeven van het eerste teken dat moet worden gebruikt om de subtekenreeks te maken. Wanneer `startIndex` een negatief getal is, wordt de beginindex bepaald vanaf het einde van de tekenreeks, waarbij `-1` het laatste teken is.

	`len:Number` (default = `0x7fffffff`) — Het aantal tekens in de subtekenreeks die wordt gemaakt. De standaardwaarde is de maximaal toegestane waarde. Wanneer `len` niet wordt opgegeven, bevat de subtekenreeks alle tekens vanaf `startIndex` tot het einde van de tekenreeks.

Geretourneerde waarde

String — Een subtekenreeks van de opgegeven parameters.

substring

()

methode

AS3 function substring(startIndex:Number = 0, endIndex:Number = 0x7fffffff):String

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Retourneert een tekenreeks die bestaat uit het teken dat wordt opgegeven door startIndex en alle tekens tot endIndex - 1. Wanneer endIndex niet is opgegeven, wordt String.length gebruikt. Wanneer de waarde van startIndex gelijk is aan de waarde van endIndex, wordt met deze methode een lege tekenreeks geretourneerd. Wanneer de waarde van startIndex hoger is dan de waarde van endIndex, worden de parameters automatisch omgewisseld voordat de functie wordt uitgevoerd. De oorspronkelijke tekenreeks blijft ongewijzigd.

Parameters

	`startIndex:Number` (default = `0`) — Een geheel getal waarmee de index wordt aangegeven van het eerste teken dat moet worden gebruikt om de subtekenreeks te maken. Geldige waarden voor `startIndex` zijn `0` tot en met `String.length`. Wanneer `startIndex` een negatieve waarde is, wordt `0` gebruikt.

	`endIndex:Number` (default = `0x7fffffff`) — Een geheel getal dat één groter is dan de index van het laatste teken in de geëxtraheerde subtekenreeks. Geldige waarden voor `endIndex` zijn `0` tot en met `String.length`. Het teken bij `endIndex` wordt niet opgenomen in de subtekenreeks. De standaardwaarde is de maximumwaarde die voor een index is toegestaan. Wanneer deze parameter wordt weggelaten, wordt `String.length` gebruikt. Wanneer deze parameter een negatieve waarde is, wordt `0` gebruikt.

Geretourneerde waarde

String — Een subtekenreeks van de opgegeven parameters.

toLocaleLowerCase

()

methode

AS3 function toLocaleLowerCase():String

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Retourneert een kopie van deze tekenreeks, waarbij alle hoofdletters zijn omgezet in kleine letters. De oorspronkelijke tekenreeks blijft ongewijzigd. Hoewel deze methode is bedoeld om de conversie af te handelen in overeenstemming met specifieke landinstellingen, produceert de implementatie van ActionScript 3.0 geen ander resultaat met de methode toLowerCase().

Geretourneerde waarde

String — Een kopie van deze tekenreeks waarbij alle hoofdletters zijn omgezet in kleine letters.

Verwante API-elementen

toLowerCase()

toLocaleUpperCase

()

methode

AS3 function toLocaleUpperCase():String

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Retourneert een kopie van deze tekenreeks, waarbij alle kleine letters zijn omgezet in hoofdletters. De oorspronkelijke tekenreeks blijft ongewijzigd. Hoewel deze methode is bedoeld om de conversie af te handelen in overeenstemming met specifieke landinstellingen, produceert de implementatie van ActionScript 3.0 geen ander resultaat met de methode toUpperCase().

Geretourneerde waarde

String — Een kopie van deze tekenreeks waarbij alle kleine letters zijn omgezet in hoofdletters.

Verwante API-elementen

toUpperCase()

toLowerCase

()

methode

AS3 function toLowerCase():String

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Retourneert een kopie van deze tekenreeks, waarbij alle hoofdletters zijn omgezet in kleine letters. De oorspronkelijke tekenreeks blijft ongewijzigd.

Met deze methode worden alle tekens (niet alleen A-Z) omgezet waarvoor een Unicode-equivalent in kleine letters bestaat:

     var str:String = " JOSÉ BARÇA";
     trace(str.toLowerCase()); // josé barça

Deze toewijzingen van hoofdletters en kleine letters worden gedefinieerd in de specificaties van de Unicode-tekendatabase

Geretourneerde waarde

String — Een kopie van deze tekenreeks waarbij alle hoofdletters zijn omgezet in kleine letters.

Verwante API-elementen

toUpperCase()

toUpperCase

()

methode

AS3 function toUpperCase():String

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Retourneert een kopie van deze tekenreeks, waarbij alle kleine letters zijn omgezet in hoofdletters. De oorspronkelijke tekenreeks blijft ongewijzigd.

Met deze methode worden alle tekens (niet alleen a-z) omgezet waarvoor een Unicode-equivalent in hoofdetters bestaat.

     var str:String = "José Barça";
     trace(str.toUpperCase()); // JOSÉ BARÇA

Deze toewijzingen van hoofdletters en kleine letters worden gedefinieerd in de specificaties van de Unicode-tekendatabase

Geretourneerde waarde

String — Een kopie van deze tekenreeks waarbij alle kleine letters zijn omgezet in hoofdletters.

Verwante API-elementen

toLowerCase()

valueOf

()

methode

AS3 function valueOf():String

Taalversie:

ActionScript 3.0

Runtimeversies:

Flash Lite 4, Flash Player 9, AIR 1.0

Retourneert de primitieve waarde van een instantie String. Deze methode is ontworpen om een object String om te zetten in een primitieve tekenreekswaarde. Omdat Flash automatisch valueOf() aanroept wanneer dit nodig is, hoeft u deze methode zelden expliciet aan te roepen.

Geretourneerde waarde

String — De waarde van de tekenreeks.

Voorbeelden Hoe dit voorbeeld te gebruiken

StringExample.as

In het volgende voorbeeld worden de klassen StringExample en StringHelper gebruikt om te tonen hoe u verschillende methoden van de klasse String kunt gebruiken. Hierbij moeten de volgende stappen worden uitgevoerd:

De constructor voor StringExample declareert diverse lokale instanties van String, die worden geïnitialiseerd met verschillende tekenreeksen en een nieuw object StringHelper.
De klasse StringHelper kent de volgende methoden:
- replace(): hiermee worden de methoden split() en join() van String aangeroepen om een subtekenreeks van de doorgegeven tekenreeks te verwijderen met een nieuwe.
- trim(): hiermee wordt zowel trimBack() als trimFront() aangeroepen met behulp van de doorgegeven tekenreeksen en wordt de bijgewerkte tekenreeks geretourneerd.
- trimFront(): hiermee worden alle tekens recursief verwijderd die overeenkomen met de parameter char, te beginnen vanaf de voorkant van de tekenreeks naar achteren toe, tot het eerste teken in de tekenreeks niet overeenkomt met char en wordt de bijgewerkte tekenreeks geretourneerd.
- trimBack(): hiermee worden alle tekens recursief verwijderd die overeenkomen met de parameter char, te beginnen vanaf de einde van de tekenreeks naar voren toe, tot het laatste teken in de tekenreeks niet overeenkomt met char en wordt de bijgewerkte tekenreeks geretourneerd.
- stringToCharacter(): hiermee wordt het eerste teken van de tekenreeks die wordt doorgegeven geretourneerd.
Vervolgens worden drie tekenreeksen geproduceerd met behulp van de gedeclareerde tekenreeksvariabelen met het aanroepen van de methode replace() die wordt gebruikt om de tweede tekenreeks te produceren en trim() om de derde tekenreeks te produceren.

package {
    import flash.display.Sprite;

    public class StringExample extends Sprite {
        public function StringExample() {
            var companyStr:String = new String("     Company X");
            var productStr:String = "Product Z Basic     ";
            var emptyStr:String = " ";
            var strHelper:StringHelper = new StringHelper();

            var companyProductStr:String = companyStr + emptyStr + productStr;
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Basic     '

            companyProductStr = strHelper.replace(companyProductStr, "Basic", "Professional");
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Professional     '

            companyProductStr = strHelper.trim(companyProductStr, emptyStr);
            trace("'" + companyProductStr + "'");    // 'Company X Product Z Professional'
        }
    }
}

class StringHelper {
    public function StringHelper() {
    }

    public function replace(str:String, oldSubStr:String, newSubStr:String):String {
        return str.split(oldSubStr).join(newSubStr);
    }

    public function trim(str:String, char:String):String {
        return trimBack(trimFront(str, char), char);
    }

    public function trimFront(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(0) == char) {
            str = trimFront(str.substring(1), char);
        }
        return str;
    }

    public function trimBack(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(str.length - 1) == char) {
            str = trimBack(str.substring(0, str.length - 1), char);
        }
        return str;
    }

    public function stringToCharacter(str:String):String {
        if (str.length == 1) {
            return str;
        }
        return str.slice(0, 1);
    }
}

Juridische kennisgeving | Online privacybeleid

String - AS3

Klassen x

length

String

charAt

charCodeAt

concat

fromCharCode

indexOf

lastIndexOf

localeCompare

match

replace

search

slice

split

substr

substring

toLocaleLowerCase

toLocaleUpperCase

toLowerCase

toUpperCase

valueOf