Bitmap  - AS3

Het object BitmapData waarnaar wordt verwezen.

Bepaalt of het object Bitmap wordt uitgelijnd naar de dichtstbijzijnde pixel. De klasse PixelSnapping bevat mogelijke waarden:

• PixelSnapping.NEVER — Er vindt geen magnetische pixeluitlijning plaats.
• PixelSnapping.ALWAYS — De afbeelding wordt altijd uitgelijnd naar de dichtstbijzijnde pixel, onafhankelijk van transformatie.
• PixelSnapping.AUTO — De afbeelding wordt uitgelijnd naar de dichtstbijzijnde pixel wanneer deze is getekend zonder rotatie of helling en wanneer deze is getekend met een schaalfactor van 99,9% tot en met 100,1%. Wanneer aan deze voorwaarden wordt voldaan, wordt de bitmapafbeelding getekend op een schaal van 100% en uitgelijnd naar de dichtstbijzijnde pixel. Met deze waarde kan intern de afbeelding zo snel mogelijk worden getekend met de vectorrendermodule.

Bepaalt of de bitmap vloeiend wordt gemaakt wanneer deze wordt geschaald. Indien true, bitmap wordt vloeiend gemaakt wanneer deze wordt geschaald. Indien false, bitmap wordt niet vloeiend gemaakt wanneer deze wordt geschaald.

Initialiseert een object Bitmap om te verwijzen naar het opgegeven object BitmapData.

	bitmapData:BitmapData (default = null) — Het object BitmapData waarnaar wordt verwezen.
	pixelSnapping:String (default = "auto") — Bepaalt of het object Bitmap wordt uitgelijnd naar de dichtstbijzijnde pixel.
	smoothing:Boolean (default = false) — Bepaalt of de bitmap vloeiend wordt gemaakt wanneer deze wordt geschaald. In de volgende voorbeelden wordt bijvoorbeeld aangegeven hoe dezelfde bitmap met factor 3 wordt geschaald wanneer smoothing is ingesteld op false (links) en true (rechts):

const IMAGE_URL:String = "http://www.helpexamples.com/flash/images/logo.png";
 
var ldr:Loader = new Loader();
ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, ldr_complete);
ldr.load(new URLRequest(IMAGE_URL));
 
var bitmap1:Bitmap;
var bitmap2:Bitmap;
var bitmap3:Bitmap;
var bitmap4:Bitmap;
 
function ldr_complete(evt:Event):void {
    var bmp:Bitmap = ldr.content as Bitmap;
 
    bitmap1 = new Bitmap(bmp.bitmapData);
    bitmap1.x = 100;
    bitmap1.y = 100;
    bitmap1.rotation = 0;
    addChild(bitmap1);
 
    bitmap2 = new Bitmap(bmp.bitmapData);
    bitmap2.x = 200;
    bitmap2.y = 100;
    bitmap2.rotation = 90;
    addChild(bitmap2);
 
    bitmap3 = new Bitmap(bmp.bitmapData);
    bitmap3.x = 300;
    bitmap3.y = 100;
    bitmap3.rotation = 180;
    addChild(bitmap3);
 
    bitmap4 = new Bitmap(bmp.bitmapData);
    bitmap4.x = 400;
    bitmap4.y = 100;
    bitmap4.rotation = 270;
    addChild(bitmap4);
}

1. De eigenschap url, de locatie en naam van het afbeeldingsbestand, wordt gemaakt.
2. De klasseconstructor roept de methode configureAssets() aan en deze methode roept de methode completeHandler() aan.
3. configureAssets() maakt een object Loader dat een gebeurtenislistener instantieert die wordt verzonden wanneer de methode completeHandler() de beeldbewerking voltooit.
4. Vervolgens wordt met de methode buildChild() een nieuwe instantie van het URLRequest-object request gemaakt waarbijurl is doorgegeven zodat de bestandsnaam en -locatie bekend zijn.
5. Het object request wordt vervolgens doorgegeven aan de methode loader.load() waarmee de afbeelding via een weergaveobject in het geheugen wordt geladen.
6. De afbeelding wordt opgenomen in het weergaveoverzicht waar de afbeelding direct op de coördinaten x = 0, y = 0 op het scherm wordt weergegeven.
7. Met de methode completeHandler() worden vervolgens de volgende taken uitgevoerd:
   1. Naast een object Bitmap wordt een tweede object Loader gemaakt dat met het object Loader wordt geïnitialiseerd.
   2. Er wordt een tweede object Bitmap, duplicate, gemaakt waarmee de methode duplicateImage() wordt aangeroepen om een kopie van de oorspronkelijke afbeelding te maken.
   3. Er wordt een object BitmapData gemaakt dat aan het object BitmapData van het object duplicate wordt toegewezen.
   4. Er wordt een nieuw object Rectangle met dezelfde coördinaten, breedte en hoogte als de oorspronkelijke afbeelding gemaakt.
   5. Er wordt een nieuw object Point met de standaardcoördinaten x = 0, y = 0 gemaakt.
   6. De volgende variabelen worden gemaakt:
      • operation: past de nieuwe kleur toe wanneer de drempelwaarde groter dan of gelijk is aan de oorspronkelijke waarde.
      • threshold: de waarde op basis waarvan elke pixel wordt vergeleken, wordt ingesteld op lichtgrijs met een alpha van 0xCC.
      • color: de kleur waarop de pixels worden ingesteld die de drempeltest doorstaan, in dit geval effen geel.
      • mask: wordt ingesteld op de tegenovergestelde kleur (transparant blauw).
      • copySource: deze variabele is op false ingesteld om aan te geven dat de pixelwaarden niet worden gekopieerd wanneer de drempelwaarde niet wordt gehaald. Deze waarde heeft geen betekenis omdat de afbeelding wordt gedupliceerd en alleen pixels die de drempelwaarde halen, worden gewijzigd.
   7. Roept de methode threshold() aan met de voorgaande variabelen. Voor de resulterende drempelwaarde wordt de volgende vergelijking gebruikt: wanneer (huidige pixelwaarde & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF), worden pixels op 0xFFFFFF00 ingesteld.

Opmerkingen:

• U moet het SWF-bestand compileren met Lokale afspeelbeveiliging ingesteld op Alleen lokale bestanden benaderen.
• U kunt dit voorbeeld alleen uitvoeren wanneer het bestand Image.gif zich in dezelfde map bevindt als uw SWF-bestand.
• U kunt het beste een afbeelding van maximaal 80 pixels breed gebruiken.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}