Mouse  - AS3

De naam van de eigen cursor.

Geeft aan of de computer of het apparaat een permanente cursor weergeeft.

De eigenschap supportsCursor heeft de waarde True bij de meeste bureaubladcomputers en de waarde False bij de meeste mobiele apparaten.

Opmerking: muisgebeurtenissen kunnen altijd worden verzonden, ongeacht of deze eigenschap de waarde True heeft. Muisgebeurtenissen kunnen zich anders gedragen op basis van de fysieke kenmerken van het aanwijsapparaat.

Verwante API-elementen

import flash.events.*;
import flash.display.*;
import flash.ui.Mouse;
import flash.text.TextField;

var supportsCursorTxt:TextField = new TextField();
supportsCursorTxt.width = 200;
supportsCursorTxt.border = true;
addChild(supportsCursorTxt);

addEventListener (MouseEvent.CLICK, getScreenKeyboardType);

function getScreenKeyboardType(e:MouseEvent):void{
    supportsCursorTxt.text= "Supports Cursor is : " + String(flash.ui.Mouse.supportsCursor);

}

if(Mouse.supportsCursor) {
    //Game acts as before
} else {
    if(Capabilities.touchscreenType == TouchscreenType.STYLUS ){
        //The Game has to change so that the character is chasing the location of the stylus as 
        //it's dragged around. Some of the animations will have to change
    }else if(Capabilities.touchscreenType = TouchscreenType.FINGER){
        //Same as above, except that the hit-area is larger for a finger.
    }else{
        //There's no pointing device at all. The developer designs some sort of custom cursor to 
        //be controlled with key presses or similar input
    }
}

Geeft aan of de huidige configuratie ondersteuning biedt voor native cursors.

Hiermee wordt de aanwijzer verborgen. De aanwijzer is standaard zichtbaar.

Opmerking: U hoeft Mouse.hide() slechts eenmaal aan te roepen, ongeacht het aantal eerdere aanroepen van Mouse.show().

Verwante API-elementen

Registreert een native cursor onder de opgegeven naam en met de opgegeven gegevens.

Parameters

Hiermee wordt de aanwijzer weergegeven. De aanwijzer is standaard zichtbaar.

Opmerking: U hoeft Mouse.show() slechts eenmaal aan te roepen, ongeacht het aantal eerdere aanroepen van Mouse.hide().

Verwante API-elementen

Hiermee wordt de registratie van de opgegeven naam van de native cursor ongedaan gemaakt.

Parameters

1. Declareer de volgende instanties van eigenschappen: cursor van het type CustomCursor, child van het type CustomButton en gutter van het type uint.
2. Wijs child toe aan een nieuwe instantie CustomButton, stel de x- en y-coördinaten elk op 10 pixels in en voeg vervolgens de instantie toe aan het weergaveoverzicht. De klasse CustomButton overschrijft de eigenschappen downState, upState, overState en hitTestState in SimpleButton. Elk van deze eigenschappen instantieert een object ButtonDisplayState, dat een verschillend vierkant tekent, afhankelijk van de status van de instantie child.
3. De instantie child wordt dan gebruikt om een gebeurtenislistener MOUSE_OVER en een listenermethode mouseOverHandler() toe te voegen, samen met een gebeurtenislistener MOUSE_OUT en een gekoppelde methode mouseOutHandler().
4. De gebeurtenislisteners werken als volgt:
   • mouseOverHandler: verbergt de 'normale' aanwijzer en voegt een listener MOUSE_MOVE toe, die de muisbewegingen verwerkt met mouseMoveHandler(), zoals hieronder wordt beschreven.
   • mouseOutHandler: als de muis buiten de aangepaste knop beweegt, wordt de 'normale' aanwijzer getoond, de gebeurtenislistener MOUSE_MOVE wordt verwijderd en de zichtbaarheid van de aangepaste cursor wordt ingesteld op false.
   • mouseMoveHandler: beweegt de aangepaste cursor naar waar de aanwijzer wordt verplaatst en stelt de zichtbaarheid van de aangepaste cursor in op true.
5. In de constructor MouseExample wordt de cursoreigenschap aan een nieuw object CustomCursor toegewezen en vervolgens aan het weergaveoverzicht toegevoegd met addChild(). De klasse CustomCursor tekent een klein, bijna zwart vierkant op de plaats van de 'normale' aanwijzer als de muis zich boven child bevindt.
6. Een vierde gebeurtenislistener van type MOUSE_LEAVE wordt toegevoegd met de gekoppelde methode mouseLeaveHandler(). In deze methode (die wordt aangeroepen als de muis het werkgebied verlaat), wordt aan mouseOutHandler() een nieuw listenerobject mouseMove doorgegeven, die de aanwijzer verwijdert, zodat deze niet achterblijft in het werkgebied.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.ui.Mouse;
    import flash.events.*;

    public class MouseExample extends Sprite {
         private var cursor:CustomCursor;
         private var child:CustomButton;
         private var gutter:uint = 10;

        public function MouseExample() {
            child = new CustomButton();
            child.x = gutter;
            child.y = gutter;
            addChild(child);

            child.addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
            child.addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);

            cursor = new CustomCursor();
            addChild(cursor);

            stage.addEventListener(Event.MOUSE_LEAVE, mouseLeaveHandler);
        }

        private function mouseOverHandler(event:MouseEvent):void {
            trace("mouseOverHandler");
            Mouse.hide();
            child.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function mouseOutHandler(event:MouseEvent):void {
            trace("mouseOutHandler");
            Mouse.show();
            child.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            cursor.visible = false;
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            cursor.x = event.localX;
            cursor.y = event.localY;
            event.updateAfterEvent();
            cursor.visible = true;
        }

        private function mouseLeaveHandler(event:Event):void {
            trace("mouseLeaveHandler");
            mouseOutHandler(new MouseEvent(MouseEvent.MOUSE_MOVE));
        }
    }
}

import flash.display.Shape;
import flash.display.SimpleButton;
    
class CustomButton extends SimpleButton {
    var upColor:uint = 0xFFCC00;
    var overColor:uint = 0xCCFF00;
    var downColor:uint = 0x00CCFF;
    var size:uint = 80;
    
    public function CustomButton() {
        downState = new ButtonDisplayState(downColor, size+10);
        overState = new ButtonDisplayState(overColor, size);
        upState = new ButtonDisplayState(upColor, size);
        hitTestState = new ButtonDisplayState(upColor, size);
    }
}

class ButtonDisplayState extends Shape {
    var bgColor:uint;
    var size:uint;
    
    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size = size;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}
    
class CustomCursor extends Shape {
    var bgColor:uint = 0x333333;
    var size:uint = 10;
    
    public function CustomCursor() {
        visible = false;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}