BitmapData  - AS3

De hoogte van de bitmapafbeelding in pixels.

De rechthoek die de grootte en de locatie van de bitmapafbeelding definieert. De boven- en linkerkant van de rechthoek zijn 0; de breedte en hoogte zijn gelijk aan de breedte en hoogte in pixels van het object BitmapData.

Definieert of de bitmapafbeelding transparantie per pixel ondersteunt. U kunt deze waarde alleen instellen wanneer u een object BitmapData maakt door true door te geven voor de parameter transparent van de constructor. Wanneer u vervolgens een object BitmapData maakt, kunt u controleren of het object transparantie per pixel ondersteunt. De waarde van de eigenschap transparent moet in dat geval true zijn.

De breedte van de bitmapafbeelding in pixels.

Maakt een object BitmapData met een opgegeven breedte en hoogte. Wanneer u een waarde opgeeft voor de parameter fillColor, wordt elke pixel in de bitmap op die kleur ingesteld.

De bitmap wordt standaard transparant gemaakt, tenzij u de waarde false doorgeeft voor de parameter transparent. Wanneer u een dekkende bitmap maakt, kunt u deze niet in een transparante bitmap wijzigen. Elke pixel in een dekkende bitmap gebruikt alleen 24-bits kleurkanaalinformatie. Wanneer u de bitmap definieert als transparant, gebruikt elke pixel 32-bits kleurkanaalinformatie, inclusief een alpha-transparantiekanaal.

In AIR 1.5 en Flash Player 10 is de maximale grootte voor een object BitmapData 8,191 pixels breed of hoog en mag het totale aantal pixels niet groter zijn dan 16,777,215 pixels. (Als een object BitmapData 8,191 pixels breed is, kan het daarom slechts 2048 pixels hoog zijn.) In Flash Player 9 en lager en AIR 1.1 en lager is de maximale hoogte 2880 pixels en de maximale breedte 2880 pixels. Wanneer u een waarde width of height opgeeft die groter is dan 2880, wordt geen nieuwe instantie gemaakt.

Maakt een gefilterde afbeelding van een bronafbeelding en een filterobject.

Deze methode is afhankelijk van het gedrag van ingebouwde filterobjecten waarmee wordt bepaald welke doelrechthoek door een invoerbronrechthoek wordt beïnvloed.

Nadat een filter is toegepast, kan de resulterende afbeelding groter zijn dan de invoerafbeelding. Wanneer u bijvoorbeeld een klasse BlurFilter gebruikt om een bronrechthoek (50,50,100,100) en een bestemmingspunt (10,10) te vervagen, is het gebied dat in de doelafbeelding verandert groter dan (10,10,60,60) als gevolg van het vervagen. Dit gebeurt intern tijdens de aanroep van applyFilter().

Wanneer de parameter sourceRect van de parameter sourceBitmapData een intern gebied is, zoals (50,50,100,100) in een afbeelding van 200 x 200, gebruikt het filter de bronpixels buiten de parameter sourceRect om de doelrechthoek te genereren.

Wanneer het object BitmapData en het object dat als de parameter sourceBitmapData is opgegeven hetzelfde object zijn, wordt in de toepassing een tijdelijke kopie van het object gebruikt om het filter uit te voeren. Voor optimale prestaties moet u deze situatie voorkomen.

Parameters

Verwante API-elementen

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.filters.BlurFilter;

var bmd:BitmapData = new BitmapData(80, 30, false, 0xFFCC00);
var rect:Rectangle = new Rectangle(10, 10, 40, 10);
bmd.fillRect(rect, 0xFF0000);

var pt:Point = new Point(10, 10);
var filter:BlurFilter = new BlurFilter();
bmd.applyFilter(bmd, rect, pt, filter);

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Retourneert een nieuw object BitmapData dat een kloon is van de oorspronkelijke instantie met een exacte kopie van de betreffende bitmap.

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd1:BitmapData = new BitmapData(100, 80, false, 0x00000000);
var bmd2:BitmapData = bmd1.clone();

bmd1.setPixel32(1, 1, 0xFFFFFFFF);

trace(bmd1.getPixel32(1, 1).toString(16)); // ffffffff
trace(bmd2.getPixel32(1, 1).toString(16)); // ff000000

var bm1:Bitmap = new Bitmap(bmd1);
this.addChild(bm1);

var bm2:Bitmap = new Bitmap(bmd2);
bm2.x = 110;
this.addChild(bm2);

Past de kleurwaarden in een opgegeven gebied van een bitmapafbeelding aan met een object ColorTransform. Wanneer de zijden van de rechthoek overeenkomen met de grenzen van de bitmapafbeelding, worden de kleurwaarden van de hele afbeelding met deze methode getransformeerd.

Parameters

Verwante API-elementen

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.ColorTransform;

var bmd:BitmapData = new BitmapData(80, 30, false, 0xFF0000);

var cTransform:ColorTransform = new ColorTransform();
cTransform.alphaMultiplier = 0.5
var rect:Rectangle = new Rectangle(0, 0, 40, 30);
bmd.colorTransform(rect, cTransform);

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Vergelijkt twee objecten BitmapData. Wanneer de twee objecten BitmapData dezelfde afmetingen (breedte en hoogte) hebben, retourneert de methode een nieuw object BitmapData waarin elke pixel is gebaseerd op het 'verschil' tussen de pixels in de twee bronobjecten.

• Wanneer twee pixels overeenkomen, is de verschilpixel 0x00000000.
• Wanneer twee pixels verschillende RGB-waarden hebben (de alpha-waarde wordt genegeerd), is de verschilpixel 0xRRGGBB. Hierbij staan RR/GG/BB voor de afzonderlijke verschillen tussen de waarden van rode, groene en blauwe kanalen (de pixelwaarde in het bronobject min de pixelwaarde in het object otherBitmapData). In dit geval worden alpha-kanaalverschillen genegeerd.
• Wanneer alleen de alpha-kanaalwaarde afwijkt, is de pixelwaarde 0xZZFFFFFF, waarbij ZZ staat voor het verschil in de alpha-waarden (de alpha-waarde in het bronobject min de alpha-waarde in het object otherBitmapData).

Bekijk bijvoorbeeld de volgende twee objecten BitmapData:

     var bmd1:BitmapData = new BitmapData(50, 50, true, 0xFFFF8800);
     var bmd2:BitmapData = new BitmapData(50, 50, true, 0xCCCC6600);
     var diffBmpData:BitmapData = bmd1.compare(bmd2) as BitmapData;
     trace ("0x" + diffBmpData.getPixel(0,0).toString(16); // 0x332200
     

Opmerking: de kleuren waarmee de twee objecten BitmapData zijn gevuld, hebben iets afwijkende RGB-waarden (0xFF0000 en 0xFFAA00). Het resultaat van de methode compare() is een nieuw object BitmapData waarbij elke pixel het verschil in de RGB-waarden tussen de twee bitmaps aangeeft.

Bekijk de volgende twee objecten BitmapData waarin de RGB-kleuren overeenkomen, maar de alpha-waarden verschillen:

     var bmd1:BitmapData = new BitmapData(50, 50, true, 0xFFFFAA00);
     var bmd2:BitmapData = new BitmapData(50, 50, true, 0xCCFFAA00);
     var diffBmpData:BitmapData = bmd1.compare(bmd2) as BitmapData;
     trace ("0x" + diffBmpData.getPixel32(0,0).toString(16); // 0x33ffffff
     

Het resultaat van de methode compare() is een nieuw object BitmapData waarbij elke pixel het verschil in de alpha-waarden tussen de twee bitmaps aangeeft.

Wanneer de objecten BitmapData equivalent zijn (met dezelfde breedte, hoogte en identieke pixelwaarden), retourneert de methode het getal 0.

Wanneer de objecten BitmapData verschillende breedten hebben, retourneert de methode het getal -3.

Wanneer de objecten BitmapData verschillende hoogten hebben, maar wel dezelfde breedte, retourneert de methode het getal -4.

In het volgende voorbeeld worden twee objecten Bitmap met verschillende breedten (50 en 60) vergeleken:

     var bmd1:BitmapData = new BitmapData(100, 50, false, 0xFFFF0000);
     var bmd2:BitmapData = new BitmapData(100, 60, false, 0xFFFFAA00);
     trace(bmd1.compare(bmd2)); // -4
     

Parameters

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd1:BitmapData = new BitmapData(50, 50, true, 0xFFFFAA00);
var bmd2:BitmapData = new BitmapData(50, 50, true, 0xCCFFAA00);
var diffBmpData:BitmapData = BitmapData(bmd1.compare(bmd2));
var diffValue:String = diffBmpData.getPixel32(1, 1).toString(16);
trace (diffValue); // 33ffffff

var bm1:Bitmap = new Bitmap(bmd1);
addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
addChild(bm2);
bm2.x = 60;

Hiermee worden gegevens overgedragen van een kanaal van een ander object BitmapData of het huidige object BitmapData naar een kanaal van het huidige object BitmapData. Alle gegevens in de andere kanalen in het doelobject BitmapData blijven behouden.

De bronkanaalwaarde en de doelkanaalwaarde kunnen een van de volgende waarden zijn:

• BitmapDataChannel.RED
• BitmapDataChannel.GREEN
• BitmapDataChannel.BLUE
• BitmapDataChannel.ALPHA

Parameters

Verwante API-elementen

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd:BitmapData = new BitmapData(100, 80, false, 0x00FF0000);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
var pt:Point = new Point(10, 10);
bmd.copyChannel(bmd, rect, pt, BitmapDataChannel.RED, BitmapDataChannel.BLUE);

var bm:Bitmap = new Bitmap(bmd);
this.addChild(bm);    

Biedt een snelle routine voor pixelmanipulatie tussen afbeeldingen zonder uitrek-, rotatie- of kleureffecten. Deze methode kopieert een rechthoekig gebied van een bronafbeelding naar een rechthoekig gebied met dezelfde grootte op het bestemmingspunt van het doelobject BitmapData.

Wanneer u de parameters alphaBitmap en alphaPoint opneemt, kunt u een secundaire afbeelding als een alpha-bron voor de bronafbeelding gebruiken. Wanneer de bronafbeelding alpha-gegevens bevat, worden beide sets alpha-gegevens gebruikt om pixels van de bronafbeelding voor de doelafbeelding samen te stellen. De parameter alphaPoint is het punt in de alpha-afbeelding dat overeenkomt met de linkerbovenhoek van de bronafbeelding. Pixels buiten het doorsnedegebied van de bronafbeelding en alpha-afbeelding worden niet naar de doelafbeelding gekopieerd.

De eigenschap mergeAlpha bepaalt of het alpha-kanaal wordt gebruikt wanneer een transparante afbeelding naar een andere transparante afbeelding wordt gekopieerd. Wanneer u pixels met de alpha-kanaalgegevens wilt kopiëren, stelt u de eigenschap mergeAlpha in op true. Standaard is de eigenschap mergeAlpha op false ingesteld.

Parameters

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd1:BitmapData = new BitmapData(40, 40, false, 0x000000FF);
var bmd2:BitmapData = new BitmapData(80, 40, false, 0x0000CC44);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
var pt:Point = new Point(10, 10);
bmd2.copyPixels(bmd1, rect, pt);

var bm1:Bitmap = new Bitmap(bmd1);
this.addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
this.addChild(bm2);
bm2.x = 50;

Vult een bytearray uit een rechthoekig gebied met pixelgegevens. Vanaf de position-index van de ByteArray schrijft deze methode voor elke pixel een geheel getal zonder teken (een niet-vermenigvuldigde 32-bits pixelwaarde) in de bytearray. Indien nodig, wordt de grootte van de bytearray aangepast aan het aantal bytes dat nodig is om alle pixels op te nemen.

Parameters

Verwante API-elementen

Maakt geheugen vrij dat voor opslag van het object BitmapData wordt gebruikt.

Wanneer de methode dispose() voor een afbeelding wordt aangeroepen, worden de breedte en hoogte van de afbeelding op 0 ingesteld. Alle volgende aanroepen van methoden of eigenschappen van deze instantie BitmapData mislukken en er wordt een uitzondering gegenereerd.

BitmapData.dispose() geeft direct geheugen vrij dat bezet wordt door werkelijke bitmapgegevens (een bitmap kan maximaal 64 MB geheugen consumeren). Nadat u BitmapData.dispose() gebruikt, is het BitmapData-object niet meer bruikbaar en de Flash-runtime geeft een uitzondering weer als u functies oproept in het BitmapData-object. BitmapData.dispose() verzamelt geen ongewenste details van het BitmapData-object (ongeveer 128 bytes); het geheugen dat wordt bezet door het werkelijke BitmapData-object, wordt vrijgegeven wanneer het BitmapData-object door de verzamelaar van ongewenste details verzameld.

Verwante API-elementen

import flash.display.BitmapData;

var myBitmapData:BitmapData = new BitmapData(100, 80, false, 0x000000FF);
trace(myBitmapData.getPixel(1, 1)); // 255 == 0xFF

myBitmapData.dispose();
try {
    trace(myBitmapData.getPixel(1, 1));
} catch (error:Error) {
    trace(error); // ArgumentError
}

Tekent het bronweergaveobject op een bitmapafbeelding met de vectorrendermodule van Flash-runtime. U kunt de parameters matrix, colorTransform, blendMode en de doelparameter clipRect opgeven om te bepalen hoe de rendering wordt uitgevoerd. U kunt ook opgeven of de bitmap vloeiend moet worden gemaakt wanneer deze wordt geschaald (dit werkt alleen wanneer het bronobject een object BitmapData is).

Opmerking: De methodedrawWithQuality() werkt precies zoals de methode draw(), maar in plaats van de eigenschap Stage.quality te gebruiken om de vectorrenderingkwaliteit te bepalen, geeft u de parameter quality op voor de methode drawWithQuality().

Deze methode houdt rechtstreeks verband met de wijze waarop objecten worden getekend met de standaardvectorrendermodule voor objecten in de ontwerpgereedschapinterface.

Het bronweergaveobject gebruikt geen van de toegepaste transformaties voor deze aanroep. Het object wordt gebruikt zoals het in de bibliotheek of het bestand bestaat, zonder matrixtransformatie, zonder kleurtransformatie en zonder overvloeimodus. Wanneer u een weergaveobject (zoals een filmclip) wilt tekenen op basis van de eigen transformatie-eigenschappen, kunt u het eigenschapsobject transform kopiëren naar de eigenschap transform van het object Bitmap dat het object BitmapData gebruikt.

Deze methode wordt ondersteund via RTMP in Flash Player 9.0.115.0 en hoger en in Adobe AIR. U kunt toegang tot streams op Flash Media Server beheren in een serverscript. Zie de eigenschappen Client.audioSampleAccess en Client.videoSampleAccess in Server-Side ActionScript Language Reference for Adobe Flash Media Server voor meer informatie.

Als het bronobject en (in het geval van een object Sprite of MovieClip) alle onderliggende objecten ervan niet uit hetzelfde domein als de aanroeper komen of zich niet in een bestand bevinden dat door de aanroeper kan worden benaderd door de methode Security.allowDomain() aan te roepen, genereert een aanroep van draw() een SecurityError-fout. Deze beperking is niet van toepassing op AIR-inhoud in de beveiligingssandbox van de toepassing.

Er gelden ook beperkingen bij het gebruik van een geladen bitmapafbeelding als de source. Een aanroep van de methode draw() is geslaagd als de geladen afbeelding afkomstig is uit hetzelfde domein als de aanroeper. Een bestand met interdomeinbeleid op de server van de afbeelding kan het domein ook toegang verlenen tot het domein van de SWF-inhoud die de methode draw() aanroept. In dit geval moet u de eigenschap checkPolicyFile van een object LoaderContext instellen en dit object gebruiken als de parameter context bij het aanroepen van de methode load() van het object Loader waarmee de afbeelding wordt geladen. Deze beperkingen zijn niet van toepassing op AIR-inhoud in de beveiligingssandbox van de toepassing.

In Windows kan de methode draw() geen SWF-inhoud vastleggen die is ingesloten in een HTML-pagina in een object HTMLLoader in Adobe AIR.

De methode draw() kan geen PDF-inhoud vastleggen in Adobe AIR. De methode kan ook geen SWF-inhoud vastleggen die is ingesloten in HTML waarin het kenmerk wmode is ingesteld op window in Adobe AIR.

Parameters

Verwante API-elementen

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.text.TextField;

var tf:TextField = new TextField();
tf.text = "bitmap text";

var myBitmapData:BitmapData = new BitmapData(80, 20);
myBitmapData.draw(tf);
var bmp:Bitmap = new Bitmap(myBitmapData);
this.addChild(bmp);

Tekent het bronweergaveobject op een bitmapafbeelding met de vectorrendermodule van Flash-runtime. U kunt de parameters matrix, colorTransform, blendMode en de doelparameter clipRect opgeven om te bepalen hoe de rendering wordt uitgevoerd. U kunt ook opgeven of de bitmap vloeiend moet worden gemaakt wanneer deze wordt geschaald (dit werkt alleen wanneer het bronobject een object BitmapData is).

Opmerking: De methodedrawWithQuality() werkt precies zoals de methode draw(), maar in plaats van de eigenschap Stage.quality te gebruiken om de vectorrenderingkwaliteit te bepalen, geeft u de parameter quality op voor de methode drawWithQuality().

Deze methode houdt rechtstreeks verband met de wijze waarop objecten worden getekend met de standaardvectorrendermodule voor objecten in de ontwerpgereedschapinterface.

Het bronweergaveobject gebruikt geen van de toegepaste transformaties voor deze aanroep. Het object wordt gebruikt zoals het in de bibliotheek of het bestand bestaat, zonder matrixtransformatie, zonder kleurtransformatie en zonder overvloeimodus. Wanneer u een weergaveobject (zoals een filmclip) wilt tekenen op basis van de eigen transformatie-eigenschappen, kunt u het eigenschapsobject transform kopiëren naar de eigenschap transform van het object Bitmap dat het object BitmapData gebruikt.

Deze methode wordt ondersteund via RTMP in Flash Player 9.0.115.0 en hoger en in Adobe AIR. U kunt toegang tot streams op Flash Media Server beheren in een serverscript. Zie de eigenschappen Client.audioSampleAccess en Client.videoSampleAccess in de Server-Side ActionScript Language Reference for Adobe Flash Media Server voor meer informatie.

Als het bronobject en (in het geval van een object Sprite of MovieClip) alle bijbehorende onderliggende objecten niet uit hetzelfde domein als de aanroeper komen of zich niet in een bestand bevinden dat door de aanroeper kan worden benaderd door de methode Security.allowDomain() aan te roepen, genereert een aanroep van drawWithQuality() een SecurityError-fout. Deze beperking is niet van toepassing op AIR-inhoud in de beveiligingssandbox van de toepassing.

Er gelden ook beperkingen bij het gebruik van een geladen bitmapafbeelding als de source. Een aanroep van de methode drawWithQuality() is geslaagd als de geladen afbeelding afkomstig is uit hetzelfde domein als de aanroeper. Een bestand met interdomeinbeleid op de server van de afbeelding kan het domein ook toegang verlenen tot het domein van de SWF-inhoud die de methode drawWithQuality() aanroept. In dit geval moet u de eigenschap checkPolicyFile van een object LoaderContext instellen en dit object gebruiken als de parameter context bij het aanroepen van de methode load() van het object Loader waarmee de afbeelding wordt geladen. Deze beperkingen zijn niet van toepassing op AIR-inhoud in de beveiligingssandbox van de toepassing.

In Windows kan de methode drawWithQuality() geen SWF-inhoud vastleggen die is ingesloten in een HTML-pagina in een object HTMLLoader in Adobe AIR.

De methode drawWithQuality() kan geen PDF-inhoud vastleggen in Adobe AIR. De methode kan ook geen SWF-inhoud vastleggen die is ingesloten in HTML waarin het kenmerk wmode is ingesteld op window in Adobe AIR.

Parameters

Verwante API-elementen

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.text.TextField;

var tf:TextField = new TextField();
tf.text = "bitmap text";

var myBitmapData:BitmapData = new BitmapData(80, 20);
myBitmapData.drawWithQuality(tf, , , , , , StageQuality.LOW);
var bmp:Bitmap = new Bitmap(myBitmapData);
this.addChild(bmp);

Hiermee wordt dit BitmapData-object gecomprimeerd met het geselecteerde compressoralgoritme, waarna een nieuw ByteArray-object wordt geretourneerd. Optioneel worden de resulterende gegevens naar de opgegeven ByteArray geschreven. Met het argument compressor wordt het coderingsalgoritme aangeduid. Dit kan PNGEncoderOptions, JPEGEncoderOptions of JPEGXREncoderOptions zijn.

In het volgende voorbeeld wordt een BitmapData-object gecomprimeerd met de volgende JPEGEncoderOptions:

     // Compress a BitmapData object as a JPEG file.
     var bitmapData:BitmapData = new BitmapData(640,480,false,0x00FF00);
     var byteArray:ByteArray = new ByteArray();
     bitmapData.encode(new Rectangle(0,0,640,480), new flash.display.JPEGEncoderOptions(), byteArray); 

Parameters

Verwante API-elementen

Vult een rechthoekig gebied van pixels met een opgegeven ARGB-kleur.

Parameters

Verwante API-elementen

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var myBitmapData:BitmapData = new BitmapData(40, 40, false, 0x0000FF00);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
myBitmapData.fillRect(rect, 0x0000FF);

var bm:Bitmap = new Bitmap(myBitmapData);
addChild(bm);

Voert een vlakvulling uit op een afbeelding, beginnend bij een (x, y)-coördinaat en vullend met een bepaalde kleur. De methode floodFill() is vergelijkbaar met het emmertje dat beschikbaar is in verscheidene tekenprogramma's. De kleur is een ARGB-kleur die alpha- en kleurinformatie bevat.

Parameters

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var myBitmapData:BitmapData = new BitmapData(40, 40, false, 0x0000FF00);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
myBitmapData.fillRect(rect, 0x000000FF);
rect = new Rectangle(15, 15, 25, 25);
myBitmapData.fillRect(rect, 0x000000FF);

myBitmapData.floodFill(10, 10, 0x00FF0000);

var bm:Bitmap = new Bitmap(myBitmapData);
addChild(bm);

Bepaalt welke doelrechthoek door de aanroep van de methode applyFilter() wordt beïnvloed, op basis van een object BitmapData, een bronrechthoek en een filterobject.

Een vervagend filter beïnvloedt bijvoorbeeld doorgaans een gebied dat groter is dan de oorspronkelijke afbeelding. Een afbeelding van 100 x 200 pixels die door een standaardinstantie van BlurFilter wordt gefilterd, waarbij blurX = blurY = 4, genereert een doelrechthoek van (-2,-2,104,204). Met de methode generateFilterRect() kunt u de grootte van deze doelrechthoek vooraf achterhalen, zodat u de juiste grootte van de doelafbeelding kunt bepalen voordat u een filterbewerking uitvoert.

Sommige filters snijden de doelrechthoek uit op basis van de grootte van de bronafbeelding. Met DropShadow wordt bijvoorbeeld geen resultaat gegenereerd dat groter is dan de bronafbeelding. In deze API wordt het object BitmapData gebruikt voor de brongrenzen, niet voor de bronparameter rect.

Parameters

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.filters.BlurFilter;

var bmd:BitmapData = new BitmapData(80, 30, false, 0xFFCC00);
var rect:Rectangle = new Rectangle(10, 10, 40, 10);
bmd.fillRect(rect, 0xFF0000);

var pt:Point = new Point(10, 10);
var filter:BlurFilter = new BlurFilter();

trace(bmd.generateFilterRect(rect, filter));
// (x=8, y=8, w=44, h=14)

bmd.applyFilter(bmd, rect, pt, filter);
var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Bepaalt een rechthoekig gebied dat alle pixels van een opgegeven kleur binnen de bitmapafbeelding volledig omvat (wanneer de parameter findColor op true is ingesteld) of alle pixels die niet van de opgegeven kleur zijn (wanneer de parameter findColor op false is ingesteld).

Wanneer u voor een bronafbeelding bijvoorbeeld de rechthoek van de afbeelding wilt bepalen die een alpha-kanaal met een andere waarde dan nul bevat, geeft u {mask: 0xFF000000, color: 0x00000000} door als parameters. Wanneer de parameter findColor op true is ingesteld, wordt de gehele afbeelding doorzocht op de grenzen van pixels waarvoor geldt: (value & mask) == color (waarbij value de kleurwaarde van de pixel is). Wanneer de parameter findColor op false is ingesteld, wordt de gehele afbeelding doorzocht op de grenzen van pixels waarvoor geldt: (value & mask) != color (waarbij value de kleurwaarde van de pixel is). Wanneer u de witruimte rondom een afbeelding wilt bepalen, geeft u {mask: 0xFFFFFFFF, color: 0xFFFFFFFF} door om de grenzen van niet-witte pixels te vinden.

Parameters

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var bmd:BitmapData = new BitmapData(80, 40, false, 0xFFFFFF);
var rect:Rectangle = new Rectangle(0, 0, 80, 20);
bmd.fillRect(rect, 0xFF0000);

var maskColor:uint = 0xFFFFFF; 
var color:uint = 0xFF0000;  
var redBounds:Rectangle = bmd.getColorBoundsRect(maskColor, color, true);
trace(redBounds); // (x=0, y=0, w=80, h=20)

var notRedBounds:Rectangle = bmd.getColorBoundsRect(maskColor, color, false);
trace(notRedBounds); // (x=0, y=20, w=80, h=20)

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Retourneert een geheel getal dat een RGB-pixelwaarde van een object BitmapData op een specifiek punt (x, y) vertegenwoordigt. De methode getPixel() retourneert een niet-vermenigvuldigde pixelwaarde. Er wordt geen alpha-informatie geretourneerd.

Alle pixels in een object BitmapData worden als vooraf vermenigvuldigde kleurwaarden opgeslagen. Bij een vooraf vermenigvuldigde afbeeldingspixel zijn de rode, groene en blauwe kleurkanaalwaarden al door de alpha-gegevens vermenigvuldigd. Wanneer de alpha-waarde bijvoorbeeld 0 is, zijn de waarden voor de RGB-kanalen ook 0, onafhankelijk van de niet-vermenigvuldigde waarden. Dit verlies van gegevens kan problemen veroorzaken wanneer u bewerkingen uitvoert. Alle BitmapData-methoden gebruiken en retourneren niet-vermenigvuldigde waarden. De interne pixelrepresentatie wordt omgezet van vooraf vermenigvuldigd in niet vermenigvuldigd voordat deze als een waarde wordt geretourneerd. Tijdens het instellen wordt de pixelwaarde vooraf vermenigvuldigd voordat de onbewerkte afbeeldingspixel wordt ingesteld.

Parameters

Verwante API-elementen

import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 40, false, 0xFF0000);

var pixelValue:uint = bmd.getPixel(0, 0);
trace(pixelValue.toString(16)); // ff0000;

Retourneert een ARGB-kleurwaarde die alpha-kanaal- en RGB-gegevens bevat. Deze methode is vergelijkbaar met de methode getPixel(), waarmee een RGB-kleur zonder alpha-kanaalgegevens wordt geretourneerd.

Alle pixels in een object BitmapData worden als vooraf vermenigvuldigde kleurwaarden opgeslagen. Bij een vooraf vermenigvuldigde afbeeldingspixel zijn de rode, groene en blauwe kleurkanaalwaarden al door de alpha-gegevens vermenigvuldigd. Wanneer de alpha-waarde bijvoorbeeld 0 is, zijn de waarden voor de RGB-kanalen ook 0, onafhankelijk van de niet-vermenigvuldigde waarden. Dit verlies van gegevens kan problemen veroorzaken wanneer u bewerkingen uitvoert. Alle BitmapData-methoden gebruiken en retourneren niet-vermenigvuldigde waarden. De interne pixelrepresentatie wordt omgezet van vooraf vermenigvuldigd in niet vermenigvuldigd voordat deze als een waarde wordt geretourneerd. Tijdens het instellen wordt de pixelwaarde vooraf vermenigvuldigd voordat de onbewerkte afbeeldingspixel wordt ingesteld.

Parameters

Verwante API-elementen

import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 40, true, 0xFF44AACC);

var pixelValue:uint = bmd.getPixel32(0, 0);
var alphaValue:uint = pixelValue >> 24 & 0xFF;
var red:uint = pixelValue >> 16 & 0xFF;
var green:uint = pixelValue >> 8 & 0xFF;
var blue:uint = pixelValue & 0xFF;

trace(alphaValue.toString(16)); // ff
trace(red.toString(16)); // 44
trace(green.toString(16)); // aa
trace(blue.toString(16)); // cc

Genereert een bytearray uit een rechthoekig gebied met pixelgegevens. Schrijft voor elke pixel een geheel getal zonder teken (een niet-vermenigvuldigde 32-bits pixelwaarde) in de bytearray.

Parameters

Verwante API-elementen

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.utils.ByteArray;

var bmd:BitmapData = new BitmapData(80, 40, true);
var seed:int = int(Math.random() * int.MAX_VALUE);
bmd.noise(seed);

var bounds:Rectangle = new Rectangle(0, 0, bmd.width, bmd.height);
var pixels:ByteArray = bmd.getPixels(bounds);

Hiermee wordt een vectorarray gegenereerd uit een rechthoekig gebied met pixelgegevens. Retourneert een Vector-object voor de opgegeven rechthoek dat bestaat uit gehele getallen zonder teken (een 32-bits, niet-vermenigvuldigde pixelwaarde).

Parameters

Berekent een histogram met binaire 256-waarde getallen van een BitmapData-object. Deze methode retourneert een Vector-object dat vier andere Vector-objecten bevat.<Number> instanties (vier Vector-objecten die Number-objecten bevatten). De vier Vector-instanties geven respectievelijk de rode, groene, blauwe en alfa componenten aan. Elke Vector-instantie bevat 256 waarden die het aantal elementen van een afzonderlijke componentwaarde voorstelt - een waarde tussen 0 en 255.

Parameters

Voert raakdetectie op pixelniveau uit tussen een bitmapafbeelding en een punt, rechthoek of andere bitmapafbeelding. Een hit wordt gedefinieerd als overlapping van een punt of rechthoek op een dekkende pixel of twee overlappende dekkende pixels. Wanneer de aanraaktest wordt uitgevoerd, wordt geen rekening gehouden met uitrek-, rotatie- of andere transformatiebewerkingen van de objecten.

Wanneer een afbeelding dekkend is, wordt deze afbeelding voor deze methode als een volledig dekkende rechthoek beschouwd. Beide afbeeldingen moeten transparant zijn om een aanraakdetectietest op pixelniveau te kunnen uitvoeren waarbij rekening wordt gehouden met transparantie. Wanneer u twee transparante afbeeldingen test, bepalen de parameters van de alpha-drempel welke alpha-kanaalwaarden, van 0 tot en met 255, als dekkend worden beschouwd.

Parameters

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd1:BitmapData = new BitmapData(80, 80, true, 0x00000000);
var rect:Rectangle = new Rectangle(20, 20, 40, 40);
bmd1.fillRect(rect, 0xFF0000FF);

var pt1:Point = new Point(1, 1);
trace(bmd1.hitTest(pt1, 0xFF, pt1)); // false
var pt2:Point = new Point(40, 40);
trace(bmd1.hitTest(pt1, 0xFF, pt2)); // true

Vergrendelt een afbeelding zodanig dat alle objecten die verwijzen naar het object BitmapData, zoals objecten Bitmap, niet worden bijgewerkt wanneer dit object BitmapData verandert. Gebruik deze methode met de methode unlock() voor en na verscheidene aanroepen van de methode setPixel() of setPixel32() om de prestaties te verbeteren.

Verwante API-elementen

import flash.display.BitmapData;

var bitmapData:BitmapData = picture.bitmapData;
bitmapData.lock();
bitmapData = complexTransformation(bitmapData);
bitmapData.unlock();
picture.bitmapData = bitmapData;

Voert overvloeiing per kanaal uit van een bronafbeelding naar een doelafbeelding. Voor elk kanaal en elke pixel wordt een nieuwe waarde berekend op basis van de kanaalwaarden van de bron- en doelpixels. In het rode kanaal wordt de nieuwe waarde bijvoorbeeld als volgt berekend (waarbij redSrc de waarde van het rode kanaal voor een pixel in de bronafbeelding is en redDest de waarde van het rode kanaal voor de overeenkomstige pixel in de doelafbeelding):

new redDest = [(redSrc * redMultiplier) + (redDest * (256 - redMultiplier))] / 256;

De waarden voor redMultiplier, greenMultiplier, blueMultiplier en alphaMultiplier zijn de vermenigvuldigingsfactoren die voor elk kleurkanaal worden gebruikt. Gebruik een hexadecimale waarde variërend van 0 tot 0x100 (256) waarbij 0 aangeeft dat de volledige waarde van het doel in het resultaat wordt gebruikt, 0x100 aangeeft dat de volledige waarde van de bron in het resultaat wordt gebruikt en de getallen hiertussen aangeven dat een overvloeikleur wordt gebruikt (zoals 0x80 voor 50%).

Parameters

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd1:BitmapData = new BitmapData(100, 80, true, 0xFF00FF00);
var bmd2:BitmapData = new BitmapData(100, 80, true, 0xFFFF0000);
var rect:Rectangle = new Rectangle(0, 0, 20, 20);
var pt:Point = new Point(20, 20);
var mult:uint = 0x80; // 50% 
bmd1.merge(bmd2, rect, pt, mult, mult, mult, mult);

var bm1:Bitmap = new Bitmap(bmd1);
addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
addChild(bm2);
bm2.x = 110;

Vult een afbeelding met pixels die willekeurige ruis vertegenwoordigen.

Parameters

Verwante API-elementen

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.BitmapDataChannel;

var bmd1:BitmapData = new BitmapData(80, 80);
var bmd2:BitmapData = new BitmapData(80, 80);

var seed:int = int(Math.random() * int.MAX_VALUE);
bmd1.noise(seed, 0, 0xFF, BitmapDataChannel.RED, false);
bmd2.noise(seed, 0, 0xFF, BitmapDataChannel.RED, true);

var bm1:Bitmap = new Bitmap(bmd1);
this.addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
this.addChild(bm2);
bm2.x = 90;

Wijst de kleurkanaalwaarden opnieuw toe in een afbeelding met maximaal vier arrays kleurenpaletgegevens, één voor elk kanaal.

Flash-runtimes gebruiken de volgende stappen om de resulterende afbeelding te genereren:

1. Nadat de rode, groene, blauwe en alpha-waarden zijn berekend, worden ze bij elkaar gevoegd op basis van een standaardberekening voor 32-bits gehele getallen.
2. De rode, groene, blauwe en alpha-kanaalwaarden van elke pixel worden geëxtraheerd tot afzonderlijke waarden 0 tot en met 255. Deze waarden worden gebruikt om nieuwe kleurwaarden in de betreffende array op te zoeken: redArray, greenArray, blueArray en alphaArray. Elk van deze vier arrays moet 256 waarden bevatten.
3. Nadat alle vier de nieuwe kanaalwaarden zijn opgehaald, worden deze gecombineerd tot een standaard-ARGB-waarde die op de pixel wordt toegepast.

Interkanaaleffecten kunnen met deze methode worden ondersteund. Elke invoerarray kan volledige 32-bits waarden bevatten en wanneer de waarden bij elkaar worden gevoegd, vinden er geen verschuivingen plaats. Deze routine ondersteunt geen vastklemming per kanaal.

Wanneer geen array voor een kanaal wordt opgegeven, wordt het kleurkanaal uit de bronafbeelding naar de doelafbeelding gekopieerd.

U kunt deze methode voor diverse effecten gebruiken, zoals algemene palettoewijzing (waarbij een kanaal wordt geselecteerd en omgezet in een afbeelding met valse kleuren). U kunt deze methode ook gebruiken voor diverse geavanceerde kleurmanipulatieberekeningen, zoals gamma, curven, niveaus en kwantisering.

Parameters

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var myBitmapData:BitmapData = new BitmapData(80, 80, false, 0x00FF0000);
myBitmapData.fillRect(new Rectangle(20, 20, 40, 40), 0x0000FF00);

var redArray:Array = new Array(256);
var greenArray:Array = new Array(256);

for(var i:uint = 0; i < 255; i++) {
    redArray[i] = 0x00000000;
    greenArray[i] = 0x00000000;
}

redArray[0xFF] = 0x0000FF00;
greenArray[0xFF] = 0x00FF0000;

var bottomHalf:Rectangle = new Rectangle(0, 0, 100, 40);
var pt:Point = new Point(0, 0);
myBitmapData.paletteMap(myBitmapData, bottomHalf, pt, redArray, greenArray);

var bm1:Bitmap = new Bitmap(myBitmapData);
addChild(bm1);

Genereert een Perlin-ruisafbeelding.

Het generatiealgoritme van Perlin-ruis interpoleert en combineert afzonderlijke willekeurige ruisfuncties (octaven genoemd) tot een enkele functie die een meer natuurlijk aandoende willekeurige ruis genereert. Net als bij octaven in muziek, is elke octaaffunctie twee keer de frequentie van de voorafgaande functie. Perlin-ruis wordt omschreven als een ‘fractale som van ruis’, omdat het meerdere sets ruisgegevens met verschillende detailniveaus combineert.

U kunt Perlin-ruisfuncties gebruiken om natuurverschijnselen en landschappen te simuleren, zoals houtstructuur, wolken en bergketens. In de meeste gevallen wordt de uitvoer van een Perlin-ruisfunctie niet direct weergegeven maar wordt deze gebruikt om andere beelden te versterken en er pseudo-willekeurige variaties aan te geven.

Eenvoudige digitale willekeurige ruisfuncties leveren vaak beelden op met harde, contrasterende punten. Dit type hard contrast komt in de natuur niet vaak voor. Het Perlin-ruisalgoritme laat meerdere ruisfuncties in elkaar overvloeien die op verschillende detailniveaus werken. Dit algoritme resulteert in kleinere variaties tussen naastgelegen pixelwaarden.

Parameters

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(200, 200, false, 0x00CCCCCC);

var seed:Number = Math.floor(Math.random() * 10);
var channels:uint = BitmapDataChannel.RED | BitmapDataChannel.BLUE;
bmd.perlinNoise(100, 80, 6, seed, false, true, channels, false, null);

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Voert een pixelovervloeiing uit van een bronafbeelding naar een doelafbeelding of op dezelfde afbeelding. Flash-runtimes gebruiken een waarde voor randomSeed om een willekeurige pixelovervloeiing te genereren. De geretourneerde waarde van de functie moet bij volgende aanroepen worden doorgegeven om de pixelovervloeiing voort te zetten totdat deze is voltooid.

Wanneer de bronafbeelding niet overeenkomt met de doelafbeelding, worden alle eigenschappen gebruikt bij het kopiëren van de pixels van de bron- naar de doelafbeelding. Met dit proces is overvloeiing van een lege afbeelding naar een volledig gevulde afbeelding mogelijk.

Wanneer de bron- en doelafbeelding overeenkomen, worden pixels met de parameter color gevuld. Met dit proces is overvloeiing op basis van een volledig gevulde afbeelding mogelijk. In deze modus wordt de doelparameter point genegeerd.

Parameters

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.utils.Timer;
import flash.events.TimerEvent;

var bmd:BitmapData = new BitmapData(100, 80, false, 0x00CCCCCC);
var bitmap:Bitmap = new Bitmap(bmd);
addChild(bitmap);

var tim:Timer = new Timer(20);
tim.start();
tim.addEventListener(TimerEvent.TIMER, timerHandler);
 
function timerHandler(event:TimerEvent):void {
    var randomNum:Number = Math.floor(Math.random() * int.MAX_VALUE);
    dissolve(randomNum);
}

function dissolve(randomNum:Number):void {
    var rect:Rectangle = bmd.rect;
    var pt:Point = new Point(0, 0);
    var numberOfPixels:uint = 100;
    var red:uint = 0x00FF0000;
    bmd.pixelDissolve(bmd, rect, pt, randomNum, numberOfPixels, red);
    var grayRegion:Rectangle = bmd.getColorBoundsRect(0xFFFFFFFF, 0x00CCCCCC, true);
    if(grayRegion.width == 0 && grayRegion.height == 0 ) {
        tim.stop();
    }
}

Schuift een afbeelding met een bepaald aantal pixels (x, y). Randgebieden buiten het schuifgebied blijven ongewijzigd.

Parameters

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var bmd:BitmapData = new BitmapData(80, 80, true, 0xFFCCCCCC);
var rect:Rectangle = new Rectangle(0, 0, 40, 40);
bmd.fillRect(rect, 0xFFFF0000);
            
var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

trace (bmd.getPixel32(50, 20).toString(16)); // ffcccccccc

bmd.scroll(30, 0); 

trace (bmd.getPixel32(50, 20).toString(16)); // ffff0000

Stelt een enkele pixel van een object BitmapData in. De huidige alpha-kanaalwaarde van de afbeeldingspixel blijft tijdens deze bewerking behouden. De waarde van de RGB-kleurparameter wordt behandeld als een niet-vermenigvuldigde kleurwaarde.

Opmerking: wanneer u de prestaties wilt verbeteren en u de methode setPixel() of setPixel32() herhaaldelijk gebruikt, roept u de methode lock() aan voordat u de methode setPixel() of setPixel32() aanroept en roept u de methode unlock() aan wanneer u alle pixelwijzigingen hebt doorgevoerd. Op deze manier voorkomt u dat objecten die naar de instantie BitmapData verwijzen, al worden bijgewerkt voordat u de pixelwijzigingen hebt doorgevoerd.

Parameters

Verwante API-elementen

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 80, false, 0xCCCCCC);

for (var i:uint = 0; i < 80; i++) {
    var red:uint = 0xFF0000;
    bmd.setPixel(i, 40, red);
}

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Stelt de kleur- en alpha-transparantiewaarden van een enkele pixel van een object BitmapData in. Deze methode is vergelijkbaar met de methode setPixel(). Het belangrijkste verschil is dat bij de methode setPixel32() een ARGB-kleurwaarde wordt gebruikt die alpha-kanaalgegevens bevat.

Alle pixels in een object BitmapData worden als vooraf vermenigvuldigde kleurwaarden opgeslagen. Bij een vooraf vermenigvuldigde afbeeldingspixel zijn de rode, groene en blauwe kleurkanaalwaarden al door de alpha-gegevens vermenigvuldigd. Wanneer de alpha-waarde bijvoorbeeld 0 is, zijn de waarden voor de RGB-kanalen ook 0, onafhankelijk van de niet-vermenigvuldigde waarden. Dit verlies van gegevens kan problemen veroorzaken wanneer u bewerkingen uitvoert. Alle BitmapData-methoden gebruiken en retourneren niet-vermenigvuldigde waarden. De interne pixelrepresentatie wordt omgezet van vooraf vermenigvuldigd in niet vermenigvuldigd voordat deze als een waarde wordt geretourneerd. Tijdens het instellen wordt de pixelwaarde vooraf vermenigvuldigd voordat de onbewerkte afbeeldingspixel wordt ingesteld.

Opmerking: wanneer u de prestaties wilt verbeteren en u de methode setPixel() of setPixel32() herhaaldelijk gebruikt, roept u de methode lock() aan voordat u de methode setPixel() of setPixel32() aanroept en roept u de methode unlock() aan wanneer u alle pixelwijzigingen hebt doorgevoerd. Op deze manier voorkomt u dat objecten die naar de instantie BitmapData verwijzen, al worden bijgewerkt voordat u de pixelwijzigingen hebt doorgevoerd.

Parameters

Verwante API-elementen

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 80, true, 0xFFCCCCCC);

for (var i:uint = 0; i < 80; i++) {
    var red:uint = 0x60FF0000;
    bmd.setPixel32(i, 40, red);
}

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Zet een bytearray om in een rechthoekig gebied met pixelgegevens. Voor elke pixel wordt de methode ByteArray.readUnsignedInt() aangeroepen en wordt de geretourneerde waarde in de pixel geschreven. Wanneer de bytearray eindigt voordat de volledige rechthoek is geschreven, genereert de functie een uitzondering. Van de gegevens in de bytearray wordt verwacht dat het 32-bits ARGB-pixelwaarden zijn. Voor- of nadat de pixels zijn gelezen, worden geen zoekbewerkingen op de bytearray uitgevoerd.

Parameters

Verwante API-elementen

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.utils.ByteArray;
import flash.geom.Rectangle;

var bmd1:BitmapData = new BitmapData(100, 100, true, 0xFFCCCCCC);
var bmd2:BitmapData = new BitmapData(100, 100, true, 0xFFFF0000);

var rect:Rectangle = new Rectangle(0, 0, 100, 100);
var bytes:ByteArray = bmd1.getPixels(rect);

bytes.position = 0;
bmd2.setPixels(rect, bytes);

var bm1:Bitmap = new Bitmap(bmd1);
addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
addChild(bm2);
bm2.x = 110;

Zet een Vector om in een rechthoekig gebied met pixelgegevens. Voor elke pixel wordt een Vectorelement in de BitmapData-pixel gelezen en geschreven. Van de gegevens in de Vector wordt verwacht dat het 32-bits ARGB-pixelwaarden zijn.

Parameters

Test pixelwaarden in een afbeelding op basis van een opgegeven drempel en stelt nieuwe kleurwaarden in voor pixels die aan de test voldoen. Met de methode threshold() kunt u kleurbereiken in een afbeelding isoleren en vervangen en andere logische bewerkingen op afbeeldingspixels uitvoeren.

De methode threshold() gebruikt de volgende testlogica:

1. Bij ((pixelValue & mask) operation (threshold & mask)) stelt u de pixel in op color;
2. Bij copySource == true stelt u de pixel in op de overeenkomende pixelwaarde van sourceBitmap.

Met de parameter operation wordt de vergelijkingsparameter opgegeven die voor de drempeltest moet worden gebruikt. Wanneer u '==' als de parameter operation gebruikt, kunt u een bepaalde kleurwaarde in een afbeelding isoleren. En wanneer u {operation: "<", mask: 0xFF000000, threshold: 0x7F000000, color: 0x00000000} gebruikt, kunt u alle doelpixels zo instellen dat ze volledig transparant zijn wanneer de alpha van de pixels van de bronafbeelding kleiner is dan 0x7F. U kunt deze techniek voor bewegende overgangen en andere effecten gebruiken.

Parameters

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.BitmapDataChannel;
import flash.geom.Point;
import flash.geom.Rectangle;

var bmd1:BitmapData = new BitmapData(200, 200, true, 0xFFCCCCCC);

var seed:int = int(Math.random() * int.MAX_VALUE);
var channels:uint = BitmapDataChannel.RED | BitmapDataChannel.BLUE;
bmd1.perlinNoise(100, 80, 12, seed, false, true, channels, false, null);

var bitmap1:Bitmap = new Bitmap(bmd1);
addChild(bitmap1);

var bmd2:BitmapData = new BitmapData(200, 200, true, 0xFFCCCCCC);
var pt:Point = new Point(0, 0);
var rect:Rectangle = new Rectangle(0, 0, 200, 200);
var threshold:uint =  0x00800000; 
var color:uint = 0x20FF0000;
var maskColor:uint = 0x00FF0000;
bmd2.threshold(bmd1, rect, pt, ">", threshold, color, maskColor, true);

var bitmap2:Bitmap = new Bitmap(bmd2);
bitmap2.x = bitmap1.x + bitmap1.width + 10;
addChild(bitmap2);

Ontgrendelt een afbeelding zodanig dat alle objecten die verwijzen naar het object BitmapData, zoals objecten Bitmap, worden bijgewerkt wanneer dit object BitmapData verandert. Gebruik deze methode met de methode lock() voor en na verscheidene aanroepen van de methode setPixel() of setPixel32() om de prestaties te verbeteren.

Parameters

Verwante API-elementen

import flash.display.BitmapData;

var bitmapData:BitmapData = picture.bitmapData;
bitmapData.lock();
bitmapData = complexTransformation(bitmapData);
bitmapData.unlock();
picture.bitmapData = bitmapData;

1. De eigenschap url, de locatie en naam van het afbeeldingsbestand, wordt gemaakt.
2. Met de klasseconstructor wordt een object Loader gemaakt dat een gebeurtenislistener instantieert die wordt verzonden wanneer de methode completeHandler() de beeldbewerking voltooit.
3. Het URLRequest-object request wordt vervolgens doorgegeven aan loader.load() waarmee de afbeelding met een weergaveobject in het geheugen wordt geladen.
4. De afbeelding wordt opgenomen in het weergaveoverzicht waar de afbeelding op de coördinaten x = 0, y = 0 op het scherm wordt weergegeven.
5. Met de methode completeHandler() worden vervolgens de volgende handelingen uitgevoerd:
   • Naast een object Bitmap wordt een tweede object Loader gemaakt dat met het object Loader wordt geïnitialiseerd.
   • Er wordt een tweede object Bitmap, duplicate, gemaakt waarmee de methode duplicateImage() wordt aangeroepen om een kopie van de oorspronkelijke afbeelding te maken.
   • Er wordt een object BitmapData gemaakt dat aan het object BitmapData van het object duplicate wordt toegewezen.
   • Er wordt een nieuw object Rectangle met dezelfde coördinaten, breedte en hoogte als de oorspronkelijke afbeelding gemaakt.
   • Er wordt een nieuw object Point met de standaardcoördinaten x = 0, y = 0 gemaakt.
   • De volgende variabelen worden gemaakt:
     • operation — Hiermee wordt de nieuwe kleur toegepast wanneer de drempelwaarde groter dan of gelijk is aan de oorspronkelijke waarde.
     • threshold — De waarde op basis waarvan elke pixel wordt vergeleken (in dit voorbeeld lichtgrijs met een alpha van 0xCC).
     • color — De kleur waarop de pixels zijn ingesteld die de drempeltest doorstaan, in dit geval effen geel.
     • mask — De tegenovergestelde kleur (transparant blauw).
     • copySource — Op false ingesteld om aan te geven dat de pixelwaarden niet worden gekopieerd wanneer de drempelwaarde niet wordt gehaald. Deze waarde heeft geen betekenis omdat de afbeelding wordt gedupliceerd en alleen pixels die de drempelwaarde halen, worden gewijzigd.
   • De methode threshold() wordt met de voorgaande variabelen aangeroepen. Voor de resulterende drempelwaarde wordt de volgende vergelijking gebruikt: wanneer (huidige pixelwaarde & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF), worden pixels op 0xFFFFFF00 ingesteld.

Opmerkingen:

• U moet het SWF-bestand compileren met Lokale afspeelbeveiliging ingesteld op Alleen lokale bestanden benaderen.
• U kunt dit voorbeeld alleen uitvoeren wanneer het bestand Image.gif zich in dezelfde map bevindt als uw SWF-bestand.
• U kunt het beste een afbeelding van ongeveer 80 pixels breed gebruiken.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapDataExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapDataExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}