Constanten en functies op hoofdniveau - Details Bron voor Adobe ActionScript® 3 (AS3 ) API

Functies op hoofdniveau of algemene functies zijn beschikbaar in elk deel van een SWF-bestand waar ActionScript-code wordt gebruikt of in elke door de gebruiker gedefinieerde klasse. De meeste algemene functies van ActionScript 2.0 zijn gemigreerd naar klassen.

Algemene functies

	Functie		Gedefinieerd door
		Array(... args):Array Maakt een nieuwe array.	Hoofdniveau
		Boolean(expression:Object):Boolean Zet de parameter expression om in een Booleaanse waarde en retourneert de waarde.	Hoofdniveau
		decodeURI(uri:String):String Decodeert een gecodeerde URI tot een tekenreeks.	Hoofdniveau
		decodeURIComponent(uri:String):String Decodeert een gecodeerde URI-component tot een tekenreeks.	Hoofdniveau
		encodeURI(uri:String):String Codeert een tekenreeks tot een geldige URI (Uniform Resource Identifier).	Hoofdniveau
		encodeURIComponent(uri:String):String Codeert een tekenreeks tot een geldige URI-component.	Hoofdniveau
		escape(str:String):String Zet de parameter in een tekenreeks om en codeert deze in een URL-gecodeerde indeling, waarbij alle niet-alfanumerieke tekens worden vervangen door reeksen die bestaan uit een procentteken (%) en een hexadecimale code.	Hoofdniveau
		int(value:Number):int Zet een bepaalde numerieke waarde om in een geheel-getalwaarde.	Hoofdniveau
		isFinite(num:Number):Boolean Retourneert true wanneer de waarde een eindig getal is en false wanneer de waarde Infinity of -Infinity is.	Hoofdniveau
		isNaN(num:Number):Boolean Retourneert true wanneer de waarde NaN (Not a Number) is.	Hoofdniveau
		isXMLName(str:String):Boolean Bepaalt of de opgegeven tekenreeks een geldige naam voor een XML-element of XML-kenmerk is.	Hoofdniveau
		Number(expression:Object):Number Zet een bepaalde waarde om in een waarde Number.	Hoofdniveau
		Object(value:Object):Object Elke waarde in ActionScript 3.0 is een object, met andere woorden, door het aanroepen van Object() op een waarde, wordt die waarde geretourneerd.	Hoofdniveau
		parseFloat(str:String):Number Zet een tekenreeks om in een drijvende-kommagetal.	Hoofdniveau
		parseInt(str:String, radix:uint = 0):Number Zet een tekenreeks om in een geheel getal.	Hoofdniveau
		String(expression:Object):String Retourneert een tekenreeksrepresentatie van de opgegeven parameter.	Hoofdniveau
		trace(... arguments):void Geeft expressies weer, of schijft deze naar logbestanden, tijdens foutopsporing.	Hoofdniveau
		uint(value:Number):uint Zet een bepaalde numerieke waarde om in een geheel getal zonder teken.	Hoofdniveau
		unescape(str:String):String Evalueert de parameter str als een tekenreeks, decodeert de URL-gecodeerde tekenreeks (alle hexadecimale reeksen worden in ASCII-tekens omgezet) en retourneert de tekenreeks.	Hoofdniveau
		Vector(sourceArray:Object):Vector.<T> Maakt een nieuwe Vectorinstantie waarvan de elementen instanties van het opgegeven gegevenstype zijn.	Hoofdniveau
		XML(expression:Object):XML Zet een object om in een XML-object.	Hoofdniveau
		XMLList(expression:Object):XMLList Zet een object om in een object XMLList.	Hoofdniveau

Constanten op hoofdniveau of algemene constanten zijn beschikbaar voor elk script en zijn zichtbaar voor elke tijdlijn en elk bereik in uw document.

Algemene constanten

	Constante		Gedefinieerd door
		Infinity : Number Een speciale waarde die positieve Infinity vertegenwoordigt.	Hoofdniveau
		-Infinity : Number Een speciale waarde die negatieve Infinity vertegenwoordigt.	Hoofdniveau
		NaN : Number Een speciaal lid van het gegevenstype Number dat een waarde vertegenwoordigt die NAN (Not a Number) is.	Hoofdniveau
		undefined : * Een speciale waarde die van toepassing is op variabelen zonder type die niet zijn geïnitialiseerd of op dynamische objecteigenschappen die niet zijn geïnitialiseerd.	Hoofdniveau

Constantedetails

-Infinity

Constante

public const -Infinity:Number

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9

Een speciale waarde die negatieve Infinity vertegenwoordigt. De waarde van deze constante is hetzelfde als Number.NEGATIVE_INFINITY.

Verwante API-elementen

Number.NEGATIVE_INFINITY

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

Het resultaat van het delen door 0 is -Infinity, maar alleen wanneer de deler een negatief getal is.


trace(0 / 0);  // NaN
trace(7 / 0);  // Infinity
trace(-7 / 0); // -Infinity

Infinity

Constante

public const Infinity:Number

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9

Een speciale waarde die positieve Infinity vertegenwoordigt. De waarde van deze constante is hetzelfde als Number.POSITIVE_INFINITY.

Verwante API-elementen

Number.POSITIVE_INFINITY

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

Het resultaat van het delen door 0 is Infinity, maar alleen wanneer de deler een positief getal is.


trace(0 / 0);  // NaN
trace(7 / 0);  // Infinity
trace(-7 / 0); // -Infinity

NaN

Constante

public const NaN:Number

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9

Een speciaal lid van het gegevenstype Number dat een waarde vertegenwoordigt die NaN (Not a Number) is. Wanneer een wiskundige expressie een waarde als resultaat heeft die niet kan worden uitgedrukt in een getal, is het resultaat NaN. In de volgende lijst worden veel voorkomende expressies beschreven die als resultaat NaN hebben.

Het delen door 0 heeft alleen NaN als resultaat wanneer de deler ook 0 is. Wanneer de deler groter is dan 0, heeft het delen door 0 Infinity als resultaat. Wanneer de deler kleiner is dan 0, heeft het delen door 0 -Infinity als resultaat;
Vierkantswortel van een negatief getal;
De arcsinus van een getal buiten het geldige bereik van 0-1;
Infinity afgetrokken van Infinity;
Infinity of -Infinity gedeeld door Infinity of -Infinity;
Infinity of -Infinity vermenigvuldigd door 0;

De waarde NaN is geen lid van de gegeventypen int of uint.

De waarde NaN wordt niet gelijk beschouwd aan elke andere waarde, inclusief NaN, waardoor met de gelijkheidsoperator niet kan worden getest of een expressie NaN is. U kunt bepalen of een getal de functie NaN is met isNaN().

Verwante API-elementen

isNaN()
Number.NaN

undefined

Constante

public const undefined:*

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9

Een speciale waarde die van toepassing is op variabelen zonder type die niet zijn geïnitialiseerd of op dynamische objecteigenschappen die niet zijn geïnitialiseerd. In ActionScript 3.0 kunnen alleen variabelen zonder type de waarde undefined bevatten, dit is niet het geval in ActionScript 1.0 en ActionScript 2.0. De volgende variabelen zijn bijvoorbeeld undefined omdat deze geen type hebben en niet geïnitialiseerd zijn:

var foo;
var bar:*;

De waarde undefined is tevens van toepassing op eigenschappen van dynamische objecten die niet-geïnitialiseerd of onbepaald zijn. Wanneer een object bijvoorbeeld een instantie is van de klasse Object, is de waarde van een dynamisch toegevoegde eigenschap undefined totdat een waarde wordt toegewezen aan die eigenschap.

Resultaten variëren wanneer undefined wordt gebruikt met verschillende functies:

De waarde die wordt geretourneerd door String(undefined), is undefined (undefined wordt omgezet in een tekenreeks).
De waarde die wordt geretourneerd door Number(undefined), is NaN.
De waarde die wordt geretourneerd door int(undefined) en uint(undefined), is 0.
De waarde die wordt geretourneerd door Object(undefined), is een nieuwe instantie Object.
Wanneer de waarde undefined wordt toegewezen aan een variabele met type, wordt de waarde omgezet in de standaardwaarde van het gegevenstype.

Verwar undefined niet met null. Wanneer null en undefined met de operator == (gelijk aan) worden vergeleken, worden ze als gelijk geïnterpreteerd. Wanneer null en undefined echter met de operator === (strikt gelijk aan) worden vergeleken, worden ze niet als gelijk geïnterpreteerd.

Verwante API-elementen

null

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

In het volgende voorbeeld wordt een variabele zonder type (myVar) gedeclareerd maar niet geïnitialiseerd. De waarde van myVar is undefined omdat de variabele geen type heeft. In beide gevallen is dit waar wanneer de variabele geen typeannotatie heeft en wanneer deze gebruik maakt van de speciale annotatie zonder type (*) (var myVar:*;).


// trace value of untyped and uninitialized variable
var myVar;
trace(myVar); // undefined

Dezelfde regel is van toepassing op niet-geïnitialiseerde eigenschappen van een dynamisch object. Bij de instantie obj van de dynamische klasse A bijvoorbeeld, is de waarde van obj.propName dat geen geïnitialiseerde eigenschap is van de instantie obj, undefined.


dynamic class A {}
var obj:A = new A()

// trace undefined property of obj
trace(obj.propName); // undefined

Functiedetails

Array

()

functie

public function Array(... args):Array

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Maakt een nieuwe array. De array kan een lengte hebben van nul of hoger. De array kan ook een enkel opgegeven object bevatten.

Wanneer u Array() aanroept zonder argumenten, wordt een lege array geretourneerd.
Wanneer u Array() aanroept met een argument van een geheel getal, wordt een array van de opgegeven lengte geretourneerd, maar de elementen van deze array bevatten ongedefinieerde waarden.
Wanneer u Array() aanroept met een opgegeven object, wordt een array met één element van het opgegeven object geretourneerd.

Het gebruik van de functie Array() is vergelijkbaar met het maken van een array via de constructor voor de Array-klasse, maar bij de functie Array() is alleen een enkele (of geen) parameterwaarde toegestaan. Met de functie Array() kunt u de nieuwe array niet vullen met meerdere waarden.

Opmerking: als u een nieuwe array wilt maken met de functie Array() en meerdere waarden doorgeeft als parameters om de array te vullen, wordt een compilerfout weergegeven. Bij de functie Array() is slechts één parameter toegestaan. Als u een array wilt vullen met meerdere waarden, moet u de constructor voor de Array-klasse gebruiken.

Met de functie Array() is typecasting van een object naar een array niet mogelijk. U kunt de operator as gebruiken voor expliciete typeomzettingen of typecasting wanneer het argument geen primitieve waarde is. Zie de voorbeeldsectie van dit item voor meer informatie. Als u een object als parameter doorgeeft aan de functie Array(), wordt een nieuwe array gemaakt waarin het object als een element is opgenomen.

Parameters

... args — U kunt geen argumenten doorgeven als u een lege array wilt; u kunt een argument van een geheel getal opgeven als u een array met een bepaalde lengte wilt, of u kunt een enkel object doorgeven als u een array wilt maken dat het enkele opgegeven object bevat.

Geretourneerde waarde

Array — Een array met een lengte van nul of meer.

Verwante API-elementen

Array, klasse
as, operator

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

In het volgende voorbeeld wordt de werking van de functie Array() getoond wanneer een argument geen primitieve waarde is. Een veel voorkomend geval van casting naar een array is de omzetting van een instantie Object waarbij de waarden worden opgeslagen in een array-notatie. Wanneer Array() wordt aangeroepen met een argument van het type Object of een ander niet-primitieve gegevenstype, wordt een verwijzing naar het object opgeslagen in een element van de nieuwe array. Wanneer het enige argument dat wordt doorgegeven, dus een object is, wordt een verwijzing naar dat object het eerste element van de nieuwe array.

var obj:Object = [ "a", "b", "c" ];
      
var newArray:Array = Array( obj );

trace(newArray == obj);    // false
trace(newArray[0] == obj); // true
trace(newArray[0][0])      // a
trace(newArray[0][1])      // b
trace(newArray[0][2])      // c

U kunt voor het casten van obj naar een array de operator as gebruiken . Deze retourneert een array-verwijzing wanneer obj een geldige array is en anders null:

var obj:Object = [ "a", "b", "c" ];
      
var newArray:Array = obj as Array;

trace(newArray == obj); // true
trace(newArray[0]);     // a
trace(newArray[1]);     // b
trace(newArray[2]);     // c

Boolean

()

functie

public function Boolean(expression:Object):Boolean

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Zet de parameter expression om in een Booleaanse waarde en retourneert de waarde.

De geretourneerde waarde hangt af van het gegevenstype en de waarde van het argument, zoals wordt beschreven in de volgende tabel:

Invoerwaarde	Voorbeeld	Geretourneerde waarde
`0`	`Boolean(0)`	`false`
`NaN`	`Boolean(NaN)`	`false`
Getal (niet `0` of `NaN`)	`Boolean(4)`	`true`
Lege tekenreeks	`Boolean("")`	`false`
Niet-lege tekenreeks	`Boolean("6")`	`true`
`null`	`Boolean(null)`	`false`
`undefined`	`Boolean(undefined)`	`false`
Instantie van klasse Object	`Boolean(new Object())`	`true`
Geen argument	`Boolean()`	`false`

In tegenstelling tot lagere versies van ActionScript, retourneert de functie Boolean() hetzelfde resultaat als de klasse constructor Boolean.

Parameters

expression:Object — Een expressie of object die/dat in een Booleaanse waarde moet worden omgezet.

Geretourneerde waarde

Boolean — Het resultaat van de omzetting naar Boolean.

decodeURI

()

functie

public function decodeURI(uri:String):String

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Decodeert een gecodeerde URI tot een tekenreeks. Retourneert een tekenreeks waarin alle tekens die eerder werden gecodeerd door de functie encodeURI, zijn hersteld naar de ongecodeerde representatie.

In de volgende tabel wordt de set van escape-reeksen weergegeven die niet zijn gedecodeerd naar tekens met de functie decodeURI. U kunt decodeURIComponent() gebruiken om de escape-reeksen uit deze tabel te decoderen.

Niet-gedecodeerde escape-reeksen	Overeenkomende tekens
`%23`	`#`
`%24`	`$`
`%26`	`&`
`%2B`	`+`
`%2C`	`,`
`%2F`	`/`
`%3A`	`:`
`%3B`	`;`
`%3D`	`=`
`%3F`	`?`
`%40`	`@`

Parameters

uri:String — Een tekenreeks die is gecodeerd met de functie encodeURI.

Geretourneerde waarde

String — Een tekenreeks waarin alle tekens die eerder werden beschermd door de functie encodeURI, worden hersteld naar de onbeschermde representatie.

Verwante API-elementen

decodeURIComponent()
encodeURI()
encodeURIComponent()

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

package {
    import flash.display.Sprite;

    public class DecodeURIExample extends Sprite {
        public function DecodeURIExample() {
            var uri:String = "http://www.example.com/application.jsp?user=<user name='some user'></user>";
            var encoded:String = encodeURI(uri);
            var decoded:String = decodeURI(encoded);
            trace(uri);        // http://www.example.com/application.jsp?user=<user name='some user'></user>
            trace(encoded);    // http://www.example.com/application.jsp?user=%3Cuser%20name='some%20user'%3E%3C/user%3E
            trace(decoded);    // http://www.example.com/application.jsp?user=<user name='some user'></user>
        }
    }
}

decodeURIComponent

()

functie

public function decodeURIComponent(uri:String):String

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Decodeert een gecodeerde URI-component tot een tekenreeks. Retourneert een tekenreeks waarin alle tekens die eerder werden beschermd door de functie encodeURIComponent, zijn hersteld naar de ongecodeerde representatie.

Deze functie verschilt van de functie decodeURI() omdat deze functie alleen kan worden gebruikt voor het deel van een URI-tekenreeks dat URI-component wordt genoemd. Een URI-component is tekst die wordt weergegeven tussen speciale tekens die componentscheidingstekens worden genoemd (: / ; en ? ). Voorbeelden van URI-componenten die veel voorkomen zijn 'http' en 'www.adobe.com'.

Een ander belangrijk verschil tussen deze functie en decodeURI() is dat, aangezien deze functie ervan uitgaat dat de functie een URI-component verwerkt, deze functie de escape-reeksen die speciale scheidingstekens vertegenwoordigen (; / ? : @ & = + $ , # ), behandelt als normale tekst die moet worden gedecodeerd.

Parameters

uri:String — Een tekenreeks die is gecodeerd met de functie encodeURIComponent.

Geretourneerde waarde

String — Een tekenreeks waarin alle tekens die eerder werden beschermd door de functie encodeURIComponent, worden hersteld naar de onbeschermde representatie.

Verwante API-elementen

decodeURI()
encodeURI()
encodeURIComponent()

encodeURI

()

functie

public function encodeURI(uri:String):String

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Codeert een tekenreeks tot een geldige URI (Uniform Resource Identifier). Zet een volledige URI om in een tekenreeks waarin alle tekens zijn gecodeerd als UTF-8 escape-reeksen, tenzij een teken behoort tot een kleine groep basistekens.

In de volgende tabel wordt de volledige set van basistekens weergegeven die niet worden omgezet in UTF-8 escape-reeksen met de functie encodeURI.

Niet-gecodeerde tekens
`0 1 2 3 4 5 6 7 8 9`
`a b c d e f g h i j k l m n o p q r s t u v w x y z`
`A B C D E F G H I J K L M N O P Q R S T U V W X Y Z`
`; / ? : @ & = + $ , #`
`- _ . ! ~ * ' ( )`

Parameters

uri:String — Een tekenreeks die een volledige URI vertegenwoordigt.

Geretourneerde waarde

String — Een tekenreeks met bepaalde tekens die zijn gecodeerd als UTF-8 escape-reeksen.

Verwante API-elementen

decodeURI()
decodeURIComponent()
encodeURIComponent()

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

package {
    import flash.display.Sprite;

    public class EncodeURIExample extends Sprite {
        public function EncodeURIExample() {
            var uri:String = "http://www.example.com/application.jsp?user=<user name='some user'></user>";
            var encoded:String = encodeURI(uri);
            var decoded:String = decodeURI(encoded);
            trace(uri);        // http://www.example.com/application.jsp?user=<user name='some user'></user>
            trace(encoded);    // http://www.example.com/application.jsp?user=%3Cuser%20name='some%20user'%3E%3C/user%3E
            trace(decoded);    // http://www.example.com/application.jsp?user=<user name='some user'></user>
        }
    }
}

encodeURIComponent

()

functie

public function encodeURIComponent(uri:String):String

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Codeert een tekenreeks tot een geldige URI-component. Zet een subtekenreeks van een URI om in een tekenreeks waarin alle tekens zijn gecodeerd als UTF-8 escape-reeksen, tenzij een teken behoort tot een zeer kleine groep basistekens.

De functie encodeURIComponent() verschilt van de functie encodeURI() omdat deze functie alleen kan worden gebruikt voor het deel van een URI-tekenreeks dat URI-component wordt genoemd. Een URI-component is tekst die wordt weergegeven tussen speciale tekens die componentscheidingstekens worden genoemd (: / ; en ? ). Voorbeelden van URI-componenten die veel voorkomen zijn 'http' en 'www.adobe.com'.

Een ander belangrijk verschil tussen deze functie en encodeURI() is dat, aangezien deze functie ervan uitgaat dat de functie een URI-component verwerkt, deze functie de escape-reeksen die speciale scheidingstekens vertegenwoordigen (; / ? : @ & = + $ , # ), behandelt als normale tekst die moet worden gecodeerd.

In de volgende tabel worden alle tekens weergegeven die niet worden omgezet in UTF-8 escape-reeksen met de functie encodeURIComponent.

Niet-gecodeerde tekens
`0 1 2 3 4 5 6 7 8 9`
`a b c d e f g h i j k l m n o p q r s t u v w x y z`
`A B C D E F G H I J K L M N O P Q R S T U V W X Y Z`
`- _ . ! ~ * ' ( )`

Parameters

uri:String

Geretourneerde waarde

String

Verwante API-elementen

decodeURI()
decodeURIComponent()
encodeURI()

escape

()

functie

public function escape(str:String):String

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Zet de parameter in een tekenreeks om en codeert deze in een URL-gecodeerde indeling, waarbij alle niet-alfanumerieke tekens worden vervangen door reeksen die bestaan uit een procentteken (%) en een hexadecimale code. Wanneer deze functie in een URL-gecodeerde tekenreeks wordt gebruikt, wordt het percentagesymbool (%) gebruikt voor escape-tekens en is het niet gelijk aan de operator % (restbepaling bij deling).

In de volgende tabel worden alle tekens weergegeven die niet worden omgezet in escape-reeksen met de functie escape().

Niet-gecodeerde tekens
`0 1 2 3 4 5 6 7 8 9`
`a b c d e f g h i j k l m n o p q r s t u v w x y z`
`A B C D E F G H I J K L M N O P Q R S T U V W X Y Z`
`@ - _ . * + /`

Opmerking: gebruik de functie encodeURIComponent() in plaats van de functie escape() als u speciale scheidingstekens (@ + /) wilt behandelen als normale tekst om te worden gecodeerd.

Parameters

str:String — De expressie die in een tekenreeks wordt omgezet en in een URL-gecodeerde indeling wordt gecodeerd.

Geretourneerde waarde

String — Een URL-gecodeerde tekenreeks.

Verwante API-elementen

unescape()
encodeURIComponent()

int

()

functie

public function int(value:Number):int

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Zet een bepaalde numerieke waarde om in een geheel-getalwaarde. Decimale waarden worden ingekort bij het decimaalteken.

Parameters

value:Number — Een waarde die naar een geheel getal moet worden omgezet.

Geretourneerde waarde

int — De omgezette geheel-getalwaarde.

Verwante API-elementen

uint()

isFinite

()

functie

public function isFinite(num:Number):Boolean

Taalversie:

ActionScript 3.0.

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Retourneert true wanneer de waarde een eindig getal is en false wanneer de waarde Infinity of -Infinity is. De aanwezigheid van Infinity of -Infinity geeft een wiskundige fout aan, zoals het delen door 0.

Parameters

num:Number — Een getal dat wordt geëvalueerd als eindig of oneindig.

Geretourneerde waarde

Boolean — Retourneert true wanneer het getal eindig is en false wanneer het getal oneindig of negatief oneindig is.

isNaN

()

functie

public function isNaN(num:Number):Boolean

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Retourneert true wanneer de waarde NaN (Not a Number) is. De functie isNaN() is nuttig om te controleren of een wiskundige expressie met succes naar een getal evalueert. isNaN() wordt het meest gebruikt om de waarde te controleren die is geretourneerd van de functies parseInt() en parseFloat(). De waarde NaN is een speciaal lid van het gegevenstype Number dat een waarde vertegenwoordigt die NaN (Not a Number) is.

Opmerking: De waarde NaN is geen lid van de gegeventypen int of uint.

In de volgende tabel wordt de geretourneerde waarde van isNaN() op verschillende invoertypen en -waarden beschreven. (Als uw compilerwaarschuwingen zijn ingesteld op strikt, genereren sommige van de volgende bewerkingen waarschuwingen.)

Invoertype/waarde	Voorbeeld	Geretourneerde waarde
0 gedeeld door 0	`isNaN(0/0)`	`true`
Getal, niet gelijk aan nul, gedeeld door `0`	`isNaN(5/0)`	`false`
Vierkantswortel van een negatief getal	`isNaN(Math.sqrt(-1))`	`true`
Arcsinus van getal groter dan 1 of kleiner dan 0	`isNaN(Math.asin(2))`	`true`
String die kan worden omgezet in Number	`isNaN("5")`	`false`
String die niet kan worden omgezet in Number	`isNaN("5a")`	`true`

Parameters

num:Number — Een numerieke waarde of wiskundige expressie die wordt geëvalueerd.

Geretourneerde waarde

Boolean — Retourneert true wanneer de waarde NaN (Not a Number) is, anders false.

isXMLName

()

functie

public function isXMLName(str:String):Boolean

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Bepaalt of de opgegeven tekenreeks een geldige naam voor een XML-element of XML-kenmerk is.

Parameters

str:String — Een tekenreeks die wordt geëvalueerd.

Geretourneerde waarde

Boolean — Retourneert true wanneer het argument str een geldige XML-naam is; anders false.

Number

()

functie

public function Number(expression:Object):Number

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Zet een bepaalde waarde om in een waarde Number. In de volgende tabel wordt het resultaat van diverse invoertypen weergegeven:

Invoertype/waarde	Voorbeeld	Geretourneerde waarde
`undefined`	`Number(undefined)`	`NaN`
`null`	`Number(null)`	`0`
`true`	`Number(true)`	`1`
`false`	`Number(false)`	`0`
`NaN`	`Number(NaN)`	`NaN`
Lege tekenreeks	`Number("")`	`0`
String die wordt omgezet in Number	`Number("5")`	Het getal (bijvoorbeeld `5`)
String die niet wordt omgezet in Number	`Number("5a")`	`NaN`

Parameters

expression:Object — Een waarde die in een getal moet worden omgezet.

Geretourneerde waarde

Number — De omgezette getalwaarde.

Object

()

functie

public function Object(value:Object):Object

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Elke waarde in ActionScript 3.0 is een object, met andere woorden, door het aanroepen van Object() op een waarde, wordt die waarde geretourneerd.

Parameters

value:Object — Een object of een getal, tekenreeks of Booleaanse waarde dat/die moet worden omgezet.

Geretourneerde waarde

Object — De waarde die wordt opgegeven door de parameter value.

parseFloat

()

functie

public function parseFloat(str:String):Number

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Zet een tekenreeks om in een drijvende-kommagetal. De functie leest, of parseert, en retourneert de getallen in een tekenreeks totdat een teken wordt bereikt dat geen deel uitmaakt van het eerste getal. Wanneer de tekenreeks niet met een getal begint dat kan worden geparseerd, retourneert parseFloat() NaN. Spaties voorafgaand aan geldige gehele getallen worden genegeerd, evenals navolgende niet-numerieke tekens.

Parameters

str:String — De tekenreeks die moet worden gelezen en omgezet in een drijvende-kommagetal.

Geretourneerde waarde

Number — Een getal of NaN (geen getal).

parseInt

()

functie

public function parseInt(str:String, radix:uint = 0):Number

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Zet een tekenreeks om in een geheel getal. Wanneer de opgegeven tekenreeks in de parameter niet in een getal kan worden omgezet, retourneert de functie NaN. Tekenreeksen die met 0x beginnen, worden als hexadecimale getallen geïnterpreteerd. In tegenstelling tot lagere versies van ActionScript worden gehele getallen die beginnen met 0 niet geïnterpreteerd als octale getallen. U moet een radix van 8 opgeven voor octale getallen. Spaties en nullen voorafgaand aan geldige gehele getallen worden genegeerd, evenals navolgende niet-numerieke tekens.

Parameters

	`str:String` — Een tekenreeks die in een geheel getal moet worden omgezet.

	`radix:uint` (default = `0`) — Een geheel getal dat de radix (grondgetal) van het te parseren getal vertegenwoordigt. Toegestane waarden lopen van 2 tot en met 36.

Geretourneerde waarde

Number — Een getal of NaN (geen getal).

String

()

functie

public function String(expression:Object):String

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Retourneert een tekenreeksrepresentatie van de opgegeven parameter.

In de volgende tabel wordt het resultaat van diverse invoertypen weergegeven:

Invoertype/waarde	Geretourneerde waarde
`undefined`	`undefined`
`null`	`null`
`true`	`true`
`false`	`"false"`
`NaN`	`NaN`
String	String
Object	Object.toString()
Number	Tekenrepresentatie van het getal

Parameters

expression:Object — Een expressie die in een tekenreeks moet worden omgezet.

Geretourneerde waarde

String — Een tekenreeksrepresentatie van een waarde die is doorgegeven voor de parameter expression.

trace

()

functie

public function trace(... arguments):void

Taalversie:

ActionScript 3.0

Runtimeversies:

Flash Player 9, AIR 1.0, Flash Lite 4

Geeft expressies weer, of schijft deze naar logbestanden, tijdens foutopsporing. Een instructie trace kan meerdere argumenten ondersteunen. Wanneer een argument in een instructie trace een ander gegevenstype dan een tekenreeks bevat, roept de functie trace de bijbehorende methode toString() voor dat gegevenstype aan. Wanneer het argument bijvoorbeeld een Booleaanse waarde is, roept de functie trace Boolean.toString() aan en wordt de geretourneerde waarde weergegeven.

Parameters

... arguments — Een of meer expressies (gescheiden door een komma) die moeten worden geëvalueerd. Bij meerdere expressies wordt tussen elke expressie een spatie ingevoegd in de uitvoer.

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

In het volgende voorbeeld wordt de klasse TraceExample gebruikt om aan te geven hoe de methode trace() kan worden gebruikt om een eenvoudige tekenreeks af te drukken. In het algemeen wordt het bericht afgedrukt naar een Foutopsporingsconsole.

package {
    import flash.display.Sprite;

    public class TraceExample extends Sprite {

        public function TraceExample() {
            trace("Hello World");
        }
    }
}

uint

()

functie

public function uint(value:Number):uint

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Zet een bepaalde numerieke waarde om in een geheel getal zonder teken. Decimale waarden worden ingekort bij het decimaalteken.

In de volgende tabel wordt de geretourneerde waarde van uint() op verschillende invoertypen en -waarden beschreven.

Invoertype/waarde	Voorbeeld	Geretourneerde waarde
`undefined`	`uint(undefined)`	`0`
`null`	`uint(null)`	`0`
`0`	`uint(0)`	`0`
`NaN`	`uint(NaN)`	`0`
Positief drijvende-kommagetal	`uint(5.31)`	Ingekort geheel getal zonder teken (bijvoorbeeld `5`)
Negatief drijvende-kommagetal	`uint(-5,78)`	Kort het getal in tot een geheel getal en past vervolgens de regel voor negatieve gehele getallen toe.
Negatief geheel getal	`uint(-5)`	De som van `uint.MAX_VALUE` en het negatief gehele getal (bijvoorbeeld `uint.MAX_VALUE + (-5)`)
`true`	`uint(true)`	`1`
`false`	`uint(false)`	`0`
Lege tekenreeks	`uint("")`	`0`
String die wordt omgezet in Number	`uint("5")`	Het getal
String die niet wordt omgezet in Number	`uint("5a")`	`0`

Parameters

value:Number — Een waarde die naar een geheel getal moet worden omgezet.

Geretourneerde waarde

uint — De omgezette geheel-getalwaarde.

Verwante API-elementen

int()

unescape

()

functie

public function unescape(str:String):String

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Evalueert de parameter str als een tekenreeks, decodeert de URL-gecodeerde tekenreeks (alle hexadecimale reeksen worden in ASCII-tekens omgezet) en retourneert de tekenreeks.

Parameters

str:String — Een tekenreeks met hexadecimale reeksen waarvoor escape-tekens moeten worden gebruikt.

Geretourneerde waarde

String — Een tekenreeks die is gedecodeerd uit een URL-gecodeerde parameter.

Vector

()

functie

public function Vector(sourceArray:Object):Vector.<T>

Taalversie:

ActionScript 3.0

Runtimeversies:

Flash Player 10, AIR 1.5, Flash Lite 4

Maakt een nieuwe Vectorinstantie waarvan de elementen instanties van het opgegeven gegevenstype zijn. Wanneer u deze functie aanroept, geeft u het gegevenstype van de elementen van de resulterende Vector op (het basistype van de Vector) met behulp van een parameter type. Deze functie gebruikt dezelfde syntaxis als bij het declareren van een Vectorinstantie of bij het aanroepen van de nieuwe Vector.<T>()-constructor:

var v:Vector.<String> = Vector.<String>(["Hello", "World"]);

De resulterende Vector wordt voorzien van de waarden in de elementen van het argument sourceArray. Als het argument sourceArray al een Vector.<T>-instantie is waarbij T het basistype is, retourneert de functie die Vector. Anders wordt de resulterende Vector voorzien van de elementen van de sourceArray-Array of -Vector.

In elk geval moet het gegevenstype van alle elementen van het argument sourceArray overeenkomen met het basistype T dat is opgegeven in de functieaanroep.

Als het argument sourceArray lengte 0 heeft, retourneert de functie een lege Vector.

Als een Vector wordt doorgegeven als het argument sourceArray en het basistype is niet T, of als een Array wordt doorgegeven en de elementen zijn niet allemaal instanties van gegevenstype T, wordt geprobeerd de waarden naar het basistype te converteren. Als de waarden automatisch kunnen worden geconverteerd, bevat de resulterende Vector de geconverteerde waarden. Als conversie niet mogelijk is, treedt een fout op.

Als een element in het argument sourceArray een instantie is van een subklasse van het basistype T, slaagt de aanroep en wordt het element aan de resulterende Vector toegevoegd. Dit werkt zelfs als het argument sourceArray een Vector is waarvan het basistype een subklasse is van T. Dit is zelfs de enige manier om een Vector met basistype T te converteren naar een Vector met een basistype dat een superklasse is van T.

De volgende code resulteert bijvoorbeeld in een compileerfout in strikte modus of in een TypeError-fout tijdens runtime, omdat geprobeerd wordt een Vector.<Sprite> toe te wijzen aan een Vector.<DisplayObject>-variabele (Sprite is een subklasse van DisplayObject):

     var v1:Vector.<Sprite> = new Vector.<Sprite>();
     v1[0] = new Sprite();
     var v2:Vector.<DisplayObject> = v1;

De volgende alternatieve versie van de code kopieert de elementen van een Vector.<Sprite>-instantie naar een Vector.<DisplayObject>-instantie:

     var v1:Vector.<Sprite> = new Vector.<Sprite>();
     v1[0] = new Sprite();
     var v2:Vector.<DisplayObject> = Vector.<DisplayObject>(v1);

Parameters

sourceArray:Object — Een Array- of Vectorinstantie waarvan de elementen de elementen van de resulterende Vector worden. Als het argument een Vectorinstantie is waarvan het daaraan gekoppelde gegevenstype hetzelfde is als het opgegeven gegevenstype, wordt het argument geretourneerd als het resultaat van de functie.

Geretourneerde waarde

Vector.<T> — Een Vectorinstantie die is voorzien van de elementen van de sourceArray-array.

Gegenereerde uitzondering

TypeError — Als het argument sourceArray een element bevat dat niet naar het opgegeven gegevenstype kan worden geconverteerd.

Verwante API-elementen

Vectorklasse

XML

()

functie

public function XML(expression:Object):XML

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Zet een object om in een XML-object.

In de volgende tabel worden de geretourneerde waarden beschreven voor verschillende invoertypen.

Type parameter	Geretourneerde waarde
Boolean	Waarde wordt eerst omgezet in een tekenreeks, daarna in een XML-object.
Null	Er wordt een fout bij uitvoering gegenereerd (uitzondering TypeError).
Number	Waarde wordt eerst omgezet in een tekenreeks, daarna in een XML-object.
Object	Zet de waarde alleen om in XML wanneer deze een tekenreeks, een getal of een Booleaanse waarde is. Anders wordt een fout bij uitvoering gegenereerd (uitzondering TypeError).
String	Waarde wordt omgezet in XML.
Ongedefinieerd	Er wordt een fout bij uitvoering gegenereerd (uitzondering TypeError).
XML	Invoerwaarde wordt ongewijzigd geretourneerd.
XMLList	Retourneert alleen een XML-object wanneer het object XMLList slechts één eigenschap van het type XML bevat. Anders wordt een fout bij uitvoering gegenereerd (uitzondering TypeError).

Parameters

expression:Object — Object dat moet worden omgezet in XML.

Geretourneerde waarde

XML — Een XML-object dat waarden bevat van het omgezette object.

Verwante API-elementen

XMLList()

XMLList

()

functie

public function XMLList(expression:Object):XMLList

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Zet een object om in een object XMLList.

In de volgende tabel worden de geretourneerde waarden beschreven voor verschillende invoertypen.

Type parameter	Geretourneerde waarde
Boolean	Waarde wordt eerst omgezet in een tekenreeks, daarna in een object XMLList.
Null	Er wordt een fout bij uitvoering gegenereerd (uitzondering TypeError).
Number	Waarde wordt eerst omgezet in een tekenreeks, daarna in een object XMLList.
Object	Zet de waarde alleen om in XMLList wanneer deze een tekenreeks, een getal of een Booleaanse waarde is. Anders wordt een fout bij uitvoering gegenereerd (uitzondering TypeError).
String	Waarde wordt omgezet in een object XMLList.
Ongedefinieerd	Er wordt een fout bij uitvoering gegenereerd (uitzondering TypeError).
XML	Waarde wordt omgezet in een object XMLList.
XMLList	Invoerwaarde wordt ongewijzigd geretourneerd.

Parameters

expression:Object — Object dat moet worden omgezet in een object XMLList.

Geretourneerde waarde

XMLList — Een object XMLList dat waarden bevat van het omgezette object.

Verwante API-elementen

XML()

Juridische kennisgeving | Online privacybeleid

Hoofdniveau

Klassen x

-Infinity

Infinity

NaN

undefined

Array

Boolean

decodeURI

decodeURIComponent

encodeURI

encodeURIComponent

escape

int

isFinite

isNaN

isXMLName

Number

Object

parseFloat

parseInt

String

trace

uint

unescape

Vector

XML

XMLList