MouseEvent  - AS3

Geeft aan of de Alt-toets actief (true) of inactief (false) is. Alleen ondersteuning voor Windows. Op andere besturingssystemen is deze eigenschap altijd ingesteld op false.

Geeft aan of de primaire muisknop wel (true) of niet (false) is ingedrukt.

Geeft aan of het indrukken van de muisknop al dan niet onderdeel is van een reeks muisklikken. Deze parameter is nul voor alle muisgebeurtenissen, behalve voor MouseEvent.mouseDown, MouseEvent.mouseUp, MouseEvent.middleMouseDown, MouseEvent.middleMouseUp, MouseEvent.rightMouseDown en MouseEvent.rightMouseUp. Luisteren naar een enkele klik, dubbelklikken of een reeks klikken is mogelijk met de parameter clickCount. Zo hebben een eerste MouseEvent.mouseDown en MouseEvent.mouseUp een clickCount met de waarde 1. De tweede MouseEvent.mouseDown en MouseEvent.mouseUp in een dubbelklikreeks hebben een clickCount met de waarde 2. Als de muis voldoende beweegt of als de multiklikreeks om welke reden dan ook wordt onderbroken, heeft de volgende MouseEvent.mouseDown een clickCount met waarde 1. De doubleClick-gebeurtenis wordt verder voortgezet zoals wordt verwacht.

Geeft aan of de Command-toets is geactiveerd (alleen Macintosh).

De waarde van de eigenschap commandKey heeft dezelfde waarde als eigenschap ctrlKey op de Macintosh. Altijd false voor Windows of Linux.

Hiermee wordt aangegeven of de Control-toets actief is op de Mac en of de Ctrl-toets actief is voor Windows of Linux.

In Windows of Linux wordt hiermee aangegeven of de Ctrl-toets actief (true) of inactief (false) is. Op de Macintosh wordt aangegeven of de Control- of Command-toets is geactiveerd.

Geeft aan hoeveel regels moeten worden verschoven wanneer de gebruiker het muiswiel draait. Een positieve waarde voor delta geeft een verschuiving naar boven aan, een negatieve waarde geeft een verschuiving naar beneden aan. Gangbare waarden zijn 1 tot en met 3, maar sneller draaien kan tot lagere waarden leiden. Deze instelling hangt af van het apparaat en het besturingssysteem en kan meestal door de gebruiker worden geconfigureerd. Deze eigenschap is alleen van toepassing op de gebeurtenis MouseEvent.mouseWheel.

Als de waarde true wordt geretourneerd, is de eigenschap relatedObject ingesteld op null vanwege redenen die te maken hebben met beveiligingssandboxen. Als de nominale waarde van relatedObject een verwijzing is naar een DisplayObject in een andere sandbox, wordt relatedObject ingesteld op null, tenzij er toestemming is de grens van deze sandbox in beide richtingen te overschrijden. Deze toestemming kan worden ingesteld door Security.allowDomain() aan te roepen vanuit een SWF-bestand of door vanaf de server een beleidsbestand beschikbaar te stellen voor een afbeeldingsbestand. In dat geval moet de eigenschap LoaderContext.checkPolicyFile worden ingesteld tijdens het laden van de afbeelding.

Verwante API-elementen

Wanneer de muisvergrendeling is uitgeschakeld is dit de horizontale coördinaat waar de gebeurtenis heeft plaatsgevonden ten opzichte van de omvattende sprite. Schakel de muisvergrendeling uit door de waarde van Stage.mouseLock in te stellen op false.

Wanneer de muisvergrendeling is ingeschakeld, is de waarde van localX en localY gelijk aan 0. Met movementX en movementY kunt u bepalen hoe de positie van de muis is veranderd. Hiervoor moet de muisvergrendeling zijn ingeschakeld.

Verwante API-elementen

Wanneer de muisvergrendeling is uitgeschakeld is dit de verticale coördinaat waar de gebeurtenis heeft plaatsgevonden ten opzichte van de omvattende sprite. Schakel de muisvergrendeling uit door de waarde van Stage.mouseLock in te stellen op false.

Wanneer de muisvergrendeling is ingeschakeld, is de waarde van localX en localY gelijk aan 0. Met movementX en movementY kunt u bepalen hoe de positie van de muis is veranderd. Hiervoor moet de muisvergrendeling zijn ingeschakeld.

Verwante API-elementen

Wanneer de muisvergrendeling is ingeschakeld, is dit de mate waarin de muis in de richting van de X-as is verplaatst sinds de laatste muisgebeurtenis. Schakel de muisvergrendeling in door de waarde van Stage.mouseLock in te stellen op true.

Wanneer de muisvergrendeling is ingeschakeld:

• localX en localY bevatten 0.
• movementX en movementY bevatten deltawaarden.
• movementX en movementY worden nooit getransformeerd op basis van werkgebiedtransformatie. Dit betekent dat de waarden van deze eigenschappen altijd binnen de schermcoördinaten vallen.

movementX en movementY zijn 0 wanneer Stage.mouseLock is ingesteld op de waarde false.

Verwante API-elementen

Wanneer de muisvergrendeling is ingeschakeld, is dit de mate waarin de muis in de richting van de Y-as is verplaatst sinds de laatste muisgebeurtenis. Schakel de muisvergrendeling in door de waarde van Stage.mouseLock in te stellen op true.

Wanneer de muisvergrendeling is ingeschakeld:

• localX en localY bevatten 0.
• movementX en movementY bevatten deltawaarden.
• movementX en movementY worden nooit getransformeerd op basis van werkgebiedtransformatie. Dit betekent dat de waarden van deze eigenschappen altijd binnen de schermcoördinaten vallen.

movementX en movementY zijn 0 wanneer Stage.mouseLock is ingesteld op de waarde false.

Verwante API-elementen

Een verwijzing naar een weergaveoverzichtobject dat betrekking heeft op de gebeurtenis. Wanneer bijvoorbeeld een gebeurtenis mouseOut plaatsvindt, vertegenwoordigt relatedObject het weergaveoverzichtobject waar het aanwijsapparaat nu naar wijst. Deze eigenschap is van toepassing op de gebeurtenissen mouseOut, mouseOver, rollOut en rollOver.

De waarde van deze eigenschap kan in twee gevallen null zijn: als er geen verwant object is of als er wel sprake is van een verwant object maar dit object zich in een beveiligingssandbox bevindt waartoe u geen toegang hebt. Gebruik de eigenschap isRelatedObjectInaccessible() om vast te stellen welke van deze redenen van toepassing is.

Verwante API-elementen

Geeft aan of de Shift-toets actief (true) of inactief (false) is.

De horizontale coördinaat waar de gebeurtenis heeft plaatsgevonden in algemene werkgebiedcoördinaten. Deze eigenschap wordt berekend wanneer de eigenschap localX is ingesteld.

De verticale coördinaat waar de gebeurtenis heeft plaatsgevonden in algemene werkgebiedcoördinaten. Deze eigenschap wordt berekend wanneer de eigenschap localY is ingesteld.

Maakt een Event-object dat informatie bevat over muisgebeurtenissen. Gebeurtenisobjecten worden als parameters aan gebeurtenislisteners doorgegeven.

Maakt een kopie van het object MouseEvent en stelt de waarde van elke eigenschap in zodat deze overeenkomt met die van het origineel.

Retourneert een tekenreeks die alle eigenschappen van het object MouseEvent bevat. De tekenreeks heeft de volgende indeling:

[MouseEvent type= value bubbles= value cancelable= value ... delta= value ]

Instrueert Flash Player of Adobe AIR te renderen nadat de verwerking van deze gebeurtenis is voltooid, als het weergaveoverzicht is gewijzigd.

Definieert de waarde van de eigenschap type van een gebeurtenisobject click.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

De constante MouseEvent.CONTEXT_MENU bevat de waarde van de eigenschap type van een contextMenu-gebeurtenisobject.

Deze gebeurtenis heeft de volgende eigenschappen:

Definieert de waarde van de eigenschap type van een gebeurtenisobject doubleClick. De eigenschap doubleClickEnabled moet true zijn voor een object opdat de doubleClick-gebeurtenis wordt gegenereerd.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een middleClick-gebeurtenisobject.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een middleMouseDown.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een middleMouseUp-gebeurtenisobject.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een gebeurtenisobject mouseDown.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een gebeurtenisobject mouseMove.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;

    public class MouseEvent_MOUSE_MOVEExample extends Sprite {
        private var innerRect:Sprite = new Sprite();
        
        public function MouseEvent_MOUSE_MOVEExample() {

            graphics.lineStyle(3, 0xFF0000, 1);
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            innerRect.graphics.lineStyle(1, 0x00FF00, 1);
            innerRect.graphics.beginFill(0xFFFFFF);
            innerRect.graphics.drawRect(10, 10, 200, 200);
            innerRect.graphics.endFill();
            innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
            innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
            addChild(innerRect);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            graphics.moveTo(event.stageX, event.stageY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }
    
        private function mouseMoveHandler(event:MouseEvent):void {
            graphics.lineTo(event.stageX, event.stageY);
        }    
    
        private function mouseUpHandler(event:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function innerRectMouseDownHandler(event:MouseEvent):void {
            innerRect.graphics.moveTo(event.localX, event.localY);
            innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    
        private function innerRectMouseMoveHandler(event:MouseEvent):void {
            innerRect.graphics.lineTo(event.localX, event.localY);
        }    
    
        private function innerRectMouseUpHandler(event:MouseEvent):void {
            innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    }
}

Definieert de waarde van de eigenschap type van een gebeurtenisobject mouseOut.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een gebeurtenisobject mouseOver.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een gebeurtenisobject mouseUp.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een gebeurtenisobject mouseWheel.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de type-eigenschap van een releaseOutside-gebeurtenisobject.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een gebeurtenisobject rightClick.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert waarde van de eigenschap type van een gebeurtenisobject rightMouseDown.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een rightMouseUp-gebeurtenisobject.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een gebeurtenisobject rollOut.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Definieert de waarde van de eigenschap type van een gebeurtenisobject rollOver.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

1. In het voorbeeld worden eigenschappen voor de grootte (100 x 100 pixels) en de achtergrondkleur (oranje) gedeclareerd, om later te gebruiken wanneer het vierkant wordt getekend.
2. De constructor maakt een nieuw object ChildSprite met de naam child. Zijn constructor tekent eerst een oranje vierkant van 100 x 100 pixels op de coördinaten (0,0) door de methode draw() aan te roepen en vervolgens 7 gebeurtenislisteners/-abonnees toe te voegen.
   • click / clickHandler(): wordt verzonden wanneer een gebruiker éénmaal met de linkermuisknop boven het vierkant klikt.
   • doubleClick / doubleClickHandler(): wordt verzonden wanneer een gebruiker met de linkermuisknop dubbelklikt boven het vierkant.
   • mouseDown / mouseDownHandler(): wanneer het object ChildSprite (het oranje vierkant wordt aangeklikt, wordt een meldingtrace() op het scherm afgedrukt en vervolgens wordt ChildSprite.draw() aangeroepen, dat een donkergeel vierkant op de plaats van het lichtblauwe tekent in mouseOverHandler(). De methode mouseDownHandler() voegt ook een gebeurtenislistener mouseMove en de abonnee mouseMoveHandler() (zie hieronder) toe, die de muisbewegingen verwerkt. methode startDrag() aangeroepen, die mogelijk maakt dat het object Sprite wordt versleept.
   • mouseOut / mouseOutHandler(): wordt verzonden wanneer de aanwijzer het vierkant verlaat. De methode draw() wordt aangeroepen om het vierkant de normale grootte en kleur terug te geven.
   • mouseOver / mouseOverHandler(): wordt verzonden wanneer de muisaanwijzer zich boven het vierkant bevindt. Met deze methode wordt het vierkant opnieuw getekend zodat het groter is en de achtergrondkleur ervan donkergeel is.
   • mouseUp / mouseUpHandler(): Wanneer de muisknop wordt losgelaten, wordt de gebeurtenislistener mouseMove verwijderd en stopDrag aangeroepen, dat het vierkant op de plaats vastzet.
   • mouseMove/mouseMoveHandler(): Wordt aangeroepen als onderdeel van de functie mouseDownHandler(), en wordt verzonden wanneer de gebruiker op de linkermuisknop drukt en een vierkant tekent.
   • mouseWheel / mouseWheelHandler(): wordt verzonden wanneer de gebruiker aan het muiswiel draait boven het vierkant.
3. De instantie ChildSprite child wordt vervolgens toegevoegd aan het weergaveoverzicht door middel van addChild(), die onmiddellijk het oranje vierkant tekent.

Opmerkingen:

• De klasse MouseEventExample zou de basis van het document moeten zijn.
• Sommige gebeurtenismethoden die hierboven zijn vermeld, declareren een lokale variabele sprite, waaraan de cast van event.target naar het type Sprite wordt toegewezen.

package {
    import flash.display.Sprite;

    public class MouseEventExample extends Sprite {
        private var size:uint = 100;
        private var bgColor:uint = 0xFFCC00;

        public function MouseEventExample() {
            var child:ChildSprite = new ChildSprite();
            addChild(child);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
    private var size:uint = 50;
    private var overSize:uint = 60;
    private var backgroundColor:uint = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;

    public function ChildSprite() {
        draw(size, size, backgroundColor);
            doubleClickEnabled = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
        addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
        addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
        addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
    }

    private function draw(w:uint, h:uint, bgColor:uint):void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler");
    }

    private function doubleClickHandler(event:MouseEvent):void {
        trace("doubleClickHandler");
    }

    private function mouseDownHandler(event:MouseEvent):void {
        trace("mouseDownHandler");
        draw(overSize, overSize, downColor);

        var sprite:Sprite = Sprite(event.target);
        sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.startDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
        trace("mouseMoveHandler");
        event.updateAfterEvent();
    }

    private function mouseOutHandler(event:MouseEvent):void {
        trace("mouseOutHandler");
        draw(size, size, backgroundColor);
    }

    private function mouseOverHandler(event:MouseEvent):void {
        trace("mouseOverHandler");
        draw(overSize, overSize, overColor);
    }

    private function mouseWheelHandler(event:MouseEvent):void {
        trace("mouseWheelHandler delta: " + event.delta);
    }

    private function mouseUpHandler(event:MouseEvent):void {
        trace("mouseUpHandler");
        var sprite:Sprite = Sprite(event.target);
        sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.stopDrag();
        draw(overSize, overSize, overColor);
    }
}