Array  - AS3

Een niet-negatief geheel getal dat het aantal elementen in de array opgeeft. Deze eigenschap wordt automatisch bijgewerkt wanneer nieuwe elementen aan de array worden toegevoegd. Wanneer u een waarde aan een arrayelement toewijst (bijvoorbeeld my_array[index] = value) en als index een getal is enindex+1 groter is dan de eigenschap length, wordt de eigenschap length bijgewerkt naarindex+1.

Opmerking: wanneer u een waarde toewijst aan de eigenschap length die korter is dan de bestaande lengte, wordt de array ingekort.

var names:Array = new Array("Bill");
names.push("Kyle");
trace(names.length); // 2

names.push("Jeff");
trace(names.length); // 3

names.shift();
names.shift();
trace(names.length); // 1

Hiermee kunt u een array maken die de opgegeven elementen bevat. U kunt waarden van een willekeurig type opgeven. Het eerste element in een array heeft altijd een index (of positie) 0.

Opmerking: voor deze klasse worden twee constructormethoden vermeld omdat de constructor variabele typen argumenten accepteert. Het gedrag van de constructor hangt af van het type en het aantal argumenten dat wordt doorgegeven, zoals in elke vermelding wordt beschreven. ActionScript 3.0 biedt geen ondersteuning voor overbelasting van methoden of constructors.

Verwante API-elementen

package {
    import flash.display.Sprite;

    public class Array_Array_3 extends Sprite {

        public function Array_Array_3() {
            var myArr:Array = new Array("one", "two", "three");
            trace(myArr.length); // 3
            trace(myArr);          // one,two,three
        }
    }
}

Hiermee kunt u een array van het opgegeven aantal elementen maken. Wanneer u geen parameters opgeeft, wordt een array met 0 elementen gemaakt. Wanneer u aantal elementen opgeeft, wordt een array gemaakt met numElements elementen.

Opmerking: voor deze klasse worden twee constructormethoden vermeld omdat de constructor variabele typen argumenten accepteert. Het gedrag van de constructor hangt af van het type en het aantal argumenten dat wordt doorgegeven, zoals in elke vermelding wordt beschreven. ActionScript 3.0 biedt geen ondersteuning voor overbelasting van methoden of constructors.

Verwante API-elementen

package {
    import flash.display.Sprite;

    public class Array_Array extends Sprite {

        public function Array_Array() {
            var myArr:Array = new Array();
            trace(myArr.length); // 0
        }
    }
}

package {
    import flash.display.Sprite;

    public class Array_Array_2 extends Sprite {

        public function Array_Array_2() {
            var myArr:Array = new Array(5);
            trace(myArr.length); // 5
            myArr[0] = "one";
            myArr.push("six");
            trace(myArr);         // one,,,,,six
            trace(myArr.length); // 6
        }
    }
}

Voegt de elementen die in de parameters zijn opgegeven samen met de elementen in een array en maakt een nieuwe array. Wanneer de parameters een array opgeven, worden de elementen van die array samengevoegd. Wanneer u geen parameters doorgeeft, is de nieuwe array een duplicaat (oppervlakkige kloon) van de oorspronkelijke array.

Parameters

var numbers:Array = new Array(1, 2, 3);
var letters:Array = new Array("a", "b", "c");
var numbersAndLetters:Array = numbers.concat(letters);
var lettersAndNumbers:Array = letters.concat(numbers);

trace(numbers);       // 1,2,3
trace(letters);       // a,b,c
trace(numbersAndLetters); // 1,2,3,a,b,c
trace(lettersAndNumbers); // a,b,c,1,2,3

Voert een testfunctie uit op elk item in de array totdat een item wordt bereikt dat voor de opgegeven functie false retourneert. U gebruikt deze methode om vast te stellen of alle items in een array aan een criterium voldoen, zoals het hebben van waarden onder een bepaald getal.

Voor deze methode moet de tweede parameter, thisObject, gelijk aan null zijn wanneer de eerste parameter, callback, de methode afsluit. U maakt bijvoorbeeld een functie in een filmclip met de naam me:

     function myFunction(obj:Object):void {
        //your code here
     }
     

Vervolgens gebruikt u de methode every() op een array met de naam myArray:

     myArray.every(myFunction, me);
     

Omdat myFunction een lid van de klasse Timeline is, die niet door me kan worden overschreven, genereert Flash-runtime een uitzondering. U kunt deze fout bij uitvoering voorkomen door de functie als volgt toe te wijzen aan een variabele:

     var myFunction:Function = function(obj:Object):void {
         //your code here
     };
     myArray.every(myFunction, me);
     

Parameters

function callback(item:*, index:int, array:Array):Boolean;

Verwante API-elementen

package {
    import flash.display.Sprite;
    public class Array_every extends Sprite {
        public function Array_every() {
            var arr1:Array = new Array(1, 2, 4);
            var res1:Boolean = arr1.every(isNumeric);
            trace("isNumeric:", res1); // true
 
            var arr2:Array = new Array(1, 2, "ham");
            var res2:Boolean = arr2.every(isNumeric);
            trace("isNumeric:", res2); // false
        }
        private function isNumeric(element:*, index:int, arr:Array):Boolean {
            return (element is Number);
        }
    }
}

Voert een testfunctie uit voor elk item in de array en maakt een nieuwe array voor alle items die voor de opgegeven functie true retourneren. Items die false retourneren, worden niet in de nieuwe array opgenomen.

Voor deze methode moet de tweede parameter, thisObject, gelijk aan null zijn wanneer de eerste parameter, callback, de methode afsluit. U maakt bijvoorbeeld een functie in een filmclip met de naam me:

     function myFunction(obj:Object):void {
        //your code here
     }
     

Vervolgens gebruikt u de methode filter() op een array met de naam myArray:

 
     myArray.filter(myFunction, me);
     

Omdat myFunction een lid van de klasse Timeline is, die niet door me kan worden overschreven, genereert Flash-runtime een uitzondering. U kunt deze fout bij uitvoering voorkomen door de functie als volgt toe te wijzen aan een variabele:

     var myFunction:Function = function(obj:Object):void {
         //your code here
         };
     myArray.filter(myFunction, me);
     

Parameters

    function callback(item:*, index:int, array:Array):Boolean;

Verwante API-elementen

package {
    import flash.display.Sprite;
    public class Array_filter extends Sprite {
        public function Array_filter() {
            var employees:Array = new Array();
            employees.push({name:"Employee 1", manager:false});
            employees.push({name:"Employee 2", manager:true});
            employees.push({name:"Employee 3", manager:false});
            trace("Employees:");
            employees.forEach(traceEmployee);
            
            var managers:Array = employees.filter(isManager);
            trace("Managers:");
            managers.forEach(traceEmployee);
        }
        private function isManager(element:*, index:int, arr:Array):Boolean {
            return (element.manager == true);
        }
        private function traceEmployee(element:*, index:int, arr:Array):void {
            trace("\t" + element.name + ((element.manager) ? " (manager)" : ""));
        }
    }
}

Voert een functie uit op elk item in de array.

Voor deze methode moet de tweede parameter, thisObject, gelijk aan null zijn wanneer de eerste parameter, callback, de methode afsluit. U maakt bijvoorbeeld een functie in een filmclip met de naam me:

     function myFunction(obj:Object):void {
        //your code here
     }
     

Vervolgens gebruikt u de methode forEach() op een array met de naam myArray:

     myArray.forEach(myFunction, me);
     

Omdat myFunction een lid van de klasse Timeline is, die niet door me kan worden overschreven, genereert Flash-runtime een uitzondering. U kunt deze fout bij uitvoering voorkomen door de functie als volgt toe te wijzen aan een variabele:

     var myFunction:Function = function(obj:Object):void {
         //your code here
         };
     myArray.forEach(myFunction, me);
     

Parameters

    function callback(item:*, index:int, array:Array):void;

package {
    import flash.display.Sprite;
    public class Array_forEach extends Sprite {
        public function Array_forEach() {
            var employees:Array = new Array();
            employees.push({name:"Employee 1", manager:false});
            employees.push({name:"Employee 2", manager:true});
            employees.push({name:"Employee 3", manager:false});
            trace(employees);
            employees.forEach(traceEmployee);
        }
        private function traceEmployee(element:*, index:int, arr:Array):void {
            trace(element.name + " (" + element.manager + ")");
        }
    }
}

package {
    import flash.display.Sprite;
    public class Array_forEach_2 extends Sprite {
        public function Array_forEach_2() {
            var employeeXML:XML = <employees>
                    <employee name="Steven" manager="false" />
                    <employee name="Bruce" manager="true" />
                    <employee name="Rob" manager="false" />
                </employees>;
            var employeesList:XMLList = employeeXML.employee;
            var employeesArray:Array = new Array();
            for each (var tempXML:XML in employeesList) {
                employeesArray.push(tempXML);
            }
            employeesArray.sortOn("@name");
            employeesArray.forEach(traceEmployee);
        }
        private function traceEmployee(element:*, index:Number, arr:Array):void {
            trace(element.@name + ((element.@manager == "true") ? " (manager)" : ""));
        }
    }
}

Zoekt naar een item in een array met strikte gelijkheid (===) en retourneert de indexpositie van het item.

Parameters

Verwante API-elementen

package {
    import flash.display.Sprite;
    public class Array_indexOf extends Sprite {
        public function Array_indexOf() {
            var arr:Array = new Array(123,45,6789);
            arr.push("123-45-6789");
            arr.push("987-65-4321");
            
            var index:int = arr.indexOf("123");
            trace(index); // -1
            
            var index2:int = arr.indexOf(123);
            trace(index2); // 0
        }
    }
}

Voeg een enkel element in een array in. Bij deze methode wordt de array gewijzigd zonder dat een kopie wordt gemaakt.

Parameters

Zet de elementen in een array om in tekenreeksen, voegt het opgegeven scheidingsteken in tussen de elementen, voegt de elementen samen en retourneert de resulterende tekenreeks. Een geneste array wordt altijd gescheiden door een komma (,) en niet door het scheidingsteken dat aan de methode join() is doorgegeven.

Parameters

Verwante API-elementen

var myArr:Array = new Array("one", "two", "three");
var myStr:String = myArr.join(" and ");
trace(myArr); // one,two,three
trace(myStr); // one and two and three

var phoneString:String = "(888) 867-5309";

var specialChars:Array = new Array("(", ")", "-", " ");
var myStr:String = phoneString;

var ln:uint = specialChars.length;
for(var i:uint; i < ln; i++) {
    myStr = myStr.split(specialChars[i]).join("");
}

var phoneNumber:Number = new Number(myStr);

trace(phoneString); // (888) 867-5309
trace(phoneNumber); // 8888675309

Zoekt naar een item in een array, vanaf het laatste item achterwaarts, en retourneert de indexpositie van het overeenkomende item met strikte gelijkheid (===).

Parameters

Verwante API-elementen

package {
    import flash.display.Sprite;
    public class Array_lastIndexOf extends Sprite {
        public function Array_lastIndexOf() {
            var arr:Array = new Array(123,45,6789,123,984,323,123,32);
            
            var index:int = arr.indexOf(123);
            trace(index); // 0
            
            var index2:int = arr.lastIndexOf(123);
            trace(index2); // 6
        }
    }
}

Voert een functie uit op elk item in een array en maakt een nieuwe array van items die overeenkomt met de resultaten van de functie op elk item in de oorspronkelijke array.

Voor deze methode moet de tweede parameter, thisObject, gelijk aan null zijn wanneer de eerste parameter, callback, de methode afsluit. U maakt bijvoorbeeld een functie in een filmclip met de naam me:

     function myFunction(obj:Object):void {
        //your code here
     }
     

Vervolgens gebruikt u de methode map() op een array met de naam myArray:

     myArray.map(myFunction, me);
     

Omdat myFunction een lid van de klasse Timeline is, die niet door me kan worden overschreven, genereert Flash-runtime een uitzondering. U kunt deze fout bij uitvoering voorkomen door de functie als volgt toe te wijzen aan een variabele:

     var myFunction:Function = function(obj:Object):void {
         //your code here
         };
     myArray.map(myFunction, me);
     

Parameters

    function callback(item:*, index:int, array:Array):String;

Verwante API-elementen

package {
    import flash.display.Sprite;
    public class Array_map extends Sprite {
        public function Array_map() {
            var arr:Array = new Array("one", "two", "Three");
            trace(arr); // one,two,Three

            var upperArr:Array = arr.map(toUpper);
            trace(upperArr); // ONE,TWO,THREE
        }
        private function toUpper(element:*, index:int, arr:Array):String {
            return String(element).toUpperCase();
        }
    }
}

Verwijdert het laatste element uit een array en retourneert de waarde van dat element.

Verwante API-elementen

var letters:Array = new Array("a", "b", "c");
trace(letters); // a,b,c
var letter:String = letters.pop();
trace(letters); // a,b
trace(letter);     // c

Voegt een of meer elementen aan het einde van een array toe en retourneert de nieuwe lengte van de array.

Parameters

Verwante API-elementen

var letters:Array = new Array();

letters.push("a");
letters.push("b");
letters.push("c");

trace(letters.toString()); // a,b,c

var letters:Array = new Array("a");
var count:uint = letters.push("b", "c");

trace(letters); // a,b,c
trace(count);   // 3

Verwijder een enkel element uit een array. Bij deze methode wordt de array gewijzigd zonder dat een kopie wordt gemaakt.

Parameters

Keert de volgorde van de array om.

var letters:Array = new Array("a", "b", "c");
trace(letters); // a,b,c
letters.reverse();
trace(letters); // c,b,a

Verwijdert het eerste element uit een array en retourneert dat element. De resterende array-elementen worden van hun oorspronkelijke positie verplaatst, van i naar i-1.

Verwante API-elementen

var letters:Array = new Array("a", "b", "c");
var firstLetter:String = letters.shift();
trace(letters);     // b,c
trace(firstLetter); // a

Retourneert een nieuwe array die bestaat uit een reeks elementen van de oorspronkelijke array. De oorspronkelijke array wordt niet gewijzigd. De geretourneerde array bevat het element startIndex en alle elementen tot (niet tot en met) het element endIndex.

Wanneer u geen parameters doorgeeft, is de nieuwe array een duplicaat (oppervlakkige kloon) van de oorspronkelijke array.

Parameters

var letters:Array = new Array("a", "b", "c", "d", "e", "f");
var someLetters:Array = letters.slice(1,3);

trace(letters);     // a,b,c,d,e,f
trace(someLetters); // b,c

var letters:Array = new Array("a", "b", "c", "d", "e", "f");
var someLetters:Array = letters.slice(2);

trace(letters);     // a,b,c,d,e,f
trace(someLetters); // c,d,e,f

var letters:Array = new Array("a", "b", "c", "d", "e", "f");
var someLetters:Array = letters.slice(-2);

trace(letters);     // a,b,c,d,e,f
trace(someLetters); // e,f

Voert een testfunctie uit op elk item in de array totdat een item wordt bereikt dat true retourneert. Gebruik deze methode om vast te stellen of items in een array aan een criterium voldoen, zoals het hebben van een waarde onder een bepaald getal.

Voor deze methode moet de tweede parameter, thisObject, gelijk aan null zijn wanneer de eerste parameter, callback, de methode afsluit. U maakt bijvoorbeeld een functie in een filmclip met de naam me:

     function myFunction(obj:Object):void {
        //your code here
     }
     

Vervolgens gebruikt u de methode some() op een array met de naam myArray:

     myArray.some(myFunction, me);
     

Omdat myFunction een lid van de klasse Timeline is, die niet door me kan worden overschreven, genereert Flash-runtime een uitzondering. U kunt deze fout bij uitvoering voorkomen door de functie als volgt toe te wijzen aan een variabele:

     var myFunction:Function = function(obj:Object):void {
         //your code here
         };
     myArray.some(myFunction, me);
     

Parameters

    function callback(item:*, index:int, array:Array):Boolean;

Verwante API-elementen

package {
    import flash.display.Sprite;
    public class Array_some extends Sprite {
        public function Array_some() {
            var arr:Array = new Array();
            arr[0] = "one";
            arr[1] = "two";
            arr[3] = "four";
            var isUndef:Boolean = arr.some(isUndefined);
            if (isUndef) {
                trace("array contains undefined values: " + arr);
            } else {
                trace("array contains no undefined values.");
            }
        }
        private function isUndefined(element:*, index:int, arr:Array):Boolean {
            return (element == undefined);
        }
    }
}

Sorteert de elementen in een array. Deze methode sorteert op basis van Unicode-waarden. (ASCII is een subset van Unicode.)

Standaard werkt Array.sort() wordt als volgt uitgevoerd:

• Sorteren is hoofdlettergevoelig (Z komt eerder dan a).
• Sorteren verloopt oplopend (a komt eerder dan b).
• De array wordt gewijzigd op basis van de sorteervolgorde; meerdere elementen met identieke sorteervelden worden in willekeurige volgorde achter elkaar in de gesorteerde array geplaatst.
• Alle elementen, ongeacht het gegevenstype, worden als tekenreeksen gesorteerd, 100 komt bijvoorbeeld eerder dan 99, omdat '1' een lagere tekenreekswaarde is dan '9'.

Wanneer u een array wilt sorteren met instellingen die afwijken van de standaardinstellingen, kunt u een van de sorteeropties gebruiken die in het gedeelte sortOptions van de parameterbeschrijving ...args worden beschreven. U kunt ook uw eigen sorteerfunctie maken. Wanneer u een aangepaste functie maakt, moet u de methode sort() aanroepen en de naam van de aangepaste functie als eerste argument gebruiken (compareFunction).

Parameters

Verwante API-elementen

var vegetables:Array = new Array("spinach",
                 "green pepper",
                 "cilantro",
                 "onion",
                 "avocado");

trace(vegetables); // spinach,green pepper,cilantro,onion,avocado
vegetables.sort();
trace(vegetables); // avocado,cilantro,green pepper,onion,spinach

var vegetables:Array = new Array("spinach",
                 "green pepper",
                 "Cilantro",
                 "Onion",
                 "Avocado");

vegetables.sort();
trace(vegetables); // Avocado,Cilantro,Onion,green pepper,spinach
vegetables.sort(Array.CASEINSENSITIVE);
trace(vegetables); // Avocado,Cilantro,green pepper,Onion,spinach

var vegetables:Array = new Array();
vegetables.push(new Vegetable("lettuce", 1.49));
vegetables.push(new Vegetable("spinach", 1.89));
vegetables.push(new Vegetable("asparagus", 3.99));
vegetables.push(new Vegetable("celery", 1.29));
vegetables.push(new Vegetable("squash", 1.44));

trace(vegetables);
// lettuce:1.49, spinach:1.89, asparagus:3.99, celery:1.29, squash:1.44

vegetables.sort();

trace(vegetables);
// asparagus:3.99, celery:1.29, lettuce:1.49, spinach:1.89, squash:1.44

//The following code defines the Vegetable class
class Vegetable {
    private var name:String;
    private var price:Number;

    public function Vegetable(name:String, price:Number) {
        this.name = name;
        this.price = price;
    }

    public function toString():String {
        return " " + name + ":" + price;
    }
}

var vegetables:Array = new Array();
vegetables.push(new Vegetable("lettuce", 1.49));
vegetables.push(new Vegetable("spinach", 1.89));
vegetables.push(new Vegetable("asparagus", 3.99));
vegetables.push(new Vegetable("celery", 1.29));
vegetables.push(new Vegetable("squash", 1.44));

trace(vegetables);
// lettuce:1.49, spinach:1.89, asparagus:3.99, celery:1.29, squash:1.44

vegetables.sort(sortOnPrice);

trace(vegetables);
// celery:1.29, squash:1.44, lettuce:1.49, spinach:1.89, asparagus:3.99

function sortOnPrice(a:Vegetable, b:Vegetable):Number {
    var aPrice:Number = a.getPrice();
    var bPrice:Number = b.getPrice();

    if(aPrice > bPrice) {
        return 1;
    } else if(aPrice < bPrice) {
        return -1;
    } else  {
        //aPrice == bPrice
        return 0;
    }
}

// The following code defines the Vegetable class and should be in a separate package.
class Vegetable {
    private var name:String;
    private var price:Number;

    public function Vegetable(name:String, price:Number) {
        this.name = name;
        this.price = price;
    }

    public function getPrice():Number {
        return price;
    }

    public function toString():String {
        return " " + name + ":" + price;
    }
}

var numbers:Array = new Array(3,5,100,34,10);

trace(numbers); // 3,5,100,34,10
numbers.sort();
trace(numbers); // 10,100,3,34,5
numbers.sort(Array.NUMERIC);
trace(numbers); // 3,5,10,34,100

Sorteert de elementen in een array op basis van een of meer velden in de array. De array moet de volgende kenmerken hebben:

• De array is een geïndexeerde array, geen associatieve array.
• Elk element van de array bevat een object met een of meer eigenschappen.
• Alle objecten hebben minstens één gemeenschappelijke eigenschap, waarvan de waarden kunnen worden gebruikt om de array te sorteren. Een dergelijke eigenschap wordt een veld genoemd.

Wanneer u meerdere parameters fieldName doorgeeft, is het eerste veld het primaire sorteerveld, het tweede veld het volgende sorteerveld, enzovoort. In Flash wordt op basis van Unicode-waarden gesorteerd. (ASCII is een subset van Unicode.) Wanneer een van de elementen die worden vergeleken niet het veld bevat dat in de parameter fieldName is opgegeven, wordt ervan uitgegaan dat het veld ongedefinieerd is en worden de elementen in willekeurige volgorde achter elkaar in de gesorteerde array geplaatst.

Standaard werkt Array.sortOn() wordt als volgt uitgevoerd:

• Sorteren is hoofdlettergevoelig (Z komt eerder dan a).
• Sorteren verloopt oplopend (a komt eerder dan b).
• De array wordt gewijzigd op basis van de sorteervolgorde; meerdere elementen met identieke sorteervelden worden in willekeurige volgorde achter elkaar in de gesorteerde array geplaatst.
• Numerieke velden worden als tekenreeksen gesorteerd, 100 komt bijvoorbeeld eerder dan 99, omdat '1' een lagere tekenreekswaarde is dan '9'.

In Flash Player 7 is de parameter options toegevoegd die u kunt gebruiken om het standaardsorteergedrag te negeren. Wanneer u een eenvoudige array wilt sorteren (bijvoorbeeld een array met slechts één veld) of wanneer u een sorteervolgorde wilt opgeven die niet door de parameter options wordt ondersteund, moet u Array.sort() gebruiken.

U kunt meerdere markeringen doorgeven door ze te scheiden met de bitsgewijze operator OR (|):

     my_array.sortOn(someFieldName, Array.DESCENDING | Array.NUMERIC);
     

In Flash Player 8 hebt u de mogelijkheid een andere sorteeroptie voor elk veld op te geven wanneer u op meer dan één veld sorteert. In Flash Player 8 en hoger accepteert de parameter options een array van sorteeropties zodanig dat elke sorteeroptie overeenkomt met een sorteerveld in de parameter fieldName. In het volgende voorbeeld wordt het primaire sorteerveld a in aflopende volgorde gesorteerd, het secundaire sorteerveld b in numerieke volgorde en het tertiaire sorteerveld c in niet-hoofdlettergevoelige volgorde:

     Array.sortOn (["a", "b", "c"], [Array.DESCENDING, Array.NUMERIC, Array.CASEINSENSITIVE]);
     

Opmerking: de arraysfieldName en options moeten hetzelfde aantal elementen bevatten, anders wordt de array options genegeerd. De opties Array.UNIQUESORT en Array.RETURNINDEXEDARRAY kunnen alleen als het eerste element in de array worden gebruikt, anders worden ze genegeerd.

Parameters

Verwante API-elementen

var vegetables:Array = new Array();
vegetables.push(new Vegetable("lettuce", 1.49));
vegetables.push(new Vegetable("spinach", 1.89));
vegetables.push(new Vegetable("asparagus", 3.99));
vegetables.push(new Vegetable("celery", 1.29));
vegetables.push(new Vegetable("squash", 1.44));

trace(vegetables);
// lettuce:1.49, spinach:1.89, asparagus:3.99, celery:1.29, squash:1.44

vegetables.sortOn("name");
trace(vegetables);
// asparagus:3.99, celery:1.29, lettuce:1.49, spinach:1.89, squash:1.44

vegetables.sortOn("price", Array.NUMERIC | Array.DESCENDING);
trace(vegetables);
// asparagus:3.99, spinach:1.89, lettuce:1.49, squash:1.44, celery:1.29

class Vegetable {
    public var name:String;
    public var price:Number;

    public function Vegetable(name:String, price:Number) {
        this.name = name;
        this.price = price;
    }

    public function toString():String {
        return " " + name + ":" + price;
    }
}

var records:Array = new Array();
records.push({name:"john", city:"omaha", zip:68144});
records.push({name:"john", city:"kansas city", zip:72345});
records.push({name:"bob", city:"omaha", zip:94010});

for(var i:uint = 0; i < records.length; i++) {
    trace(records[i].name + ", " + records[i].city);
}
// Results:
// john, omaha
// john, kansas city
// bob, omaha

trace("records.sortOn('name', 'city');");
records.sortOn(["name", "city"]);
for(var i:uint = 0; i < records.length; i++) {
    trace(records[i].name + ", " + records[i].city);
}
// Results:
// bob, omaha
// john, kansas city
// john, omaha

trace("records.sortOn('city', 'name');");
records.sortOn(["city", "name"]);
for(var i:uint = 0; i < records.length; i++) {
    trace(records[i].name + ", " + records[i].city);
}
// Results:
// john, kansas city
// bob, omaha
// john, omaha

class User {
    public var name:String;
    public var age:Number;
    public function User(name:String, age:uint) {
        this.name = name;
        this.age = age;
    }

    public function toString():String {
        return this.name + ":" + this.age;
    }
}

var users:Array = new Array();
users.push(new User("Bob", 3));
users.push(new User("barb", 35));
users.push(new User("abcd", 3));
users.push(new User("catchy", 4));

trace(users); // Bob:3,barb:35,abcd:3,catchy:4

users.sortOn("name");
trace(users); // Bob:3,abcd:3,barb:35,catchy:4

users.sortOn("name", Array.CASEINSENSITIVE);
trace(users); // abcd:3,barb:35,Bob:3,catchy:4

users.sortOn("name", Array.CASEINSENSITIVE | Array.DESCENDING);
trace(users); // catchy:4,Bob:3,barb:35,abcd:3

users.sortOn("age");
trace(users); // abcd:3,Bob:3,barb:35,catchy:4

users.sortOn("age", Array.NUMERIC);
trace(users); // Bob:3,abcd:3,catchy:4,barb:35

users.sortOn("age", Array.DESCENDING | Array.NUMERIC);
trace(users); // barb:35,catchy:4,Bob:3,abcd:3

var indices:Array = users.sortOn("age", Array.NUMERIC | Array.RETURNINDEXEDARRAY);
var index:uint;
for(var i:uint = 0; i < indices.length; i++) {
    index = indices[i];
    trace(users[index].name, ": " + users[index].age);
}

// Results:
// Bob : 3
// abcd : 3
// catchy : 4
// barb : 35

Voegt elementen aan een array toe en verwijdert elementen uit een array. Bij deze methode wordt de array gewijzigd zonder dat een kopie wordt gemaakt.

Opmerking: wanneer u deze methode in een subklasse van Array wilt negeren, gebruikt u...args voor de parameters, zoals getoond in dit voorbeeld:

     public override function splice(...args) {
       // your statements here
     }
     

Parameters

var vegetables:Array = new Array("spinach",
                 "green pepper",
                 "cilantro",
                 "onion",
                 "avocado");

var spliced:Array = vegetables.splice(2, 2);
trace(vegetables); // spinach,green pepper,avocado
trace(spliced);    // cilantro,onion

vegetables.splice(1, 0, spliced);
trace(vegetables); // spinach,cilantro,onion,green pepper,avocado

 
var vegetables:Array = new Array("spinach",
                 "green pepper",
                 "cilantro",
                 "onion",
                 "avocado");
 
 var spliced:Array = vegetables.splice(2, 2);
 trace(vegetables); // spinach,green pepper,avocado
 trace(spliced);    // cilantro,onion
 
 vegetables.splice(1, 0, "cilantro", "onion");
 trace(vegetables); // spinach,cilantro,onion,green pepper,avocado

Retourneert een tekenreeks die de elementen in de opgegeven array vertegenwoordigt. Elk element in de array, beginnend met index 0 en eindigend met de hoogste index, wordt omgezet in een samengevoegde tekenreeks en wordt gescheiden door komma's. In de ActionScript 3.0-implementatie retourneert deze methode dezelfde waarde als de methode Array.toString().

Verwante API-elementen

Retourneert een tekenreeks die de elementen in de opgegeven array vertegenwoordigt. Elk element in de array, beginnend met index 0 en eindigend met de hoogste index, wordt omgezet in een samengevoegde tekenreeks en wordt gescheiden door komma's. Gebruik de methode Array.join() om een aangepast scheidingsteken op te geven.

Verwante API-elementen

var vegetables:Array = new Array();
vegetables.push(1);
vegetables.push(2);
vegetables.push(3);
vegetables.push(4);
vegetables.push(5);
var vegnums:String = vegetables.toString();
trace(vegnums+",6");
// 1,2,3,4,5,6

Voegt een of meer elementen aan het begin van een array toe en retourneert de nieuwe lengte van de array. De overige elementen in de array worden van de oorspronkelijke positie i verplaatst naar i+1.

Parameters

Verwante API-elementen

var names:Array = new Array();
names.push("Bill");
names.push("Jeff");

trace(names); // Bill,Jeff

names.unshift("Alfred");
names.unshift("Kyle");

trace(names); // Kyle,Alfred,Bill,Jeff

Geeft niet-hoofdlettergevoelig sorteren op voor de sorteermethoden van de klasse Array. U kunt deze constante voor de parameter options in de methode sort() of sortOn() gebruiken.

De waarde van deze constante is 1.

Verwante API-elementen

Geeft aflopend sorteren op voor de sorteermethoden van de klasse Array. U kunt deze constante voor de parameter options in de methode sort() of sortOn() gebruiken.

De waarde van deze constante is 2.

Verwante API-elementen

Geeft numeriek sorteren (in plaats van sorteren op tekens) op voor de sorteermethoden van de klasse Array. Wanneer u deze constante in de parameter options opneemt, sorteren de methoden sort() en sortOn() getallen als numerieke waarden, niet als tekenreeksen van numerieke tekens. Zonder de constante NUMERIC wordt elk arrayelement als een tekenreeks gesorteerd en worden de resultaten in Unicode-volgorde geproduceerd.

Wanneer voorbeeld wordt de array van waarden [2005, 7, 35] genomen. Wanneer de constante NUMERIC niet is opgenomen in de parameter options, wordt de gesorteerde array [2005, 35, 7], maar als de constante NUMERIC wel is opgenomen, wordt de gesorteerde array [7, 35, 2005].

Deze constante is alleen van toepassing op getallen in de array, niet op tekenreeksen die numerieke gegevens bevatten zoals ['23', '5'].

De waarde van deze constante is 16.

Verwante API-elementen

Geeft op dat een sorteerhandeling een array retourneert die bestaat uit arrayindexen. U kunt deze constante gebruiken voor de parameter options in de methode sort() of sortOn(), zodat u toegang hebt tot meerdere weergaven van de arrayelementen terwijl de oorspronkelijke array ongewijzigd blijft.

De waarde van deze constante is 8.

Verwante API-elementen

Geeft de vereiste om uniek te sorteren op voor de sorteermethoden van de klasse Array. U kunt deze constante voor de parameter options in de methode sort() of sortOn() gebruiken. De unieke sorteeroptie breekt het sorteren af wanneer twee elementen of velden die worden gesorteerd, identieke waarden hebben.

De waarde van deze constante is 4.

Verwante API-elementen