QName  - AS3

De lokale naam van het object QName.

De URI (Uniform Resource Identifier) van het object QName.

Maakt een object QName dat een kopie is van een ander object QName. Wanneer de doorgegeven parameter aan de constructor een object QName is, wordt een kopie van het object QName gemaakt. Wanneer de parameters geen object QName is, wordt de parameter omgezet in een tekenreeks en toegewezen aan de eigenschap localName van de nieuwe instantie QName. Wanneer de parameter undefined of niet nader opgegeven is, wordt een nieuw object QName gemaakt met de eigenschap localName ingesteld op een lege tekenreeks.

Opmerking: voor deze klasse worden twee constructormethoden vermeld omdat elke vorm andere parameters accepteert. Het gedrag van de constructor hangt af van het type en het aantal parameters dat wordt doorgegeven, zoals in elke vermelding wordt beschreven. ActionScript 3.0 biedt geen ondersteuning voor overbelasting van methoden of constructors.

Maakt een QName met een object URI van een object Namespace en een localName van een object QName. Wanneer een van de parameters niet van het verwachte gegevenstype is, wordt de parameter omgezet in een tekenreeks en toegewezen aan de overeenkomstige eigenschap van het nieuwe object QName. Wanneer beide parameters bijvoorbeeld tekenreeksen zijn, wordt een nieuw object QName geretourneerd met een eigenschap uri ingesteld op de eerste parameter en een eigenschap localName ingesteld op de tweede parameter. De volgende permutaties, plus vele andere. zijn dus geldige vormen van de constructor:

QName (uri:Namespace, localName:String);
QName (uri:String, localName: QName);
QName (uri:String, localName: String);

Wanneer u null doorgeeft voor de parameter uri, wordt de eigenschap uri van het nieuwe object QName ingesteld op null.

Opmerking: voor deze klasse worden twee constructormethoden vermeld omdat elke vorm andere parameters accepteert. Het gedrag van de constructor hangt af van het type en het aantal parameters dat wordt doorgegeven, zoals in elke vermelding wordt beschreven. ActionScript 3.0 biedt geen ondersteuning voor overbelasting van methoden of constructors.

Retourneert een tekenreeks die bestaat uit de URI en de lokale naam van het object QName, gescheiden door '::'.

De indeling hangt af van de eigenschap uri van het object QName:

If uri == "" 
		toString returns localName
	else if uri == null
		toString returns *::localName 
	else
		toString returns uri::localName

Retourneert het object QName.

1. Een instantie Namespace maken en vervolgens gebruiken als invoer voor de constructor QName. Deze aanpak heeft de voorkeur wanneer u de eigenschap Namespace.prefix later voor andere doeleinden wilt gebruiken.
2. Een instantie QName maken met een eenvoudige tekenreekswaarde voor de parameter uri in de constructor QName.

Deze code doet het volgende:

1. Een XML-variabele met de naam rssXML definiëren.
2. Een nieuw object Namespace maken met het voorvoegsel dc.
3. Een nieuw object QName maken met het object Namespace en de creator voor lokale naam.
4. De methode showDescendants() aanroepen, die de methode XML.descendants() gebruikt om een instantie XMLList te verkrijgen met alle afstammende elementen waarvan de gekwalificeerde naam overeenkomt met de opgegeven instantie QName.
5. De gekwalificeerde naam en de tekstwaarde weergeven van elk element in de lijst met een lus for each.
6. Nog een object QName maken met een tekenreekswaarde voor de parameter uri en de date voor lokale naam.
7. De methode showDescendants() opnieuw aanroepen om de naam en de tekstwaarde weer te geven van de afstammende elementen.

package
{
    import flash.display.Sprite;
    
    public class QNameExample extends Sprite
    {
        public function QNameExample()
        {
            var rssXML:XML =  <rdf:RDF
              xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
              xmlns="http://purl.org/rss/1.0/"
              xmlns:dc="http://purl.org/dc/elements/1.1/">
              <channel rdf:about="http://www.xml.com/cs/xml/query/q/19">
                <title>Test RSS</title>
                <link>http://www.adobe.com/</link>
                <description>This is a test RSS document.</description>
                <language>en-us</language>
                <items>
                  <rdf:Seq>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flash/"/>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flex/"/>
                  </rdf:Seq>
                </items>
              </channel>
              <item rdf:about="http://www.adobe.com/devnet/flash/">
                <title>Flash Developer Center</title>
                <link>http://www.adobe.com/devnet/flash/</link>
                <description>Welcome to the Flash Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-08-08</dc:date>    
              </item>
              <item rdf:about="http://www.adobe.com/devnet/flex/">
                <title>Flex Developer Center</title>
                <link>http://www.adobe.com/devnet/flex/</link>
                <description>Welcome to the Flex Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-10-16</dc:date>    
              </item>
            </rdf:RDF>;
            
            var dcNamespace:Namespace = new Namespace("dc", "http://purl.org/dc/elements/1.1/");
            var creatorQName:QName = new QName(dcNamespace, "creator");
            trace(creatorQName.uri); // http://purl.org/dc/elements/1.1/
            trace(creatorQName.localName); // creator
            
            showDescendants(rssXML, creatorQName);
            
            var dateQName:QName = new QName("http://purl.org/dc/elements/1.1/", "date");
            trace(dateQName.uri); // http://purl.org/dc/elements/1.1/
            trace(dateQName.localName); // date
            
            showDescendants(rssXML, dateQName);
        }
        
        public function showDescendants(xmlData:XML, qualifiedName:QName):void
        {
            var decendantList:XMLList = xmlData.descendants(qualifiedName);
            
            for each (var element:XML in decendantList)
            {
                trace(element.name()); // the fully qualified name, 
                                       // like "http://purl.org/dc/elements/1.1/::creator"
                trace(element); // the simple text value of each element, like "Adobe"
            }                
        }
    }
}