| Pakket | flash.ui |
| Klasse | public final class MouseCursorData |
| Overerving | MouseCursorData  Object |
| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10.2, AIR 2.6 |
U geeft de cursor weer met gebruik van de functie Mouse.registerCursor(). Roep Mouse.unregisterCursor() aan om de cursorafbeelding weer door het besturingssysteem te laten besturen. Roep Mouse.supportsNativeCursor aan om te testen of native cursors worden ondersteund op de actieve computer.
De maximale cursorgrootte is 32x32 pixels. Transparantie wordt door de meeste besturingssystemen ondersteund.
Een native muiscursor wordt rechtstreeks geïmplementeerd door het cursormechanisme van het besturingssysteem en is een efficiëntere wijze voor het weergeven van een aangepaste cursorafbeelding dan het gebruik van een weergaveobject. U kunt de cursor animeren door meer dan één afbeelding op te geven in de data-eigenschap en de framesnelheid in te stellen.
De cursor wordt alleen weergegeven binnen de grenzen van het werkgebied. Buiten het werkgebied wordt besturing van de cursorafbeelding geretourneerd naar het besturingssysteem.
Meer informatie
Verwante API-elementen
Overerfde openbare eigenschappen verbergen
Overerfde openbare eigenschappen weergeven| Eigenschap | Gedefinieerd door | ||
|---|---|---|---|
 | constructor : Object
Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie. | Object | |
| data : Vector.<BitmapData>
Een vector met BitmapData-objecten met de cursorafbeelding of -afbeeldingen. | MouseCursorData | ||
| frameRate : Number
De framesnelheid voor het animeren van de cursor. | MouseCursorData | ||
| hotSpot : Point
De hotspot van de cursor, uitgedrukt in pixels. | MouseCursorData | ||
| Methode | Gedefinieerd door | ||
|---|---|---|---|
Maakt een MouseCursorData-object. | MouseCursorData | ||
|
Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd. | Object | |
|
Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven. | Object | |
|
Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd. | Object | |
|
Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in. | Object | |
|
Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies. | Object | |
|
Retourneert een tekenreeksrepresentatie van het opgegeven object. | Object | |
|
Retourneert de primitieve waarde van het opgegeven object. | Object | |
data | eigenschap |
data:Vector.<BitmapData>| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10.2, AIR 2.6 |
Een vector met BitmapData-objecten met de cursorafbeelding of -afbeeldingen.
Geef meerdere afbeeldingen op en stel de eigenschap framerate in om de cursor te animeren.
De maximale cursorgrootte bedraagt 32x32 pixels.
Implementatie
public function get data():Vector.<BitmapData> public function set data(value:Vector.<BitmapData>):voidframeRate | eigenschap |
frameRate:Number| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10.2, AIR 2.6 |
De framesnelheid voor het animeren van de cursor.
Geef meerdere afbeeldingen op in de data-eigenschap en stel de framesnelheid in op een grotere waarde dan 0 om de cursor te animeren. De cursorframesnelheid kan afwijken van de huidige SWF-framesnelheid.
Implementatie
public function get frameRate():Number public function set frameRate(value:Number):voidhotSpot | eigenschap |
hotSpot:Point| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10.2, AIR 2.6 |
De hotspot van de cursor, uitgedrukt in pixels.
De hotspot is het punt op de cursor waaronder muisklikken worden geregistreerd. Standaard is de linkerbovenhoek (0,0) de hotspot.
Implementatie
public function get hotSpot():Point public function set hotSpot(value:Point):voidMouseCursorData | () | Constructor |
public function MouseCursorData()| Taalversie: | ActionScript 3.0 |
| Runtimeversies: | Flash Player 10.2, AIR 2.6 |
Maakt een MouseCursorData-object.
Roep de functie Mouse.registerCursor() aan om de cursor weer te geven.
Verwante API-elementen
In het voorbeeld worden de via de klasse Graphics beschikbare tekenopdrachten gebruikt om acht geroteerde afbeeldingen van een pijl te maken. Deze afbeeldingen worden in een vector geduwd en toegewezen aan de data-eigenschap van het MouseCursorData-object. (U kunt ook vooraf gerenderde bitmapafbeeldingen gebruiken voor uw cursors.)
package {
import flash.display.Sprite;
import flash.display.Shape;
import flash.display.BitmapData;
import flash.display.GraphicsPath;
import flash.ui.MouseCursorData;
import flash.ui.Mouse;
import flash.geom.Matrix;
public class MouseCursorDataExample extends Sprite {
//Graphics path data for an arrow
private var cursorPoints:Vector.<Number> = new <Number>[0,8, 16,8, 16,0, 24,12, 16,24, 16,16, 0,16, 0,8];
private var cursorDrawCommands:Vector.<int> = new <int>[1,2,2,2,2,2,2,2];
public function MouseCursorDataExample() {
var mouseCursorData:MouseCursorData = new MouseCursorData();
mouseCursorData.data = makeCursorImages();
mouseCursorData.frameRate = 1;
Mouse.registerCursor( "spinningArrow", mouseCursorData );
Mouse.cursor = "spinningArrow";
}
//Returns a Vector containing 8 cursor images
private function makeCursorImages():Vector.<BitmapData>
{
var cursorData:Vector.<BitmapData> = new Vector.<BitmapData>();
var cursorShape:Shape = new Shape();
cursorShape.graphics.beginFill( 0xff5555, .75 );
cursorShape.graphics.lineStyle( 1 );
cursorShape.graphics.drawPath( cursorDrawCommands, cursorPoints );
cursorShape.graphics.endFill();
var transformer:Matrix = new Matrix();
//Rotate and draw the arrow shape to a BitmapData object for each of 8 frames
for( var i:int = 0; i < 8; i++ )
{
var cursorFrame:BitmapData = new BitmapData( 32, 32, true, 0 );
cursorFrame.draw( cursorShape, transformer );
cursorData.push( cursorFrame );
transformer.translate(-15,-15);
transformer.rotate( 0.785398163 );
transformer.translate(15,15);
}
return cursorData;
}
}
}
Wed Jun 13 2018, 11:42 AM Z