XML  - AS3

Bepaalt of XML-opmerkingen worden genegeerd wanneer XML-objecten de bron-XML-gegevens parseren. De opmerkingen worden standaard genegeerd (true). Wanneer u XML-opmerkingen wilt opnemen, moet u deze eigenschap instellen op false. De eigenschap ignoreComments wordt alleen tijdens de XML-parsering gebruikt en niet tijdens het aanroepen van een methode als myXMLObject.child(*).toXMLString(). Wanneer de bron-XML opmerkingsknooppunten bevat, worden deze tijdens de XML-parsering bewaard of genegeerd.

Verwante API-elementen

XML.ignoreComments = false;
var xml1:XML = 
        <foo>
            <!-- comment -->
        </foo>;
trace(xml1.toXMLString()); // <foo><!-- comment --></foo>

XML.ignoreComments = true;
var xml2:XML = 
        <foo>
            <!-- example -->
        </foo>;
trace(xml2.toXMLString()); // <foo/>

Bepaalt of XML-verwerkingsinstructies worden genegeerd wanneer XML-objecten de bron-XML-gegevens parseren. De verwerkingsinstructies worden standaard genegeerd (true). Wanneer u XML-verwerkingsinstructies wilt opnemen, moet u deze eigenschap instellen op false. De eigenschap ignoreProcessingInstructions wordt alleen tijdens de XML-parsering gebruikt en niet tijdens het aanroepen van een methode als myXMLObject.child(*).toXMLString(). Wanneer de bron-XML verwerkingsinstructieknooppunten bevat, worden deze tijdens de XML-parsering bewaard of genegeerd.

Verwante API-elementen

XML.ignoreProcessingInstructions = false;
var xml1:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml1.toXMLString()); // <foo><?exampleInstruction ?></foo>

XML.ignoreProcessingInstructions = true;
var xml2:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml2.toXMLString()); // <foo/>

Bepaalt of witruimtetekens aan het begin en het einde van tekstknooppunten worden genegeerd tijdens parseren. Witruimte worden standaard genegeerd (true). Wanneer een tekstnode 100% witruimte is en de eigenschap ignoreWhitespace is ingesteld op true, wordt geen knooppunt gemaakt. Wanneer u witruimte wilt weergeven in een tekstnode, moet u de eigenschap ignoreWhitespace instellen op false.

Wanneer u een XML-object maakt, wordt de huidige waarde van de eigenschap ignoreWhitespace in de cache opgeslagen. Het wijzigen van ignoreWhitespace heeft geen invloed op het gedrag van bestaande XML-objecten.

XML.ignoreWhitespace = false;
var xml1:XML = <foo>    </foo>;
trace(xml1.children().length()); // 1

XML.ignoreWhitespace = true;
var xml2:XML = <foo>    </foo>;
trace(xml2.children().length()); // 0

Bepaalt de mate van inspringing die op de methoden toString() en toXMLString() wordt toegepast wanneer de eigenschap XML.prettyPrinting is ingesteld op true. Inspringing wordt toegepast met het spatieteken en niet met het tab-teken. De standaardwaarde is 2.

Verwante API-elementen

var xml:XML = <foo><bar/></foo>;
XML.prettyIndent = 0;
trace(xml.toXMLString());

XML.prettyIndent = 1;
trace(xml.toXMLString());

XML.prettyIndent = 2;
trace(xml.toXMLString());

Bepaalt of de methoden toString() en toXMLString() witruimtetekens tussen sommige tags normaliseren. De standaardwaarde is true.

Verwante API-elementen

var xml:XML = <foo><bar/></foo>;
XML.prettyPrinting = false;
trace(xml.toXMLString());

XML.prettyPrinting = true;
trace(xml.toXMLString());

Maakt een nieuw XML-object. U moet de constructor gebruiken om een XML-object te maken voordat u een methode van de klasse XML aanroept.

U kunt de methode toXMLString() gebruiken om een tekenreeksrepresentatie van het XML-object te retourneren, ongeacht of het XML-object eenvoudige inhoud of complexe inhoud bevat.

Verwante API-elementen

//
// Requires:
//   - TextArea control UI component in the Flash Professional Library.
//
import fl.controls.TextArea;
 
var xml:XML;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
 
var urlLoader:URLLoader = new URLLoader();
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
var textArea:TextArea = new TextArea();
textArea.move(5, 5);
textArea.setSize(stage.stageWidth - 10, stage.stageHeight - 10);
addChild(textArea);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.currentTarget.data);
    textArea.text = xml.toXMLString();
}

var xml:XML;
var textArea:TextField = new TextField();
textArea.width = 300;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.target.data);
    textArea.text = xml.toXMLString();
    addChild(textArea);
}

Voegt een naamruimte toe aan de verzameling naamruimten binnen bereik voor het XML-object. Wanneer de naamruimte al bestaat binnen het bereik van de naamruimten voor het XML-object (met een voorvoegsel dat overeenkomt met het voorvoegsel van de opgegeven parameter), wordt het voorvoegsel van de bestaande naamruimte ingesteld op undefined. Indien de invoerparameter een object Namespace is, wordt deze direct gebruikt. Indien dit een object QName is, wordt de URI van de invoerparameter gebruikt om een nieuwe naamruimte te maken. Zoniet, dan wordt deze omgezet in een tekenreeks en wordt een naamruimte gemaakt van deze tekenreeks.

Parameters

var xml1:XML = <ns:foo xmlns:ns="www.example.com/ns" />;
var nsNamespace:Namespace = xml1.namespace();

var xml2:XML = <bar />;
xml2.addNamespace(nsNamespace);
trace(xml2.toXMLString()); // <bar xmlns:ns="www.example.com/ns"/>

Voegt het opgegeven onderliggende item aan het einde van de eigenschappen van het XML-object toe. De methode appendChild() maakt gebruik van een XML-object, een object XMLList of een ander gegevenstype die vervolgens wordt omgezet in een tekenreeks.

Gebruik de operator delete (XML) om XML-knooppunten te verwijderen.

Parameters

Verwante API-elementen

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.appendChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>hello</p>
trace(xml.p[1].toXMLString()); // <p>world</p>

Retourneert de XML-waarde van het kenmerk waarvan de naam overeenkomt met de parameter attributeName. Kenmerken zijn beschikbaar binnen XML-elementen. In het volgende voorbeeld heeft het element een kenmerk met de naam gender en de waarde boy: <first gender="boy">John</first>.

De parameter attributeName kan elk gegevenstype zijn. Tekenreeks is echter het meest voorkomende gegevenstype. Wanneer een ander object wordt doorgegeven dan een object QName, gebruikt de parameter attributeName de methode toString() om de parameter om te zetten in een tekenreeks.

Wanneer u een gekwalificeerde naamverwijzing nodig heeft, kunt u een object QName doorgeven. Een object QName definieert een naamruimte en de lokale naam die u kunt gebruiken om de gekwalificeerde naam van een kenmerk te definiëren. Het aanroepen van attribute(qname) is dan ook niet hetzelfde als het aanroepen van attribute(qname.toString()).

Parameters

Verwante API-elementen

 var xml:XML = <ns:node xmlns:ns = "http://uri" ns:attr = '7' />       
 var qn:QName = new QName("http://uri", "attr");
 trace (xml.attribute(qn)); // 7

 var xml:XML = <example class="first" />
 trace(xml.attribute("class"));
 

Retourneert een lijst met kenmerkwaarden voor het opgegeven XML-object. U kunt de methode name() met de methode attributes() gebruiken om de naam van een kenmerk te retourneren. Gebruik van xml.attributes() is gelijk aan xml.@*.

Verwante API-elementen

var xml:XML=<example id='123' color='blue'/>
trace(xml.attributes()[1].name()); //color

 
var xml:XML = <example id='123' color='blue'/>
var attNamesList:XMLList = xml.@*;

trace (attNamesList is XMLList); // true
trace (attNamesList.length()); // 2

for (var i:int = 0; i < attNamesList.length(); i++)
{ 
    trace (typeof (attNamesList[i])); // xml
    trace (attNamesList[i].nodeKind()); // attribute
    trace (attNamesList[i].name()); // id and color
} 

Somt de onderliggende items van een XML-object op. Een onderliggend XML-item is een XML-element, -tekstknooppunt, -opmerking of -verwerkingsinstructie.

Gebruik de parameter propertyName om de inhoud van een specifiek onderliggend XML-item weer te geven. Als u bijvoorbeeld de inhoud van een onderliggend item met de naam <first> wilt retourneren, roept u child("first") van het XML-object aan. U kunt hetzelfde resultaat genereren met het indexnummer van het onderliggende item. Het indexnummer identificeert de positie van het onderliggende item in de lijst van andere onderliggende XML-items. child(0) retourneert bijvoorbeeld het eerste onderliggende item in een lijst.

U kunt een asterisk (*) gebruiken om alle onderliggende items in een XML-document weer te geven. Bijvoorbeeld doc.child("*").

U kunt de methode length() met de asteriskparameter (*) van de methode child() gebruiken om het totaal aantal onderliggende items weer te geven. Bijvoorbeeld numChildren = doc.child("*").length().

Parameters

Verwante API-elementen

var xml:XML = 
        <foo>
            <bar>text1</bar>
            <bar>text2</bar>
        </foo>;
trace(xml.child("bar").length());  // 2
trace(xml.child("bar")[0].toXMLString()); // <bar>text1</bar>
trace(xml.child("bar")[1].toXMLString()); // <bar>text2</bar>

Identificeert de op nul geïndexeerde positie van dit XML-object binnen de context van het bovenliggende object.

var xml:XML = 
            <foo>
                <bar />
                text
                <bob />
            </foo>;
trace(xml.bar.childIndex()); // 0
trace(xml.bob.childIndex()); // 2

Somt de onderliggende items van het XML-object op in de volgorde waarin zij worden weergegeven. Een onderliggend XML-item is een XML-element, -tekstknooppunt, -opmerking of -verwerkingsinstructie.

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var xml:XML = 
        <foo id="22">
            <bar>44</bar>
            text
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml.children().length()); // 4
trace(xml.children()[0].toXMLString()); // <bar>44</bar>
trace(xml.children()[1].toXMLString()); // text
trace(xml.children()[2].toXMLString()); // <!-- comment -->
trace(xml.children()[3].toXMLString()); // <?instruction ?>

Somt de eigenschappen op van het XML-object dat XML-opmerkingen bevat.

XML.ignoreComments = false;
var xml:XML = 
        <foo>
            <!-- example -->
            <!-- example2 -->
        </foo>;
trace(xml.comments().length()); // 2
trace(xml.comments()[1].toXMLString()); // <!-- example2 -->

Vergelijkt het XML-object met de opgegeven parameter value.

Parameters

var xml:XML = 
        <order>
            <item>Rice</item>
            <item>Kung Pao Shrimp</item>
        </order>;
trace(xml.item[0].contains(<item>Rice</item>)); // true
trace(xml.item[1].contains(<item>Kung Pao Shrimp</item>)); // true
trace(xml.item[1].contains(<item>MSG</item>)); // false

Retourneert een kopie van het opgegeven XML-object. De kopie is een duplicaat van de hele boomstructuur met knooppunten. Het gekopieerde XML-object heeft geen bovenliggende items en retourneert null wanneer u de methode parent() probeert aan te roepen.

var xml1:XML = <foo />;
var xml2:XML = xml1.copy();
xml2.appendChild(<bar />);
trace(xml1.bar.length()); // 0
trace(xml2.bar.length()); // 1

Retourneert een object met de volgende parameters ingesteld op de standaardwaarden: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent en prettyPrinting. De standaard waarden zijn:

• ignoreComments = true
• ignoreProcessingInstructions = true
• ignoreWhitespace = true
• prettyIndent = 2
• prettyPrinting = true

Opmerking: deze methode wordt niet toegepast op een instantie van de klasse XML. Deze methode wordt toegepast op XML, zoals in de volgende code: var df:Object = XML.defaultSettings().

Verwante API-elementen

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

Retourneert alle afstammingen (kinderen, kleinkinderen, achterkleinkinderen, enzovoort) van het XML-object die de opgegeven parameter name hebben. Deze parameter name is optioneel. De parameter name kan een object QName, een gegevenstype String of een ander gegevenstype zijn die vervolgens wordt omgezet in een gegevenstype String.

Gebruik de parameter '*' om alle afstammingen te retourneren. Wanneer geen parameter is doorgegeven, wordt de tekenreeks '*' doorgegeven en worden alle afstammingen van het XML-object geretourneerd.

Parameters

Verwante API-elementen

var xml:XML = 
  <enrollees>
    <student id="239">
        <class name="Algebra" />
        <class name="Spanish 2"/>
    </student>
    <student id="206">
        <class name="Trigonometry" />
        <class name="Spanish 2" />
    </student>
  </enrollees>
trace(xml.descendants("class")); 

XML.ignoreComments = false;
var xml:XML = 
        <body>
            <!-- comment -->
            text1
            <a>
                <b>text2</b>
            </a>
        </body>;
trace(xml.descendants("*").length()); // 5
trace(xml.descendants("*")[0]); // // <!-- comment -->
trace(xml.descendants("*")[1].toXMLString()); // text1
trace(xml.descendants("a").toXMLString()); // <a><b>text2</b></a>
trace(xml.descendants("b").toXMLString()); // <b>text2</b>

Somt de elementen van een XML-object op. Een element bestaat uit een start- en een eindtag. Voorbeeld: <first></first>. Deze parameter name is optioneel. De parameter name kan een object QName, een gegevenstype String of een ander gegevenstype zijn die vervolgens wordt omgezet in een gegevenstype String. U kunt de parameter name gebruiken om een specifiek element weer te geven. Het element first retourneert John in het volgende voorbeeld: <first>John</first>.

U kunt de asterisk (*) gebruiken als de parameter om alle elementen weer te geven. De asterisk is tevens de standaardparameter.

U kunt de methode length() gebruiken met de asteriskparameter om het totaal aantal elementen weer te geven. Bijvoorbeeld numElement = addressbook.elements("*").length().

Parameters

Verwante API-elementen

var xml:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
            text
            <a>1</a>
            <b>2</b>
        </foo>;
trace(xml.elements("*").length()); // 2
trace(xml.elements("*")[0].toXMLString()); // <a>1</a>
trace(xml.elements("b").length()); // 1
trace(xml.elements("b")[0].toXMLString()); // <b>2</b>

var xml:XML =
 <student id="206">
    <class name="Trigonometry" />
    <class name="Spanish 2" />
 </student>
trace(xml.elements("class")); 

Controleert of het XML-object complexe inhoud bevat. Een XML-object bevat complexe inhoud wanneer het onderliggende elementen heeft. XML-objecten die kenmerken, opmerkingen, verwerkingsinstructies en tekstknooppunten vertegenwoordigen, hebben geen complexe inhoud. Een object dat deze onderdelen bevat, kan echter nog altijd worden beschouwd als een object met complexe inhoud (wanneer het object onderliggende items heeft).

Verwante API-elementen

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

Controleert of het object de eigenschap heeft die door de parameter p wordt opgegeven.

Parameters

var xml:XML = 
        <foo>
            <a />
            <a>
                <b>10</b>
            </a>
            <a>
                <b>11</b>
            </a>
        </foo>;
trace(xml.a.(hasOwnProperty("b") && b == "11")); 

trace(xml.a.(b == "11"));

var xml:XML = 
        <orders>
            <order id='1'>
                <item>toothbrush</item>
                <item>toothpaste</item>
            </order>
            <order>
                <returnItem>shoe polish</returnItem>
            </order>
        </orders>;
trace(xml.order.(hasOwnProperty("item") && item.contains("toothbrush"))); 

Controleert of het XML-object eenvoudige inhoud bevat. Een XML-object bevat eenvoudige inhoud wanneer het een tekstknooppunt, een kenmerkknooppunt of een XML-element zonder onderliggende elementen vertegenwoordigt. XML-objecten die opmerkingen en verwerkingsinstructies vertegenwoordigen, bevatten geen eenvoudige inhoud.

Verwante API-elementen

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

Hiermee worden de naamruimten voor het XML-object opgesomd, gebaseerd op het bovenliggende item van het object.

Voegt de opgegeven parameter child2 in na de parameter child1 in dit XML-object en retourneert het resulterende object. Wanneer de parameter child1 null is, voegt de methode de inhoud van child2 in voor alle onderliggende items van het XML-object (in andere woorden, na geen). Wanneer child1 wordt opgegeven, maar deze niet bestaat in het XML-object, wordt het XML-object niet gewijzigd en wordt undefined geretourneerd.

Wanneer u deze methode aanroept voor een onderliggend XML-item dat geen element is (tekst, kenmerk, opmerkingen, pi, enzovoort), wordt undefined geretourneerd.

Gebruik de operator delete (XML) om XML-knooppunten te verwijderen.

Parameters

Verwante API-elementen

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildAfter(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

 <menu>
     <item>burger</item>
     <saleItem>fries</saleItem>
     <item>soda</item>
 </menu>

Voegt de opgegeven parameter child2 in vóór de parameter child1 in dit XML-object en retourneert het resulterende object. Wanneer de parameter child1 null is, voegt de methode de inhoud van child2 in na alle onderliggende items van het XML-object (in andere woorden, voor geen). Wanneer child1 wordt opgegeven, maar deze niet bestaat in het XML-object, wordt het XML-object niet gewijzigd en wordt undefined geretourneerd.

Wanneer u deze methode aanroept voor een onderliggend XML-item dat geen element is (tekst, kenmerk, opmerkingen, pi, enzovoort), wordt undefined geretourneerd.

Gebruik de operator delete (XML) om XML-knooppunten te verwijderen.

Parameters

Verwante API-elementen

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildBefore(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

 <menu>
     <saleItem>fries</saleItem>
     <item>burger</item>
     <item>soda</item>
 </menu>

Bij XML-objecten retourneert deze methode altijd het gehele getal 1. De methode length() van de klasse XMLList retourneert een waarde van 1 voor een object XMLList dat slechts een waarde bevat.

Geeft het lokale-naamgedeelte van de gekwalificeerde naam van het XML-object als resultaat.

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.localName()); // Envelope

Geeft de gekwalificeerde naam voor het XML-object als resultaat.

Verwante API-elementen

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.name().localName); // Envelope
trace(xml.name().uri); // "http://www.w3.org/2001/12/soap-envelope"

var xml:XML = 
        <foo x="15" y="22">
            text
        </foo>;
        
trace(xml.name().localName); // foo
trace(xml.name().uri == ""); // true
trace(xml.children()[0]); // text
trace(xml.children()[0].name()); // null
trace(xml.attributes()[0]); // 15
trace(xml.attributes()[0].name()); // x

Wanneer geen parameter is opgegeven, wordt als resultaat de naamruimte gegeven die is gekoppeld aan de gekwalificeerde naam voor dit XML-object. Wanneer een parameter prefix wordt opgegeven, retourneert de methode de naamruimte die overeenkomt met de parameter prefix en die binnen het bereik valt voor het XML-object. Wanneer er geen dergelijke naamruimte is, retourneert de methode undefined.

Parameters

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
var soap:Namespace = xml.namespace();
trace(soap.prefix); // soap
trace(soap.uri); // http://www.w3.org/2001/12/soap-envelope

var body:XML = xml.soap::Body[0];
trace(body.namespace().prefix); // soap
trace(xml.namespace().uri); // http://www.w3.org/2001/12/soap-envelope
trace(body.namespace("wx").uri); // "http://example.com/weather"

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">
                <!-- ... -->
        </rdf:RDF>;
                    
trace(xml.namespace()); // http://www.w3.org/1999/02/22-rdf-syntax-ns#
trace(xml.namespace("dc")); // http://purl.org/dc/elements/1.1/
trace(xml.namespace("foo")); // undefined

Somt naamruimtedeclaraties op die zijn gekoppeld aan het XML-object in de context van het bovenliggende item.

Verwante API-elementen

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">

            <!-- ... -->
            
        </rdf:RDF>;
                    
for (var i:uint = 0; i < xml.namespaceDeclarations().length; i++) {
    var ns:Namespace = xml.namespaceDeclarations()[i]; 
    var prefix:String = ns.prefix;
    if (prefix == "") {
        prefix = "(default)";
    }
    trace(prefix + ":" , ns.uri);
}

rdf: http://www.w3.org/1999/02/22-rdf-syntax-ns#
 dc: http://purl.org/dc/elements/1.1/
 (default): http://purl.org/rss/1.0/

Geeft het type knooppunt op: tekst, opmerking, verwerkingsinstructie, kenmerk of element.

Verwante API-elementen

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;

var xml:XML = 
    <example id="10">
        <!-- this is a comment -->
        <?test this is a pi ?>
        and some text
    </example>;

trace(xml.nodeKind()); // element
trace(xml.children()[0].nodeKind()); // comment
trace(xml.children()[1].nodeKind()); // processing-instruction
trace(xml.children()[2].nodeKind()); // text
trace(xml.@id[0].nodeKind()); // attribute

Voegt aangrenzende tekstknooppunten samen en verwijdert lege tekstknooppunten voor het XML-object en alle afstammende XML-objecten.

var xml:XML = <body></body>;
xml.appendChild("hello");
xml.appendChild(" world");
trace(xml.children().length()); // 2
xml.normalize();
trace(xml.children().length()); // 1

Retourneert het onderliggende item van het XML-object. Wanneer het XML-object geen bovenliggend item heeft, retourneert de methode undefined.

var xml:XML = 
    <body>
        <p id="p1">Hello</p>
        <p id="p2">Test:
            <ul>
                <li>1</li>
                <li>2</li>
            </ul>
        </p>
    </body>;
var node:XML = xml.p.ul.(li.contains("1"))[0]; // == <ul> ... </ul>
trace(node.parent().@id); // p2

Voegt een kopie van het opgegeven onderliggende object in het XML-element in voorafgaand aan bestaande XML-eigenschappen voor dat element.

Gebruik de operator delete (XML) om XML-knooppunten te verwijderen.

Parameters

Verwante API-elementen

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.prependChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>world</p>
trace(xml.p[1].toXMLString()); // <p>hello</p>

Wanneer een parameter name is opgegeven, worden hiermee alle onderliggende items van het XML-object opgesomd die verwerkingsinstructies met die name bevatten. Zonder parameters somt de methode alle onderliggende items van het XML-object op die verwerkingsinstructies bevatten.

Parameters

XML.ignoreProcessingInstructions = false;
var xml:XML =
    <body>
            foo
            <?xml-stylesheet href="headlines.css" type="text/css" ?>
            <?instructionX ?>
            
    </body>;

trace(xml.processingInstructions().length()); // 2
trace(xml.processingInstructions()[0].name()); // xml-stylesheet

Controleert of de eigenschap p voorkomt in de set eigenschappen die kan worden herhaald in een instructie for..in die op het XML-object wordt toegepast. Retourneert alleen true wanneer toString(p) == "0".

Parameters

var xml:XML = 
        <body>
             <p>Hello</p>
               <p>World</p>
        </body>;

trace(xml.propertyIsEnumerable(0)); // true
trace(xml.propertyIsEnumerable(1)); // false

for (var propertyName:String in xml) {
    trace(xml[propertyName]);
}

var list:XMLList = xml.p;
trace(list.propertyIsEnumerable(0)); // true
trace(list.propertyIsEnumerable(1)); // true
trace(list.propertyIsEnumerable(2)); // false

for (var propertyName:String in list) { 
    trace(list[propertyName]);
}

Verwijdert de opgegeven naamruimte voor dit object en alle afstammingen. De methode removeNamespaces() verwijdert geen naamruimte wanneer hiernaar wordt verwezen door de gekwalificeerde naam van het object of de gekwalificeerde naam van de kenmerken van het object.

Parameters

var xml:XML = 
    <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
        xmlns:dc="http://purl.org/dc/elements/1.1/" 
        xmlns="http://purl.org/rss/1.0/">
    
        <!-- ... -->
        
    </rdf:RDF>;

trace(xml.namespaceDeclarations().length); // 3
trace(xml.namespaceDeclarations()[0] is String); // 
var dc:Namespace = xml.namespace("dc");
xml.removeNamespace(dc);
trace(xml.namespaceDeclarations().length); // 2

Verwijdert de eigenschappen die door de parameter propertyName zijn opgegeven met de parameter value. Wanneer geen eigenschappen overeenkomen met propertyName, blijft het XML-object ongewijzigd.

Parameters

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace(1, <p>Bob</p>);
trace(xml);

 <body>
     <p>Hello</p>
     <p>Bob</p>
     <hr/>
 </body>
 

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("p", <p>Hi</p>); 
trace(xml);

 <body>
     <p>Hi</p>
     <hr/>
 </body>;
 

var xml:XML = 
    <ns:body xmlns:ns = "myNS">
        <ns:p>Hello</ns:p>
        <ns:p>World</ns:p>
        <hr/>
    </ns:body>;

var qname:QName = new QName("myNS", "p");
xml.replace(qname, <p>Bob</p>);
trace(xml);

 <ns:body xmlns:ns = "myNS">
     <p>Bob</p>
     <hr/>
 </ns:body>
 

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("*", <img src = "hello.jpg"/>);
trace(xml);

 <body>
     <img src="hello.jpg"/>
 </body>
 

Vervangt de eigenschappen van het onderliggende item van het XML-object door de set XML-eigenschappen die in de parameter value is opgegeven.

Parameters

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
    </body>;

var list:XMLList = xml.p;

xml.setChildren(<p>hello</p>);
trace(xml);

//    <body>
//        <p>hello</p>
//    </body>

xml.setChildren(list);
trace(xml);

//    <body>
//        <p>Hello</p>
//        <p>World</p>
//    </body>

Wijzigt de lokale naam van het XML-object in de opgegeven parameter name.

Parameters

var xml:XML = 
    <ns:item xmlns:ns="http://example.com">
        toothbrush
    </ns:item>;
    
xml.setLocalName("orderItem");
trace(xml.toXMLString()); // <ns:orderItem xmlns:ns="http://example.com">toothbrush</ns:orderItem>

Stelt de naam van het XML-object in op de opgegeven gekwalificeerde naam of kenmerknaam.

Parameters

var xml:XML = 
    <item>
        toothbrush
    </item>;
    
xml.setName("orderItem");
trace(xml.toXMLString()); // <orderItem>toothbrush</orderItem>

Stelt de naamruimte in die aan het XML-object is gekoppeld.

Parameters

var xml1:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
            <!-- ... -->
        </soap:Envelope>;
var ns:Namespace = xml1.namespace("soap");

var xml2:XML = 
    <Envelope>
        <Body/>
    </Envelope>;
    
xml2.setNamespace(ns);

trace(xml2);

Stelt de waarden voor de volgende XML-eigenschappen in: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent en prettyPrinting. De volgende instellingen worden standaard toegepast wanneer geen parameter setObj wordt opgegeven:

• XML.ignoreComments = true
• XML.ignoreProcessingInstructions = true
• XML.ignoreWhitespace = true
• XML.prettyIndent = 2
• XML.prettyPrinting = true

Opmerking: deze methode wordt niet toegepast op een instantie van de klasse XML. Deze methode wordt toegepast op XML, zoals in de volgende code: XML.setSettings().

Parameters

Verwante API-elementen

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

Haalt de volgende eigenschappen op: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent en prettyPrinting.

Verwante API-elementen

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

Retourneert een object XMLList van alle XML-eigenschappen van het XML-object die XML-tekstknooppunten vertegenwoordigen.

var xml:XML =
        <body>
            text1
            <hr/>
            text2
        </body>;
trace(xml.text()[0]); // text1
trace(xml.text()[1]); // text2

Biedt een overschrijfbare methode voor het aanpassen van de JSON-codering van waarden in een XML-object.

De JSON.stringify()-methode zoekt naar een toJSON()-methode op elk object dat deze doorloopt. Als de toJSON()-methode gevonden wordt, roept JSON.stringify() deze aan voor elke waarde die wordt gevonden en wordt deze doorgegeven in de sleutel die een paar vormt met de waarde.

XML biedt een standaardimplementatie van toJSON() die gewoon de naam van de klasse retourneert. Clients die XML-objecten willen exporteren naar JSON, moeten hun eigen implementatie opgeven. U kunt dit doen door de toJSON()-methode op het klasseprototype opnieuw te definiëren.

De toJSON()-methode kan een waarde van elk type retourneren. Als een object wordt geretourneerd, loopt stringify() recursief door dat object. Als toJSON() een tekenreeks retourneert, loopt stringify() niet recursief door de tekenreeks en gaat de methode verder met doorlopen van de tekenreeks.

Parameters

Verwante API-elementen

Retourneert een tekenreeksrepresentatie van het XML-object. De regels voor deze omzetting hangen af van het feit of het XML-object eenvoudige inhoud of complexe inhoud bevat:

• Wanneer het XML-object eenvoudige inhoud bevat, retourneert toString() de inhoud van de tekenreeks van het XML-object zonder de volgende onderdelen: starttag, kenmerken, naamruimtedeclaraties en eindtag.

• Wanneer het XML-object complexe inhoud bevat, retourneert toString() een XML-gecodeerde tekenreeks die het volledige XML-object vertegenwoordigt, inclusief starttag, kenmerken, naamruimtedeclaraties en eindtag.

U kunt toXMLString() gebruiken om elke keer het volledige XML-object te laten retourneren.

Verwante API-elementen

var test:XML = <type name="Joe">example</type>;
trace(test.toString()); //example

var test:XML = 
<type name="Joe">
    <base name="Bob"></base>
    example
</type>;
trace(test.toString());
  // <type name="Joe">
  // <base name="Bob"/>
  // example
  // </type> 

Retourneert een tekenreeksrepresentatie van het XML-object. In tegenstelling tot de methode toString(), retourneert de methode toXMLString() altijd de starttag, kenmerken en eindtag van het XML-object, ongeacht of het XML-object eenvoudige inhoud of complexe inhoud bevat. (De methode toString() verwijdert deze items voor XML-objecten die eenvoudige inhoud bevatten.)

Verwante API-elementen

var xml:XML =
        <p>hello</p>;
trace(xml); // hello
trace(xml.toXMLString()); // <p>hello</p>

Retourneert het XML-object.

var xml:XML = <p>hello</p>;
trace(xml.valueOf() === xml); // true