ColorMatrixFilter  - AS3

Array van 20 items voor 4 x 5 kleurtransformatie. U kunt de eigenschap matrix niet wijzigen door de waarde ervan rechtstreeks te wijzigen (bijvoorbeeld myFilter.matrix[2] = 1;). U moet in plaats hiervan een verwijzing naar de array maken, de wijziging in de verwijzing doorvoeren en de waarde herstellen.

De kleurmatrixfilter scheidt elke bronpixel in rode, groene, blauwe en alpha-componenten zoals srcR, srcG, srcB en srcA. Wanneer u het resultaat van elk van de vier kanalen wilt berekenen, moet u de waarde van elke pixel in de afbeelding vermenigvuldigen met de waarden in de transformatiematrix. Een verschuiving tussen -255 en 255 kan optioneel aan elk resultaat worden toegevoegd (het vijfde item in elke rij van de matrix). De filter combineert iedere kleurcomponent weer tot een pixel en schrijft het resultaat uit. In de volgende formule komen a[0] tot en met a[19] overeen met de items 0 tot en met 19 in de array van 20 items die wordt doorgegeven aan de eigenschap matrix:

	redResult   = (a[0]  * srcR) + (a[1]  * srcG) + (a[2]  * srcB) + (a[3]  * srcA) + a[4]
	greenResult = (a[5]  * srcR) + (a[6]  * srcG) + (a[7]  * srcB) + (a[8]  * srcA) + a[9]
	blueResult  = (a[10] * srcR) + (a[11] * srcG) + (a[12] * srcB) + (a[13] * srcA) + a[14]
	alphaResult = (a[15] * srcR) + (a[16] * srcG) + (a[17] * srcB) + (a[18] * srcA) + a[19]
	

Voor elke kleurwaarde in de array geldt dat 1 betekent dat 100% van dat kanaal wordt verzonden naar de uitvoer, waardoor de waarde van het kleurkanaal behouden blijft.

De berekeningen worden op niet-vermenigvuldigde kleurwaarden uitgevoerd. Wanneer de invoerafbeelding uit vooraf vermenigvuldigde kleurwaarden bestaat, worden deze waarden automatisch omgezet in niet-vermenigvuldigde kleurwaarden voor deze bewerking.

Er zijn twee geoptimaliseerde modi beschikbaar:

Alleen alpha. Wanneer u een filter aan een matrix doorgeeft die alleen het alpha-component aanpast, zoals hier wordt getoond, optimaliseert het filter de prestaties:

	    1 0 0 0 0
	    0 1 0 0 0
	    0 0 1 0 0
	    0 0 0 N 0  (where N is between 0.0 and 1.0)
	

Snellere versie. Alleen beschikbaar bij processors met een SSE-/Altivec-versneller, zoals Intel ^® Pentium ^® 3 en hoger en Apple ^® G4 en hoger. De versneller wordt gebruikt wanneer het bereik van de vermenigvuldigertermen tussen -15,99 en 15,99 ligt en het bereik van de optellertermen a[4], a[9], a[14] en a[19] binnen het bereik -8000 en 8000 ligt.

Initialiseert een nieuwe instantie ColorMatrixFilter met de opgegeven parameters.

Retourneert een kopie van dit filterobject.

De functie buildChild() maakt een nieuw object Loader met de naam loader. Voor elke aanroep van buildChild() moet u een gebeurtenislistener aan het object Loader koppelen om naar gebeurtenissen complete te luisteren, die worden afgehandeld door de functie die wordt doorgegeven aan buildChild().

De functies applyRed(), applyGreen() enapplyBlue() gebruiken verschillende waarden voor de array matrix om verschillende effecten te bereiken.

Opmerking: gebruik voor het beste resultaat een afbeelding van ongeveer 80 pixels breed. De naam en locatie van het afbeeldingsbestand moet overeenkomen met de waarde die u doorgeeft aan de eigenschap url. De waarde die wordt doorgegeven aan url in het voorbeeld verwijst bijvoorbeeld naar een afbeeldingsbestand met de naam Image.jpg dat zich in dezelfde map bevindt als uw SWF-bestand.

package {
    import flash.display.DisplayObject;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.filters.ColorMatrixFilter;
    import flash.net.URLRequest;

    public class ColorMatrixFilterExample extends Sprite {
        private var size:uint  = 140;
        private var url:String = "Image.jpg";

        public function ColorMatrixFilterExample() {
            buildChild(null);
            buildChild(applyRed);
            buildChild(applyGreen);
            buildChild(applyBlue);
        }

        private function buildChild(loadHandler:Function):void {
            var loader:Loader = new Loader();
            loader.x = numChildren * size;
            loader.y = size;
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            if (loadHandler != null) {
                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadHandler);
            }

            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function applyRed(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([1, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 0, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 0, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyGreen(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([0, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 1, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 0, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyBlue(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([0, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 0, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 1, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyFilter(child:DisplayObject, matrix:Array):void {
            var filter:ColorMatrixFilter = new ColorMatrixFilter(matrix);
            var filters:Array = new Array();
            filters.push(filter);
            child.filters = filters;
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}